[DEFNAME Rank_System]
RANK "04000a970"
PLAYER_FAME "5000"
PLAYER_LIST "5"
PLAYER_REWARD "1,i_pet_ostard_desert"
RANK_ACTIVE "1"
[FUNCTION rank]
REF9=<DEF.RANK>
IF !(<REF9>)
RETURN 1
ENDIF
SRC.F_RESENDIALOG <QVAL (<F_RANK_SORGULA <SRC>>)?D_RANK_KAYIT:D_RANK>
[FUNCTION f_rank_kaydol]
REF9=<DEF.RANK>
REF9.MORE1 ++
REF9.TAG0.<REF9.MORE1>_RANK <ARGS>
[FUNCTION f_rank_sorgula]
REF9=<DEF.RANK>
FOR <REF9.MORE1>
IF (<REF9.TAG0.<LOCAL._FOR>_RANK>==<ARGS>)
RETURN 0
ENDIF
ENDFOR
RETURN 1
[FUNCTION f_rank_islem]
REF3=<DEF.RANK>
FOR <REF3.DMORE1>
REF4=<REF3.TAG0.<LOCAL._FOR>_RANK>
IF <DARGS>==1
REF4.EVENTS -E_RANK
REF4.TAG0.PUAN=
REF3.CLEARTAGS
REF3.MORE1
ELSE
REF4.TAG0.PUAN=
ENDIF
ENDFOR
[FUNCTION f_rank_cik]
REF3=<DEF.RANK>
FOR <REF3.DMORE1>
IF (<REF3.TAG0.<LOCAL._FOR>_RANK> == <ARGS>)
REF3.TAG0.<LOCAL._FOR>_RANK=
ENDIF
ENDFOR
[FUNCTION f_birinci_rank]
REF9=<DEF.RANK>
FOR <REF9.MORE1>
IF (<UID.<REF9.TAG0.<LOCAL._FOR>_RANK>.dTAG0.PUAN> > <dLOCAL.POINT>)
LOCAL.POINT=<UID.<REF9.TAG0.<LOCAL._FOR>_RANK>.dTAG0.PUAN>
LOCAL.UID=<REF9.TAG0.<LOCAL._FOR>_RANK>
ENDIF
ENDFOR
RETURN <LOCAL.UID>
[DIALOG D_RANK]
50,50
NOMOVE
RESIZEPIC 0 0 02422 500 (<DEF.PLAYER_LIST>*50)
DHTMLGUMP 180 13 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Rank Sistemi
DHTMLGUMP 40 40 999 20 0 0 <DEF.BFONT_RED><DEF.BFONT_SIZE7>Oyuncu ismi:
DHTMLGUMP 200 40 999 20 0 0 <DEF.BFONT_RED><DEF.BFONT_SIZE7>Puanı:
DHTMLGUMP 340 40 999 20 0 0 <DEF.BFONT_RED><DEF.BFONT_SIZE7>Şuanki Konumu:
DHTMLGUMP 140 217 999 20 0 0 <DEF.BFONT_RED>Belirlenen ödül : <SERV.ITEMDEF.<F_SELECT 2,<DEF.PLAYER_REWARD>>.NAME>
REF9=<DEF.RANK>
FOR <REF9.MORE1>
LOCAL.RANK_<dLOCAL._FOR> <REF9.TAG0.<LOCAL._FOR>_RANK>
ENDFOR
FOR X <REF9.MORE1>
FOR Y <REF9.MORE1>
IF (<UID.<LOCAL.RANK_<dLOCAL.X>>.dTAG0.PUAN> > <UID.<LOCAL.RANK_<dLOCAL.Y>>.dTAG0.PUAN>)
LOCAL.GECICI=<LOCAL.RANK_<dLOCAL.Y>>
LOCAL.RANK_<dLOCAL.Y>=<LOCAL.RANK_<dLOCAL.X>>
LOCAL.RANK_<dLOCAL.X>=<LOCAL.GECICI>
ENDIF
ENDFOR
ENDFOR
FOR <dDEF.PLAYER_LIST>
REF45=<LOCAL.RANK_<dLOCAL._FOR>>
LOCAL.X=<EVAL (<LOCAL._FOR>*30)+45>
DHTMLGUMP 40 <dLOCAL.X> 999 20 0 0 <dLOCAL._FOR>.<REF45.NAME>
DHTMLGUMP 200 <dLOCAL.X> 999 20 0 0 <REF45.dTAG0.PUAN>
DHTMLGUMP 350 <dLOCAL.X> 999 20 0 0 <QVAL (<REF45.ISONLINE>)?<REF45.REGION.NAME>:Offline>
ENDFOR
[DIALOG d_rank_kayit]
100,100
NOMOVE
RESIZEPIC 0 0 02422 295 200
DHTMLGUMP 80 18 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Rank Sistemi
DHTMLGUMP 25 50 999 20 0 0 Sizin durumunuz : <QVAL (<F_RANK_SORGULA <SRC>>)?Sisteme kayıt olmamış:Sisteme kayıtlı>
DHTMLGUMP 55 98 999 20 0 0 Evet,kayıt olmak istiyorum.
DHTMLGUMP 55 128 999 20 0 0 Hayır,kayıt olmak istemiyorum.
BUTTON 30 99 <DEF.BUTTONID_1> 1 0 1
BUTTON 30 129 <DEF.BUTTONID_1> 1 0 2
[DIALOG d_rank_kayit BUTTON]
ON=1
IF (<F_RANK_SORGULA <SRC>>)
F_RANK_KAYDOL <SRC>
SRC.EVENTS +e_rank
SRC.SYS_OK Rank sistemine kayıt edildiniz.
ELSE
SRC.SYS_HATA Rank sistemine zaten kayıt edilmişsiniz.
ENDIF
ON=2
SRC.SYS_HATA Rank sistemine kayıt olmaktan vazgeçtiniz.
[EVENTS e_rank]
ON=@Kill
REF3=<ARGO>
IF (<REF3.ISCHAR>) && (<REF3.FAME> >= <dDEF.PLAYER_FAME>) && (<REF3>!=<SRC>)
SRC.TAG0.PUAN ++
SRC.SYS_OK <REF3.NAME> isimli hedefi öldürerek rank puanı kazandınız.Yeni puanınız:<SRC.DTAG0.PUAN>
REF3.TAG0.PUAN --
REF3.SYS_HATA <SRC.NAME> isimli hedef tarafından öldürüldüğünüz için rank puanı kaybettiniz.
IF (<REF3.ISPLAYER>)
SERV.B @1153,,1 Rank Duyuru:
SERV.B @50,,1 Anons:<REF3.NAME>,<SRC.NAME> tarafından <REGION.NAME> civarlarında katledildi.
ENDIF
ENDIF
[ITEMDEF I_RANK_SISTEM]
ID I_GRAVESTONE_17
NAME Rank Sistemi
TYPE T_NORMAL
ON=@Create
TIMER = <EVAL (3600*24)*7>
ATTR |= 010
COLOR = 0455
ON=@Click
MSG_OK [Kayıtlı:<dMORE1>]
MSG_NORMAL [En iyi rank:<UID.<F_BIRINCI_RANK>.NAME>]
MSG_NORMAL [Kalan süre:<F_LOOK_TIME <DTIMER>>]
RETURN 1
ON=@Dclick
RETURN 1
ON=@Pickup_Ground
RETURN 1
ON=@Timer
REF4=<F_BIRINCI_RANK>
IF STRMATCH("<F_SELECT 1,<DEF.PLAYER_REWARD>>","1")
SERV.NEWITEM <F_SELECT 2,<DEF.PLAYER_REWARD>>,1,<REF4.FINDLAYER(29)>
ENDIF
SERV.B @1153,1,1 Rank Duyuru:
SERV.B @50,,1 Rank sistemi hafta birincisi : <REF4.NAME>
TIMER=<EVAL (3600*24)*7>
VAR0.WEEK_WHO_FIRST=<REF4.NAME>
F_RANK_ISLEM 2
RETURN 1
