[DEFNAME kufurdedektor]
KUFUR_CONTAINER 040001ffc

[FUNCTION kufur]
IF (<TAG0.KUFURDEDEKTOR>)
   SYSMESSAGE @,,1 Küfür dedektörü hala aktif.
   RETURN 1
ENDIF
SERV.NEWITEM i_kufur_dedektor
NEW.TIMER 1
NEW.P <P>
NEW.LINK <UID>
NEW.TAG.DATE <SERV.RTIME>
TAG.KUFURDEDEKTOR 1
NEW.REMOVEFROMVIEW

[SPEECH spk_kufur]
ON=*
TAG.ARGS <TAG.ARGS><SRC.NAME> [<SRC.UID>]: <ARGS><DEF.BR>
FOR 10
   IF (<TAG0.KONUSAN<dLOCAL._FOR>> == <SRC.UID>)
      RETURN 1
   ENDIF
ENDFOR
FOR 10
   IF !(<TAG0.KONUSAN<dLOCAL._FOR>>)
      TAG.KONUSAN<dLOCAL._FOR> <SRC.UID>
      TAG0.KONUSAN += 1
      RETURN 1
   ENDIF
ENDFOR

[DIALOG d_kufur]
100,100
nomove

page 0
resizepic 0 0 5054 400 500
gumppictiled 10 10 380 480 2624
checkertrans 10 10 380 480

page 1
dtext 30 20 1153 Küfür Şikayetinde Bulunan: <LINK.NAME> [<LINK.UID>]
dtext 30 40 1153 Tarih: <TAG.DATE>
button 30 65 4006 4005 0 2 0
dtext 65 67 1153 İşlemler
dhtmlgump 30 100 350 370 0 1 <TAG0.ARGS>
button 220 65 4006 4005 1 0 1
dtext 255 67 1153 Sil

page 2
button 360 10 4015 4014 0 1 0
FOR <dTAG0.KONUSAN>
   IF (<TAG0.KONUSAN<dLOCAL._FOR>>)
      REF1=<TAG0.KONUSAN<dLOCAL._FOR>>
      dtext 30 <EVAL (<dLOCAL._FOR> * 40) - 18> 1153 <REF1.NAME> (<REF1.UID>)
      button 30 <EVAL (<dLOCAL._FOR> * 40)> 4006 4005 1 0 <EVAL <LOCAL._FOR> + 1>
      dtext 65 <EVAL (<dLOCAL._FOR> * 40) + 2> 1153 Jail (küfür)
      button 220 <EVAL (<dLOCAL._FOR> * 40)> 4006 4005 1 0 <EVAL <LOCAL._FOR> + 11>
      dtext 255 <EVAL (<dLOCAL._FOR> * 40) + 2> 1153 Jail (hakaret)
   ENDIF
ENDFOR

[DIALOG d_kufur BUTTON]
ON=1
REMOVE

ON=2 11
REF1=<TAG0.KONUSAN<EVAL <ARGN> - 1>>
SERV.NEWITEM i_jail_timer
NEW.TIMER <EVAL <DEF0.JAIL_KUFUR> * 60 * 60>
NEW.TAG.SUC kufur
REF1.EQUIP <NEW>
SRC.SYSMESSAGE @,,1 <REF1.NAME>, <DEF0.JA_KUFUR> suçundan jaillanmıştır.
IF !(<REF1.ISONLINE>)
   REF1.EVENTS +kufurdenjail
ELSE
   REF1.SYSMESSAGE @,,1 Küfür dedektörü tarafından yakalandınız.
ENDIF
IF !(<LINK.ISONLINE>)
   LINK.TAG.REF1 <REF1>
   LINK.EVENTS +kufurdenjail2
ELSE
   LINK.SYSMESSAGE @,,1 <REF1.NAME>, sizin şikayetiniz üzerine jaillanmıştır.
ENDIF
USEITEM

ON=12 21
REF1=<TAG0.KONUSAN<EVAL <ARGN> - 11>>
SERV.NEWITEM i_jail_timer
NEW.TIMER <EVAL <DEF0.JAIL_HAKARET> * 60 * 60>
NEW.TAG.SUC hakaret
REF1.EQUIP <NEW>
SRC.SYSMESSAGE @,,1 <REF1.NAME>, <DEF0.JA_HAKARET> suçundan jaillanmıştır.
IF !(<REF1.ISONLINE>)
   REF1.EVENTS +kufurdenjail
ELSE
   REF1.SYSMESSAGE @,,1 Küfür dedektörü tarafından yakalandınız.
ENDIF
IF !(<LINK.ISONLINE>)
   LINK.TAG.REF1 <REF1>
   LINK.EVENTS +kufurdenjail2
ELSE
   LINK.SYSMESSAGE @,,1 <REF1.NAME>, sizin şikayetiniz üzerine jaillanmıştır.
ENDIF
USEITEM

[EVENTS kufurdenjail]
ON=@Login
SYSMESSAGE @,,1 Küfür dedektörü tarafından yakalandınız.
EVENTS -kufurdenjail

[EVENTS kufurdenjail2]
ON=@Login
REF1=<TAG.REF1>
TAG.REF1=
SYSMESSAGE @,,1 <REF1.NAME>, sizin şikayetiniz üzerine jaillanmıştır.
EVENTS -kufurdenjail2

[ITEMDEF i_kufur_dedektor]
ID=i_book_sm
NAME=what up biatch
TYPE=T_COMM_CRYSTAL

ON=@Create
ATTR <ATTR>|attr_invis
MORE1=60
SPEECH=spk_kufur

ON=@DClick
SDIALOG d_kufur
RETURN 1

ON=@Timer
IF !(<MORE1>)
   CONT <DEF.KUFUR_CONTAINER>
   LINK.TAG.KUFURDEDEKTOR
   SERV.ALLCLIENTS F_STAFF_MSG Yeni küfür şeysi. Bi stara gidip bakın mümkünse.
   RETURN 1
ENDIF
P <LINK.P>
REMOVEFROMVIEW
TIMER 1
MORE1 --
RETURN 1

ON=@Click
MESSAGE @,,1 Şikayet Eden: <LINK.NAME> [<LINK.UID>]
MESSAGE @,,1 Tarih: <TAG.DATE>
RETURN 1

[FUNCTION f_staff_msg]
IF (<ACCOUNT.PLEVEL> > 1)
   SYSMESSAGE @69,1,1 <args>
ENDIF