[DIALOG D_INSCRIPTION_ITEM_PROPS]
40, 20
src.closealldialogs
PAGE 0
resizepic 0 0 5054 550 465
checkertrans 10 10 530 445
gumppictiled 10 205 170 45 2624
checkertrans 10 205 170 45
gumppictiled 10 390 365 30 2624
checkertrans 10 390 365 30
gumppictiled 10 285 170 70 2624
checkertrans 10 285 170 70
gumppictiled 10 10 530 30 2624
checkertrans 10 10 530 30
gumppictiled 10 45 160 155 2624
checkertrans 10 45 160 155
gumppictiled 175 45 365 100 2624
checkertrans 175 45 365 100
gumppictiled 175 150 365 100 2624
checkertrans 175 150 365 100
gumppictiled 175 255 365 100 2624
checkertrans 175 255 365 100
gumppictiled 175 360 365 60 2624
checkertrans 175 360 365 60

tilepic 40 60 <SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.ID>

xmfhtmlgumpcolor 190 15 200 35 1044009 0 0 32767 //inscription menu

xmfhtmlgumpcolor 180 55 100 30 1011152 0 0 32767 //item
dhtmlgump 330 55 250 30 0 0 <DEF.BFONT_WHITE><SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.NAME><DEF.BFONTE>
IF (0<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>)
LOCAL.CRAFTCHANCE=<eval <floatval ((<src.inscription>/(<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>/10))*0.75)-0.05>/10000>
LOCAL.EXCEPTIONALCHANCE=<eval <floatval ((<src.inscription>/(<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>/10))*0.75)-0.30>/10000>
ELSE
LOCAL.CRAFTCHANCE=100
LOCAL.EXCEPTIONALCHANCE=100
ENDIF
IF (<LOCAL.CRAFTCHANCE> > 100)
LOCAL.CRAFTCHANCE=100
ENDIF
IF (<LOCAL.EXCEPTIONALCHANCE> > 100)
LOCAL.EXCEPTIONALCHANCE=100
ENDIF

xmfhtmlgumpcolor 180 100 120 30 1044057 0 0 32767 //success chance
dtext 420 100 1153 <FVAL <LOCAL.CRAFTCHANCE>*10>%
xmfhtmlgumpcolor 180 120 120 30 1044058 0 0 32767 //exceptional chance
dtext 420 120 1153 <FVAL <LOCAL.EXCEPTIONALCHANCE>*10>%

dhtmlgump 180 160 250 30 0 0 <DEF.BFONT_WHITE>Inscription<DEF.BFONTE>
dtext 420 160 1153 <FVAL <serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>>
IF (<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.2.val>)
dhtmlgump 180 180 250 30 0 0 <DEF.BFONT_WHITE>Magery<DEF.BFONTE>
dtext 420 180 1153 <FVAL <serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.2.val>>
ENDIF

xmfhtmlgumpcolor 30 260 100 30 1044055 0 0 32767
dhtmlgump 200 260 300 200 0 0 <DEF.BFONT_WHITE><serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.RESMAKE><DEF.BFONTE>

xmfhtmlgumpcolor 30 360 100 30 1044056 0 0 32767

resizepic 10 430 5120 530 23
checkertrans 10 430 530 23

button 20 431 0fae 0fb0 1 0 1
xmfhtmlgumpcolor 55 433 100 30 1044150 0 0 32767 //back

button 320 431 4005 4006 1 0 2
xmfhtmlgumpcolor 355 433 100 30 1044151 0 0 32767 //make now

[DIALOG D_INSCRIPTION_ITEM_PROPS BUTTON]
ON=1
DIALOG d_newcraft_dialog_INSCRIPTION

ON=2
SRC.F_CRAFTITEM_INSCRIPTION

[DIALOG d_newcraft_dialog_INSCRIPTION]
40, 20
src.closealldialogs
PAGE 0
resizepic 0 0 5054 550 465
gumppictiled 10 10 530 30 2624
checkertrans 10 10 530 30
gumppictiled 10 45 160 280 2624
checkertrans 10 45 160 280
gumppictiled 175 45 365 280 2624
checkertrans 175 45 365 280
//////
gumppictiled 10 330 160 40 2624
checkertrans 10 330 160 40
gumppictiled 175 330 365 40 2624
checkertrans 175 330 365 40
gumppictiled 10 375 530 85 2624
checkertrans 10 375 530 85
xmfhtmlgumpcolor 190 15 200 35 1044009 0 0 32767 //inscription menu
xmfhtmlgumpcolor 10 45 150 35 1044010 0 0 32767 //categories

FOR 0 8
xmfhtmlgumpcolor 40 <EVAL 65+(22*<LOCAL._FOR>)> 100 35 <EVAL 1044369+<LOCAL._FOR>> 0 0 32767 //First circle
button 10 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 0 <EVAL <LOCAL._FOR>+2> 1
ENDFOR

xmfhtmlgumpcolor 280 45 150 35 1044011 0 0 32767 //selections
xmfhtmlgumpcolor 20 340 100 35 1044012 0 0 32767 //notices
dhtmlgump 200 330 320 35 0 0 <DEF.BFONT_WHITE><SRC.CTAG.INSCRIPTION.MESSAGE><DEF.BFONTE>

button 290 425 4005 4006 1 0 69
xmfhtmlgumpcolor 325 427 100 35 1044013 0 0 32767 //make last
button 290 400 4005 4006 1 0 10000
IF (!(<SRC.TAG0.MARKITEM>))
xmfhtmlgumpcolor 325 402 100 35 1044017 0 0 32767 //mark item
ELSE
xmfhtmlgumpcolor 325 402 100 35 1044018 0 0 32767 //do not mark
ENDIF

button 20 425 0fb1 0fb3 1 0 0
xmfhtmlgumpcolor 55 427 100 35 1011441 0 0 32767 //exit

PAGE 2 //first circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044381+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+2>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1002>
ENDFOR

PAGE 3 //second circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044389+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+10>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1010>
ENDFOR

PAGE 4 //third circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044397+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+18>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1018>
ENDFOR

PAGE 5 //fourth circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044405+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+26>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1026>
ENDFOR

PAGE 6 //fifth circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044413+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+34>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1034>
ENDFOR

PAGE 7 //sixth circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044421+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+42>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1042>
ENDFOR

PAGE 8 //seventh circle
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044429+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+50>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1050>
ENDFOR

PAGE 9
FOR 0 7
xmfhtmlgumpcolor 215 <EVAL 65+(22*<LOCAL._FOR>)> 150 35 <EVAL 1044437+<LOCAL._FOR>> 0 0 32767
button 180 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 1 0 <EVAL <LOCAL._FOR>+58>
button 500 <EVAL 65+(22*<LOCAL._FOR>)> 0FAB 0FAD 1 0 <EVAL <LOCAL._FOR>+1058>
ENDFOR

PAGE 10
xmfhtmlgumpcolor 215 65 150 35 1041267 0 0 32767 //Runebook
button 180 65 4005 4006 1 0 66
button 500 65 0FAB 0FAD 1 0 1066
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1023834 0 0 32767 //spellbook
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 67
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1067
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1072940 0 0 32767 //scrapper's compendium
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 68
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1068

[DIALOG d_newcraft_dialog_INSCRIPTION BUTTON]
ON=0
SRC.CTAG.INSCRIPTION.MESSAGE=

ON=2 69
IF (<ARGN1> != 69)
F_SELECT_INSCRIPTIONITEM <EVAL <ARGN1>-2>
ENDIF
SRC.F_CRAFTITEM_INSCRIPTION

ON=1002 1068
F_SELECT_INSCRIPTIONITEM <EVAL <ARGN1>-1002>
DIALOG D_INSCRIPTION_ITEM_PROPS

ON=10000
IF (<SRC.TAG0.MARKITEM>)
SRC.TAG.MARKITEM=
ELSE
SRC.TAG.MARKITEM=1
ENDIF
DIALOG d_newcraft_dialog_INSCRIPTION

[FUNCTION F_CRAFTITEM_INSCRIPTION]
LOCAL.MAGERYPROPCHANCE=<FEVAL <FLOATVAL ((<SRC.MAGERY>/1.5)+(<SRC.LUCK>/45))+10>>
IF (<LOCAL.MAGERYPROPCHANCE> > 98)
LOCAL.MAGERYPROPCHANCE=98
ENDIF
IF (0<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>)
LOCAL.CRAFTCHANCE=<eval <floatval ((<src.INSCRIPTION>/(<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>/10))*0.75)-0.05>/10000>
LOCAL.EXCEPTIONALCHANCE=<eval <floatval ((<src.INSCRIPTION>/(<serv.itemdef.<SRC.CTAG.INSCRIPTION.ITEM>.skillmake.1.val>/10))*0.75)-0.30>/10000>
ELSE
LOCAL.CRAFTCHANCE=100
LOCAL.EXCEPTIONALCHANCE=100
ENDIF
IF (!(<SRC.CTAG0.INSCRIPTION.ITEM>))
SRC.CTAG.INSCRIPTION.MESSAGE=You must select an item to make.
ELIF (!(<SRC.FINDID.i_pen_and_ink>))
SRC.CTAG.INSCRIPTION.MESSAGE=The tool must be on your person to use.
ELIF (!(<SRC.CANMAKESKILL <SRC.CTAG.INSCRIPTION.ITEM>>))
SRC.CTAG.INSCRIPTION.MESSAGE=You don't have the required skills to attempt this item.
ELIF (!(<SRC.CANMAKE <SRC.CTAG.INSCRIPTION.ITEM>>))
SRC.CTAG.INSCRIPTION.MESSAGE=You don't have the components needed to make that.
ELIF (<SRC.CTAG0.IJUSTCRAFTED>)
SRC.CTAG.INSCRIPTION.MESSAGE=You must wait a few moments before crafting another item.
ELIF (<LOCAL.CRAFTCHANCE> > <R100>)
SRC.SKILLGAIN INSCRIPTION <eval (<SRC.INSCRIPTION>/10)+1>
SRC.CTAG.IJUSTCRAFTED=1
SRC.TIMERF 2,CTAG.IJUSTCRAFTED=
SRC.CTAG.INSCRIPTION.MESSAGE=You craft the item.
SERV.NEWITEM=<SRC.CTAG.INSCRIPTION.ITEM>
SERV.LOG <NAME> (<UID>) crafts <NEW.NAME> (<NEW.BASEID>)
IF (<NEW.BASEID> == i_spellbook) || (<NEW.BASEID> == i_scrappers_compendium)
NEW.GIVEITEMEVENT T_PROPRIEDADES
IF (<LOCAL.EXCEPTIONALCHANCE> > <R100>)
SRC.CTAG.BS.MESSAGE=You create an exceptional quality item.
IF (<SRC.TAG0.MARKITEM>)
NEW.TAG.CRAFTEDBY=<SRC.NAME>
ENDIF
FOR <R3,4>
LOCAL.GAVEPROP=0
IF (<LOCAL.MAGERYPROPCHANCE> >= <R1,100>)
WHILE (!(<LOCAL.GAVEPROP>))
DORAND 8
BEGIN
IF (!(<LOCAL.GAVELOWERMANACOST>))
NEW.TAG0.LOWERMANACOST += <R3,7>
LOCAL.GAVELOWERMANACOST=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEFASTERCASTING>))
NEW.TAG0.FASTERCASTING ++
LOCAL.GAVEFASTERCASTING=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEFASTERCASTRECOVERY>))
NEW.TAG0.FASTERCASTRECOVERY += <R1,2>
LOCAL.GAVEFASTERCASTRECOVERY=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEMAGICDAMINCREASE>))
NEW.TAG0.MAGICDAMINCREASE += <R5,12>
LOCAL.GAVEMAGICDAMINCREASE=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEMANAREGENERATION>))
NEW.GIVEITEMEVENT T_STATUS_BONUS
NEW.TAG0.MANAREGENERATION += <R1,2>
LOCAL.GAVEMANAREGENERATION=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEMANAINCREASE>))
NEW.GIVEITEMEVENT T_STATUS_BONUS
NEW.TAG0.MANAINCREASE += <R3,8>
LOCAL.GAVEMANAINCREASE=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVESLAYER>))
NEW.SETSLAYER
LOCAL.GAVESLAYER=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVELOWERREAGENTCOST>))
NEW.TAG0.LOWERREAGENTCOST += <R5,16>
LOCAL.GAVELOWERREAGENTCOST=1
LOCAL.GAVEPROP=1
ENDIF
END
ENDDO
ENDWHILE
ENDIF
ENDFOR
ENDIF
ENDIF

NEW.BOUNCE
SRC.CONSUME <SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.RESOURCES>
ELSE
SRC.CTAG.INSCRIPTION.MESSAGE=You failed to create the item, and some of your materials are lost.
FOR <SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.RESOURCES.COUNT>
IF (<R1,4> == 1)
SRC.CONSUME <SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL> <SERV.ITEMDEF.<SRC.CTAG.INSCRIPTION.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>
ENDIF
ENDFOR
ENDIF
DIALOG d_newcraft_dialog_INSCRIPTION

[FUNCTION F_SELECT_INSCRIPTIONITEM]
DOSWITCH <ARGN1>
SRC.CTAG.INSCRIPTION.ITEM=i_scroll_reactive_armor
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CLUMSY
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CREATE_FOOD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_FEEBLEMIND
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_HEAL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MAGIC_ARROW
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_NIGHT_SIGHT
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_WEAKEN
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_AGILITY
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CUNNING
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CURE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_HARM
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MAGIC_TRAP
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MAGIC_UNTRAP
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_PROTECTION
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_STRENGTH
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_BLESS
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_FIREBALL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MAGIC_LOCK
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_POISON
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_TELEKINESIS
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_TELEPORT
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_UNLOCK
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_WALL_OF_STONE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_ARCHCURE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_ARCHPROTECTION
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CURSE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_FIRE_FIELD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_GREATER_HEAL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_LIGHTNING
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MANA_DRAIN
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_RECALL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_BLADE_SPIRITS
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_DISPEL_FIELD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_INCOGNITO
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MAGIC_REFLECTION
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MIND_BLAST
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_PARALYZE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_POISON_FIELD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_CREATURE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_DISPEL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_ENERGY_BOLT
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_EXPLOSION
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_INVISIBILITY
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MARK
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MASS_CURSE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_PARALYZE_FIELD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_REVEAL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_CHAIN_LIGHTNING
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_ENERGY_FIELD
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_FLAMESTRIKE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_GATE_TRAVEL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MANA_VAMPIRE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_MASS_DISPEL
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_METEOR_SWARM
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_POLYMORPH
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_EARTHQUAKE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_ENERGY_VORTEX
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_RESURRECTION
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_ELEM_AIR
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_DAEMON
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_ELEM_EARTH
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_ELEM_FIRE
SRC.CTAG.INSCRIPTION.ITEM=I_SCROLL_SUMMON_ELEM_WATER
SRC.CTAG.INSCRIPTION.ITEM=I_RUNEBOOK
SRC.CTAG.INSCRIPTION.ITEM=I_SPELLBOOK
SRC.CTAG.INSCRIPTION.ITEM=I_SCRAPPERS_COMPENDIUM
ENDDO

[EOF]