[defname item_Zones]
zones 2 // toplam zone sayısı
zone_1 = i_katana_Vanq 10000,i_Spear_vanq 10000,i_Scimitar_vanq 10000,i_Bow_vanq 10000,i_Crossbow_vanq 10000,i_Crossbow_vanq 10000,i_Crossbow_vanq 10000,i_Crossbow_vanq 10000
zone_2 = i_potion_healgreat 0 20,i_potion_curegreat 0 20,i_bandage 0 20,i_potion_refreshtotal 0 20,i_potion_poisondeadly 0 20

[function f_give_Stones]
for 1 <def.zones>
serv.newitem i_stone_item,1,<src.uid>
new.tag0.stone <dlocal._for>
endfor

[itemdef i_stone_item]
id i_gravestone_17
name Item Stone
weight 100

ON=@create
attr attr_static

ON=@dclick
sdialog d_itemstone
return 1

ON=@click
message @,,1 Eşya taşı
return 1

[DIALOG d_itemstone]
0, 0
PAGE 0
resizepic 0 0 5054 240 360
gumppictiled 10 10 220 340 2624
checkertrans 10 10 220 340 2624
dorigin 10 10
dtext +40 +10 32 <serv.servname> Eşya Menusu
dtext +30 +30 038 Eşya
dtext +120 +30 038 Fiyat
local.loop=0
local.page=1
page 1
for 0 <eval <f_array <def.zone_<dtag0.stone>>>-1>
if (<local.y> > 10)
local.y=0
button +180 +300 015e1 015e5 0 <eval <local.page>+1> 1
local.page += 1
page <dlocal.page>
button +165 +300 015e3 015e7 0 <eval <local.page>-1> 1
endif

local.y +=1
local.price <streat <f_array_item <def.zone_<dtag0.stone>>, <eval <local._for>+1>>>
dhtmlgump +30 +<eval 20 + (<local.y>*30)> 250 25 0 0 <def.l1><def.r1><def.bfont_white> <serv.itemdef.<f_array_item <def.zone_<dtag0.stone>>, <eval <dlocal._for> + 1>>.name> ==> <def.bfont_yellow><qval (<local.price>)?<dlocal.price>:Ücretsiz>
button +10 +<eval 20 + (<local.y>*30)> 2714 2715 1 0 <eval <dlocal._for>+1>
endfor

[dialog d_itemstone button]
ON=1,999
local.fiyat <streat <f_array_item <def.zone_<dtag0.stone>>, <dargn>>>
if (<src.gold> >= <local.fiyat>)
src.yeniesya <strarg <f_array_item <def.zone_<dtag0.stone>>, <dargn>>>,<streat <streat <f_array_item <def.zone_<dtag0.stone>>, <dargn>>>>
src.gold -=<local.fiyat>
src.sys_Good Ödeme yapıldı. <dlocal.fiyat> altın.
else
src.sys_error Bu eşyayı satın almak için <dlocal.fiyat> altın ödemelisiniz.
return 1
endif

[function yeniesya]
if <argv[1]>
serv.newitem <argv[0]>,<argv[1]>,<uid>
else
serv.newitem <argv[0]>,1,<uid>
endif

[FUNCTION f_array]
return <dargv>

[FUNCTION f_array_item]
local.temp = <argv[<eval <argv> - 1>]> -1
return <argv[<dlocal.temp>]>