[ITEMDEF i_drum_stat]
ID=i_drum
NAME=Drum
TYPE=T_NORMAL

ON=@CREATE
DORAND 3
TAG0.STAT Str
TAG0.STAT Int
TAG0.STAT Dex
ENDDO
ATTR |= 010

ON=@CLICK
MSG_OK [<TAG0.STAT>]
MSG_NORMAL <NAME>
RETURN 1

ON=@DCLICK
LOCAL.STAT=<EVAL (<SRC.STR>+<SRC.INT>+<SRC.DEX>)>
IF (<SRC.<TAG0.STAT>> >= 100)
SRC.SYS_HATA <TAG0.STAT> statınız zaten maximum seviyede.
ELSEIF <EVAL (<LOCAL.STAT> +1)> > 225
SRC.SYS_HATA Statlarınız aşılmış bu işlemi yapamazsınız.
ELSEIF (<SRC.F_CHECK_STAT 32,44,47>)
SRC.SYS_HATA Statlarınız etkileyen bir büyü altında iken bunu yapamazsınız.
ELSE
SRC.<TAG0.STAT> ++
ENDIF
RETURN 1

[FUNCTION f_check_stat]
FOR 0 2
IF (<FINDLAYER.<ARGV[<dLOCAL._FOR>]>>)
RETURN 1
ENDIF
ENDFOR
RETURN 0

[FUNCTION stat]
SRC.FINDLAYER(32).REMOVE
SRC.FINDLAYER(44).REMOVE
SRC.FINDLAYER(47).REMOVE
SRC.F_RESENDIALOG D_STAT_SYSTEM

[DIALOG D_STAT_SYSTEM]
300,100
NOMOVE
RESIZEPIC 0 0 02422 245 330
DHTMLGUMP 60 18 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Stat Sistemi
DHTMLGUMP 55 45 999 20 0 0 Str seviyeniz : <SRC.STR>
DHTMLGUMP 55 75 999 20 0 0 İnt seviyeniz : <SRC.INT>
DHTMLGUMP 55 105 999 20 0 0 Dex seviyeniz : <SRC.DEX>
DHTMLGUMP 55 135 999 20 0 0 <QVAL (<SRC.ISEVENT.E_STAT>)?Statlarımın korumasını kaldır:Statlarımı korumaya al>
DHTMLGUMP 30 170 150 150 0 0 Bu menüden sadece stat düşürme,koruma altına alma gibi işlemler yapabilirsiniz.Statlarınızı arttırmak için şehirlerde bulunan 'Stat Drum' ları kullanabilirsiniz.

FOR 4
BUTTON 30 <EVAL (<LOCAL._FOR>*30)+15> <DEF.BUTTONID_1> 1 0 <DLOCAL._FOR>
ENDFOR

[DIALOG D_STAT_SYSTEM BUTTON]
ON = 1,3
LOCAL.STAT "Str,Int,Dex"
LOCAL.STAT2 "<F_SELECT <DARGN>,<LOCAL.STAT>>
IF (<SRC.F_FLAGS_CHECK>)
SRC.SYS_HATA Bu durumda iken bunu yapamazsınız.
ELSEIF (<SRC.F_CHECK_STAT 32,44,47>)
SRC.SYS_HATA Statlarınız etkileyen bir büyü altında iken bunu yapamazsınız.
ELSEIF <EVAL (<SRC.<LOCAL.STAT2>>-1)> < 25
SRC.SYS_HATA <LOCAL.STAT2> statınızı 25'ten aşağı düşüremezsiniz.
ELSE
IF (<SRC.<LOCAL.STAT2>> != 0)
SRC.<LOCAL.STAT2> --
SRC.F_RESENDIALOG D_STAT_SYSTEM
ENDIF
ENDIF

ON = 4
IF (<SRC.F_CHECK_STAT 32,44,47>)
SRC.SYS_HATA Statlarınızı etkileyen bir büyü altında iken bunu yapamazsınız.
ELSEIF !(<SRC.ISEVENT.E_STAT>) && <EVAL (<SRC.STR>+<SRC.INT>+<SRC.DEX>> != 225)
SRC.SYS_HATA Bunu yapabilmek için stat toplamınız 225 olması gerekir.
ELSE
SRC.F_UNEQUIP_PACK
IF !(<SRC.ISEVENT.E_STAT>)
SRC.TAG0.STR = <SRC.STR>
SRC.TAG0.INT = <SRC.INT>
SRC.TAG0.DEX = <SRC.DEX>
SRC.SYS_OK Statlarınız koruma altına alınmıştır.
SRC.EVENTS +e_stat
ELSE
SRC.SYS_OK Statlarınızın koruması kalkmıştır.
SRC.EVENTS -e_stat
ENDIF
ENDIF

[EVENTS E_STAT]
On=@SkillStart
SRC.F_STAT_OPTIONS

On=@SpellCast
SRC.F_STAT_OPTIONS

On=@EnvironChange
IF !(<SRC.F_CHECK_STAT 32,44,47>) && (<TAG0.STR>) && (<TAG0.INT>) && (<TAG0.DEX>)
SRC.STR <SRC.TAG0.STR>
SRC.DEX <SRC.TAG0.DEX>
SRC.INT <SRC.TAG0.INT>
ENDIF

On=@Login
SRC.F_STAT_OPTIONS

On=@UserWarMode
SRC.F_STAT_OPTIONS

[FUNCTION f_stat_options]
IF (<F_CHECK_STAT 32,44,47>) || !(<TAG0.STR>) || !(<TAG0.INT>) || !(<TAG0.DEX>)
RETURN 0
ELSE
STR <dTAG0.STR>
INT <dTAG0.INT>
DEX <dTAG0.DEX>
ENDIF

[EOF]