[PLEVEL 5]
fellowship

[FUNCTION fellowship]
IF <src.tag.FELLOWSHIP>=0
SRC.SYSMESSAGE You have to know the secret to that spell!
return 1
ELSEIF (<ISGM> )
GM 0
ELSE
RETURN 1
ENDIF

FLAGS <FLAGS>|statf_freeze
FONT 8
SAY FELLOWSHIP
FONT 3

NEWITEM i_m_fellowship
ACT.TAG.P <P>
ACT.CONT <UID>

IF (<ARGN> == 4805000) || (<ARGN> < 0)
ACT.MOREY <EVAL fellowship_default>
ELIF (<ARGN> > <EVAL fellowship_maxtime> )
ACT.MOREY <EVAL fellowship_maxtime>
ELSE
ACT.MOREY <ARGN>
ENDIF

[FUNCTION dupelayer]
IF (<FINDLAYER(<ARGS> )> )
TRY NEWITEM <FINDLAYER(<ARGS> ).BASEID>
TRY ACT.DISPID <FINDLAYER(<ARGS> ).DISPID>
TRY ACT.COLOR <FINDLAYER(<ARGS> ).COLOR>
ACT.CONT <VAR.NPCUID>
ACT.UPDATE
ENDIF

[CHARDEF c_clone]
ID=c_man
NAME=Clone
CAN=MT_EQUIP|MT_WALK|MT_RUN|MT_USEHANDS|MT_SWIM|MT
_GHOST

ON=@Create
FLAGS=statf_conjured|statf_invul
DEX=0
TAG.NOCLICK 1

[EVENTS e_clone]
ON=@Click
RETURN 1

ON=@NPCSeeNewPlayer
IF (<SRC.UID> == <TAG.MASTERUID> )
FACE
IF (<EVAL fellowship_faceaway> == 1)
DOSWITCH <DIR>
DIR 4
DIR 5
DIR 6
DIR 7
DIR 0
DIR 1
DIR 2
DIR 3
ENDDO
UPDATE
ENDIF
RETURN 0
ENDIF
IF (<SRC.UID> != <TAG.MASTERUID> ) && (<FINDID.i_m_clone.TAG.STAGE> == 3)
NPC brain_monster
FLAGS <FLAGS> &~ statf_invul
FLAGS <FLAGS> | statf_war
DEX {250 400}
STAM <DEX>
TAG.DONE 1
ATTACK
RETURN 0
ENDIF
RETURN 1

ON=@EnvironChange
IF !(<FLAGS> & statf_war) && (0<TAG.DONE> == 1)
REMOVE
ENDIF

[ITEMDEF i_m_clone]
ID=i_memory
TYPE=t_eq_script
NAME=Clone

ON=@Create
ATTR=attr_decay
TAG.STAGE 1
TAG.DECAY 0

ON=@Timer
IF (<TAG.STAGE> == 1)
CONT.KARMA {-8001 -9000}
CONT.FAME {5000 7000}
CONT.STR {25 50}
CONT.INT {25 50}
CONT.HITS <CONT.STR>
CONT.STAM <CONT.DEX>
CONT.MANA <CONT.INT>
// CONT.FLAGS <CONT.FLAGS> | statf_war
CONT.SWORDSMANSHIP {65.0 80.0}
CONT.FENCING {65.0 80.0}
CONT.MACEFIGHTING {65.0 80.0}
CONT.ARCHERY {65.0 80.0}
CONT.WRESTLING {65.0 80.0}
CONT.PARRYING {75.0 90.0}
CONT.TACTICS {75.0 90.0}
CONT.UPDATE
TAG.STAGE 2
TIMER 3
ELIF (<TAG.STAGE> == 2)
IF (<LINK.FLAGS> & statf_freeze)
LINK.FLAGS <LINK.FLAGS> &~ statf_freeze
ENDIF

IF (<LINK.ACCOUNT.PLEVEL> >= 4) && !(<LINK.ISGM> )
LINK.GM 1
ENDIF

TAG.STAGE 3
TIMER <MOREY>
ELIF (<TAG.STAGE> == 3)
CONT.REMOVE
ENDIF
RETURN 1

[ITEMDEF i_m_fellowship]
ID=i_memory
TYPE=t_eq_script
NAME=Don't Blink

ON=@Create
ATTR=attr_decay
MORE1=5
MOREX=12
TIMER=0

ON=@Timer
IF (<MORE1> > 0)
CONT.ANIM 011
MORE1 <MORE1>-1
TIMER 2
RETURN 1
ELSE
MOREX <MOREX>-1
IF (<MOREX> < 0)
REMOVE
RETURN 1
ENDIF
ENDIF

CONT.NEWNPC c_clone
CONT.ACT.EVENTS e_clone
CONT.ACT.TAG.MASTERUID <CONT.UID>
CONT.ACT.P <TAG.P>
VAR.NPCUID <CONT.ACT.UID>

CONT.ACT.BODY <CONT.BODY>
CONT.ACT.NAME <CONT.NAME>
CONT.ACT.TITLE <CONT.TITLE>
CONT.ACT.COLOR <CONT.COLOR>

DOSWITCH <MOREX>
BEGIN
CONT.ACT.MOVE -3 -5
CONT.DIR 7
END
BEGIN
CONT.ACT.MOVE 0 -6
CONT.DIR 0
END
BEGIN
CONT.ACT.MOVE 3 -5
CONT.DIR 1
END
BEGIN
CONT.ACT.MOVE 5 -3
CONT.DIR 1
END
BEGIN
CONT.ACT.MOVE 6 0
CONT.DIR 2
END
BEGIN
CONT.ACT.MOVE 5 3
CONT.DIR 3
END
BEGIN
CONT.ACT.MOVE 3 5
CONT.DIR 3
END
BEGIN
CONT.ACT.MOVE 0 6
CONT.DIR 4
END
BEGIN
CONT.ACT.MOVE -3 5
CONT.DIR 5
END
BEGIN
CONT.ACT.MOVE -5 3
CONT.DIR 5
END
BEGIN
CONT.ACT.MOVE -6 0
CONT.DIR 6
END
BEGIN
CONT.ACT.MOVE -5 -3
CONT.DIR 7
END
ENDDO
CONT.UPDATE

CONT.dupelayer layer_hand1
CONT.dupelayer layer_hand2
CONT.dupelayer layer_shoes
CONT.dupelayer layer_pants
CONT.dupelayer layer_shirt
CONT.dupelayer layer_helm
CONT.dupelayer layer_gloves
CONT.dupelayer layer_ring
CONT.dupelayer layer_collar
CONT.dupelayer layer_hair
CONT.dupelayer layer_half_apron
CONT.dupelayer layer_chest
CONT.dupelayer layer_wrist
CONT.dupelayer layer_beard
CONT.dupelayer layer_tunic
CONT.dupelayer layer_arms
CONT.dupelayer layer_cape
CONT.dupelayer layer_robe
CONT.dupelayer layer_skirt
CONT.dupelayer layer_legs
CONT.dupelayer layer_horse
CONT.dupelayer layer_light
CONT.dupelayer layer_pack

CONT.NEWITEM i_m_clone
CONT.ACT.LINK <CONT.UID>
CONT.ACT.MOREY <MOREY>
CONT.ACT.TIMER <EVAL <MOREX> + 3>
CONT.ACT.CONT <VAR.NPCUID>

VAR.NPCUID
TIMER 1
RETURN 1

[EOF]