//*/*/*/*/*/*/*/*/*/*/*/*/*/*/*/
//
// BAŞLANGIÇ
//
//*/*/*/*/*/*/*/*/*/*/*/*/*/*/*/

/////
/// Arrayların çalışması için gerekli komuttur silmeyin.
/////

[function dizi]
local.dizi <argv[<eval <argv> - 1>]> - 1
return <argv[<dlocal.dizi>]>

/////
/// Def. ayarlarını kendinize göre yapabilirsiniz, diğerleri bölümüne bişey eklediginizde ordaki
/// 2. virgüldeki sayıyıda arttırın nekadar eklerseniz okadar arttırın.
/// max. ekleme sınırını arttırmak içinde 1. virgüldeki sayıyı arttırabilirsiniz.
/////

[defname mat_options]
Reg 500,8,i_reag_black_pearl,i_reag_blood_moss,i_reag_garlic,i_reag_ginseng,i_reag_mandrake_root,i_reag_nightshade,i_reag_sulfur_ash,i_reag_spider_silk  // reg sayısı, regler, her regden max kaçtane
Ore 400,12,i_ore_iron,i_ore_dull_copper,i_ore_copper,i_ore_bronze,i_ore_gold,i_ore_shadow,i_ore_agapite,i_ore_verite,i_ore_valorite,i_ore_mytheril,i_ore_bloodrock,i_ore_blackrock  // ore sayısı, orelar, her oredan max kaçtane
Ingot 450,12,i_ingot_iron,i_ingot_dull_copper,i_ingot_copper,i_ingot_bronze,i_ingot_gold,i_ingot_shadow,i_ingot_agapite,i_ingot_verite,i_ingot_valorite,i_ingot_mytheril,i_ingot_bloodrock,i_ingot_blackrock  // ingot sayısı, ingotlar, her ingotdan max kaçtane
Other 750,6,i_bandage,i_potion_Healgreat,i_potion_curegreat,i_cloth,i_log,i_scroll_blank

/////
/// Ana itemimiz.
/////

[itemdef i_matbag]
id i_backpack
name Material Bag
weight 25
type t_eq_script
value 64205

ON=@Create
for 1 <dizi <def.reg>,2>
tag.reg<dlocal._for> 0
endfor
for 1 <dizi <def.ore>,2>
tag.ore<dlocal._for> 0
endfor
for 1 <dizi <def.ingot>,2>
tag.ingot<dlocal._for> 0
endfor
for 1 <dizi <def.other>,2>
tag.other<dlocal._for> 0
endfor
color 0835
attr 06

ON=@Click
message @07a1,1,1 <name>
return 1

on=@Dclick
src.matbag Reg,<uid>
return 1

/////
/// Dialog açma aparatı
/////

[function matbag]
ctag.matmenu <args>
dialogclose d_matbag_cikart
dialogclose d_matbag
dialog d_matbag

/////
/// Malzeme çıkartma ekranı
/////

[dialog d_matbag_cikart]
0,0
nomove
ref2 <dizi <ctag.matopts>,3>
local.materyal <dizi <ctag.matopts>,1>
local.sira <dizi <ctag.matopts>,2>
local.max <dizi <def.<local.materyal>>,1>
local.eklemat <dizi <ctag.matopts>,4>
resizepic 20 20 5120 310 100
resizepic 25 25 3000 300 90
resizepic 90 45 3000 38 30
dtextentry 93 50 30 20 0 0 <ref2.dtag.<local.materyal><dlocal.sira>>
dhtmlgump 35 50 100 20 0 0 <def.bfont_dred>Çantadan
dhtmlgump 135 50 200 20 0 0 <def.bfont_dred>adet <def.bfont_dgreen><serv.itemdef.<local.eklemat>.name> <def.bfont_dred>çıkart.
dhtmlgump 55 85 100 20 0 0 <def.bfont_dred>Tamam
button 35 85 56 56 1 0 1

[dialog d_matbag_cikart button]
on 1
ref2 <dizi <ctag.matopts>,3>
local.materyal <dizi <ctag.matopts>,1>
local.sira <dizi <ctag.matopts>,2>
local.max <dizi <def.<local.materyal>>,1>
local.eklemat <dizi <ctag.matopts>,4>

if !<isnum <argtxt[0]>>
sysmessage @0846,1,1 Sadece sayıları kullanabilirsiniz.
dialog d_matbag_cikart
return 1
endif

if <argtxt[0]> > <ref2.dtag.<local.materyal><dlocal.sira>>
sysmessage @0846,1,1 Çantada bukadar <serv.itemdef.<local.eklemat>.name> bulunmuyor.
dialog d_matbag_cikart
return 1
endif

timerf 1,sysmessage @0846,1,1 Material çantanızdan <dargtxt[0]> adet <serv.itemdef.<local.eklemat>.name> çıkartıldı.
serv.newitem <local.eklemat>
new.amount <argtxt[0]>
new.bounce
new.fix
ref2.tag.<local.materyal><dlocal.sira> -=<argtxt[0]>
src.matbag <local.materyal>,<ref2>

/////
/// Ana dialog'umuz zaten bundan başka dialog yok çıkartma dışında.
/////

[dialog d_matbag]
0,0
nomove

resizepic 20 20 5120 750 550
resizepic 25 25 3000 740 540
resizepic 35 55 3000 720 2
dhtmlgump 305 35 200 20 0 0 <def.bfont_size7><def.bfont_dred><serv.servname> Material Bag Sistemi

ref1 <dizi <ctag.matmenu>,2>
local.page <def.<dizi <ctag.matmenu>,1>>
local.carp 35
local.ekle 40

// bu istisnalar dialog dizaynının görüntü güzelliği için.
//istisna 1
if strmatch('<dizi <ctag.matmenu>,1>','Ore')
local.ore 1
endif

//istisna 2
if strmatch('<dizi <ctag.matmenu>,1>','Ingot')
local.ingot 1
endif

if strmatch('<dizi <ctag.matmenu>,1>','Other')
local.other 1
endif

resizepic 35 488 3000 720 2
dhtmlgump 125 518 200 20 0 0 <def.bfont_dred>Aktif Bölüm : <def.bfont_dgreen><qval (<local.other> = 1)? Diğer:<dizi <ctag.matmenu>,1>>

if strmatch('<dizi <ctag.matmenu>,1>','reg')
dhtmlgump 400 505 200 20 0 0 <def.bfont_dgray>Reg Bölümü Seçili
else
dhtmlgump 400 505 200 20 0 0 <def.bfont_dred>Reg Bölümüne Geç
button 380 505 55 55 1 0 31001
endif

if strmatch('<dizi <ctag.matmenu>,1>','Ore')
dhtmlgump 600 505 200 20 0 0 <def.bfont_dgray>Ore Bölümü Seçili
else
dhtmlgump 600 505 200 20 0 0 <def.bfont_dred>Ore Bölümüne Geç
button 580 505 55 55 1 0 31002
endif

if strmatch('<dizi <ctag.matmenu>,1>','other')
dhtmlgump 400 530 200 20 0 0 <def.bfont_dgray>Diğerleri Bölümü Seçili
else
dhtmlgump 400 530 200 20 0 0 <def.bfont_dred>Diğerleri Bölümüne Geç
button 380 530 55 55 1 0 31003
endif

if strmatch('<dizi <ctag.matmenu>,1>','ingot')
dhtmlgump 600 530 200 20 0 0 <def.bfont_dgray>Ingot Bölümü Seçili
else
dhtmlgump 600 530 200 20 0 0 <def.bfont_dred>Ingot Bölümüne Geç
button 580 530 55 55 1 0 31004
endif

for x 1 <dizi <local.page>,2>
tilepic <qval (<local.ingot> = 1)? 20:30> <eval (<dlocal.x>*<dlocal.carp>)+<dlocal.ekle>> <qval (<local.ore> = 1)? 019b8:<serv.itemdef.<dizi <local.page>,<eval <dlocal.x>+2>>.id>>
dhtmlgump 75 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+3>> 500 20 0 0 <def.bfont_dred>Materyal çantanızda <def.bfont_dgreen><ref1.dtag.<dizi <ctag.matmenu>,1><dlocal.x>> <def.bfont_dred>adet <def.bfont_dblue><serv.itemdef.<dizi <local.page>,<eval <dlocal.x>+2>>.name><def.bfont_dred> bulunmaktadır. (<def.bfont_dgreen><ref1.dtag.<dizi <ctag.matmenu>,1><dlocal.x>><def.bfont_dred>/<def.bfont_red><dizi <local.page>,1><def.bfont_dred>)
resizepic 35 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+28>> 3000 720 2
local.olan <ref1.dtag.<dizi <ctag.matmenu>,1><dlocal.x>>
local.max <dizi <local.page>,1>
local.yuzde <eval <eval <local.olan>*100> / <local.max>>
resizepic 610 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+9>> 3000 102 12
resizepic 610 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+11>> 5120 <dlocal.yuzde> 8
dhtmlgump 540 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+5>> 400 20 0 0 <def.bfont_dred> %<def.bfont_dgreen><dlocal.yuzde> <def.bfont_dred>dolu
if <local.olan> != <local.max>
button 720 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+7>> 55 55 1 0 <dlocal.x>
endif
if <local.olan> > 0
button 740 <eval (<dlocal.x>*<dlocal.carp>)+<eval <dlocal.ekle>+7>> 56 56 1 0 <eval <dlocal.x>+100>
endif
endfor

[dialog d_matbag button]
on 1 100
sysmessage @0846,1,1 Eklemek istediğiniz <serv.itemdef.<dizi <def.<dizi <ctag.matmenu>,1>>,<eval <dargn>+2>>.name> isimli materyali seçiniz.
targetf eklemat <dizi <ctag.matmenu>,1>,<dargn>,<dizi <ctag.matmenu>,2>,<dizi <def.<dizi <ctag.matmenu>,1>>,<eval <dargn>+2>>

on 101 5000
sysmessage @0846,1,1 <serv.itemdef.<dizi <def.<dizi <ctag.matmenu>,1>>,<eval <eval <dargn>-100>>+2>.name> isimli materyalden nekadar çıkartmak istediğinizi yazınız.
ctag.matopts <dizi <ctag.matmenu>,1>,<eval <dargn>-100>,<dizi <ctag.matmenu>,2>,<dizi <def.<dizi <ctag.matmenu>,1>>,<eval <eval <dargn>-100>>+2>
dialogclose d_matbag_cikart
dialog d_matbag_cikart

on 31001
matbag Reg,<dizi <ctag.matmenu>,2>
on 31002
matbag Ore,<dizi <ctag.matmenu>,2>
on 31003
matbag Other,<dizi <ctag.matmenu>,2>
on 31004
matbag Ingot,<dizi <ctag.matmenu>,2>

/////
/// burasıda malzeme ekleme olayı, bütün bölümler ve malzemeler tek bi komutta ekleniyor.
/////

[function eklemat]
ref2 <dizi <args>,3>
local.materyal <dizi <args>,1>
local.sira <dizi <args>,2>
local.max <dizi <def.<local.materyal>>,1>
local.eklemat <dizi <args>,4>

if <argo.baseid> != <local.eklemat>
src.sysmessage @0846,1,1 Bu seçtiğiniz bir <serv.itemdef.<local.eklemat>.name> değil.
targetf eklemat <dizi <args>,1>,<dizi <args>,2>,<dizi <args>,3>,<dizi <args>,4>
return 1
endif

if <argo.cont> != <src.findlayer.21.uid>
src.sysmessage @0846,1,1 Sadece çantanızdaki <serv.itemdef.<local.eklemat>.name> isimli materyalleri ekleyebilirsiniz.
targetf eklemat <dizi <args>,1>,<dizi <args>,2>,<dizi <args>,3>,<dizi <args>,4>
return 1
endif

local.eklencek <argo.amount>

if <eval <argo.amount> + <ref2.tag.<local.materyal><dlocal.sira>>> >= <dlocal.max>
local.eklencek <eval <dlocal.max>-<ref2.tag.<local.materyal><dlocal.sira>>>
timerf 1,src.sysmessage @0846,1,1 Seçtiğiniz <serv.itemdef.<local.eklemat>.name> materyalinin <eval <argo.amount>-<local.eklencek>> adet kadarı sığmadı.
endif

src.consume <local.eklemat> <local.eklencek>
timerf 1,src.sysmessage @0846,1,1 <dlocal.eklencek> adet <serv.itemdef.<local.eklemat>.name> materyali çantaya eklendi.
ref2.tag.<local.materyal><dlocal.sira> +=<dlocal.eklencek>
src.matbag <local.materyal>,<ref2>

[EOF]