// Yarışma :: UO-Dev 1. Scripting Yarışması
// Adres :: http://www.uo-developer.com
// Yazar :: aldarson
// Script Adı :: corpse clothing system

[comment system]
sistemin çalışması:herhangi bir nesnenin type'sini t_scisscors_corpse olarak ayarlayınız
bu nesneyle obody'si c_dragon_new olan bir ceset seçilirse dialog açılır(ayarlı olan:80 tailoring lazım)
bu dialogda 5 tane armordan rasgele birisini yapabilirsin ben deri armorlar eklemedim i_leather dan gittim
siz ekleyebilirsiniz.

[defname system_item]
new_item i_leather_gloves,i_leather_gorget,i_leather_tunic,i_leather_sleeves,i_leather_leggings,80.0

[function f_select]
return=<argv[<argv[0]>]>

[typedef t_scisscors_corpse]
on=@dclick
target @50,,1 Hangi cesetten armor yapıcaksınız?
  return 1

on=@targon_item
ref1=<src.targ.uid>
  if !<ref1.type> == t_corpse || <ref1.link.isplayer> || !<ref1.link.obody>==c_dragon_new
    src.sys_normal Bundan armor yapamassınız.
     elseif <src.distance <ref1>> >2
      src.sys_ok Çok uzaktasınız.
       elseif <src.tailoring> < <f_select 6,<def.new_item>>
        src.sys_ok Mininum <f_select 6,<def.new_item>> tailoring lazım.
         else
          src.ctag0.info=<ref1.uid>,<ref1.tag0.parca>
           sdialog d_corpse_clothing
    endif
     return 1

on=@targon_char
src.sys_ok Bu bir ceset değil.
   return 1

on=@targon_ground
  src.sys_ok Bu bir ceset değil.
    return 1

[dialog d_corpse_clothing]
50,50
nomove
resizepic 0 0 5120 400 250
resizepic 10 10 3000 380 230

tilepic 300 105 <serv.itemdef.<streat <src.ctag0.info>>.id>

dhtmlgump 30 30 200 20 0 0 <def.bfont_blue><serv.name> Corpse Clothing System
dhtmlgump 20 80 999 20 0 0 <def.bfont_red>Bu cesetten yapılacak armor parçası : <serv.itemdef.<streat <src.ctag0.info>>.name>
dhtmlgump 20 150 200 20 0 0 <def.bfont_red>armor parçasını dik
dhtmlgump 250 150 200 20 0 0 <def.bfont_red>iptal et

button 150 150 210 211 1 0 2
button 210 150 210 211 1 0 1

[dialog d_corpse_clothing button]
on 0,1
src.sys_ok vazgeçtiniz.

on 2
if (<src.distance <strarg <src.ctag0.info>>> >2)
src.sys_ok Cesede uzaksınız.
elseif !(<src.restest 1 i_crystal_new>) || !(<src.restest 2 i_hide_new>)
src.sys_ok Gerekli malzemeler(1 new crystal,2 new hide)
else
src.consume 1 i_crystal_new
src.consume 2 i_hide_new
serv.newitem <streat <src.ctag0.info>>,1,<src.findlayer(layer_pack)>
src.sys_ok <serv.itemdef.<streat <src.ctag0.info>>.name> yapıldı.
try uid.<strarg <src.ctag0.info>>.remove
src.clearctags
endif

[chardef c_dragon_new]
id c_dragon_red
name Power Armor Dragon
armor 50
dam 50
can mt_walk|mt_run

on=@create
str={300 400}
int={300 400}
dex={200 400}
karma=-9000
fame=1000
tactics={100 200}
magicresistance={100 200}
wrestling={100 200}

on=@gethit
if (<flags>&statf_poisoned)
spelleffect s_cure,1000,<uid>
endif
foritems 10
if (<type> == t_spell)
spelleffect s_mass_dispel,1000
endif
endfor

on=@npcrestock
item=i_crystal_new
item=i_hide_new,2

on=@deathcorpse
argo.tag0.parca <f_select <R1,5>,<def.new_item>>

[itemdef i_crystal_new]
id i_crystal_green
name New Crystal

on=@create
color=080a

[itemdef i_hide_new]
id i_Hide
name New Hide

on=@create
color=080a