[TYPEDEF t_bandage]
ON=@DCLICK
IF (<SRC.FINDID(i_use_bandage)>) && (<SRC.FINDID(i_use_bandage).TIMER> < 0)
SRC.FINDID(i_use_bandage).Remove
ENDIF
IF (<TOPOBJ>!=<SRC>)
SRC.SYS_HATA Bandajları kullanmanız için çantanızda olması gerekir.
ELSEIF (<SRC.FINDID(i_use_bandage)>)
SRC.SYS_HATA Bandajları şuanda kullanamazsınız.
ELSEIF (<SRC.CTAG0.MORTAL>)
SRC.SYS_HATA Mortal Strike etkisi altında iken bandaj kullanamazsınız.
ELSEIF (<SRC.ACTION>==Skill_Magery) || (<SRC.ACTION>==ID(Skill_Magery))
SRC.SYS_HATA Büyü yaparken bandajları kullanamazsınız.
ELSEIF (<SRC.CTAG0.USED_BANDAGE>)
SRC.SYS_HATA Bandajları kullanmak için biraz daha beklemelisiniz.
ELSE
SRC.TARGETF F_HEALING_SYSTEM
SRC.SYS_OK Bandajları neyin üstünde kullanıcaksınız?
ENDIF
RETURN 1

[FUNCTION f_healing_system]
REF1=<ARGO.UID>
IF (<REF1.ISPLAYER>)
LOCAL.MAX_BANDAGE=<EVAL (<SRC.HEALING>/13)>
LOCAL.MIN_BANDAGE=<EVAL (<SRC.HEALING>/28)>
LOCAL.USE_BANDAGE=<EVAL (<LOCAL.MAX_BANDAGE>-<LOCAL.MIN_BANDAGE>)>
ELSE
LOCAL.MAX_VETERINARY=<EVAL (<SRC.VETERINARY>/14)>
LOCAL.MIN_VETERINARY=<EVAL (<SRC.VETERINARY>/28)>
LOCAL.USE_VETERINARY=<EVAL (<LOCAL.MAX_VETERINARY>-<LOCAL.MIN_VETERINARY>)>
ENDIF

IF (<dLOCAL.USE_BANDAGE> < 1)
LOCAL.USE_BANDAGE=<R1,2>
ENDIF

IF (<SRC.CTAG0.MORTAL>)
SRC.SYS_HATA Mortal Strike etkisi altında iken bandaj kullanamazsınız.
ELSEIF (<REF1.ISITEM>) || STRMATCH(*golem*,<REF1.BASEID>)
SRC.SYS_HATA <REF1.NAME> isimli hedefi iyileştiremezsiniz.
ELSEIF (<SRC.F_FLAGS2_CHECK>)
SRC.SYS_HATA Şu anki durumunuzda bunu yapamazsınız.
ELSEIF (<REF1.HITS> >= <REF1.MAXHITS>) && !(<REF1.FLAGS>&Statf_Poisoned) && !(<REF1.FINDID(i_bleeding)>)
SRC.SYS_HATA <QVAL (<REF1>!=<SRC>)?<REF1.NAME> adlı hedefin tedaviye ihtiyacı yok.:Tedaviye ihtiyaç duymuyorsunuz.>
ELSEIF (<SRC.F_CANSEELOS <REF1>>)
SRC.SYS_HATA <REF1.NAME> isimli hedefe ulaşamıyorsunuz.
ELSEIF (<REF1.TAG0.MORTAL>)
SRC.SYS_HATA <REF1.NAME> mortal strike etkisi altında olduğundan bandaj işlemini gerçekleştiremezsiniz.
ELSEIF (<SRC.ACTION>==Skill_Magery) || (<SRC.ACTION>==ID(Skill_Magery))
SRC.SYS_HATA Şuan da bandajları kullanamazsınız.
ELSEIF (<SRC.FINDID(i_use_bandage)>)
SRC.SYS_HATA Şuan da bandajları kullanamazsınız.
ELSEIF (<REF1.ISPLAYER>) && (<SRC.F_Guild_Sorgu <REF1>>)
SRC.SYS_HATA Order/Chaos üyelerini iyileştiremezsiniz.
ELSE

IF !(<REF1.FLAGS>&Statf_Dead) && (<REF1.HITS> < <REF1.MAXHITS>) || (<REF1.FLAGS>&Statf_Poisoned) || (<REF1.FINDID(i_bleeding)>)
SERV.NEWITEM i_use_bandage
NEW.LINK=<REF1>
NEW.MOREX <QVAL (<REF1.ISPLAYER>)?<dLOCAL.USE_BANDAGE>:<dLOCAL.USE_VETERINARY>>
NEW.EQUIP
RETURN 1
ENDIF

IF (<REF1.FLAGS>&Statf_Dead)
IF (<SRC.HEALING> <80.0) || !(<SRC.RESTEST 5 I_BANDAGE>)
SRC.SYS_HATA Oyuncuları canlandırmak için 5 bandage ve 80.0 healing yeteneğinizin olması gerekir.
ELSEIF (<REF1.FINDID(i_anhk_timer)>)
SRC.SYS_HATA Bu kişiyi şuan da canlandıramazsınız.
ELSEIF (<SRC.F_Guild_Sorgu <REF1>>)
SRC.SYS_HATA Order/Chaos üyelerini hayata döndüremezsiniz.
ELSE
SRC.FACE <REF1>
REF1.SpellEffect s_Resurrection,1000,<REF1>
REF1.SAYUA 038,6,6,0 *Hayata Döner*
SRC.CONSUME 5 i_bandage
IF (<REF1.KILLS> >= <SERV.MURDERMINCOUNT>) || (<REF1.ISCRIMINAL>) || (<SRC.F_Guild_Isenemy <REF1>>)
SRC.CRIMINAL 1
ENDIF
ENDIF
ENDIF

[ITEMDEF i_use_bandage]
ID I_MEMORY
NAME=Bandage System
TYPE=T_EQ_SCRIPT

ON=@CREATE
ATTR=ATTR_INVIS|ATTR_DECAY

ON=@EQUIP
TIMER=5
CONT.ANIM=17
CONT.SPELLFREEZE=4
CONT.SYS_OK <QVAL (<LINK>!=<CONT>)?<LINK.NAME> isimli hedefe bandaj uygulanıyor...:Bandajınız uygulanıyor...>
CONT.FACE=<LINK>
CONT.EVENTS +E_HEALING

ON=@UNEQUIP
CONT.EVENTS -E_HEALING

ON=@TIMER
IF (<LINK.HITS> >= <LINK.MAXHITS>) && !(<LINK.FLAGS>&Statf_Poisoned) && !(<LINK.FINDID(i_bleeding)>)
CONT.SYS_HATA <LINK.NAME> tedaviye ihtiyaç duymuyor.
ELSEIF (<LINK.FINDID(i_bleeding)>) && (<CONT.HEALING> <70.0)
CONT.SYS_HATA Yarayı tedavi edebilecek kadar yetenekli değilsiniz yada bandajınız bulunmuyor.
ELSEIF (<LINK.FLAGS>&Statf_Poisoned) && (<CONT.HEALING> <60.0)
CONT.SYS_HATA Zehiri tedavi edebilecek kadar yetenekli değilsiniz yada bandajınız bulunmuyor.
ELSEIF !(<CONT.RESTEST 1 I_BANDAGE>)
CONT.SYS_HATA Çantanızda bandaj bulunmadığı için işlem iptal edildi.
ELSEIF (<LINK.FLAGS>&Statf_Dead|Statf_Stone)
CONT.SYS_HATA <LINK.NAME> o durumda iken tedavi edemezsiniz.
ELSEIF (<CONT>!=<LINK>) && (<LINK.ISPLAYER>) && (<CONT.F_Guild_Sorgu <LINK>>) || (<CONT.F_Guild_Isenemy <LINK>>)
CONT.SYS_HATA Order/Chaos üyelerini ve düşmanlarınızı iyileştiremezsiniz.
ELSE
IF (<LINK.FLAGS>&Statf_Poisoned)
LINK.SAYUA 038,6,6,0 <QVAL (<LINK>!=<CONT>)?*Zehiri iyileştirilir*:*Zehiri iyileştirir*>
IF (<LINK.FINDID(i_rune_poison)>) || (<LINK.FINDID(i_rune_poison_field)>)
LINK.FINDID(i_rune_poison).REMOVE
LINK.FINDID(i_rune_poison_field).REMOVE
ENDIF
ELSEIF (<LINK.FINDID(i_bleeding)>)
LINK.FINDID(i_bleeding).REMOVE
LINK.SAYUA 038,6,6,0 <QVAL (<LINK>!=<CONT>)?*Yarası iyileştirilir*:*Yarayı iyileştirir*>
ELSE
LINK.HITS <EVAL (<LINK.HITS>+<MOREX>)>
LINK.SAYUA 038,6,6,0 <QVAL (<LINK>!=<CONT>)?*İyileştirilir*:*Kendini iyileştirir*>
IF (<LINK.HITS> > <LINK.MAXHITS>)
LINK.HITS=<LINK.MAXHITS>
ENDIF
ENDIF
ENDIF

CONT.CONSUME I_BANDAGE 1
IF (<LINK.ISPLAYER>) || (<LINK.ID>==c_skill_dummy_heal)
CONT.SKILLGAIN 17 1.0
ELSE
CONT.SKILLGAIN 39 1.0
ENDIF
IF (<LINK>!=<CONT>) && (<LINK.KILLS> >= <SERV.MURDERMINCOUNT>) || (<LINK.ISCRIMINAL>)
CONT.CRIMINAL 1
ENDIF
CONT.CTAG0.USED_BANDAGE=1
CONT.TIMERF 2,CTAG0.USED_BANDAGE=
REMOVE
RETURN 1

[EVENTS e_healing]
On=@LogOut
SRC.F_BANDAGE_CANCEL

On=@SpellCast
SRC.F_BANDAGE_CANCEL

On=@GetHit
IF (<dARGN1> > 20)
F_BANDAGE_CANCEL
ENDIF

On=@Death
SRC.F_BANDAGE_CANCEL

[FUNCTION f_bandage_cancel]
SAYUA 038,6,6,0 *Bandajları Yırtılır*
FINDID(i_use_bandage).REMOVE
Tag0.Nomovetill=0
EVENTS -e_healing