[comment Basic]
Yeni bir scriptle karşınızdayım. Scriptte sadece paladin spellbookunun bence olması gereken hali bulunuyor. Üstüne spelleri eklerseniz güzel bir paladin skilli yazabilirsiniz.

[defname Paladin]
pic1 05101,Close Wounds,10,10,1
pic2 05100,Cleanse by Fire,10,10,5
pic3 05108,Remove Curse,10,20,5
pic4 05102,Consecrate We..,10,10,15
pic5 05109,Sacred Journey,20,20,15
pic6 05104,Divine Fury,10,15,25
pic7 05103,Dispel Evil,10,15,35
pic8 05105,Enemy of One,10,20,45
pic9 05106,Holy Light,10,15,55
pic10 05107,Noble Sacrifice,30,20,65

[itemdef i_book_paladin]
id 8786
name Book of Chivalry
type t_pala_book

on=@create
attr 04

[typedef t_pala_book]
on=@dclick
src.dialog d_book_chivalry
return 1

[dialog d_book_chivalry]
0,0
gumppic 100 50 02b01
dtext 203 66 048c INDEX
dtext 370 66 048c INDEX
dtext 155 90 0 Close Wounds
dtext 155 110 0 Cleanse by Fire
dtext 155 130 0 Remove Curse
dtext 155 150 0 Consecrate Weapon
dtext 155 170 0 Sacred Journey
dtext 322 90 0 Divine Fury
dtext 322 110 0 Dispel Evil
dtext 322 130 0 Enemy of One
dtext 322 150 0 Holy Light
dtext 322 170 0 Noble Sacrifice
dtext 160 210 048c Tithing Point: <src.tag0.tithing>

button 270 95 08af 08b0 1 0 1
button 270 115 08af 08b0 1 0 2
button 270 135 08af 08b0 1 0 3
button 270 155 08af 08b0 1 0 4
button 270 175 08af 08b0 1 0 5

button 430 95 08af 08b0 1 0 6
button 430 115 08af 08b0 1 0 7
button 430 135 08af 08b0 1 0 8
button 430 155 08af 08b0 1 0 9
button 430 175 08af 08b0 1 0 10

[dialog d_book_chivalry button]
on 1 10
ctag0.whichone_chiv <dargn>
dialog d_book_chivalry_spells

[dialog d_book_chivalry_spells]
0,0
gumppic 100 50 02b01 //book


///////////Sağ Çizgi
if !(<src.dctag0.whichone_chiv> == 10)
gumppic 322 165 0835
gumppic 337 165 0835
gumppic 354 165 0835
gumppic 371 165 0835
gumppic 388 165 0835
gumppic 405 165 0835
gumppic 422 165 0835
gumppic 439 165 0835
endif
///////////Sol Çizgi
gumppic 152 165 0835
gumppic 167 165 0835
gumppic 184 165 0835
gumppic 201 165 0835
gumppic 218 165 0835
gumppic 235 165 0835
gumppic 252 165 0835
gumppic 269 165 0835



local.whichone_chiv <src.ctag0.whichone_chiv>
local.other_chiv <eval <local.whichone_chiv>+1>

gumppic 202 90 <f_Basic_ayir 1,<def.pic<dlocal.whichone_chiv>>>
if !(<src.dctag0.whichone_chiv> == 10)
gumppic 362 90 <f_Basic_ayir 1,<def.pic<dlocal.other_chiv>>>
endif

dtext 153 135 048c Spell: <f_Basic_ayir 2,<def.pic<dlocal.whichone_chiv>>>
if !(<src.dctag0.whichone_chiv> == 10)
dtext 320 135 048c Spell: <f_Basic_ayir 2,<def.pic<dlocal.other_chiv>>>
endif

dtext 154 170 048c Need:
if !(<src.dctag0.whichone_chiv> == 10)
dtext 321 170 048c Need:
endif

local.left_thithing=<f_Basic_ayir 3,<def.pic<dlocal.whichone_chiv>>>
local.left_mana=<f_Basic_ayir 4,<def.pic<dlocal.whichone_chiv>>>
local.left_skill=<f_Basic_ayir 5,<def.pic<dlocal.whichone_chiv>>>

dtext 190 170 048c <dlocal.left_thithing> Tithing
dtext 190 190 048c <dlocal.left_mana> Mana
dtext 190 210 048c <dlocal.left_skill>.0 Chivalry

local.right_thithing=<f_Basic_ayir 3,<def.pic<dlocal.other_chiv>>>
local.right_mana=<f_Basic_ayir 4,<def.pic<dlocal.other_chiv>>>
local.right_skill=<f_Basic_ayir 5,<def.pic<dlocal.other_chiv>>>

if !(<src.dctag0.whichone_chiv> == 10)
dtext 367 170 048c <dlocal.right_thithing> Tithing
dtext 367 190 048c <dlocal.right_mana> Mana
dtext 367 210 048c <dlocal.right_skill>.0 Chivalry
endif

button 150 58 089d 089d 1 0 1
button 421 58 089e 089e 1 0 2


[dialog d_book_chivalry_spells button]
on 1
if (<src.dctag0.whichone_chiv> == 1)
src.sdialog d_book_chivalry
else
src.ctag0.whichone_chiv -=1
src.dialogclose d_book_chivalry_spells
src.dialog d_book_chivalry_spells
endif

on 2
if (<src.dctag0.whichone_chiv> == 10)
src.sdialog d_book_chivalry
else
src.ctag0.whichone_chiv +=1
src.dialogclose d_book_chivalry_spells
src.dialog d_book_chivalry_spells
endif

[function f_basic_ayir]
if !strcmpi('<argv[0]>','length')
return <eval <argv>-1>
//elif !<isnum <argv[0]>> //length olayıyla çakışabilir çakışırsa && <argv[0]> != length
//return Ilk deger sadece rakam olabilir.
elif <argv[0]> == 0
return "0" tanimsiz.
else
local.ayir <argv[<argv[0]>]>
return <local.ayir>
endif