//// aydın ////
//// kurulum : i_alchemist_pestle yi alchemistlere sattırın , i_gem_magic ide yaratıklara loot ////ekleyin

[itemdef i_alchemist_pestle]
ID=i_mortar_pestle
NAME=mortar and pestle
WEIGHT=1
TYPE=t_script
VALUE=650

ON=@CREATE
COLOR=0482

ON=@CLICK
act.message @0481 for crafting skill potions.

ON=@DCLICK
if (<src.ctag0.alchemyused>>0)
src.sysmessage @,3,1 You must wait perform another action.
return 1
endif
IF ( <TOPOBJ.UID> != <SRC.UID> )
src.SYSMESSAGE @,3,1 The item must be in your pack.
RETURN 1
ENDIF
src.sdialog d_alchemist_pestle
return 1

[DIALOG d_alchemist_pestle]
0, 28
NOMOVE
src.flags |= statf_freeze
resizepic 30 30 2620 740 400
checkertrans 0 0 770 430
dtext 80 60 2100 Which skill you use to crafting the potion?

//kim yazdı lo bunu :d
var.y 100
for 0 13
button 80 <eval <var.y>> 210 211 1 0 <eval <local._for>+1>
dtext 103 <eval <var.y>> 800 <serv.skill.<eval <local._for>>.name>
var.y +=20
endfor

var.y 100
for 14 27
button 250 <eval <var.y>> 210 211 1 0 <eval <local._for>+1>
dtext 273 <eval <var.y>> 800 <serv.skill.<eval <local._for>>.name>
var.y +=20
endfor

var.y 100
for 28 41
button 420 <eval <var.y>> 210 211 1 0 <eval <local._for>+1>
dtext 443 <eval <var.y>> 800 <serv.skill.<eval <local._for>>.name>
var.y +=20
endfor

var.y 100
for 42 54
button 590 <eval <var.y>> 210 211 1 0 <eval <local._for>+1>
dtext 613 <eval <var.y>> 800 <serv.skill.<eval <local._for>>.name>
var.y +=20
endfor

[dialog d_alchemist_pestle button]
ON=0
src.flags &= ~statf_freeze

on 1 55
src.ctag0.alchemyused 1
src.timerf 8 , src.ctag0.alchemyused
var.argn <argn> -1
if (<src.alchemy><118.0)
src.sysmessage @,3,1 You are not a good enough alchemist to make a skill potion.
src.flags &= ~statf_freeze
return 1
endif
IF !( <src.restest 1 i_bottle_empty> )
src.SYSMESSAGE @,3,1 You need an empty bottle to make a skill potion.
src.flags &= ~statf_freeze
RETURN 1
ENDIF
IF !( <src.restest 7 i_gem_magic> )
src.SYSMESSAGE @,3,1 You need 7 magic gems to make a skill potion.
src.flags &= ~statf_freeze
RETURN 1
ENDIF
src.tag.alchemy.skill = "<serv.skill.<eval <var.argn>>.name>"
src.tag.alchemy.color = "<eval <var.argn>>"
if (<src.<src.tag.alchemy.skill>><980)
src.sysmessage @,3,1 You need 98.0 <src.tag.alchemy.skill> skill to make <src.tag.alchemy.skill> potion.
src.flags &= ~statf_freeze
return 1
endif
src.anim 17
src.sound 79
src.timerf 0 , src.sound 79
src.timerf 1 , src.anim 17
src.timerf 1 , src.sound 79
src.timerf 2 , src.sound 79
src.timerf 3 , src.anim 17
src.timerf 3 , src.sound 79
src.timerf 4 , src.sound 79
src.timerf 5 , src.anim 17
src.timerf 5 , src.sound 79
src.timerf 6 , src.f_alchemy_finish

[FUNCTION f_alchemy_finish]
src.flags &= ~statf_freeze
local.chance=<eval <src.alchemy>/4>
IF rand(<eval <local.chance>>)>20.0
src.newitem i_bottle_skill
new.tag.skillname = "<src.tag.alchemy.skill>"
new.tag0.seconds = <eval <src.alchemy>/10>
new.color = "<src.tag.alchemy.color>"
new.more2 = <eval <src.alchemy>/4.0>
new.bounce
src.consume 1 i_bottle_empty
src.consume 3 i_gem_magic
src.emote make a skill potion.
else
src.consume 1 i_bottle_empty
src.consume 3 i_gem_magic
src.emote failed to make the skill potion.
endif

//// ITEM /////

[ITEMDEF i_bottle_skill]
ID=i_bottle_empty
NAME=skill potion
WEIGHT=0.1
TYPE=t_script
VALUE=5000

ON=@CREATE
ATTR=attr_magic

ON=@TOOLTIP
add_tooltip <eval <more2>>.0 <tag.skillname>
add_tooltip <eval <tag0.seconds>> seconds

ON=@DCLICK
IF ( <TOPOBJ.UID> != <SRC.UID> )
src.SYSMESSAGE @,3,1 <name> must be in your pack.
RETURN 1
ENDIF
if (<src.restest 1 i_mem_skillup_potion>)
src.sysmessage @,3,1 You cannot drink another skill potion yet.
return 1
endif
src.anim 19
src.newitem i_mem_skillup_potion
new.tag.skill <tag.skillname>
new.tag.amount <eval <more2>>
new.tag.timerd <eval <tag0.seconds>>
new.equip
src.effect 3,i_fx_BLESS_EFFECT,16,20
if (<amount>>1)
amount -= 1
fix
else
remove
endif
src.newitem i_bottle_empty
new.bounce
return 1

[ITEMDEF i_mem_skillup_potion]
ID=i_gold
TYPE=t_eq_script
NAME=skillup

ON=@Create
color 0480
ATTR=attr_invis|attr_decay

ON=@EQUIP
timer <tag0.timerd>
cont.<tag.skill> += <eval <tag.amount>>0
src.sysmessage @035,3,1 bless effect has been started.

ON=@TIMER
cont.<tag.skill> -= <eval <tag.amount>>0
cont.sysmessage @035,3,1 bless effect has been finished.
REMOVE
RETURN 1

[itemdef i_gem_magic]
ID=i_cannon_ball
NAME=Magic Gem
WEIGHT=1
TYPE=t_script
VALUE=100

ON=@CREATE
COLOR=0481

ON=@DCLICK
return 1