[events e_staff]
On=@click
message @0803,1 <serv.servname>
message @07ea <name>
return 1

on=@dclick
title <serv.servname> Staff Member
src.ctag.staffuid <uid>
src.sdialog d_stuf

[dialog d_stuf]
0,0
nomove

resizepic 20 20 5120 250 300
resizepic 30 30 3000 230 280
resizepic 40 60 3000 210 2
for 1 7
resizepic 40 <eval (<local._for>*25)+50> 3000 210 20
endfor
dhtmlgump 55 40 200 20 0 0 <def.bfont_dred> <serv.name> Staff Bilgi Menüsü
dhtmlgump 40 76 200 20 0 0 <def.bfont_dred> Staff : <uid.<src.ctag.staffuid>.name>
dhtmlgump 40 101 200 20 0 0 <def.bfont_dred> Baktığı Page Sayısı : <uid.<src.ctag.staffuid>.dtag.pages>
dhtmlgump 40 126 200 20 0 0 <def.bfont_dred> Online Süresi : <eval (<uid.<src.ctag.staffuid>.account.totalconnecttime> / 60)> saat
dhtmlgump 40 152 200 20 0 0 <def.bfont_dred> İlk Giriş : <strarg <uid.<src.ctag.staffuid>.account.firstconnectdate>>
dhtmlgump 40 177 200 20 0 0 <def.bfont_dred> Son Giriş : <strarg <uid.<src.ctag.staffuid>.account.lastconnectdate>>
dhtmlgump 40 200 200 20 0 0 <def.bfont_dred> İyi Yönde Oyları : <eval <uid.<src.ctag.staffuid>.tag0.iyioy>>
dhtmlgump 40 227 200 20 0 0 <def.bfont_dred> Kötü Yönde Oyları : <eval <uid.<src.ctag.staffuid>.tag0.kotuoy>>
dhtmlgump 75 253 200 20 0 0 İyi Yönde Oy Kullan
dhtmlgump 75 283 200 20 0 0 Kötü Yönde Oy Kullan
button 40 250 4006 4007 1 0 1
button 40 280 4006 4007 1 0 2

[dialog d_stuf button]
on=1
if (<uid.<src.ctag.staffuid>.uid> == <src.uid>)
src.sysmessage @0785,1,1 Kendinize Oy Veremezsiniz.
return 1
endif

if (<src.dtag0.oyhakki> == 0)
src.sysmessage @0785,1,1 Oy kullanma hakkınız kalmamış.
return 1
endif

if (<src.account.plevel> > 1)
src.s <uid.<src.ctag.staffuid>.name> isimli staff a iyi oy verdim.
endif

var.songonderen <src.name>
try uid.<src.ctag.staffuid>.tag0.iyioy=<eval <uid.<src.ctag.staffuid>.tag0.iyioy>+1>
try uid.<src.ctag.staffuid>.sysmessage @0785,1,1 <var.songonderen> Size İyi Yönde bi oy attı. şuanki iyi yöndeki oyunuz <eval <uid.<src.ctag.staffuid>.tag0.iyioy>> kadar. İyi çalışmalar.
src.tag0.oyhakki -=1
src.sysmessage @0785,1,1 <uid.<src.ctag.staffuid>.name> İsimli staff a iyi oy verdiniz.

on=2
if (<uid.<src.ctag.staffuid>.uid> == <src.uid>)
src.sysmessage @0785,1,1 Kendinizin Oyunu Azaltamazsiniz.
return 1
endif

if (<src.dtag0.oyhakki> == 0)
src.sysmessage @0785,1,1 Oy kullanma hakkınız kalmamış.
return 1
endif

if (<src.account.plevel> > 1)
src.s <uid.<src.ctag.staffuid>.name> isimli staff a kötü oy verdim.
endif
var.songonderen <src.name>
try uid.<src.ctag.staffuid>.tag0.kotuoy=<eval <uid.<src.ctag.staffuid>.tag0.kotuoy>+1>
try uid.<src.ctag.staffuid>.sysmessage @0785,1,1 <var.songonderen> Size Kötü Yönde bi oy attı. şuanki kötü yöndeki oyunuz <eval <uid.<src.ctag.staffuid>.tag0.kotuoy>> kadar. İyi çalışmalar.
src.tag0.oyhakki -=1
src.sysmessage @0785,1,1 <uid.<src.ctag.staffuid>.name> İsimli staff a kötü oy verdiniz.