[DEFNAME KILLDUSUR]
BIRIMKILL 5000
MAXTEKSEFER 250

[FUNCTION KILLDUSUR]
IF !(<KILLS>)
SYSMESSAGE @,,1 Killiniz zaten ''0''(sıfır).
RETURN 1
ENDIF

SDIALOG D_KILLDUSUR
[DIALOG D_KILLDUSUR]
50,50
PAGE 0
RESIZEPIC 20 10 3500 220 255
NOMOVE
DORIGIN 20 30
DHTMLGUMP +10 +0 200 25 0 0 <def.bfont_red> <SERV.SERVNAME> Kill Düşürme Sistemi

PAGE 1
DHTMLGUMP +20 +30 180 125 0 0 <def.bfont_black>-Toplam kill sayınız : <def.bfont_red><KILLS><def.bfont_black><DEF.BR>-kill düşürmenin bedeli <def.bfont_red><bolukayir <DDEF.BIRIMKILL>><def.bfont_black> altındır.<DEF.BR>-Bir seferde en fazla <def.bfont_red><DDEF.MAXTEKSEFER><def.bfont_black> kill düşürebilirsiniz.<DEF.BR>-Kill sayinizi sıfırlamak için <def.bfont_red><bolukayir <EVAL (<KILLS>*<DEF.BIRIMKILL>)>><def.bfont_black> altina ihtiyacınız var.
DTEXTENTRY +50 +180 180 25 1153 1 <KILLS>
BUTTON +30 +180 2714 2715 1 0 1

[DIALOG D_KILLDUSUR BUTTON]
ON=1
IF !(<ISNUM <ARGTXT[1]>>)
SYSMESSAGE @,,1 Sadece rakam girebilirsiniz.
RETURN 1
ENDIF

IF (<ARGTXT[1]> > <DEF.MAXTEKSEFER>)
SYSMESSAGE @,,1 Tek seferde en fazla <DDEF.MAXTEKSEFER> kill düşürebilirsiniz.
RETURN 1
ENDIF

IF (<KILLS> < <ARGTXT[1]>)
SYSMESSAGE @,,1 Bu kadar kille sahip değilsiniz.
RETURN 1
ENDIF

IF (<GOLD> < <EVAL (<KILLS>*<DEF.BIRIMKILL>)>)
SYSMESSAGE @,,1 Gereken para : <bolukayir <EVAL (<KILLS>*<DEF.BIRIMKILL>)>>. Sizin paranız <bolukayir <GOLD>>. Ihtiyacınız olan miktar : <bolukayir <EVAL (<EVAL (<KILLS>*<DEF.BIRIMKILL>)>-<GOLD>)>>
RETURN 1
ENDIF

GOLD -=<EVAL (<KILLS>*<DEF.BIRIMKILL>)>
KILLS -=<ARGTXT[1]>
SYSMESSAGE @,,1 <ARGTXT[1]> kill düşürüldü. Kalan kill ==> <KILLS>.

[FUNCTION BolukAyir] // from jeem
IF (<EVAL STRLEN(<ARGS>)> > 3)
   LOCAL.STRLEN=<EVAL STRLEN(<ARGS>)>
   LOCAL.CURRENTDIGIT=<EVAL STRLEN(<ARGS>)>
   WHILE (<LOCAL.CURRENTDIGIT> > 3)
      ARGS=<STRSUB 0 <EVAL (<LOCAL.CURRENTDIGIT> - 3)> <ARGS>>.<STRSUB <EVAL (<LOCAL.CURRENTDIGIT> - 3)> 50 <ARGS>>
      LOCAL.CURRENTDIGIT -= 3
   ENDWHILE
ENDIF
RETURN <ARGS>