///////////////////////////////////////////////////////////////////////
// *Scripter Name : Raskol Serna
// *Shard Name : The Rosario Game
// *Shard Address : www.rosario.gen.tr
// *Personal Address : www.raskolserna.com
// *Messenger and E-Mail : raskolserna@msn.com
// *Sphere Version : Specially 0.56b and maybe other releases
//
// *Bu kodlar TheRaskol tarafından yazılmış veya editlenmiştir.
// *The codes are written or were edited by TheRaskol (Raskol Serna).
///////////////////////////////////////////////////////////////////////

[ITEMDEF i_deed_animal]
DEFNAME=i_deed_animal
NAME=a animal shrink deed
ID=i_deed
WEIGHT=5
TYPE=t_script
VALUE=70

CATEGORY=Custom Items
SUBSECTION=Deeds
DESCRIPTION=Animal Shrink Deed

On=@Create
color 32

On=@Click
if (<more2>)
if (<tag.trade_fame> > 9990)
tag.trade_title Lord
endif
if (<tag.trade_karma> > 100)
message @063 <tag.trade_title> [<tag.trade_name>]
elseif (<tag.trade_karma> > -800)
message <tag.trade_title> [<tag.trade_name>]
elseif (<tag.trade_karma> < -799)
message @026 <tag.trade_title> [<tag.trade_name>]
endif
endif
message <name>
return 1

on=@dropon_ground
if (<tag0.dispid>)
dispid <tag.dispid>
endif

on=@dropon_char
if (<tag0.dispid>)
dispid <tag.dispid>
endif

on=@dropon_item
if (<tag0.dispid>)
dispid <tag.dispid>
endif

On=@DClick
if (<topobj.uid> != <src.uid>)
src.sysmessage @0845,1,1 Bunu kullanabilmeniz için çantanızda olmalıdır!
elseif (<more2>)
if (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @0845,1,1 Gizlenmiş durumdayken bunu kullanamazsınız!
return 1
endif
try src.newnpc <tag.trade_id>
link <src.act.uid>
link.name <tag.trade_name>
link.karma <tag.trade_karma>
link.fame <tag.trade_fame>
link.str <tag.trade_str>
link.hits <tag.trade_str>
link.dex <tag.trade_dex>
link.int <tag.trade_int>
link.food <tag.trade_food>
link.color <color>
link.oskin <link.color>
link.memorydel <src.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <src.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
link.update
link.anim 5
link.bark 3
remove
else
target
src.sysmessage @666,1,1 Küçültmek istediğiniz hayvanı seçiniz.
endif
return 1

On=@TargOn_Item
src.sysmessage @0845,1,1 Bu tür eşyaları küçültemezsiniz!
return 1

On=@TargOn_Char

if !(<src.targ.npc>)
src.sysmessage @0845,1,1 Player'ları küçültemezsiniz!
elseif !(<src.targ.ismypet>)
src.sysmessage @0845,1,1 Bu hayvan size ait değildir!
elseif (<src.targ.flags>&statf_stone) || (<src.targ.flags>&statf_freeze)
src.sysmessage @0845,1,1 Hayvanı bu durumda küçültemezsiniz!
elseif ((<src.targ.body> == c_man) || (<src.targ.body> == c_woman))
src.sysmessage @0845,1,1 Bu tür eşyaları küçültemezsiniz!
elseif (<src.targ.flags>&statf_invul) || (<src.targ.color> == 07fff)
src.sysmessage @0845,1,1 Bu hayvanı küçültemezsiniz!
elseif (<src.targ.memoryfindtype.memory_war_targ>)
src.sysmessage @0845,1,1 Hayvan şuan da çok kızgın!
elseif (<src.targ.findid.i_rune_summon_creature>)
src.sysmessage @0845,1,1 Summon hayvanları küçültemezsiniz!
elseif ((<src.targ.id> == c_llama_pack) || (<src.targ.id> == c_horse_pack))
src.sysmessage @0845,1,1 Pack hayvanları küçültemezsiniz!
elseif (<src.targ.food> < 6)
src.sysmessage @0845,1,1 Bu hayvan şuan da açtır !
elseif (<src.targ.findid.i_rune_bless>) || (<src.targ.findid.i_rune_protection>) || (<src.targ.findid.i_rune_reactive_armor>) || (<src.targ.findid.i_rune_agility>) || (<src.targ.findid.i_rune_strength>)
        src.sysmessage @0845,1,1 Bu hayvanın üzerinde büyü var yada potion içmiş.
elseif (<src.targ.hits> < <src.targ.str>)
src.sysmessage @0845,1,1 Bu hayvan şuan da yaralıdır!
elseif (<src.targ.findid.i_rune_poison>)
src.sysmessage @0845,1,1 Bu hayvan şuan da zehirlidir!
elseif !(<src.targ.canseelos>)
src.sysmessage @0845,1,1 Seçtiğiniz hayvan'a ulaşamıyorsunuz!
elseif (<src.targ.distance> > 3)
src.sysmessage @0845,1,1 Seçtiğiniz hayvan'a ulaşamıyorsunuz!
elseif (<src.targ.id> == c_m_golem_tinker1)
src.newitem i_pet_golem1
src.act.name <src.targ.name>
src.act.bounce
src.targ.remove
remove
elseif (<src.targ.id> == c_m_golem_tinker2)
src.newitem i_pet_golem2
src.act.name <src.targ.name>
src.act.bounce
src.targ.remove
remove
else
name Shrink Animal
attr 00
more2 1
color <src.targ.color>
tag.trade <src.targ.job>
tag.trade_id <src.targ.id>
tag.trade_name <src.targ.name>
tag.trade_str <src.targ.str>
tag.trade_dex <src.targ.dex>
tag.trade_int <src.targ.int>
tag.trade_karma <src.targ.karma>
tag.trade_fame <src.targ.fame>
tag.trade_food <src.targ.food>
src.targ.bark 2
src.targ.remove
src.sysmessage @00482,1,1 Seçtiğiniz hayvan pet haline getirildi.
dispid <src.targ.icon>
tag.dispid <src.targ.icon>
update
endif
return 1