[function f_on_move]     
obj <local.char>
obj.trigger @move


//////////////////////////////////////////////////////////////

[ITEMDEF 0c85]
//orfluer flowers
DEFNAME=i_flower_orfluer
name=Rare Flowers
VALUE=1
CATEGORY=Vegetation
SUBSECTION=Plants and Flowers
DESCRIPTION=Orfluer Flowers

on=@create
morey 1
color=00
attr=attr_move_never
timerf 5.timer -1
timerf 5.attr 010

on=@click
message <def.sys> Rare Çiçeği
return 1

on=@dclick
if (<src.findlayer(25)>)
src.sysmessage @38,,1 Hata: At uzerindeyken cicegi toplayamazsiniz
elseif (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @38,,1 Hata: Gizlenmis durumdayken cicegi toplayamazsiniz
elseif <src.findid.i_raretimer>
src.sysmessage @38,,1 Zaten cicegi topluyorsunuz
elseif (<topobj.uid> == <src.uid>)
src.sys_normal Bu çiçeği rare yapımında kullanabilirsiniz..
elseif (<src.targ.distance> >2)
src.sys_error Çiceğe yetişemiyorsunuz.
else
src.tag.rareuid <src.targ.uid>
src.newitem i_raretimer
new.equip
src.events +e_rarespell
src.dialogclose d_runebook
src.dialogclose d_moongate_menu
endif
return 1


//////////////////////////////////////////////////////////////


[itemdef i_raretimer]
name raretimer
id 0186a
type t_eq_script
weight 0
layer layer_special

On=@Create
attr attr_invis|attr_newbie
more1 30

On=@Equip
timer 1


On=@Timer
if (<cont>)
if (<more2>)
remove
elseif (<more1>)
cont.sysmessage @1153 <eval <more1>>
more1 (<more1> - 1)
timer 1
cont.anim 32
else
if (<uid.<cont.tag.rareuid>>)
cont.uid.<cont.tag.rareuid>.remove
serv.newitem i_flower_orfluerr
cont.sysmessage @480,,1 Cicegi toplamayi basardiniz
new.cont <cont.findlayer(layer_pack)>
cont.events -e_rarespell
more2 1
timer 1
endif
endif
endif
return 1

//////////////////////////////////////////////////////////////

[events e_rarespell]

on=@death
if (<src.findid.i_raretimer>)
src.findid.i_raretimer.remove
src.sysmessage @38,,1 Cicegi toplayamadiniz
return 1
endif

on=@move
findid.i_raretimer.remove
events -e_rarespell
sysmessage @38,,1 Cicegi toplayamadiniz

on=@damage
findid.i_raretimer.remove
sysmessage @38,,1 Cicegi toplayamadiniz

on=@spelleffect
if (<argn> == 1)
findid.i_raretimer.remove
sysmessage @38,,1 Cicegi toplayamadiniz
endif

On=@SpellCast
if !((<argn> == 4) || (<argn> == 6) || (<argn> == 7) || (<argn> == 11) || (<argn> == 16) || (<argn> == 36))
src.sysmessage @38,,1 Cicek toplarken bu tur buyuleri atamazsiniz !!!
src.f_fizzle
return 1
endif

//////////////////////////////////////////////////////////////

[ITEMDEF i_flowers_orfluerr]
DEFNAME=i_flower_orfluerr
id=0c85
name=Rare Flowers
VALUE=1
CATEGORY=Vegetation
SUBSECTION=Plants and Flowers
DESCRIPTION=Orfluer Flowers

on=@create
morey 1
dorand 14
color=0799
color=0795
color=0455
color=01
color=0798
color=0ba4
color=0796
color=0800
color=0809
color=0812
color=08a1
color=0b80
color=0b79
color=2045
enddo

on=@click
message <name>
return 1


On=@DClick
if !(<topobj.uid> == <src.uid>)
src.sysmessage @38,,1 Hata: Esya cantanizda olmali.
else
target
return 1
endif

On=@TargOn_Item
if !(<src.targ.topobj.uid> == <src.uid>)
src.sysmessage @38,,1 Hata: Boyayacaginiz esya cantanizda olmali.
elseif !((<src.targ.baseid> == i_dye_tub_rare))
src.sysmessage @38,,1 Hata: Sadece Dye Tub Rare boyuyabilirsiniz.
elseif  ((<SRC.alchemy> < 90.0))
        src.sysmessage @38,,1 Hata: Alchemy skilliniz 90'dan yuksek olmali.
else
src.targ.color <color>
src.targ.update
morey (<morey> - 1)
remove
endif
return 1

On=@TargOn_Char
src.sysmessage @38,,1 Hata: Sadece Dye Tub Rare boyuyabilirsiniz.
return 1



[ITEMDEF i_dye_tub_rare]
//Dying Tub
ID=i_dye_tub
NAME=Rare Dye
TYPE=T_DYE_VAT
WEIGHT=10
CATEGORY=Items by Professions
SUBSECTION=Tailor
DESCRIPTION=Rare Dying Tub

RESOURCES=100 i_log
SKILLMAKE=CARPENTRY 100.0 ,alchemy 80.0

ON=@Create
morey 5
color 00

ON=@Click
if (0<tag.charged>==00)
tag.charged=1
tag.charge=10
endif
message @48,,1 [<eval <tag.charge>>]
message @0800 <name>
return 1
On=@DClick
if (0<tag.charged>==00)
tag.charged=1
tag.charge=10
endif
if (0<tag.charge>==00)
src.sysmessage @38,,1 Hata: Bu boya kurumus, veya bitmis
remove
return 1
endif
target
return 1


On=@TargOn_Char
return 1

On=@TargOn_Item
if !(<src.targ.topobj.uid> == <src.uid>)
src.sysmessage @38,,1 Hata: Boyayacaginiz esya uzerinizde olmali.
elseif !((<src.targ.type> = t_clothing) || (<src.targ.baseid> == i_bag) || (<src.targ.baseid> == i_magerobe_npc) || (<src.targ.baseid> == i_robe))
src.sysmessage @38,,1 Hata: Bunu boyayamazsiniz
elseif (<src.targ.baseid> == i_tc_mr3) || (<src.targ.baseid> == i_tc_mr6) || (<src.targ.baseid> == i_tc_mr9) || (<src.targ.baseid> == i_tc_mr12) || (<src.targ.baseid> == i_tc_mr15)
src.sysmessage @38,,1 Hata: Bunu boyayamazsiniz
elseif  ((<SRC.TAILORING> < 90.0))
        src.sysmessage @38,,1 Hata: Tailoring skilliniz 90'dan yuksek olmali.
elseif (<src.targ.attr>&attr_newbie)
src.sysmessage @38,,1 Hata: Newbie itemleri boyayamazsiniz
else
src.targ.color <color>
src.targ.update
tag.charge=<eval <tag.charge>-1>
endif
return 1


/////////////////////////////////////////////////////////

[itemdef i_deadly_mushroom]
id=0d16
TYPE=t_spellicon
name=deadly mushroom
CATEGORY=Spell Icons
SUBSECTION=Third Circle

on=@create
attr 010

on=@click
message <name>
return 1

on=dclick
return 1

on=@step
if (<src.isplayer>)
if (<src.account.plevel> < 2)
if !(<src.flags> & statf_dead)
src.poison 999
serv.newitem i_fx_curse
src.new.color 00
src.new.p=<src.p>
src.new.timer 2
src.new.attr=attr_decay
src.sound=snd_SPELL_POISON
endif
endif
endif
return 1

[itemdef 011c7]
defname=i_rare_kazani
type t_script
name=rare kazani

on=@create
color=0482
attr=attr_move_never

on=@click
message <def.sys> Rare Üretim Kazanı
return 1

on=@dclick
if (<src.targ.distance> >2)
src.sys_error Kazan'a yetişemiyorsunuz..
return 1
elseif (<src.alchemy> < 99.9)
src.sys_error Kazanı kullanabilmeniz için 100.0 alchemy gereklidir..
return 1
endif
src.sdialog d_raremenu

[dialog d_raremenu]
50,50
resizepic 160 50 8500 420 200
resizepic 170 60 3000 400 180
resizepic 180 140 3000 100 35
resizepic 310 140 3000 100 35
resizepic 440 140 3000 100 35
resizepic 440 190 3000 110 35
tilepic 170 135 9035 0
tilepic 305 145 4011 0
tilepic 430 145 4104 0
tilepic 430 193 4011 0

dhtmlgump 265 70 200 20 0 0 <def.bfont_red><serv.servname> Rare Üretim Sistemi
dhtmlgump 180 100 500 20 0 0 Rare yapımı için gerekli malzemeler ; 1 rare çiçeği, 1 dye tub,
dhtmlgump 180 115 150 20 0 0 1 dolu su kovası gereklidir.
dhtmlgump 230 200 100 20 0 0 Rare Üret
//dhtmlgump 460 220 100 20 0 0 rare dye
dhtmlgump 195 170 100 20 0 0 rare çiçeği
dhtmlgump 335 170 100 20 0 0 dye tub
dhtmlgump 460 170 100 20 0 0 su kovası
dtext 220 150 <qval (<src.findid.i_flower_orfluer>)?0110:025> <qval (<src.findid.i_flower_orfluer>)?Var:Yok>
dtext 365 150 <qval (<src.findid.i_dye_tub_rare>)?0110:025> <qval (<src.findid.i_dye_tub_rare>)?Var:Yok>
dtext 480 150 <qval (<src.findid.i_dolu_su_kovasi>)?0110:025> <qval (<src.findid.i_dolu_su_kovasi>)?Var:Yok>
if (<src.findid.i_flower_orfluer>) && (<src.findid.i_dye_tub_rare>) && (<src.findid.i_dolu_su_kovasi>)
dtext 480 200 0110 : Yapılabilir
else
dtext 460 200 025 : Yapılamaz
endif

button 190 200 4006 4007 1 0 1

[dialog d_raremenu button]
on=1
if (<src.findid.i_flower_orfluer>) && (<src.findid.i_dye_tub>) && (<src.findid.i_dolu_su_kovasi>)
serv.newitem i_dye_tub_rare
new.bounce
src.sys_normal Rare dye yaptınız.
src.consume 1 i_flower_orfluer
src.consume 1 i_dye_tub
src.consume 1 i_dolu_su_kovasi
src.sound 32
else
src.sys_error Rare dye yapabilmeniz için 1 rare çiçeği, 1 dye tub, 1 dolu su kovasi, 100.0 alchemy ve 100.0 carpentry gereklidir..
src.dialog d_raremenu
return 1
endif

[itemdef i_su_kovasi]
type t_script
name=su kovasi (bos)
weight=3
id=4105

on=@create
color=0
attr=0

on=@click
message <def.sys> Su Kovası
message @025,1,1 [boş]
return 1

on=@dclick
if !(<topobj.uid> == <src.uid>)
src.sys_error Sadece çantanızda kullanabilirsiniz..
return 1
endif
if !(<src.isneartype t_water 1>)
src.sys_error Suya yakın yerlerde doldurabilirsiniz..
return 1
else
src.consume 1 i_su_kovasi
serv.newitem i_dolu_su_kovasi
src.sayua 0713,6,6,0 * Su Kovası Doldurur *
src.sound 38
src.anim 13
new.bounce
return 1
endif

[itemdef i_dolu_su_kovasi]
type t_script
name=Su Kovasi (dolu)
weight=3
id=4104

on=@create
color=0
attr=0

on=@click
message <def.sys> Su Kovası
message @0110,1,1 [dolu]
return 1