// Yarışma :: UO-Dev 1. Scripting Yarışması
// Adres :: http://www.uo-developer.com
// Yazar :: Basic
// Script Adı :: Elemental Sistemi

on=@success
local.ele <R1,11>
if (<rand(<eval (2000/<mining>)*<dlocal.ele>>)> == 1)
emote found something which have a material of <f_basic_ayir 1,<def.ele<dlocal.ele>>>.
createelemental <dlocal.ele>
endif

[defname elemental_system]
ele1 Earth,100,100
ele2 Copper,150,100
ele3 Agapite,400,170
ele4 Bronze,400,170
ele5 Shadow,400,170
ele6 Verite,700,250
ele7 Valorite,700,250
ele8 Mytheril,900,300
ele9 Bloodrock,1900,900
ele10 Blackrock,2300,1200
compass s,se,e,ne,n,nw,w,sw

[function createelemental]
serv.newnpc c_elem_earth
new.color <def.color_o_<f_basic_ayir 1,<def.ele<args>>>>
new.name <f_basic_ayir 1,<def.ele<args>>> Elemental
new.str <f_Basic_ayir 2,<def.ele<args>>>
new.hits <new.str>
new.dex <f_basic_ayir 3,<def.ele<args>>>
new.stam <new.dex>
new.tactics 1000
new.wrestling 1000
new.home <p>
new.homedist 2
new.p <p>
new.events e_elem
new.sayua Arrgh!!
new.anim 12
new.flags 04
new.timerf 2,new.flags 020
new.findlayer(21).remove
ref1=<new.uid>
serv.newitem i_elem_memory,1,<ref1>
new.timer 180

[itemdef i_elem_memory]
id i_gold
type t_eq_script
name Elemental Memory

on=@timer
cont.emote can't find which he need.
timerf 1,cont.emote returning back to the earth.
timerf 2,cont.anim 12
timerf 3,cont.remove

[events e_elem]
on=@death
for 1 8
serv.newitem i_fire_column
new.attr attr_decay | attr_static
new.p <p>
new.timer 1
new.move <f_Basic_ayir <dlocal._for>,<def.compass>> 1
serv.newitem i_ore_<strarg <name>>
new.p <p>
new.amount <R1,10>
new.timer 600
new.move <f_Basic_ayir <dlocal._for>,<def.compass>> 1
endfor


[function f_basic_ayir]
if !strcmpi('<argv[0]>','length')
return <eval <argv>-1>
//elif !<isnum <argv[0]>> //length olayıyla çakışabilir çakışırsa && <argv[0]> != length
//return Ilk deger sadece rakam olabilir.
elif <argv[0]> == 0
return "0" tanimsiz.
else
local.ayir <argv[<argv[0]>]>
return <local.ayir>
endif