[Defname crafting_hamit]
alchemy_items_0=Less,Normal,Great,Super,Drink,Other
alchemy_items_Less=i_potion_explosionless,i_potion_poisonless,i_potion_healless,i_potion_cureless,i_potion_bleedless
alchemy_items_Normal=i_potion_agility,i_potion_refresh,i_potion_explosion,i_potion_poison,i_potion_heal,i_potion_cure,i_potion_strength,i_potion_nightsight,i_potion_bleed
alchemy_items_Great=i_potion_agilitygreat,i_potion_explosiongreat,i_potion_poisongreat,i_potion_healgreat,i_potion_curegreat,i_potion_strengthgreat,i_potion_bleedgreat
alchemy_items_Super=i_potion_refreshtotal,i_potion_poisondeadly,i_potion_bleedsuper
alchemy_items_Drinks=i_bottle_ale,i_ale_honey,i_ale_amber,i_ale_brown,i_ale_stout,i_ale_spiced,i_ale_smoked,i_ale_oktoberfest,i_bottle_liquor,i_bottle_wine
alchemy_items_Other=i_potion_invisibility,i_potion_shrink

inscription_items_0=Page_1,Page_2,Page_3,Page_4,Page_5,Page_6,Page_7,Page_8,Other
inscription_items_Page_1=i_scroll_clumsy,i_scroll_create_food,i_scroll_feeblemind,i_scroll_heal,i_scroll_magic_arrow,i_scroll_night_sight,i_scroll_reactive_armor,i_scroll_weaken
inscription_items_Page_2=i_scroll_agility,i_scroll_cunning,i_scroll_cure,i_scroll_harm,i_scroll_magic_trap,i_scroll_magic_untrap,i_scroll_protection,i_scroll_strength
inscription_items_Page_3=i_scroll_bless,i_scroll_fireball,i_scroll_magic_lock,i_scroll_poison,i_scroll_telekinesis,i_scroll_teleport,i_scroll_unlock,i_scroll_wall_of_stone
inscription_items_Page_4=i_scroll_archcure,i_scroll_archprotection,i_scroll_curse,i_scroll_fire_field,i_scroll_greater_heal,i_scroll_lightning,i_scroll_mana_drain,i_scroll_recall
inscription_items_Page_5=i_scroll_blade_spirits,i_scroll_dispel_field,i_scroll_incognito,i_scroll_magic_reflection,i_scroll_mind_blast,i_scroll_paralyze,i_scroll_poison_field,i_scroll_summon_creature
inscription_items_Page_6=i_scroll_dispel,i_scroll_energy_bolt,i_scroll_explosion,i_scroll_invisibility,i_scroll_mark,i_scroll_mass_curse,i_scroll_paralyze_field,i_scroll_reveal
inscription_items_Page_7=i_scroll_chain_lightning,i_scroll_energy_field,i_scroll_flamestrike,i_scroll_gate_travel,i_scroll_mana_vampire,i_scroll_mass_dispel,i_scroll_meteor_swarm,i_scroll_polymorph
inscription_items_Page_8=i_scroll_earthquake,i_scroll_energy_vortex,i_scroll_resurrection,i_scroll_summon_elem_air,i_scroll_summon_daemon,i_scroll_summon_elem_earth,i_scroll_summon_elem_fire,i_scroll_summon_elem_water
inscription_items_Other=i_spellbook,i_spellbook_full,i_runebook

bowcraft_items_0=Items,Bows,Other
bowcraft_items_Items=i_arrow,i_xbolt,i_arrow_shaft
bowcraft_items_Bows=i_bow,i_crossbow,i_crossbow_heavy,i_bow_elven
bowcraft_items_Other=i_feather

carpentery_items_0=Chairs,Containers,Tables,Weapons,Furniture,Miner_Tools,Tailor_Tools,Dyes,Other
carpentery_items_Chairs=i_chair_throne,i_chair_wood_rough_dark,i_chair_wood_fancy_cushion,i_chair_wood_cushion,i_chair_wood,i_chair_wood_bamboo,i_chair_stool_BAR,i_chair_stool,i_bench_wood_dark
carpentery_items_Containers=i_chest_wooden_brass,i_box_wood,i_crate_small,i_crate_md,i_crate_lg
carpentery_items_Tables=i_table_nightstand,i_table_wood_rough_small,i_table_wood_rough_board,i_bench_woodworker_end,i_vise,i_bench_cooper,i_table_writing
carpentery_items_Weapons=i_club,i_staff_gnarled,i_staff_quarter,i_shepherds_crook,i_staff_black,i_fishing_pole,i_shield_wood
carpentery_items_Furniture=i_bar_door_ne,i_bar_piece,i_bookcase,i_bookcase_full,i_armoir_dk,i_armoir_lt,i_bureau_2,i_music_stand,i_music_stand_tall
carpentery_items_Miner_Tools=i_deed_forge,i_deed_anvil
carpentery_items_Tailor_Tools=i_spinning_wheel,01062,01061
carpentery_items_Dyes=i_dye_tub,i_dye_tub_rare,i_dye_tub_armor,i_dye_tub_animal,i_dye_tub_weapons
carpentery_items_Other=i_deed_bboardw,i_deed_bboardn,i_deed_pickpockw,i_deed_pickpockn,i_deed_dummyw,i_deed_dummyn,i_saddle

tailor_items_0=Hats,Shirts,Pants,Shoes,Leather,Studded,Female_Armor,Bags,Other
tailor_items_Hats=i_skull_cap,i_bandana,i_hat_floppy,i_hat_wide_brim,i_hat_straw,i_hat_straw_tall,i_bonnet,i_hat_feather,i_hat_jester,i_cap,i_hat_wizards
tailor_items_Shirts=i_doublet,i_shirt_plain,i_shirt_fancy,i_tunic,i_surcoat,i_dress_plain,i_dress_full,i_cape,i_robe,i_jester_suit
tailor_items_Pants=i_pants_short,i_pants_long,i_kilt,i_skirt_long
tailor_items_Shoes=i_sandals,i_shoes_plain,i_boots_calf,i_boots_thigh
tailor_items_Leather=i_leather_gorget,i_leather_cap,i_leather_gloves,i_leather_sleeves,i_leather_leggings,i_leather_tunic
tailor_items_Studded=i_studded_gorget,i_studded_gloves,i_studded_sleeves,i_studded_leggings,i_studded_tunic
tailor_items_Female_Armor=i_armor_female_shorts,i_armor_female_skirt,i_armor_female_bustier,i_armor_female_bustier_studded,i_armor_female_leather,i_armor_female_studded
tailor_items_Bags=i_backpack,i_pouch,i_bag
tailor_items_Other=i_sash,i_apron_half,i_apron_full,i_deathshroud

crafting_areas_x=200,345,490,200,345,490,200,345,490,200,345,490
crafting_areas_y=82,82,82,182,182,182,282,282,282,382,382,382

//*************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2012
// TARİH: 31.01.2012
// SAAT : 15:37
// KONU : Crafting Dialog
//*************************************
VERSION=0.56b

[DIALOG d_menu_crafting]
0,0
NOMOVE
resizepic 0 0 5054 650 450
resizepic 10 40 3000 305 400
dtext 20 15 250 <serv.servname> <src.ctag0.crafting> Menu
resizepic 10 40 3500 160 400
resizepic 165 40 3500 475 400
dtext 50 48 00 Categories

local.t 70
for cat 1 <qval <f_moonsep 0,<def.<src.ctag0.crafting>_items_0>> <= 9 ? <f_moonsep 0,<def.<src.ctag0.crafting>_items_0>> : 9>

for sep 2 <f_moonsep 0,<explode _,<f_moonsep <dlocal.cat>,<def.<src.ctag0.crafting>_items_0>>>>
local.menu="<local.menu> <f_moonsep <dlocal.sep>,<explode _,<f_moonsep <dlocal.cat>,<def.<src.ctag0.crafting>_items_0>>>>"
endfor

dtext 60 <eval <dlocal.t> + 2> 00 <streat <local.menu>>
button 25 <dlocal.t> 4005 4006 0 <dlocal.cat>
local.t +=30
local.menu=""
endfor

for all 1 <qval <f_moonsep 0,<def.<src.ctag0.crafting>_items_0>> <= 9 ? <f_moonsep 0,<def.<src.ctag0.crafting>_items_0>> : 9>
PAGE <dlocal.all>
src.ctag.button <dlocal.all>,1
for page 1 <qval <f_moonsep 0,<def.<src.ctag0.crafting>_items_<f_moonsep <dlocal.all>,<def.<src.ctag0.crafting>_items_0>>>> <= 12 ? <f_moonsep 0,<def.<src.ctag0.crafting>_items_<f_moonsep <dlocal.all>,<def.<src.ctag0.crafting>_items_0>>>> : 12>
tilepic <eval <f_moonsep <dlocal.page>,<def.crafting_areas_x>> + 20> <eval <f_moonsep <dlocal.page>,<def.crafting_areas_y>> - 20> <serv.itemdef.<f_moonsep <dlocal.page>,<def.<src.ctag0.crafting>_items_<f_moonsep <dlocal.all>,<def.<src.ctag0.crafting>_items_0>>>>.id>
dtext <f_moonsep <dlocal.page>,<def.crafting_areas_x>> <f_moonsep <dlocal.page>,<def.crafting_areas_y>> 00 <strsub 0 20,<serv.itemdef.<f_moonsep <dlocal.page>,<def.<src.ctag0.crafting>_items_<f_moonsep <dlocal.all>,<def.<src.ctag0.crafting>_items_0>>>>.name>>
button <eval <f_moonsep <dlocal.page>,<def.crafting_areas_x>> - 20> <eval <f_moonsep <dlocal.page>,<def.crafting_areas_y>> + 2> 2511 2510 1 0 <f_moonsep 1,<src.ctag0.button>><f_moonsep 2,<src.ctag0.button>>
src.ctag.button=<dlocal.all>,<eval <f_moonsep 2,<src.ctag0.button>> + 1>
endfor
endfor
src.ctag.button

[DIALOG d_menu_crafting BUTTON]
on=0
src.hata Sayfayı kapattınız.
src.ctag.crafting
return 1

on=1 9999
src.ctag.makelast <f_moonsep <strsub 1 4 <dargn>>,<def.<src.ctag0.crafting>_items_<f_moonsep <strsub 0 1 <dargn>>,<def.<src.ctag0.crafting>_items_0>>>>
src.ctag.crafting
src.f_makelast

[function f_moonsep]
if <argv[0]> == 0
return <eval <argv> - 1>
else
return <argv[<argv[0]>]>
endif

[Function hata]
sysmessage @026,,1 <args>

[Function makelast]
src.f_makelast

[Function tekraryap]
src.f_makelast

[Function f_makelast]
if !(<ctag0.makelast> == 0)
  if (<canmake <ctag0.makelast>>)
  makeitem=<ctag0.makelast>
  else
  for 1 <f_moonsep 0,<SERV.ITEMDEF.<ctag0.makelast>.RESOURCES>>
  ctag.makelast_error <qval (<ctag0.makelast_error>) ? <ctag.makelast_error>,> <SERV.ITEMDEF.<ctag0.makelast>.RESOURCES.<dlocal._for>.val><SERV.ITEMDEF.<SERV.ITEMDEF.<ctag0.makelast>.RESOURCES.<dlocal._for>.key>.NAME>
    if <dlocal._for> == <f_moonsep 0,<SERV.ITEMDEF.<ctag0.makelast>.RESOURCES>>
    sysmessage @026,,1 Bunu yapabilmek için çantanızda <ctag.makelast_error> olması gereklidir.
    ctag.makelast_error
    endif
  endfor
  endif
else
sysmessage @026,,1 Herhangi bir eşya yapmadınız.
return 1
endif

[ITEMDEF i_potion_bleedless]
ID=0f08
Type=t_potion_bleed
Name=Lesser Bleed
TDATA1=i_bottle_empty

RESOURCES=i_reag_garlic 3,i_bottle_empty
SKILLMAKE=alchemy 33.1

ON=@Create
COLOR=060
MORE2=40.0
MOREY=7

[ITEMDEF i_potion_bleed]
ID=0f08
Type=t_potion_bleed
Name=Bleed
TDATA1=i_bottle_empty

RESOURCES=i_reag_garlic 5,i_bottle_empty
SKILLMAKE=alchemy 57.3

ON=@Create
COLOR=060
MORE2=60.0
MOREY=4

[ITEMDEF i_potion_bleedgreat]
ID=0f08
Type=t_potion_bleed
Name=Greater Bleed
Tdata1=i_bottle_empty

RESOURCES=i_reag_garlic 8,i_bottle_empty
SKILLMAKE=alchemy 83.0

ON=@Create
COLOR=060
MORE2=80.0
MOREY=2

[ITEMDEF i_potion_bleedsuper]
ID=0f08
Type=t_potion_bleed
Name=Super Bleed
Tdata1=i_bottle_empty

RESOURCES=i_reag_garlic 11,i_bottle_empty
SKILLMAKE=alchemy 96.9

ON=@Create
COLOR=060
MORE2=100.0
MOREY=1

[Typedef t_potion_bleed]
ON=@DClick
if (<src.findid.i_bleeding>) || (<src.findid.i_bleeding2>)
  if rand(<morey>) == 1
  src.findid.i_bleeding.remove
  src.findid.i_bleeding2.remove
  src.events -e_bleed
  src.effect snd_spell_poison
  src.effect 3,0376a,2,10,1
  src.sayua 048,6,6,0 *Yarasini Tedavi Eder*
  consume 1
  src.act <tdata1>
  else
  src.sayua 048,6,6,0 *Tedavi Uygulayamadınız*
  consume 1
  src.act <tdata1>
  return 1
  endif
else
src.hata Tedaviye ihtiyacınız yok.
return 1
endif

[ITEMDEF i_spellbook_full]
ID=i_spellbook
NAME=Spellbook
TYPE=t_spellbook

RESOURCES=i_spellbook 1,i_scroll_blank 64
SKILLMAKE=inscription 100.0,magery 100.0,evaluatingintel 100.0,meditation 100.0

ON=@CREATE
ATTR=attr_magic|attr_newbie
MORE=04ffffffff
MORE2=04ffffffff

Son Düzenlemeler;
Potionların kendi resimleri ile gösterilmesi.
PAGE ayarları tek olarak yapıldı. Böylece sadece defname eklemesi yaparak dialog kullanılabilecek.
Bir sayfaya en fazla 12 item, 9 kategori sınırı konuldu.
Makelast src. hatası düzeltildi.
Defnameler artık kendi kategorilerine göre işlem yapacak.
alchemy_items_all defname'i kaldırıldı.
restest yerine, canmake ile sorgu fazlalığı kaldırıldı.
İçki kategorisi eklendi.
Bleed potion itemleri yazıldı.
Rare,exlosionsuper gibi gereksiz itemler kaldırıldı.
Inscription menüsü eklendi.
Bir dialog tüm dialoglara uyarlandı.
Tailor, Carpentery ve BowCraft menüleri eklendi.

Kullanımı;
src.ctag.crafting skilladı
sdialog d_menu_crafting

Örnek;
[Function alchemy]
src.ctag.crafting alchemy
sdialog d_menu_crafting

PAGE 1
if (<dargv[0]> = 1)
...
..
endif

PAGE 2
if (<dargv[0]> = 2)
...
..
endif