Kendinize yaver edinin ve birlikte party yapın.. Yaverinizin ve kendinizin skillerini geliştirin sonrasında savaşa gidin..

//yaver system
//01 ocak 2008

[itemdef i_yaver]
id i_pet_man
name Yaver
defname i_yaver
type t_normal

on=@create
attr attr_newbie

on=@dclick
if (0<src.tag.yaver>.hits> > 0)
src.sysmessage @55 Sizin yaveriniz var.
return 1
else
try src.newnpc c_yaver_warrior
link <src.act.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <src.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
link.update
link.face
link.tag.owner <src.uid>
link.say Yes Sir?
src.tag.yaver <link.uid>
return 1
endif

[function ownerrefresh]
try uid.<src.tag.yaver>.findid.i_memory.remove
try uid.<src.tag.yaver>.newitem i_memory
try uid.<src.tag.yaver>.act.attr 04
try uid.<src.tag.yaver>.act.more1 04
try uid.<src.tag.yaver>.act.more2 <serv.time>
try uid.<src.tag.yaver>.act.morep <uid.<src.tag.yaver>.p>
try uid.<src.tag.yaver>.act.color memory_ipet
try uid.<src.tag.yaver>.act.timer -1
try uid.<src.tag.yaver>.act.link <src.uid>
try uid.<src.tag.yaver>.act.cont <uid.<src.tag.yaver>.uid>
try uid.<src.tag.yaver>.flags <uid.<src.tag.yaver>.flags>&statf_pet
try uid.<src.tag.yaver>.update
try uid.<src.tag.yaver>.face

[chardef c_yaver_warrior]
name #NAMES_HUMANMALE
defname c_yaver_warrior
id c_man
foodtype 55 t_food
can mt_walk|mt_run|mt_usehands
tevents e_yaver
tspeech spk_yaver

on=@create
color 083ea
str {55 70}
dex {40 55}
int 25

swordsmanship 500
fencing 500
archery 500
wrestling 300
anatomy 300
healing 300
karma {1000 1200}
fame {800 1000}
kills 3
//item i_mt_ostard_desert // binek
item i_chainmail_tunic
item i_chainmail_coif
item i_chainmail_leggings
item i_shield_round_metal

item i_book_lg
itemnewbie random_male_hair
color colors_hair
itemnewbie random_facial_hair
color match_hair
itemnewbie random_shoes
itemnewbie i_sword_long

on=@click
sayua,0795,0,0,trk <name> the Yaver
return 1

[events e_yaver]
on=@environchange
if (rand(10) == 1)
food <eval <food> - 1>
endif

on=@dclick
if (<src.uid> = <uid.<tag.owner>.uid>)
pack
endif

on=@hit
if (<findlayer(1).type> = t_weapon_sword)
if (<swordsmanship> < 1000)
swordsmanship <eval <swordsmanship> +1>
endif
elseif (<findlayer(2).type> = t_weapon_xbow) || (<findlayer(2).type> = t_weapon_bow)
if (<archery> < 1000)
archery <eval <archery> +1>
endif
elseif (<findlayer(1).type> = t_weapon_fence)
if (<swordsmanship> < 1000) || (<tactics> < 1000)
fencing <eval <fencing> +1>
endif
elseif !(<findlayer(1)>)
if (<wrestling> < 1000)
wrestling <eval <wrestling> +1>
endif
endif
if (<tactics> < 1000)
tactics <eval <tactics> +1>
endif

if (rand(2) == 1)
if (<dex> < 100)
dex <eval <dex> +1>
endif
endif

on=@gethit
if (<findlayer(2).type> = t_shield)
if (<parrying> < 1000)
parrying <eval <parrying> +1>
endif
endif
if (<eval (<str> - <hits>)> > 10)
if (<restest i_bandage>)
if !(<findid.i_yaver_bandaj>)
if (rand(2) == 1)
newitem i_yaver_bandaj
new.cont <uid>
new.timer 2
anim 17
attack <src.uid>
if (rand(<eval (<anatomy> / 100)>) == 1)
findid.i_yaver_bandaj.remove
sayua 90,0,0,trk *bandajları yırtılır*
endif
endif
endif
endif
endif

if (<act.baseid>=c_vortex)
sayua 0481,0,0,trk *büyü etkisini kaldırır*
effect=3,i_fx_heal_effect,6,35,1
sound snd_spell_greater_heal
src.remove
endif
if (<act.baseid>=c_blade_spirit)
sayua 0481,0,0,trk *büyü etkisini kaldırır*
effect=3,i_fx_heal_effect,6,35,1
sound snd_spell_greater_heal
src.remove
endif
if (<act.baseid>=c_daemon)
sayua 0481,0,0,trk *büyü etkisini kaldırır*
effect=3,i_fx_heal_effect,6,35,1
sound snd_spell_greater_heal
src.remove
endif
if (<act.baseid>=c_bear_polar)
sayua 0481,0,0,trk *büyü etkisini kaldırır*
effect=3,i_fx_heal_effect,6,35,1
sound snd_spell_greater_heal
src.remove
endif
if (<flags> &statf_poisoned)
if (rand(2) == 1)
sayua 048,0,0,trk *zehiri iyileştirir*
effect=3,i_fx_heal_effect,6,35,1
sound snd_spell_cure
findid.i_rune_poison.remove
endif
endif
if (rand(2) == 1)
if (<str> < 275)
str <eval <str> +1>
endif
endif



[itemdef i_yaver_bandaj]
defname i_yaver_bandaj
name yaver bandaj
id i_bandage
type t_Eq_Script

on=@timer
cont.sayua 048,0,0,trk *kendini tedavi eder*
cont.effect 3,i_fx_heal_effect,6,35,1
cont.sound snd_spell_heal
if (<cont.hits> > 125) && (<cont.healing> > 999)
cont.hits <cont.str>
else
cont.hits <eval (<cont.hits> + (<cont.healing> / 20))>
endif

if (<cont.anatomy> < 1000)
cont.anatomy <cont.anatomy> + 1
endif
if (<cont.healing> < 1000)
cont.healing <cont.healing> + 1
endif
cont.consume 1 i_bandage
remove
return 1

[speech spk_yaver]
on=yaver
if (<src.uid> != <uid.<tag.owner>.uid>)
say I am <uid.<tag.owner>.name>'s yaver.
else
src.sdialog d_yaver
endif
return 1

on=*hello*
on=*hi*
dorand 5
say Hello!
say Hi, Hows goin?
say Greetings!
say Ums not bad!
say Welcome my friend.
enddo
return 1

on=*pack*
if (<src.uid> = <uid.<tag.owner>.uid>)
pack
endif
return 1

on=*
IF ( <flags>& statf_war )
dorand 3
say You will not talk your way out of this
say Be quiet and fight scoundrel
say Fight me coward!
enddo
else
dorand 10
say What a good day!
say Are you okay?
say Nice speaking to you.
say The yaver system is fine!
say Hello!
say What are you doing?
say I am <uid.<tag.owner>.name>'s yaver.
say May i meet you?
say Bee Shard is too funny, because you are here!
say Don't touch me! Only watch me!
enddo
endif
return 1

[DIALOG d_yaver]
0,0

resizepic 5 5 3500 325 230
dhtmlgump 50 20 100 20 0 0 güncelle
button 30 20 56 55 1 0 1
dhtmlgump 50 40 150 20 0 0 <def.fontbrown>>stat max : 400
dhtmlgump 50 60 150 20 0 0 str : <src.uid.<tag.yaver>.hits>/<src.uid.<tag.yaver>.str>-275
dhtmlgump 50 80 150 20 0 0 dex : <src.uid.<tag.yaver>.stam>/<src.uid.<tag.yaver>.dex>-100
dhtmlgump 50 100 150 20 0 0 int : <src.uid.<tag.yaver>.mana>/<src.uid.<tag.yaver>.int>-25

dhtmlgump 180 40 150 20 0 0 <def.fontbrown>>skill max : 800
dhtmlgump 180 60 150 20 0 0 swordsmanship : <src.uid.<tag.yaver>.swordsmanship>
dhtmlgump 180 80 150 20 0 0 fencing : <src.uid.<tag.yaver>.fencing>
dhtmlgump 180 100 150 20 0 0 archery : <src.uid.<tag.yaver>.archery>
dhtmlgump 180 120 150 20 0 0 wrestling : <src.uid.<tag.yaver>.wrestling>
dhtmlgump 180 140 150 20 0 0 anatomy : <src.uid.<tag.yaver>.anatomy>
dhtmlgump 180 160 150 20 0 0 healing : <src.uid.<tag.yaver>.healing>
dhtmlgump 180 180 150 20 0 0 tactics : <src.uid.<tag.yaver>.tactics>
dhtmlgump 180 200 150 20 0 0 parrying : <src.uid.<tag.yaver>.parrying>

dhtmlgump 50 120 150 20 0 0 <def.fontbrown>>durum
dhtmlgump 50 140 150 20 0 0 food : <src.uid.<tag.yaver>.food>
dhtmlgump 50 160 150 20 0 0 armor : <src.uid.<tag.yaver>.ar>
dhtmlgump 50 180 150 20 0 0 fame : <src.uid.<tag.yaver>.fame>
dhtmlgump 50 200 150 20 0 0 karma : <src.uid.<tag.yaver>.karma>

dhtmlgump 180 20 150 20 0 0 party-box : <qval (0<src.uid.<tag.yaver>.tag.party> = 1) ? açık : kapalı>
button 160 20 56 55 1 0 2

[DIALOG d_yaver TEXT]

[DIALOG d_yaver BUTTON]
on=1
src.ownerrefresh
src.sysmessage @55 Yaveriniz guncellendi.
on=2
if (0<uid.<src.tag.yaver>.tag.party> = 1)
src.flags <flags>&~statf_war
src.update
src.ownerrefresh
try uid.<src.tag.yaver>.say Partybox is finish.
try uid.<src.tag.yaver>.tag.party 2
else
try uid.<src.tag.yaver>.say Come on my master!
src.sysmessage @55 Yaveriniz ile partybox basladi.
try uid.<src.tag.yaver>.attack <src.uid>
try uid.<src.tag.yaver>.tag.party 1
endif
return 1

[EOF]