[DEFNAME PIN_SYSTEM]
PIN_SYSTEM "D_PIN_CHANGE,D_PIN_KOD_CHANGE"

[FUNCTION pin]
SRC.F_CLOSEDIALOG pin
IF !(<ACCOUNT.TAG0.PIN_INFO>) && !(<CTAG0.PIN_ENTER>)
SRC.F_RESENDIALOG D_PIN_NEW
ELSEIF (<CTAG0.PIN_ENTER>) && (<ACCOUNT.TAG0.PIN_INFO>)
SRC.F_RESENDIALOG D_PIN_SYSTEM
ELSE
SRC.F_RESENDIALOG D_PIN_ENTER
ENDIF

[DIALOG D_PIN_NEW]
100,100
nomove
resizepic 0 0 02422 300 300
resizepic 110 97 3000 100 30
resizepic 114 200 3000 100 30
dtextentry 115 100 400 20 0 1
dtextentry 120 202 400 20 0 2
dhtmlgump 85 16 999 20 0 0 <def.bfont_red><serv.name> Pin Sistemi
dhtmlgump 30 50 999 20 0 0 Lütfen bir pin şifresi belirleyiniz.
dhtmlgump 30 150 999 20 0 0 Lütfen bir gizli kod belirleyiniz.
dhtmlgump 30 100 70 20 0 0 Pin Şifrem:
dhtmlgump 30 203 70 20 0 0 Gizli Kodum:
dhtmlgump 40 250 50 20 0 0 Tamam
dhtmlgump 203 250 50 20 0 0 Vazgeç
button 80 250 <def.buttonid_2> 1 0 1
button 180 250 <def.buttonid_1> 1 0 0

[dialog d_pin_new button]
on=0
src.sys_ok Güvenlik için pin şifresi kaydetmeniz daha iyi olacaktır.

on=1
IF (<ISEMPTY <ARGTXT[1]>>) || (<ISEMPTY <ARGTXT[2]>>)
SRC.SYS_HATA Bilgileri eksiksiz girmeniz gereklir.
ELSEIF <EVAL STRLEN(<ARGTXT[1]>)> != 4
SRC.SYS_HATA Pin şifreniz 4 karakterden oluşabilir.
ELSEIF !(<ISNUMBER <ARGTXT[1]>>)
SRC.SYS_HATA Pin şifreniz sadece rakam içerebilir.
ELSE
SRC.ACCOUNT.TAG0.pin_info <ARGTXT[1]>,<ARGTXT[2]>
SRC.EVENTS +PIN
SRC.SYS_OK Pin şifreniz oluşturuldu,iyi oyunlar dileriz.
ENDIF

[dialog d_pin_enter]
100,100
nomove
resizepic 0 0 02422 350 180
resizepic 100 97 2620 100 30
dhtmlgump 105 16 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Pin Sistemi
dhtmlgump 30 50 999 20 0 0 Lütfen pin şifrenizi giriniz.
dhtmlgump 30 97 70 20 0 0 Pin şifrem:
dhtmlgump 235 96 999 20 0 0 Tamam
dhtmlgump 235 116 999 20 0 0 Pinimi unuttum

button 210 96 <DEF.BUTTONID_1> 1 0 1
button 210 116 <DEF.BUTTONID_1> 1 0 2

dtextentry 105 100 400 20 0 1

[dialog d_pin_enter button]
ON=1
IF !STRMATCH("<ARGTXT[1]>","<STRARG <SRC.ACCOUNT.TAG0.PIN_INFO>>")
src.sys_hata Hatalı pin şifresi girdiniz.
ELSE
SRC.SYS_OK Pin girişi başarılı...
SRC.CTAG0.PIN_ENTER=1
ENDIF

on=2
SRC.F_RESENDIALOG D_PIN_LOST

[dialog d_pin_lost]
100,100
nomove
resizepic 0 0 02422 300 180
resizepic 100 97 3000 100 30
dhtmlgump 85 16 999 20 0 0 <def.bfont_RED><serv.name> Pin Sistemi
dhtmlgump 30 50 150 20 0 0 Lütfen gizli koduzunu giriniz.
dhtmlgump 36 100 100 20 0 0 Gizli Kod:
dhtmlgump 235 102 100 20 0 0 Tamam

button 210 102 <def.buttonid_1> 1 0 1
dtextentry 105 100 400 20 0 1

[dialog d_pin_lost button]
ON=0
SRC.SYS_OK Giriş yapmaktan vazgeçtiniz.

ON=1
<qval strmatch("<ARGTXT[1]>","<STREAT <SRC.ACCOUNT.TAG0.PIN_INFO>>")?src.sys_ok Doğru giriş yaptınız,pin şifreniz-<STRARG <SRC.ACCOUNT.TAG0.PIN_INFO>>:src.sys_hata Gizli kodunuzu yanlış girdiniz!>

[dialog d_pin_system]
100,100
nomove
resizepic 0 0 02422 300 260
dhtmlgump 85 16 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Pin Sistemi
dhtmlgump 40 50 999 20 0 0 Hangi işlemleri yapacaksınız ?
dhtmlgump 60 89 999 20 0 0 Pin şifremi değiştir.
dhtmlgump 60 119 999 20 0 0 Gizli kodu değiştir.
dhtmlgump 60 150 999 20 0 0 Pin sistemini kullanmak istemiyorum.
dhtmlgump 60 180 999 20 0 0 Çıkış yap.

FOR 4
BUTTON 30 <EVAL (<LOCAL._FOR>*30)+60> <DEF.BUTTONID_1> 1 0 <DLOCAL._FOR>
ENDFOR

[dialog d_pin_system button]
ON=1,2
<QVAL !(<SRC.CTAG0.PIN_ENTER>)?SRC.SYS_HATA Pin girişi yapmalısınız!:SRC.F_RESENDIALOG <F_SELECT <DARGN>,<DEF.PIN_SYSTEM>>>

on=3
IF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Pin girişi yapmalısınız.
ELSE
SRC.EVENTS -pin
SRC.ACCOUNT.TAG0.PIN_INFO=
SRC.CTAG0.PIN_ENTER=
SRC.SYS_OK Bilgileriniz sıfırlandı ve sistem iptal edildi.
ENDIF

on=4
SRC.CTAG0.PIN_ENTER=
src.sys_ok Çıkış yaptınız.

[dialog d_pin_kod_change]
100,100
nomove
resizepic 0 0 02422 300 300
resizepic 110 97 3000 100 30
resizepic 114 200 3000 100 30

dtextentry 115 100 400 20 0 1
dtextentry 120 202 400 20 0 2

dhtmlgump 85 16 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Pin Sistemi
dhtmlgump 30 50 999 20 0 0 Eski güvenli kodunuzu giriniz.
dhtmlgump 30 150 999 20 0 0 Yeni güvenli kodunuzu giriniz.
dhtmlgump 30 100 70 20 0 0 Eski Kodum:
dhtmlgump 30 203 90 20 0 0 Yeni Kodum:

dhtmlgump 40 250 50 20 0 0 Tamam
dhtmlgump 203 250 50 20 0 0 Vazgeç

button 80 250 <DEF.BUTTONID_2> 1 0 1
button 180 250 <DEF.BUTTONID_1> 1 0 0

[dialog d_pin_kod_change button]
on=0
src.sys_ok Gizli kod değiştirme işleminden vazgeçtiniz.

on=1
IF (<ISEMPTY <ARGTXT[1]>>) || (<ISEMPTY <ARGTXT[2]>>)
SRC.SYS_HATA Bilgileri eksiksiz girmelisiniz.
ELSEIF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Pin girişi yapmalısınız.
ELSEIF !STRMATCH('<ARGTXT[1]>','<STREAT <SRC.ACCOUNT.TAG0.PIN_INFO>>')
SRC.SYS_HATA Hatalı kod girdiniz.
ELSE
LOCAL.OLD=<STRARG <SRC.ACCOUNT.TAG0.PIN_INFO>>
SRC.ACCOUNT.TAG0.PIN_INFO <LOCAL.OLD>,<ARGTXT[2]>
SRC.SYS_OK Gizli kodunuz değiştirilmiştir.
ENDIF
RETURN 1

[dialog d_pin_change]
100,100
nomove
resizepic 0 0 02422 300 300
resizepic 110 97 3000 100 30
resizepic 114 200 3000 100 30

dtextentry 115 100 400 20 0 1
dtextentry 120 202 400 20 0 2

dhtmlgump 85 16 999 20 0 0 <DEF.BFONT_RED><SERV.NAME> Pin Sistemi
dhtmlgump 30 50 999 20 0 0 Eski pin şifrenizi giriniz.
dhtmlgump 30 150 999 20 0 0 Yeni pin şifrenizi giriniz.
dhtmlgump 30 100 999 20 0 0 Eski pinim :
dhtmlgump 30 203 999 20 0 0 Yeni pinim :

dhtmlgump 40 250 999 20 0 0 Tamam
dhtmlgump 203 250 999 20 0 0 Vazgeç

button 80 250 <DEF.BUTTONID_2> 1 0 1
button 180 250 <DEF.BUTTONID_1> 1 0 0

[dialog d_pin_change button]
on=0
src.sys_ok Pin değiştirme işlemini iptal ettiniz.

ON=1
IF (<ISEMPTY <ARGTXT[1]>>) || (<ISEMPTY <ARGTXT[2]>>)
SRC.SYS_HATA Bilgileri eksiksiz girmelisiniz.
ELSEIF !STRMATCH("<ARGTXT[1]>","<STRARG <SRC.ACCOUNT.TAG0.PIN_INFO>>")
SRC.SYS_HATA Eski şifrenizi yanlış girdiniz.
ELSEIF !(<ISNUMBER <ARGTXT[1]>>)
SRC.SYS_HATA Pin şifreniz sadece rakamlardan oluşabilir.
ELSEIF (STRLEN(<ARGTXT[2]>)) != 4
SRC.SYS_HATA Pin şifreniz 4 karakter içerebilir.
ELSE
LOCAL.OLD=<STREAT <SRC.ACCOUNT.TAG0.PIN_INFO>>
SRC.ACCOUNT.TAG0.PIN_INFO=<ARGTXT[2]>,<LOCAL.OLD>
SRC.SYS_OK Pin şifrenizi değiştirdiniz.
ENDIF

[EVENTS pin]
On=@ItemPickup_Ground
IF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Lütfen pin girişi yapınız!('.pin')
RETURN 1
ENDIF

On=@ItemDclick
IF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Lütfen pin girişi yapınız!('.pin')
RETURN 1
ENDIF

On=@ItemPickup_Pack
IF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Lütfen pin girişi yapınız!('.pin')
RETURN 1
ENDIF

On=@ItemTargon_Item
IF !(<SRC.CTAG0.PIN_ENTER>)
SRC.SYS_HATA Lütfen pin girişi yapınız!('.pin')
RETURN 1
ENDIF

[EOF]