UO-Dev Arama


Yazar: Bilinmiyor
Tarih: 26-04-2020 18:27





https://i.hizliresim.com/6a2MEF.jpg

Kod:
[Function Staffkontrol]
Local.toplamstaff=
For 0 <Eval <Serv.Clients>-1>
If <Uid.<Serv.Client.<Local._For>.uid>.Account.Plevel> >1
Local.toplamstaff +=1
Endif
Endfor
Return <dlocal.toplamstaff>


[Dialog d_Helpmenu]

185,0
NoMove
Page 0
Resizepic 25 25 83 400 350
Resizepic 32 35 9300 387 330
AlphaBlack 32 35 387 330
DHtmlgump 25 45 400 20 0 0 <def.h6><def.bfont_yellow><def.center><serv.name> Help Menü
Page 1
Resizepic 50 220 5120 170 130
Resizepic 230 220 5120 170 130
//DText 110 230 1153 Stuck
//DText 110 260 1153 Istatistikler
//DText 110 290 1153 Website
//DText 110 320 1153 Forumlar
DHtmlgump 110 230 120 20 0 0 <def.h6><def.bfont_white>Stuck
DHtmlgump 110 260 120 20 0 0 <def.h6><def.bfont_white>Istatistikler
DHtmlgump 110 290 120 20 0 0 <def.h6><def.bfont_white>Web Sayfası
DHtmlgump 110 320 120 20 0 0 <def.h6><def.bfont_white>Forumlar


//DHtmlgump 250 230 140 20 0 0 <def.h6><def.bfont_White>Çevrimiçi Yetkili : <qval <Staffkontrol>?<def.bfont_black><Staffkontrol>:<def.bfont_red>Yok>
DHtmlgump 250 230 140 20 0 0 <def.h6><def.bfont_White>Bekleyen Page   : <qval <dserv.gmpages>?<def.bfont_black><dserv.gmpages>:<def.bfont_red>Yok>
DHtmlgump 250 260 140 20 0 0 <def.h6><def.bfont_White>Çevrimiçi Oyuncu : <def.bfont_black><serv.clients>
DHtmlgump 250 290 140 20 0 0 <def.h6><def.bfont_White>Guild Sayısı     : <qval <serv.guilds>?<def.bfont_black><serv.guilds>:<def.bfont_red>Yok>
DHtmlgump 250 320 140 20 0 0 <def.h6><def.bfont_White>Aile Sayısı      : <def.bfont_black><Serv.Itemdef.i_aile.Instances>

Button 70 230 4006 4007 0 2 1000
Button 70 260 4006 4007 0 102 1000
Button 70 290 4006 4007 1 0 4
Button 70 320 4006 4007 1 0 5

Resizepic 35 65 5170 <qval <Staffkontrol> ? 271:380> 155
IF (StrMatch("Asede","<Account.Name>")) && (<Src.ISGM>) && (<Src.Account.Plevel> > 6)
Button 50 70 5401 5402 0 100 1000
DText 70 68 1153 Duyuruları düzenle
Endif

For 1 10
If !(<ISEMPTY <Var.HelpDuyuru<dlocal._for>>>)
Local.Helpduyuru .="<def.bfont_red>••• <def.bfont_black><Var.HelpDuyuru<dlocal._for>><def.br>"
Endif
EndFor
DHtmlgump 55 90 <qval <Staffkontrol> ? 250:345> 100 0 1 <def.bfont_red><def.center>DUYURULAR</center><STRSub 1 0 <Local.Helpduyuru>>

If (<Staffkontrol> >0)
For 0 <Hval <Serv.Clients>-1>
If (<Serv.Client.<Eval <Local._For>>.Account.Plevel> > 1)
Local.Siralama .="<def.bfont_red><Qval (<Serv.Client.<Local._For>.Account.Plevel>==8)?• Yönetici •:• Yetkili •><Def.BR><def.bfont_green><Serv.Client.<Local._For>.Name><Def.BR>"
Endif
Endfor
Dhtmlgump 315 100 90 70 0 1 <Def.center><STRSub 1 0 <Local.Siralama>>
Resizepic 310 100 9300 87 70
DText 327 65 039 Çevrimiçi
DText 344 180 039 Bize iletin
Button 312 180 4030 4031 1 0 1
Endif

Page 2 // Stuck
Resizepic 85 75 5170 280 255
For 1 10
Button 160 <Eval 85 + (<dLocal._For>*20)> 10710 10711 <Qval (<Src.Account.Jail>)?0:1> 0 <Eval <dLocal._For>+100>
EndFor
Local.OzamanRenk 339
DText 200 100 <Local.OzamanRenk> Britain
DText 200 120 <Local.OzamanRenk> Buccaneer's Den
DText 200 140 <Local.OzamanRenk> Delucia
DText 200 160 <Local.OzamanRenk> Jhelom
DText 200 180 <Local.OzamanRenk> Magincia
DText 200 200 <Local.OzamanRenk> Minoc Vesper
DText 200 220 <Local.OzamanRenk> Moonglow
DText 200 240 <Local.OzamanRenk> Skara Brae
DText 200 260 <Local.OzamanRenk> Trinsic
DText 200 280 <Local.OzamanRenk> Yew
Button 175 332 5603 5607 0 1 1000
DText 200 330 1153 Ana sayfaya dön

Page 100
Resizepic 65 75 5170 320 255
For 1 10
IF !(<IsEmpty <Var.HelpDuyuru<dLocal._For>>>)
Local.Kactane ++
Dhtmlgump 125 <Eval 85 + <dLocal.Kactane>*20> 200 20 0 0 <Def.BFont_Black><STRSub 0 30 <Var.Helpduyuru<dLocal._For>>>...
Button 100 <Eval 85 + <dLocal.Kactane>*20> 5401 5402 1 0 <Eval <dLocal._For> + 200>
Endif
Endfor
Button 335 332 4011 4012 0 101 1000
DText 260 333 1153 Duyuru Ekle
Button 80 332 5603 5607 0 1 1000
DText 105 330 1153 Geri

Page 101

Resizepic 65 75 5170 320 255
For 1 10
Resizepic 85 <Eval 104 + <dLocal._For>*18> 9300 280 16
EndFor
DText 90 100 1153 Lütfen bir duyuru yazın;
DTextenTry 90 120 270 140 1152 1
Button 320 332 5407 5407 1 0 1453
DText 225 330 1153 Duyuru Kaydet
Button 80 332 5603 5607 0 100 1000
DText 105 330 1153 Geri

Page 102
Resizepic 40 80 5120 150 40
DText 95 80 1153 Pvp 1.si
DText 60 97 339 Deneme

Resizepic 40 120 5120 150 40
DText 95 120 1153 Topuk 1.si
DText 60 137 339 Deneme

Resizepic 40 160 5120 150 40
DText 95 160 1153 Expo 1.si
DText 60 177 339 Deneme

Resizepic 40 200 5120 150 40
DText 95 200 1153 Tame 1.si
DText 60 217 339 Deneme

Resizepic 40 240 5120 150 40
DText 95 240 1153 En Son Ölüm
DText 60 257 339 Deneme

Resizepic 40 280 5120 150 40
DText 95 280 1153 En Son Öldüren
DText 60 297 339 Deneme


[Dialog d_Helpmenu Button]

On=1 // Page
If (<src.findid.i_page_yasak>)
src.sysmessage @07a1,,1 Page atabilmek icin <eval <src.findid.i_page_yasak.timer> / 60> dakika beklemelisiniz.
Return 1
Endif
Src.dialog d_page_sender

On=2 // Stuck
Src.Stuckcek

//On=3 İstatistik
//On=4 Websitesi
//On=5 Forumlar

On=100 110
IF (<Argn> == 101)
Src.Stuckcek Britain
ElseIF (<Argn> == 102)
Src.Stuckcek Buccaneer's Den
ElseIF (<Argn> == 103)
Src.Stuckcek Delucia
ElseIF (<Argn> == 104)
Src.Stuckcek Jhelom
ElseIF (<Argn> == 105)
Src.Stuckcek Magincia
ElseIF (<Argn> == 106)
Src.Stuckcek Minoc Vesper
ElseIF (<Argn> == 107)
Src.Stuckcek Moonglow
ElseIF (<Argn> == 108)
Src.Stuckcek Skara Brae
ElseIF (<Argn> == 109)
Src.Stuckcek Trinsic
ElseIF (<Argn> == 110)
Src.Stuckcek Yew
Endif
On=200 210
Serv.Var.HelpDuyuru<Eval <Argn> - 200>
Src.Sysmessage @07a1,,1 Duyuru silinmiştir.
SDialog D_HelpMenu,100
On=1453
For 1 10
IF (<IsEmpty <Var.HelpDuyuru<dLocal._For>>>)
Serv.Var.Helpduyuru<dLocal._For> <ArgTxt[1]>
Src.Sysmessage @07a1,,1 Duyurunuz başarıyla kaydedilmiştir.
Return 1
Endif
EndFor
Src.Sysmessage @38,,1 Duyuru listeniz dolu.! Yeni duyuru eklemek için bir duyuruyu silmeniz gerekmektedir.
//////////////////////////// STUCK//////////////////////////////////////////////
[Function Stuckcek]
If (<ISEMPTY <Tag.Gidiyorum>>)
Tag.Gidiyorum <Args>
Endif
If !(<Tag0.Dialog>)
Tag0.Kalan 60
Endif
If (<Tag0.Dialog> == 60)
DialogClose Stuckzaman
Sysmessage @077a,,1 Belirlenen kordinatlara gönderildiniz.
Src.Go <Tag.Gidiyorum>
Src.Update
Tag.Gidiyorum=
Flags <Src.Flags>&~04
Tag0.Dialog=
Return 1
Endif

SRC.FLAGS=<SRC.FLAGS>|020004
DialogClose Stuckzaman
Tag0.Dialog +=1
tag0.Kalan -=1
Dialog Stuckzaman
TimerF 1,Stuckcek

[Dialog Stuckzaman]
-10,590   // Sol Alt Köşede
//200,200 // Ortada karakter üzerinde
Noclose
Nomove
resizepic 10 10 83 340 115
resizepic 20 20 9300 320 95
resizepic 30 80 5120 300 25
resizepic 30 80 9300 <eval ((<tag0.dialog>)*5)-1> 25
Checkertrans 20 20 320 95
resizepic 50 30 9300 260 20
resizepic 50 55 9300 260 20
dhtmlgump 60 30 250 20 0 0 <def.bfont_black>Bulunduğunuz kordinatlar : <def.h6><def.bfont_red><src.p>
dhtmlgump 60 55 250 20 0 0 <def.h7><def.bfont_green><Tag0.Gidiyorum> için kalan süre : <def.h7><def.bfont_red><def.bfont_red><dtag0.kalan> saniye
if (<eval (0+<eval <eval <src.tag0.dialog>*100>/60>)> > 53)
endif
DText 170 83 039 %<eval (0+<eval <eval <src.tag0.dialog>*100>/60>)>

//////////////////////////////////////////PAGE//////////////////////////////////

[PLEVEL 2]
pg

[FUNCTION pg]
if !(<serv.gmpages>)
src.sysmessage @077a,,1 Bekleyen page bulunmamaktadir.
else
src.ctag0.page_index =
dialogclose d_page_view
if (<src.dctag0.page_handle>)
src.ctag0.page_index = <eval <src.ctag0.page_handle>-1>
else
src.ctag0.page_index = 0
endif
dialog d_page_view 0 <src.dctag0.page_index>
endif
return 1

[DIALOG d_page_view]
150,100
nomove
Resizepic 0 0 83 450 350
Resizepic 8 10 9300 435 330

dtext 162 30 1152 <serv.name> Page Sistemi

Resizepic 42 252 83 370 70
resizepic 50 262 5054 355 50

src.ctag0.page_index = <dargv[0]>
gumppic 80 80 <qval(<uid.<strarg <serv.gmpage.<dargv[0]>.reason>>.isonline>)?0939:0938>
dhtmlgump 80 58 200 20 0 0 <def.bfont_red><eval <serv.gmpage.<dargv[0]>.time>/60> dk önce gönderildi. <qval(<serv.gmpage.<dargv[0]>.handled>)?<qval(<serv.gmpage.<dargv[0]>.handled> != <src>)?(<uid.<strarg <serv.gmpage.<dargv[0]>.handled>>.name> ilgileniyor.)>:>
dtext 100 75 <qval(<uid.<strarg <serv.gmpage.<dargv[0]>.reason>>.isonline>)?040:38> <uid.<strarg <serv.gmpage.<dargv[0]>.reason>>.name> (<strarg <serv.gmpage.<dargv[0]>.reason>>)
dhtmlgump 80 100 295 120 1 1 <streat <serv.gmpage.<dargv[0]>.reason>>
dtext 200 230 50 <eval <argv[0]>+1> / <serv.gmpages>
if !(<src.dctag0.page_handle>)
if (<serv.gmpage.<eval <argv[0]>+1>.reason>)
button 260 230 9903 9905 1 0 1
endif
if (<eval <argv[0]>+1> > 1)
button 170 230 9909 9911 1 0 2
endif
endif
button 80 275 0FA2 0Fa4 1 0 3
dtext 115 275 1153 Sil
button 150 275 0FA5 0FA7 1 0 4
dtext 185 275 1153 Git
button 220 275 0FAE 0FB0 1 0 5
dtext 255 275 1153 Getir
button 295 275 0FAB 0FAD 1 0 6
dtext 330 275 1153 Mesaj

[DIALOG d_page_view BUTTON]
ON=0
src.ctag0.page_index =

ON=1
src.ctag0.page_index +=1
sdialog d_page_view 0 <src.ctag0.page_index>

ON=2
src.ctag0.page_index -=1
sdialog d_page_view 0 <src.ctag0.page_index>

ON=3 6
if (<serv.gmpage.<src.ctag0.page_index>.handled>) && (<serv.gmpage.<src.ctag0.page_index>.handled> != <src>)
src.sysmessage Bu bildiri ile <uid.<eval <serv.gmpage.<src.ctag0.page_index>.handled>>.name> ilgileniyor.
sdialog d_page_view 0 <src.ctag0.page_index>
elif !((<dargn> = 3) || (<dargn> = 6)) && !(<uid.<strarg <serv.gmpage.<src.dctag0.page_index>.reason>>.isonline>)
src.sysh_trk Bildiriyi yapan oyuncu oyunda degil.
sdialog d_page_view 0 <src.ctag0.page_index>
else
if (<dargn> = 3)
try gmpage.<src.dctag.page_index>.handle
try gmpage.<src.dctag0.page_index>.d
src.ctag0.page_handle=
src.sysmessage @07a1,,1 Bildiri silindi.
elif (<dargn> = 4)
src.go <uid.<strarg <serv.gmpage.<src.dctag0.page_index>.reason>>.p>
try gmpage.<src.ctag0.page_index>.handle
src.ctag0.page_handle=<eval <src.ctag0.page_index>+1>
elif (<dargn> = 5)
try uid.<strarg <serv.gmpage.<src.dctag0.page_index>.reason>>.go <src.p>
try gmpage.<src.ctag0.page_index>.handle
src.ctag0.page_handle=<eval <src.dctag0.page_index>+1>
elif (<dargn> = 6)
src.ctag0.page_handle=<eval <src.dctag0.page_index>+1>
try gmpage.<src.ctag0.page_index>.handle
sdialog d_page_send_msg 0 <src.dctag0.page_index>
endif
src.ctag0.page_index=
src.update
endif

[DIALOG d_page_send_msg]
0,0

resizepic 42 40 83 355 320
resizepic 50 50 5120 340 300
Checkertrans 50 50 340 300
dtext 80 80 48 <uid.<strarg <serv.gmpage.<dargv[0]>.reason>>.name> (<strarg <serv.gmpage.<dargv[0]>.reason>>)
dhtmlgump 80 100 280 70 1 1 <streat <serv.gmpage.<dargv[0]>.reason>>
dtext 80 170 50 Göndermek istediğiniz cevap;
resizepic 80 190 3000 280 105
dtextentry 85 195 260 100 1153 0 <var.blank>
button 80 310 4005 4007 1 0 1
dtext 115 310 50 Gönder

[DIALOG d_page_send_msg BUTTON]
ON=0
src.pg

ON=1
local.pg=<eval <src.ctag0.page_handle>-1>
ref1=<strarg <serv.gmpage.<dlocal.pg>.reason>>
ref1.tag0.page_msg = <streat <serv.rtime>> <src> <argtxt[0]>
if (<ref1.isonline>)
trysrc <ref1> dialog d_page_msg
else
ref1.events +e_pg_msg
endif
src.sysmessage @039,,1 Mesajınız Gönderildi.
try gmpage.<dlocal.pg>.d
src.ctag0.page_handle=

[DIALOG d_page_msg]
0,0
Nomove

page 1
button 15 30 30 30 0 2 2
dtext 15 60 039 Mesajınız Var!

page 2
resizepic 200 150 83 340 200
resizepic 208 160 9300 325 180
//resizepic 50 50 5120 340 200
dtext 230 180 39 Gönderen: <uid.<strarg <streat <src.tag0.page_msg>>>.name>, Tarih: <strarg <src.tag0.page_msg>>
dhtmlgump 230 200 280 120 1 1 <streat <streat <src.tag0.page_msg>>>

[DIALOG d_page_msg BUTTON]
ON=0
src.tag0.page_msg=

[EVENTS e_pg_msg]
ON=@login
src.sdialog d_page_msg
src.events -e_pg_msg




[function page_info]
if (<account.plevel> > 1)
sysmessageua 048,0,0,trk <args>
endif

[itemdef i_page_yasak]
defname i_page_yasak
id i_memory
type t_eq_Script

on=@create
timer 60*2

on=@timer
cont.sysmessage Page yasaginiz kalkmistir.
remove
return 1

[itemdef i_staff_yasak]
defname i_staff_yasak
id i_memory
type t_eq_Script

on=@create
timer 60*5

on=@timer
cont.sysmessage @60,,1 <name> Page yasağınız kalkmıştır
remove
return 1

[DIALOG d_page_sender]
150,40
nomove
///noclose

Resizepic 0 150 83 500 200
Resizepic 5 160 5120 490 180
Checkertrans 5 160 490 180
dtext 170 170 039 <Serv.Name> Page Sistemi
Resizepic 10 195 9300 480 100
dtext 140 310 0455 Page Gönder
button 100 310 4030 4031 1 0 1
dtext 340 310 0455 Sayfa Temizle
button 300 310 4006 4007 1 0 2

button 470 170 3 4 1 0 3

////dtextentry 15 200 460 90 039 0
dtextentrylimited 15 200 460 90 1152 0 250

[DIALOG d_page_sender TEXT]
<gmpages>

[DIALOG d_page_sender BUTTON]
ON=0
Src.sysmessage @39,,1 Çıkış yaptınız.
ON=1
if (<src.findid.i_staff_yasak>)
src.sysmessage  Cezanızın bitmesi için <eval <src.findid.i_staff_yasak.timer> / 60> dakika beklemelisiniz.
elseif (<src.findid.i_jailcik>) || (<flags>&statf_stone) || (<Src.Account.Jail>)
src.sysh_trk Şuan page atamassınız.
elseif (<src.findid.i_page_yasak>)
src.Sysmessage @07a1,,1 Page atabilmek icin <eval <src.findid.i_page_yasak.timer> / 60> dakika beklemelisiniz.
else
gmpage add <src> <argtxt[0]>
src.message @077a,,1 Bildiriniz gönderildi. <dserv.gmpages>. sıradasınız.
src.newitem i_page_yasak
src.act.equip
endif

ON=2
src.dialog d_page_sender

ON=3
sysmessage @39,,1 Çıkış yaptınız.


[EOF]



Yorumlar

Henüz yorum yapılmamıştır.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : Henüz Oylanmamış   
Oylar: 0

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
Jail Menu0Freeman08-09-2016
Page Sistemi0Weight17-04-2011
Skills Menu0Amesron26-08-2009
Namer's Help Menu V1,20Amesron18-08-2009
Page Sistemi0TheRaskol29-07-2009


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,