[DEFNAME houses]
Houses_Cat_1 "i_deed_House_stone_wood_small,i_deed_House_stone_brick_small,i_deed_House_stone_small,i_deed_house_stone_plaster_small"
Houses_Cat_2 "i_deed_House_wood_plaster_small,i_deed_House_wood_thatched_small,i_deed_house_wood_plaster_2story"
Houses_Cat_3 "i_deed_house_3room,i_deed_house_stone_plaster_2story,i_deed_shop_marble_small,i_deed_shop_stone_small,i_deed_villa_2story,i_deed_house_patio_sand,i_deed_house_patio_marble"
Houses_Cat_4 "i_deed_tower,i_deed_keep,i_deed_castle"

[DIALOG d_house_created]
50,50
NoMove
PAGE 1
Resizepic 20 20 02422 210 165
DhtmlGump 50 40 300 20 0 0 <Def.Bfont_Red><SERV.NAME> Ev Yapma Menüsü
DhtmlGump 75 78 300 20 0 0 Küçük Binalar
DhtmlGUmp 75 98 300 20 0 0 Tahta Binalar
DhtmlGump 75 118 300 20 0 0 Diğer Binalar
DhtmlGump 75 138 300 20 0 0 Büyük Binalar

FOR 4
Button 50 <EVAL (<LOCAL._FOR>*20)+58> <DEF.BUTTONID_1> 0 <EVAL <LOCAL._FOR> +1> 1
ENDFOR

PAGE 2
Resizepic 20 20 02422 260 165
DhtmlGump 80 40 300 20 0 0 <Def.Bfont_Red><SERV.NAME> Küçük Binalar
FOR <F_ARRAY <DEF.HOUSES_CAT_1>>
Button 50 <EVAL (<LOCAL._FOR>*20)+50> <DEF.BUTTONID_1> 2 0 <EVAL <LOCAL._FOR> +5>
DhtmlGump 70 <EVAL (<LOCAL._FOR>*20)+50> 300 20 0 0 <STRSUB 10 99 <SERV.ITEMDEF.<F_SELECT <DLOCAL._FOR>,<DEF.HOUSES_CAT_1>>.NAME>>
ENDFOR

PAGE 3
Resizepic 20 20 02422 290 145
DhtmlGump 90 40 300 20 0 0 <Def.Bfont_Red><SERV.NAME> Tahta Binalar
FOR <F_ARRAY <DEF.HOUSES_CAT_2>>
Button 50 <EVAL (<LOCAL._FOR>*20)+50> <DEF.BUTTONID_1> 3 0 <EVAL <LOCAL._FOR> +10>
DhtmlGump 70 <EVAL (<LOCAL._FOR>*20)+50> 300 20 0 0 <STRSUB 10 99 <SERV.ITEMDEF.<F_SELECT <DLOCAL._FOR>,<DEF.HOUSES_CAT_2>>.NAME>>
ENDFOR

PAGE 4
Resizepic 20 20 02422 295 220
DhtmlGump 90 40 300 20 0 0 <Def.Bfont_Red><SERV.NAME> Diğer Binalar
FOR <F_ARRAY <DEF.HOUSES_CAT_3>>
Button 50 <EVAL (<LOCAL._FOR>*20)+50> <DEF.BUTTONID_1> 4 0 <EVAL <LOCAL._FOR> +25>
DhtmlGump 70 <EVAL (<LOCAL._FOR>*20)+50> 300 20 0 0 <STRSUB 10 99 <SERV.ITEMDEF.<F_SELECT <DLOCAL._FOR>,<DEF.HOUSES_CAT_3>>.NAME>>
ENDFOR

PAGE 5
Resizepic 20 20 02422 180 145
DhtmlGump 50 40 300 20 0 0 <Def.Bfont_Red><SERV.NAME> Büyük Binalar
FOR <F_ARRAY <DEF.HOUSES_CAT_4>>
Button 50 <EVAL (<LOCAL._FOR>*20)+50> <DEF.BUTTONID_1> 5 0 <EVAL <LOCAL._FOR> +45>
DhtmlGump 70 <EVAL (<LOCAL._FOR>*20)+50> 300 20 0 0 <STRSUB 10 99 <SERV.ITEMDEF.<F_SELECT <DLOCAL._FOR>,<DEF.HOUSES_CAT_4>>.NAME>>
ENDFOR

[DIALOG d_house_created BUTTON]
ON=6,200
IF (<dARGN> >= 6) && (<dARGN> <= 9)
LOCAL.CAT = 1,5
ELSEIF (<dARGN> >= 11) && (<dARGN> <= 13)
LOCAL.CAT = 2,10
ELSEIF (<dARGN> >= 26) && (<dARGN> <= 32)
LOCAL.CAT = 3,25
ELSEIF (<dARGN> >= 46) && (<dARGN> <= 48)
LOCAL.CAT = 4,45
ENDIF
LOCAL.ITEM = <F_SELECT (<EVAL <ARGN>-<STREAT <LOCAL.CAT>>>),<DEF.HOUSES_CAT_<STRARG <dLOCAL.CAT>>>>
IF (<TOPOBJ>!=<SRC>)
SRC.SYS_HATA Ev yapım aleti çantanızda olmalıdır.
ELSEIF !(<SRC.CANMAKE <LOCAL.ITEM>>)
SRC.SYSMESSAGE @58,,1 <STRSUB 10 99 <SERV.ITEMDEF.<LOCAL.ITEM>.NAME>> yapabilmek için <SERV.ITEMDEF.<LOCAL.ITEM>.RESMAKE> gerekli.
SRC.SYS_HATA Bu eşyayı yapabilmek için <SERV.ITEMDEF.<LOCAL.ITEM>.SKILLMAKE> gerekli.
ELSE
SRC.MAKEITEM <LOCAL.ITEM>
ENDIF

[ITEMDEF i_house_crafting]
ID i_hammer_sledge
Name Ev Yapim Aleti
VALUE 10000
TYPE t_normal

On=@Create
ATTR=Attr_Newbie
COLOR=0fa1

On=@Dclick
IF (<TOPOBJ>!=<SRC>)
SRC.SYS_HATA Bunu kullana bilmek için çantanızla olması gerekir.
ELSE
F_ResenDialog d_house_created
ENDIF
RETURN 1

On=@Click
MSG_NORMAL <NAME>
RETURN 1

[ITEMDEF i_house_stone]
ID i_ingot_iron
NAME Taş
WEIGHT 0.1
TYPE t_normal

On=@Create
COLOR=0482

On=@Click
MSG_NORMAL <AMOUNT> <NAME>
RETURN 1

On=@Dclick
SRC.SYS_HATA Ev yapımında kullanılır.
RETURN 1