[DEFNAME admin_strings]
admin_plevel_3 "Seer"
admin_plevel_4 "Game Master"
admin_plevel_5 "Developer"
admin_plevel_6 "Administrator"
admin_plevel_7 "Owner"

[DEFNAME msg_toggles]
gm_one_way 0 //Oyuncular yetkililere cevap gonderebilirler mi? 1 = hayır 0 = evet
msg_self 0 //oyuncular kendi aralarında mesajlasabilirler mi? 1= evet 0 = hayır
list_staff 0 //Yetkilileri listede goster? 1=evet 0=hayır

[plevel 1]
online
reply
private

[FUNCTION online]
ctag.list_numplayers=0
ctag.list_page=1
serv.allclients list_getplayers
ctag.list_numpages=<eval (((<ctag0.list_numplayers>-1) / 10) + 1)>
dialog d_spherelist

[FUNCTION list_getplayers]

IF !(<def.list_staff>)
if (<account.plevel> > <src.account.plevel>) || ((<tag0.private>) && !(<sRC.isgm>))
return
else
src.ctag0.list_numplayers += 1
try src.ctag.list_p<eval (<src.ctag0.list_numplayers>)>=<uid>
endif
ELSE
if (<tag0.private>) && !(<sRC.isgm>)
return
else
src.ctag0.list_numplayers += 1
try src.ctag.list_p<eval (<src.ctag0.list_numplayers>)>=<uid>
endif
ENDIF

[FUNCTION list_getplayers_list]
for x 1 50
try ctag.list_p<eval <local.x>>=01
end
ctag.list_numplayers=50

[DIALOG d_spherelist]
100,100
src.dialogclose d_spherelist
local.oldobj=<obj>
page 0 // Basic layout
GUMPPIC 10 10 027
dtext 30 15 1152 <serv.servname>
dtext 30 35 1152 Listed Clients: <eval <ctag0.list_numplayers>> / <serv.clients>
page 1
dtext 30 55 1152 Msg
dtext 75 55 1152 Karakter adi
list_renderdialog
obj=<local.oldobj>
if (<ctag0.list_page> > 1)
button 28 274 4014 4015 1 0 1
endif
if (<ctag0.list_page> < <ctag0.list_numpages>)
button 210 274 4005 4006 1 0 2
endif
dtext 105 275 1152 Page <eval <ctag0.list_page>> / <eval <ctag0.list_numpages>>

[FUNCTION list_renderdialog]
local.y=75
for x <eval ((<ctag0.list_page> - 1) * 10) + 1> <eval (<ctag0.list_page> * 10)>
if (<local.x> > <ctag0.list_numplayers>)
return
endif
obj=<ctag0.list_p<eval <local.x>>>
local.hue=0480
IF (<OBJ.UID>==<SRC.UID>)
IF (<def.msg_self>)
button 30 <local.y> 4011 4013 1 0 <eval (1000 + <local.x>)>
dtext 75 <local.y> 0779 <QVAL <OBJ.FINDID.i_rune_incognito.UID> ? <OBJ.FINDID.i_rune_incognito.NAME> : <obj.name>>
ELSE
dtext 75 <local.y> 0779 <QVAL <OBJ.FINDID.i_rune_incognito.UID> ? <OBJ.FINDID.i_rune_incognito.NAME> : <obj.name>>
ENDIF
ELSE
IF (<OBJ.ACCOUNT.PLEVEL> > <SRC.ACCOUNT.PLEVEL>)
dtext 75 <local.y> <local.hue> <QVAL <OBJ.FINDID.i_rune_incognito.UID> ? <OBJ.FINDID.i_rune_incognito.NAME> : <obj.name>>
ELSE
button 30 <local.y> 4011 4013 1 0 <eval (1000 + <local.x>)>
dtext 75 <local.y> <local.hue> <QVAL <OBJ.FINDID.i_rune_incognito.UID> ? <OBJ.FINDID.i_rune_incognito.NAME> : <obj.name>>
ENDIF
ENDIF
local.y += 20
end

[DIALOG d_spherelist BUTTON]
on=1
ctag.list_page -= 1
if (<ctag0.list_page> < 1)
SYSMESSAGE @,3,1 Hata:Listeleme tamamlanamıyor...
ctag.list_page=1
endif
dialog d_spherelist
on=2
ctag.list_page += 1
if (<ctag0.list_page> > <ctag0.list_numpages>)
SYSMESSAGE @,3,1 Hata:Listeleme tamamlanamıyor...
ctag.list_page=<ctag0.list_numpages>
endif
dialog d_spherelist
on=1001,65535
try uid.<ctag0.list_p<eval <argn> - 1000>>.dialog d_playermsg, 2




[DIALOG d_playermsg]
100,100
SRC.CTAG0.RECEIVER=<UID>
//NOCLOSE
PAGE 0
GUMPPIC 10 10 027
DTEXT 50 30 07a1 Mesajınız var!
dtextentry 38 55 180 180 0 0
BUTTON 35 240 4005 4006 1 0 1
DTEXT 70 240 07a1 Send

[DIALOG d_playermsg button]
ON=0
src.ctag0.receiver=
RETURN 1


on=1
obj=<src.ctag0.receiver>
IF (<SRC.TAG0.PRIVATE>)
SRC.TAG.PRIVATE=
SRC.SYSMESSAGE @,3,1 Ozel mod kapatıldı...
ENDIF
IF (<isempty <ARGTXT[0]>>)
SYSMESSAGE @,3,1 @0b32 Herhangi bir karakter girilmedi...
dialog d_playermsg
return 1
ENDIF
FOR <SERV.CLIENTS>
IF !(STRCMPI("<OBJ.name>","<name>"))
IF !(<SRC.ISGM>)
IF !(<ISEMPTY <OBJ.CTAG.MESSAGE3>>)
SRC.SYSMESSAGE @,3,1 @0b32 Bu oyuncunun mesaj kutusu dolu.
SRC.SYSMESSAGE @,3,1 @0b32 Lutfen daha sonra tekrar deneyiniz...
RETURN 1
ENDIF
IF !(<ISEMPTY <OBJ.CTAG.MESSAGE>>)
IF (<ISEMPTY <OBJ.CTAG.MESSAGE2>>)
OBJ.ctag0.message2 <argtxt[0]>
OBJ.ctag0.reply2 = <src.uid>
SRC.SYSMESSAGE @,3,1 @0b32 Bekleyen mesaj (2)
OBJ.SYSMESSAGE @,3,1 @0b32 Beklemede olan 2 mesajiniz tutuluyor!
SRC.SOUND 74
ELSE
OBJ.ctag0.message3 <argtxt[0]>
OBJ.ctag0.reply3 = <src.uid>
SRC.SYSMESSAGE @,3,1 @0b32 Bekleyen mesaj (3)
OBJ.SYSMESSAGE @,3,1 @0b32 Beklemede olan 3 mesajiniz tutuluyor!
OBJ.SYSMESSAGE @,3,1 @0b32 Uyari:Mesaj kutunuzu bosaltana kadar mesaj alamayacaksiniz!
SRC.SOUND 74
ENDIF
ELSE
OBJ.ctag0.message <argtxt[0]>
OBJ.ctag0.reply = <src.uid>
TRYSRC <OBJ> dialog d_pm_notify
SRC.SYSMESSAGE @,3,1 @0b32 Mesaj gonderildi!
SRC.SOUND 74
ENDIF
ELSE
OBJ.ctag0.prefix <def.admin_plevel_<src.account.plevel>>
OBJ.ctag0.gmreply <src.uid>
OBJ.CTAG0.gmmessage <argtxt[0]>
TRYSRC <OBJ> src.dialog d_gmpm_notify
SRC.SYSMESSAGE @,3,1 @0b32 Mesaj gonderildi!
SRC.SOUND 74
ENDIF
RETURN 1
ENDIF
ENDFOR
src.ctag.receiver=

[FUNCTION private]
IF (<tag0.Private>)
tag.private=
SYSMESSAGE @,3,1 @0b32 Gizlilik kapatıldı.
else
tag.private=1
SYSMESSAGE @,3,1 @0b32 Gizlilik aktif edildi.
SYSMESSAGE @,3,1 @0b32 Gizlilik modunda iken mesaj alamazsiniz!
endif

[DIALOG d_pm_notify]
50,50
SRC.SOUND 0234
NOCLOSE
PAGE 0
DTEXT 21 0 07a1 Gelen Mesaj:
button 20 20 01e 01e 1 0 1
DTEXT 21 41 07a1 Acmak icin tikla

[DIALOG d_pm_notify BUTTON]
ON=1
SRC.DIALOG d_pm

[DIALOG d_pm]
100,100
NOCLOSE
PAGE 0
GUMPPIC 10 10 027
DTEXT 30 30 07a1 From: <uid.<ctag.reply>.name>
dhtmlgump 32 50 180 180 0 0 <src.ctag0.message>
button 210 15 4017 4018 1 0 0
BUTTON 35 240 4005 4006 1 0 1
DTEXT 70 240 07a1 Reply


[DIALOG d_pm BUTTON]
ON=0
f_msg_queue

ON=1
SRC.CTAG.TO=<src.ctag.reply>
SRC.DIALOG d_reply




[DIALOG d_gmpm_notify]
150,50
SRC.SOUND 0234
NOCLOSE
PAGE 0
DTEXT 15 0 01 Gelen Mesaj:
button 20 20 01e 01e 1 0 1
DTEXT 1 21 01 Yetkili Tarafindan!
DTEXT 18 41 01 Acmak icin tikla

[DIALOG d_gmpm_notify BUTTON]
ON=1
SRC.DIALOG d_gmpm

[DIALOG d_gmpm]
100,100
NOCLOSE
PAGE 0
GUMPPIC 10 10 027
DTEXT 30 30 01 Gonderen: <uid.<ctag.gmreply>.name>
if !<def.gm_one_way>
BUTTON 35 240 4005 4006 1 0 1
DTEXT 70 240 07a1 Cevapla
ENDIF
dhtmlgump 32 50 180 180 0 0 <src.ctag.gmmessage>
button 210 15 4017 4018 1 0 0


[DIALOG d_gmpm BUTTON]
ON=0
SRC.CTAG.GMMESSAGE=

ON=1
SRC.CTAG.TO=<SRC.CTAG.GMREPLY>
SRC.DIALOG d_reply



[DIALOG d_reply]
100,100
PAGE 0
GUMPPIC 10 10 027
DTEXT 40 30 07a1 To: <uid.<ctag.to>.name>
dtextentry 38 55 120 180 0 0
BUTTON 35 240 4005 4006 1 0 1
DTEXT 70 240 07a1 Gonder

[DIALOG d_reply BUTTON]
ON=0
SRC.CTAG.TO=
SRC.CTAG0.MESSAGE=
src.ctag.gmmessage=
src.ctag.gmreply=
SRC.f_msg_queue

on=1
IF (<isempty <ARGTXT[0]>>)
SYSMESSAGE @,3,1 @0b32 Hata:Herhangi bir karakter girilmedi!
dialog d_reply
return 1
ENDIF
OBJ=<src.ctag0.to>
IF !(<OBJ.isonline>) || (<OBJ.tag0.private>)
SYSMESSAGE @,3,1 Oyuncu offline veya gizli modda!
SRC.CTAG.REPLY=
ELSE
IF (<ISGM>)
OBJ.ctag0.gmmessage <argtxt[0]>
OBJ.ctag0.gmreply = <src.uid>
SRC.SYSMESSAGE @,3,1 @0b32 Mesaj gonderildi!
TRYSRC <OBJ> dialog d_gmpm_notify
SRC.SOUND 74
SRC.CTAG.TO=
src.ctag.receiver=
src.f_msg_queue
RETURN 1
ELSE
IF !(<ISEMPTY <OBJ.CTAG.MESSAGE3>>)
SRC.SYSMESSAGE @,3,1 @0b32 Bu kisinin mesaj kutusu su an dolu.
SRC.SYSMESSAGE @,3,1 @0b32 Lutfen daha sonra tekrar deneyin...
SRC.CTAG.TO=
IF !(<OBJ.ISGM>)
src.f_msg_queue
ENDIF
RETURN 1
ENDIF
IF !(<ISEMPTY <OBJ.CTAG.MESSAGE>>)
IF (<ISEMPTY <OBJ.CTAG.MESSAGE2>>)
OBJ.ctag0.message2 <argtxt[0]>
OBJ.ctag0.reply2 = <src.uid>
SRC.SYSMESSAGE @,3,1 @0b32 Bekleyen Mesaj (2)
OBJ.SYSMESSAGE @,3,1 @0b32 Beklemede olan 2 mesajiniz tutuluyor!
SRC.SOUND 74
SRC.CTAG.TO=
IF !(<OBJ.ISGM>)
src.f_msg_queue
ENDIF
RETURN 1
ELSE
OBJ.ctag0.message3 <argtxt[0]>
OBJ.ctag0.reply3 = <src.uid>
SRC.SYSMESSAGE @,3,1 @0b32 Bekleyen Mesaj (3)
OBJ.SYSMESSAGE @,3,1 @0b32 Beklemede olan 3 mesajiniz tutuluyor!
OBJ.SYSMESSAGE @,3,1 @0b32 Uyari:Mesaj kutunuzu bosaltana kadar mesaj alamayacaksiniz!
SRC.SOUND 74
SRC.CTAG.TO=
IF !(<OBJ.ISGM>)
src.f_msg_queue
ENDIF
RETURN 1
ENDIF
ELSE
OBJ.ctag0.reply = <src.uid>
OBJ.ctag0.message <argtxt[0]>
SRC.SYSMESSAGE @,3,1 @0b32 Message sent!
TRYSRC <OBJ> dialog d_pm_notify
SRC.SOUND 74
SRC.CTAG.TO=
IF !(<OBJ.ISGM>)
src.f_msg_queue
ENDIF
RETURN 1
ENDIF
ENDIF
ENDIF
src.ctag.receiver=
src.ctag.gmmessage=
src.ctag.gmreply=

[FUNCTION f_msg_queue]
IF (<ISEMPTY <SRC.CTAG.MESSAGE2>>)
SRC.CTAG.SENDER=
SRC.CTAG.REPLY=
SRC.CTAG.MESSAGE=
ELSE
SRC.CTAG.SENDER=<SRC.CTAG.SENDER2>
SRC.CTAG.REPLY=<SRC.CTAG.REPLY2>
SRC.CTAG.MESSAGE=<SRC.CTAG.MESSAGE2>
SRC.CTAG.SENDER2=
SRC.CTAG.REPLY2=
SRC.CTAG.MESSAGE2=
SRC.DIALOG d_pm_notify
ENDIF
IF !(<ISEMPTY <SRC.CTAG.MESSAGE3>>)
SRC.CTAG.SENDER2=<SRC.CTAG.SENDER3>
SRC.CTAG.REPLY2=<SRC.CTAG.REPLY3>
SRC.CTAG.MESSAGE2=<SRC.CTAG.MESSAGE3>
SRC.CTAG.SENDER3=
SRC.CTAG.REPLY3=
SRC.CTAG.MESSAGE3=
ELSE
SRC.CTAG.SENDER2=
SRC.CTAG.REPLY2=
SRC.CTAG.MESSAGE2=
ENDIF