[FUNCTION spawn]
IF !(STRCMP(<ARGS>,?))
SRC.SYSMESSAGE Opens up the spawn creation dialog.
SRC.SYSMESSAGE Format: spawn ARGUMENT
SRC.SYSMESSAGE Where ARGUMENT can be 1 or 2.  1 will recreate the last spawn point set up.
SRC.SYSMESSAGE 2 will clear spawn settings.
RETURN 1
ENDIF
IF (<ARGN> == 1)
SRC.NEWITEM=01ea7
SRC.ACT.P=<P>
SRC.ACT.TYPE=34
SRC.ACT.AMOUNT=<TAG.SPAWNAMOUNT>
SRC.ACT.MORE=<TAG.SPAWNID>
SRC.ACT.MOREX=<TAG.MINTIME>
SRC.ACT.MOREY=<TAG.MAXTIME>
SRC.ACT.MOREZ=<TAG.MAXDIST>
SRC.ACT.ATTR=0b0
SRC.ACT.DCLICK
SRC.MESSAGE=Spawn created and initialized.
SRC.MESSAGE=First creature will spawn in <ACT.TIMER> seconds.
RETURN 1
ENDIF
IF (<ARGN> == 2)
src.tag0.SPAWNAMOUNT=0
src.tag0.SPAWNID=0
src.tag0.MINTIME=0
src.tag0.MAXTIME=0
src.tag0.MAXDIST=0
SRC.MESSAGE Spawn settings cleared.
RETURN 1
ENDIF
IF !(0<src.tag0.SPAWNAMOUNT>)
src.tag0.SPAWNAMOUNT=1
src.tag0.SPAWNID=c_man
src.tag0.MINTIME=5
src.tag0.MAXTIME=10
src.tag0.MAXDIST=5
ENDIF
SRC.DIALOG d_spawner
RETURN 1

[DIALOG d_spawner]
0,0
resizepic 400 370 5054 350 215
page 0
text 500 375 1000 0
text 405 395 1000 1
button 550 395 2440 2440 1 0 1
text 560 396 1000 6
text 405 425 1000 2
button 550 425 2440 2440 1 0 2
text 560 426 1000 7
text 405 455 1000 3
button 550 455 2440 2440 1 0 3
text 560 456 1000 8
text 405 485 1000 4
button 550 485 2440 2440 1 0 4
text 560 486 1000 9
text 405 515 1000 5
button 550 515 2440 2440 1 0 5
text 560 516 1000 10
button 415 545 2076 2075 1 0 6
button 615 545 2073 2072 1 0 0

[DIALOG d_spawner TEXT]
Creature Spawn
Amount
Creature ID
Minimum time
Maximum time
Maximum Distance
<eval <src.tag0.SPAWNAMOUNT>>
<src.tag0.SPAWNID>
<eval <src.tag0.MINTIME>>
<eval <src.tag0.MAXTIME>>
<eval <src.tag0.MAXDIST>>

[DIALOG d_spawner BUTTON]
ONBUTTON=0
SYSMESSAGE=Spawning Canceled
RETURN 0

ONBUTTON=1
INPDLG TAG.SPAWNAMOUNT 3
RETURN 1

ONBUTTON=2
INPDLG TAG.SPAWNID 20
RETURN 1

ONBUTTON=3
INPDLG TAG.MINTIME 10
RETURN 1

ONBUTTON=4
INPDLG TAG.MAXTIME 10
RETURN 1

ONBUTTON=5
INPDLG TAG.MAXDIST 5
RETURN 1

ONBUTTON=6
NEWITEM=01ea7
ACT.P=<P>
ACT.TYPE=34
ACT.AMOUNT=<TAG.SPAWNAMOUNT>
ACT.MORE=<TAG.SPAWNID>
ACT.MOREX=<TAG.MINTIME>
ACT.MOREY=<TAG.MAXTIME>
ACT.MOREZ=<TAG.MAXDIST>
ACT.ATTR=0b0
ACT.DCLICK
MESSAGE=Spawn created and initialized.
MESSAGE=First creature will spawn in <ACT.TIMER> seconds.
RETURN 0

[EOF]