/////////////////////////////////////////////////////////////////
// Scripter Name: Lewless                                      //
// Last Edited: 28 Haziran 2008 By Lewless                     //
/////////////////////////////////////////////////////////////////


[ITEMDEF i_staff_taming10]
ID=i_staff_gnarled
NAME=+10 taming staff
TYPE=t_weapon_mace_staff
VALUE=254
TWOHANDS=Y
LAYER=2
WEIGHT=10
DAM=5,10

On=@Create
color 39
more2 0
timer -1
hitpoints 5

On=@DClick
equip
if (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @95,,1 Gizlenmis durumdayken bunu kullanamazsiniz.
elseif (<src.targ.region.defname> == a_townZoo)
src.sysmessage @95,,1 Bu bolgede taming yasaktir.
elseif (<timer> == -1)
target @95,,1 Hangi hayvani ehlilestirmek istiyorsunuz?
endif
return 1

On=@UnEquip
more2 0
timer -1
link -1
src.events -e_taming_f
src.taming (<src.taming> - 10.0)

On=@Equip
dispid i_staff_gnarled
src.taming (<src.taming> + 10.0)
return 1

on=@click
message @50 +10 taming staff
return 1

On=@Timer
cont.checks <link.uid>
if !(<var.see>
cont.sysmessage @95,,1 Hayvan gorus alaninizdan cikti.
elseif (<link.npc> != brain_animal)
cont.sysmessage @95,,1 Bunu ehlillestiremezsiniz.
elseif !(<link.taming>
cont.sysmessage @95,,1 Bunu ehlillestiremezsiniz.
elseif (<eval <cont.taming>> < <link.taming>
cont.anim 19
cont.sysmessage @95,,1 <link.name> icin taming skilliniz yeterli degil. (gerekli skill: <link.taming>
elseif (<eval <cont.animallore>> < <link.animallore>
cont.anim 19
cont.sysmessage @95,,1 <link.name> icin animal lore skilliniz yeterli degil. (gerekli skill: <link.taming>
elseif (<cont.flags> & (statf_dead|statf_freeze|statf_invisible|statf_sleeping|statf_polymorph|statf_stone|statf_hidden))
cont.sysmessage @95,,1 Su anki durumunuzda bu hayvani tame edemezsiniz.
elseif (<link.memoryfindtype.memory_ipet>
cont.sysmessage @95,,1 <link.name>, ugraslariniz sirasinda, baska biri tarafindan ehlilestirildi.
elseif (<link.memoryfindtype.memory_fight>
cont.sysmessage @95,,1 Hayvan su an musait degil.
elseif (<link.memoryfindtype.memory_war_targ.link> == <cont.uid>
cont.sysmessage @95,,1 Hayvan su an size cok kizgin.
elseif (<var.dist> > 3)
cont.sysmessage @95,,1 Hayvandan uzaklastiniz.
link.tag.tamer=0
elseif (<cont.distance 0<link.memoryfindtype.memory_ispawned.link.uid>> > 5)
cont.sysmessage @95,,1 Bu hayvan yuvasindan uzaklasmis.

else
if (<more2> < 6)
dorand 8
cont.say @0800 Gel <link.name>...
cont.say @0800 Sana zarar vermeyecegim.
cont.say @0800 Guzel, <link.name>.
cont.say @0800 Her zaman senin gibi bir <link.name> sahibi olmak istemistim..
cont.say @0800 Cok tatlisin, <link.name>.
cont.say @0800 Seni incitmeyecegim, <link.name>.
cont.say @0800 Arkadasin olmak istiyorum.
cont.say @0800 Gel <link.name>
enddo
dorand 2
cont.anim 17
cont.anim 19
enddo
timer 2
more2 (<more2> + 1)
return 1
endif
more2 0

if !(<link.npc> == 1)
cont.sysmessage @95,,1 Bunu ehlilestiremezsiniz.
return 1
endif

if (rand(100) < 75)
if (<link.memoryfindtype.memory_ispawned>
link.memoryfindtype.memory_ispawned.remove
endif
link.karma -50
link.memorydel <cont.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <cont.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
cont.sysmessage @95,,1 <link.name> sizi sahibi olarak kabul etti.
if ((<cont.skilllock[35]> == 0) && (<cont.skilltotal> < 800.0) && (<cont.taming> < 100.0))
if (<cont.taming> < 30.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 50.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 60.0)
if (rand(3) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 75.0)
if (rand(3) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 87.0)
if (rand(5) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 100.0)
if (rand(6) == 1)
cont.taming (<cont.taming> + 1)
endif
endif
endif
else
cont.sysmessage @95,,1 Bu hayvana Sahip Oldunuz...
return 1
endif

if !((<link.id>=c_horse_brown_lt) || (<link.id>=c_horse_brown_dk) || (<link.id>=c_horse_gray) || (<link.id>=c_horse_tan) || (<link.id>=c_shire) || (<link.id>=c_random) || (<link.id>=c_llama))
if ((<cont.skilllock[2]> == 0) && (<cont.skilltotal> < 800.0) && (<cont.animallore> < 100.0))
if (<cont.animallore> < 30.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 50.0)
if (rand(2) == 1)
cont.animallore (<cont.taming> + 1)
endif
elseif (<cont.animallore> < 60.0)
if (rand(3) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 75.0)
if (rand(3) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 87.0)
if (rand(5) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 100.0)
if (rand(6) == 1)
cont.animallore (<cont.animallore> + 1)
endif
endif
endif
else
cont.sysmessage @95,,1 Bu hayvana Sahip Oldunuz...
return 1
endif

link.tag.tamer <cont.uid>
link -1
else
cont.sysmessage @95,,1 Hayvani evcillestirmeyi basaramadiniz.
link -1
endif
return 1

On=@TargOn_Char
if !(<src.targ.region.defname> == a_townZoo)
if ((<src.targ.npc> == 1) && (<src.targ.id> != c_pv))
if !(<src.targ.canseelos>
src.sysmessage @95,,1 Hayvana ulasamiyorsunuz.
elseif (<src.targ.distance> > 3)
src.sysmessage @95,,1 Hayvana yeterince yakin degilsiniz.
elseif (<src.targ.memoryfindtype.memory_ipet>
if (<src.targ.memoryfindtype.(memory_ipet|memory_guard).link> == <src.uid>
src.sysmessage <src.targ.name> zaten size ait.
src.targ.flags <src.targ.flags>&statf_pet
else
src.sysmessage @95,,1 <src.targ.name> bir baskasina ait.
endif
elseif (<src.targ.memoryfindtype.memory_fight>
src.sysmessage @95,,1 Hayvan su an musait degil.
elseif (<src.targ.memoryfindtype.memory_war_targ.link> == <src.uid>
src.sysmessage @95,,1 Hayvan su an size cok kizgin.
elseif (<src.targ.findid.i_rune_summon_creature>
src.sysmessage @95,,1 Buyu ile yaratilmis hayvanlari ehlilestiremezsiniz.
elseif (0<src.targ.tag.tamer> == 0<src.uid> // tamerlar elele bug-free dunyaya
src.sysmessage @95,,1 Hayvan artik sizi umursamiyor.
elseif (<src.taming> < <src.targ.taming>
src.anim 19
src.sysmessage @95,,1 <src.targ.name> icin taming skilliniz yeterli degil. (gerekli skill: <src.targ.taming>
elseif (<src.animallore> < <src.targ.animallore>
src.anim 19
src.sysmessage @95,,1 <src.targ.name> icin animal lore skilliniz yeterli degil. (gerekli skill: <src.targ.animallore>
elseif (<src.distance 0<src.targ.memoryfindtype.memory_ispawned.link.uid>> > 5)
src.sysmessage @95,,1 Bu hayvan yuvasindan uzaklasmis.
else // tame etmeye ba$la...
link <src.targ.uid>
src.anim 19
timer 2
endif
else
src.sysmessage @95,,1 Bunu ehlillestiremezsiniz.
endif
else
src.sysmessage @95,,1 Bu bolgede taming yasaktir.
endif
return 1

On=@TargOn_Item
return 1

[function memorydel] // memory silen loop
if (0<args>
if (<findid.i_memory.link> == <args>
findid.i_memory.remove
memorydel <args>
endif
endif

[FUNCTION checks]
newitem i_checks
act.link <argn>
equip <act.uid>

[ITEMDEF i_checks]
ID=i_memory
TYPE=t_eq_script
NAME=Checks

ON=@Equip
var.dist <link.distance>
var.see <link.canseelos>
remove