[FUNCTION AddLuckItem]
// Syntax:
// ON=@Death
// AddLuckItem {ItemID},{Amount}
// Example:
// AddLuckItem i_ttm_l5,1
REF1=<ATTACKER.MAX>
IF (<REF1.LUCK> <= 100)
   LOCAL.CHANCE = <HVAL (<REF1.LUCK> * 1292) / 100>
ELSEIF (<REF1.LUCK> <= 200)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 100) * 607) / 100) + 1292>
ELSEIF (<REF1.LUCK> <= 300)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 200) * 480) / 100) + 1898>
ELSEIF (<REF1.LUCK> <= 400)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 300) * 412) / 100) + 2378>
ELSEIF (<REF1.LUCK> <= 500)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 400) * 368) / 100) + 2790>
ELSEIF (<REF1.LUCK> <= 600)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 500) * 337) / 100) + 3158>
ELSEIF (<REF1.LUCK> <= 700)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 600) * 312) / 100) + 3495>
ELSEIF (<REF1.LUCK> <= 800)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 700) * 293) / 100) + 3807>
ELSEIF (<REF1.LUCK> <= 900)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 800) * 277) / 100) + 4100>
ELSEIF (<REF1.LUCK> <= 1000)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 900) * 264) / 100) + 4378>
ELSEIF (<REF1.LUCK> <= 1100)
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 1000) * 252) / 100) + 4642>
ELSE
   LOCAL.CHANCE = <HVAL (((<REF1.LUCK> - 1100) * 242) / 100) + 4894>
ENDIF
IF (<R1,10000> <= <LOCAL.CHANCE>)
   SERV.NEWITEM <ARGV[0]>
   IF (<NEW.CAN>&can_i_pile)
      NEW.AMOUNT=<ARGV[1]>
      BOUNCE=<NEW>
   ELSE
      BOUNCE=<NEW>
      IF (<ARGV[1]> > 1)
         FOR <HVAL (<ARGV[1]> - 1)>
            SERV.NEWITEM <ARGV[0]>,1,<UID>
         ENDFOR
      ENDIF
   ENDIF
ENDIF