//Yazılış tarihi:07/06/2010
//Yazılış nedeni:Can sıkıntısı
//Son güncelleme:07/06/2010
//Yazan kişi:İsmail Köse

//Slash eklemek için
[function slashekle]
local.str=<asc <args>>
local.string=s
for i 0 strlen(<local.str>)
    local.check=<strarg <local.str>>
    local.last=<local.check>
    if <local.check>==00
        return <strsub 1 <eval strlen(<local.string>)-2> <local.string>>
    endif
    if <local.check>=<asc \>
        local.last=<asc \>
        local.string <strsub 0 <eval strlen(<local.string>)-1> <local.string>>\\s
    elif <local.check>=<asc '>
        local.string <strsub 0 <eval strlen(<local.string>)-1> <local.string>>\'s
    else
        local.string <strsub 0 <eval strlen(<local.string>)-1> <local.string>><chr <local.check>>s
    endif
    local.str=<streat <local.str>>
endfor
return <strsub 1 <eval strlen(<local.string>)-2> <local.string>>

//Tablo yaratmak için
[function Culum_Duyuru_Kur]
db.connect
if <db.connected>
db.execute "create table culum_duyuru_tablo (kimlik int unsigned not null auto_increment primary key,duyuru text,zaman text,esyakimlik text,yazankisi text);"
src.sysmessageua 666,0,0,trk, Duyuru:Başarı ile kuruldu.
db.close
else
src.sysmessageua 666,0,0,trk, Veritabanı:Mysql'a erişim sağlanamıyor lütfen ayarlarınızı kontrol edin.
endif

//Duyuru sistemini kaldırmak için

[function Culum_Duyuru_Sil]
db.connect
if <db.connected>
db.execute "drop table culum_duyuru_tablo"
src.sysmessageua 666,0,0,trk, Duyuru:Başarı ile silindi.
db.close
else
src.sysmessageua 666,0,0,trk, Veritabanı:Mysql'a erişim sağlanamıyor lütfen ayarlarınızı kontrol edin.
endif

[function Culum_Res_At]
serv.resync



//Duyuru girişi ve silme işlemi için
[function Duyuru]
src.dialog zamanayarla
[function Duyurusil]
src.dialog culum_duyuru_duzenle

//Duyuru zamanını ayarlamak için
[dialog zamanayarla]
0, 0
noclose
nomove
resizepic 0 0 1228 390 300
page 0
dtext 115 5 50 <serv.name> Duyuru menüsü
dhtmlgump 25 100 175 25 1 0 Duyuru zamanı : <eval <src.tag.zaman>>
dhtmlgump 25 50 350 50 0 0 Saygın, "<src.name>" lütfen zamanı dakika cinsinden seçiniz.
button 200 100 252 253 106 1 2
button 225 100 250 251 106 1 1
button 315 180 5579 5580 106 1 3
button 25 180 5545 5546 106 1 4


[dialog zamanayarla button]
on=1
src.tag.zaman ++
src.dialogclose zamanayarla
src.dialog zamanayarla

on=2
src.tag.zaman --
src.dialogclose zamanayarla
src.dialog zamanayarla

on=3
src.dialogclose
src.sysmessageua 666,0,0,trk, İptal edildi.

on=4
src.dialogclose
Src.dialog Culum_Duyuru_Yolla
src.sysmessageua 666,0,0,trk, Duyuru menüsü açıldı.

//Duyuru girişini yapmak için
[DIALOG Culum_Duyuru_Yolla]
0, 0
noclose
nomove
resizepic 0 0 1228 390 300
page 0
dtextentry 25 110 350 75 300 1
dtext 115 5 50 <serv.name> Duyuru menüsü
dhtmlgump 25 80 125 25 1 0 Duyuru içeriği:
dhtmlgump 25 50 350 50 0 0 Saygın, "<src.name>" lütfen duyuruyu kısa ve öz yazınız!
dhtmlgump 115 190 170 50 0 0 Lütfen duyurularda güzel Türkçe'mizi bozmayalım.
button 25 180 5545 5546 106 1 1
button 315 180 5579 5580 106 1 2

[DIALOG Culum_Duyuru_Yolla BUTTON]

on=1
db.connect
if (<db.connected>)
serv.newitem i_duyurucu
new.p 5454,1103
db.execute "insert into culum_duyuru_tablo (kimlik,duyuru,esyakimlik,yazankisi,zaman) values (NULL,'<slashekle <ARGTXT[1]>>','<new.uid>','<slashekle <src.name>>','<eval <src.tag.zaman>>')"
src.sysmessageua 666,0,0,trk, Saygın "<src.name>" Duyuru başarı ile kaydedildi.
endif
db.close

on=2
src.dialogclose
src.sysmessageua 666,0,0,trk, Duyuru iptal edildi.

//Duyuru göstermek için
[DIALOG Culum_Duyuru_Goster]
0,0

PAGE 1
button 15 30 30 30 0 2 1
dtext 15 60 020 Duyuru!

PAGE 2
resizepic 30 30 1228 390 300
dtext 115 35 50 <serv.name> Duyuru menüsü

dhtmlgump 70 75 150 25 1 0 Yazan kişi : <var.yazan>
dhtmlgump 70 125 300 125 1 1 Duyuru içeriği: <var.duyuru>

//Rowall'a teşekkürler
[function rowall]
trysrc <uid> dialog Culum_Duyuru_Goster

//Duyuran elemanımız
[itemdef i_duyurucu]
id i_memory
name Duyurucu

on=@create
timer 5


on=@timer
db.connect
if <db.connected>
db.query "select * from culum_duyuru_tablo where esyakimlik='<uid>'"
var.duyuru = <db.row.duyuru>
var.yazan = <db.row.yazankisi>
serv.allclients rowall
timer <eval <db.row.zaman>*60>
db.close
return 1
else
timer 25
return 1
endif



//Duyuru sileceğimiz menü
[DIALOG Culum_Duyuru_Duzenle]
0, 0
resizepic 0 0 5150 650 500
page 0
noclose
nomove
db.connect
if (<db.connected>)
db.query "select * from culum_duyuru_tablo order by kimlik DESC"
dhtmlgump 100 3 550 50 0 0"<serv.name>" duyuru düzenleme menüsüne hoş geldiniz. - Toplam duyuru: <eval <db.row.numrows>>
if (<eval <src.tag.sayfa>> == 0)
src.tag.sayfa 0
endif
db.query "select * from culum_duyuru_tablo order by kimlik DESC  limit <eval <src.tag.sayfa>>, <eval <src.tag.sayfa>+5> ;"
if (<eval <db.row.numrows>> > 0)
dhtmlgump 25 40 50 25 1 0 Sil
dhtmlgump 85 40 125 25 1 0 Gönderen
dhtmlgump 225 40 300 25 1 0 Duyuru
dhtmlgump 550 40 50 25 1 0 Zaman
for cek 0 <eval <db.row.numrows>-1>
if (<local.satir> = 0)
local.satir 80
endif
radio 30 <dlocal.satir> 56 55 0 <db.row.<dlocal.cek>.kimlik>
dhtmlgump 85 <dlocal.satir> 125 25 1 0 <db.row.<dlocal.cek>.yazankisi>   
dhtmlgump 225 <dlocal.satir> 300 25 1 0 <db.row.<dlocal.cek>.duyuru>   
dhtmlgump 550 <dlocal.satir> 50 25 1 0 <db.row.<dlocal.cek>.zaman>
local.satir +=75
endfor


button 175 410 5545 5546 106 1 4
button 420 410 5579 5580 106 1 3



button 570 450 4005 4006 106 1 2
else
dhtmlgump 250 200 170 30 1 0 Duyuru yok!
endif

if !(<eval <src.tag.sayfa>> < 1)
button 50 450 4014 4015 106 1 1
endif
db.close


endif

[DIALOG Culum_duyuru_Duzenle BUTTON]

on=1
src.tag.sayfa <eval <src.tag.sayfa>-5>
src.dialog Culum_Duyuru_Goster

on=2
src.tag.sayfa <eval <src.tag.sayfa>+5>
src.dialog Culum_Duyuru_Goster

on=3
src.dialogclose
src.sysmessageua 666,0,0,trk, Duyuru düzenleme iptal edildi.
src.tag.sayfa 0

on=4
db.connect
if <db.connected>
db.query "select * from culum_duyuru_tablo where kimlik='<argchkid>'"
uid.<db.row.esyakimlik>.remove
db.query "delete from culum_duyuru_tablo where kimlik='<argchkid>'"
src.sysmessageua 666,0,0,trk, Duyuru başarı ile silindi.
else
src.sysmessageua 666,0,0,trk, Veritabanı:Mysql'a erişim sağlanamıyor lütfen ayarlarınızı kontrol edin.
endif