[FUNCTION affet]
SRC.TARGETF F_AFFET2
SRC.SYS_OK Kimi affedeceksiniz ?

[FUNCTION f_affet2]
<QVAL <ARGO.FINDID(i_jailcik)> ? ARGO.FINDID(i_jailcik).TIMER 1 : SRC.SYS_HATA <ARGO.NAME> jailde bulunmuyor.>

[FUNCTION hapis]
SRC.F_RESENDIALOG D_HAPIS

[DIALOG d_hapis]
100,100
NOMOVE
RESIZEPIC 70 120 9390 250 250
RESIZEPIC 100 180 3000 150 30
RESIZEPIC 100 250 3000 150 30

DHTMLGUMP 135 125 200 20 0 0 <DEF.BFONT_BLUE><SERV.NAME> Jail Sistemi
DHTMLGUMP 100 152 150 20 0 0 Hapis Nedenini Yazınız.
DHTMLGUMP 100 220 200 20 0 0 Hapis Süresini Yazınız.(Saat)
DHTMLGUMP 120 300 50 20 0 0 Gönder
DHTMLGUMP 230 300 60 20 0 0 Vazgeç
DTEXTENTRY 105 182 150 16 07a1 1
DTEXTENTRY 105 252 150 16 07a1 2
BUTTON 170 300 <DEF.BUTTONID_2> 1 0 1
BUTTON 200 300 <DEF.BUTTONID_1> 1 0 2

[DIALOG d_hapis BUTTON]
ON=1
IF (<ISEMPTY <ARGTXT[1]>>) || (<ISEMPTY <ARGTXT[2]>>)
SRC.SYS_HATA Lütfen bir hapis nedeni ve süresi giriniz.
ELSEIF !(<ISNUMBER <ARGTXT[2]>>)
SRC.SYS_HATA Jail süresine harf giremezsiniz.
ELSE
SRC.SYS_OK [<ARGTXT[1]>] suçundan kimi [<F_LOOK_TIME <EVAL (<ARGTXT[2]>*3600)>>] kadar jaile atacaksınız ?
SRC.TARGETF F_HAPIS <ARGTXT[1]>,<ARGTXT[2]>
ENDIF

on=2
SRC.SYS_OK Jail menüsünü kapattınız.

[FUNCTION F_HAPIS]
REF1=<ARGO.UID>
IF (<REF1.FINDID(i_stuck_ice)>)
REF1.FINDID(i_stuck_ice).Tag0.Gidilecek JAIL<R1,10>
ELSEIF (<REF1>==<SRC>)
SRC.SYS_OK Kendini jaile mi yollayacaksın ?
ELSEIF (<REF1.FINDID(i_jailcik)>)
SRC.SYS_HATA <REF1.NAME> zaten hapis cezasını çekiyor.
ELSE
REF1.ACTION = -1
REF1.GO JAIL<R1,10>
REF1.TAG0.HAPIS=1,<ARGV[0]>
REF1.EVENTS +e_hapis
SERV.NEWITEM i_jailcik,1,<REF1>,1
NEW.TIMER=<EVAL (<ARGV[1]>*3600)>
ENDIF

[EVENTS e_hapis]
On=@Click
IF STRMATCH("<STRARG <dTAG0.HAPIS>>","1")
MSG_NORMAL [Suçu:<STREAT <TAG0.HAPIS>>]
MSG_NORMAL [Süre:<F_LOOK_TIME <FINDID(i_jailcik).TIMER>>]
ENDIF

On=@SpellSelect
RETURN 1
On=@Hit
RETURN 1
On=@GETHIT
RETURN 1
On=@SpellEffect
RETURN 1
On=@SpellCast
RETURN 1
On=@SkillStart
SRC.ACTION = -1
RETURN 1
On=@ItemDclick
RETURN 1
On=@DEATH
HITS=<MAXHITS>
RETURN 1
On=@UserWarMode
RETURN 1
On=@Attack
RETURN 1
On=@SkillUseQuick
RETURN 1
On=@HitTry
RETURN 1
ON=@EnvironChange
IF (<FINDID(i_jailcik)>) && (<FINDID(i_jailcik).TIMER> <= 0)
SERV.WRITEFILE SCRIPTS/LOGS/LOGS1.TXT Jail memory problemi : Karakter hesabı:(<ACCOUNT>),Adı:(<NAME>=<UID>),Tarih(<SERV.RTIME>)
ENDIF

[ITEMDEF i_jailcik]
ID=i_memory
TYPE=t_eq_script
NAME=Jail System

ON=@CREATE
ATTR=ATTR_NEWBIE|ATTR_INVIS|ATTR_DECAY

ON=@TIMER
CONT.SYS_OK Jail cezanız bitti.Birdaha jaile girmemek üzere iyi oyunlar.
CONT.EVENTS -E_HAPIS
CONT.CLEARTAGS HAPIS
CONT.GO <SERV.AREA.<F_SELECT <R1,9>,<DEF.MOON>>.NAME>
REMOVE
RETURN 1