UO-Dev Arama


Yazar: 4s3d3
Tarih: 26-04-2020 18:29





https://i.hizliresim.com/j8iUDs.jpg

https://i.hizliresim.com/UvO9zF.jpg

https://i.hizliresim.com/87uj1W.jpg

Kod:
[Defname VendorSistemAyalari]
VendorKomutum "C_player_vendor"
VSistemKesinti "50"

[DIALOG UrunArama]
250,150
NoMove
Page 0
Resizepic 0 0 83 320 150
Resizepic 7 10 5120 307 130
Checkertrans 7 10 307 130
DText 40 20 1152 Hangi ürünün en uygununu arıyorsunuz ?
Resizepic 80 50 9270 160 40
DTextentrylimited 90 60 145 20 1152 1 20
DText 155 100 1152 Ürünü Ara
Button 120 100 4024 4025 1 0 1

[DIALOG UrunArama Button]
On=1
IF ((Strlen(<ArgTxt[1]>)) < 3)
Src.Sysmessage @38,,1 Arama yapabilmeniz için en az 3 karakter kullanmalısınız.
Return 1
Endif
IF !(STRRegex(^[a-zA-Z0-9 ']+$,<Argtxt[1]>))
Src.Sysmessage @38,,1 Geçersiz arama yaptınız.
Return 1
Endif
Src.CTag0.AradigimUrun <ArgTxt[1]>
Src.SDialog FirsatUrunleri

[DIALOG FirsatUrunleri]
100,120
NoMove
Page 0
Resizepic 0 45 83 520 330
Resizepic 7 55 5120 507 310
Checkertrans 7 55 507 310
Page 1
Local.FirsatUrunleri = 0
Forinstances <Def.VendorKomutum>
ForCont <Findlayer.21>
IF (<Price> > 0) && (StrMatch(*<Src.CTag0.AradigimUrun>*,'<Name>'))
Local.FirsatUrunleri<dLocal.FirsatUrunleri> <UID>
Local.FirsatUrunleri ++
EndIF
EndFor
EndFor
For a 0 <Eval <Local.FirsatUrunleri>-1>
For b 0 <Eval <Local.FirsatUrunleri>-1>
Local.1 = <UID.<Local.FirsatUrunleri<dLocal.a>>.Price>
Local.2 = <UID.<Local.FirsatUrunleri<dLocal.b>>.Price>
IF <dLocal.1> < <dLocal.2>
Local.t = <Local.FirsatUrunleri<dLocal.b>>
Local.FirsatUrunleri<dLocal.b> = <Local.FirsatUrunleri<dLocal.a>>
Local.FirsatUrunleri<dLocal.a> = <Local.t>
EndIF
EndFor
EndFor
IF (<DLocal.FirsatUrunleri>)
Resizepic 12 60 9300 60 20
Resizepic 100 60 9300 80 20
Resizepic 220 60 9300 80 20
Resizepic 360 60 9300 80 20
DHtmlGump 10 60 60 25 0 0 <Def.Center><Def.BFont_Green> DETAY
DHtmlGump 105 60 70 25 0 0 <Def.Center><Def.BFont_Green>EŞYA
DHtmlGump 225 60 70 25 0 0 <Def.Center><Def.BFont_Green>FİYAT
DHtmlGump 365 60 70 25 0 0 <Def.Center><Def.BFont_Green>SATAN KİŞİ
Else
DText 80 190 38 Aradığınız isimde bir eşyanın vendor satışı bulunmamaktadır.
Endif
For 0 9
IF <Local.FirsatUrunleri<dLocal._For>>
Ref1 = <Local.FirsatUrunleri<dLocal._For>>
Resizepic 65 <Eval (<Local._For>*25)+90> 9300 135 20
Resizepic 200 <Eval (<Local._For>*25)+90> 9300 120 20
Resizepic 320 <Eval (<Local._For>*25)+90> 9300 170 20
DHtmlGump 70 <Eval (<Local._For>*25)+90> 125 25 0 0 <Def.BFont_DGreen><Ref1.Name>
DHtmlGump 205 <Eval (<Local._For>*25)+90> 105 25 0 0 <Def.BFont_Black><BolukAyir <Ref1.Price>>gp
DHtmlGump 325 <Eval (<Local._For>*25)+90> 105 25 0 0 <Def.BFont_Red><Ref1.TopObj.MemoryFindType.Memory_IPet.Link.Name>
Button 37 <Eval (<Local._For>*25)+92> 2224 2224 1 0 <Eval <Local._For>+29051453>
EndIF
EndFOR
Page 53
Ref2=<Local.FirsatUrunleri<Src.DCTag0.BaktigimUrun>>
Src.CTag.BaktigimUrun1 <UID.<Ref2>>
Button 30 330 9706 9707 0 1 26081071
DText 50 327 38 Geri
DText 190 80 38 Vendor Ürün İnceleme
DText 160 300 38 Satıcıya Git
Button 120 300 4005 4006 1 0 18091048
DText 310 300 38 Ürünü Satın Al
Button 270 300 4023 4024 1 0 10111444
IF (<Def.VSistemKesinti>)
DHtmlGump 0 270 520 25 0 0 <Def.Center><Def.BFont_Size3><Def.BFont_LRed>Bu sistemden yapılan tüm alışverişlerde + % <Eval <Def.VSistemKesinti>> kesinti uygulanmaktadır.
DHtmlGump 270 330 130 25 0 0 <Def.BFont_Size3><Def.BFont_LRed><Def.Center>( <BolukAyir <Eval <Ref2.Price> + <Eval <Eval <Ref2.Price> * <Def.VSistemKesinti>> / 100>>>gp )
Endif
IF (<IsWeapon <UID.<Ref2>.BaseID>>) || (<IsArmor <UID.<Ref2>.BaseID>>) || (<UID.<Ref2>.Amount> > 1) || (<UID.<Ref2>.Type> == T_Figurine)
Resizepic 35 120 9300 215 20
Resizepic 35 150 9300 215 20
Resizepic 35 180 9300 215 20
Resizepic 35 210 9300 215 20
Resizepic 35 240 9300 215 20
Else
Resizepic 145 120 9300 215 20
Resizepic 145 150 9300 215 20
Resizepic 145 180 9300 215 20
Resizepic 145 210 9300 215 20
Resizepic 145 240 9300 215 20
Endif
IF (<IsWeapon <UID.<Ref2>.BaseID>>) || (<IsArmor <UID.<Ref2>.BaseID>>) || (<UID.<Ref2>.Amount> > 1) || (<UID.<Ref2>.Type> == T_Figurine)
Resizepic 265 120 9300 215 20
Resizepic 265 150 9300 215 20
IF !(<UID.<Ref2>.Amount> > 1)
Resizepic 265 180 9300 215 20
Resizepic 265 210 9300 215 20
Resizepic 265 240 9300 215 20
Endif
Endif
IF (<IsWeapon <UID.<Ref2>.BaseID>>) || (<IsArmor <UID.<Ref2>.BaseID>>) || (<UID.<Ref2>.Amount> > 1) || (<UID.<Ref2>.Type> == T_Figurine)  // T_Figurine == Animal Deed
DHtmlGump 40 120 210 25 0 0 <Def.BFont_DGreen>Satıcı Kişi : <Def.BFont_Purple><UID.<Ref2>.TopObj.MemoryFindType.Memory_IPet.Link.Name>
DHtmlGump 40 150 210 25 0 0 <Def.BFont_DGreen>Ürün Adı  : <Def.BFont_DPurple><UID.<Ref2>.Name>
DHtmlGump 40 180 210 25 0 0 <Def.BFont_DGreen>Ürün Fiyat : <Def.BFont_Purple><BolukAyir <UID.<Ref2>.Price>> gp
DHtmlGump 40 210 210 25 0 0 <Def.BFont_DGreen>Vendor Kordinat : <Def.BFont_DPurple><UID.<Ref2>.TopObj.P>
DHtmlGump 40 240 210 25 0 0 <Def.BFont_DGreen>Konum : <Def.BFont_Purple><UID.<Ref2>.TopObj.Region.Name>
Else
DHtmlGump 150 120 210 25 0 0 <Def.BFont_DGreen>Satıcı Kişi : <Def.BFont_Purple><UID.<Ref2>.TopObj.MemoryFindType.Memory_IPet.Link.Name>
DHtmlGump 150 150 210 25 0 0 <Def.BFont_DGreen>Ürün Adı  : <Def.BFont_DPurple><UID.<Ref2>.Name>
DHtmlGump 150 180 210 25 0 0 <Def.BFont_DGreen>Ürün Fiyat : <Def.BFont_Purple><BolukAyir <UID.<Ref2>.Price>> gp
DHtmlGump 150 210 210 25 0 0 <Def.BFont_DGreen>Vendor Kordinat : <Def.BFont_DPurple><UID.<Ref2>.TopObj.P>
DHtmlGump 150 240 210 25 0 0 <Def.BFont_DGreen>Konum : <Def.BFont_Purple><UID.<Ref2>.TopObj.Region.Name>
Endif
IF (<IsWeapon <UID.<Ref2>.BaseID>>)
DHtmlGump 270 120 210 25 0 0 <Def.BFont_DGreen>Eskime Durumu : <Def.BFont_Purple>% <Eval 100 - <Eval <UID.<Ref2>.HitPoints> * 100> / <UID.<Ref2>.HitPoints>>
DHtmlGump 270 150 210 25 0 0 <Def.BFont_DGreen>Silahın Kullanım Hızı : <Def.BFont_DPurple><UID.<Ref2>.Speed>
DHtmlGump 270 180 210 25 0 0 <Def.BFont_DGreen>Vereceği Hasar Aralığı : <Def.BFont_Purple><UID.<Ref2>.Dam>
DHtmlGump 270 210 210 25 0 0 <Def.BFont_DGreen>Silahın MoreY Değeri : <Def.BFont_DPurple><UID.<Ref2>.MoreY>
DHtmlGump 270 240 210 25 0 0 <Def.BFont_DGreen>Silah Üzerinde Zehir : <Def.BFont_Purple><Qval <UID.<Ref2>.MoreZ>?Var:Yok>
Endif
IF (<UID.<Ref2>.Type> == T_Figurine)
DHtmlGump 270 120 210 25 0 0 <Def.BFont_DGreen>STR : <Def.BFont_Purple><UID.<UID.<Ref2>.More2>.Str>
DHtmlGump 270 150 210 25 0 0 <Def.BFont_DGreen>DEX : <Def.BFont_DPurple><UID.<UID.<Ref2>.More2>.Dex>
DHtmlGump 270 180 210 25 0 0 <Def.BFont_DGreen>INT : <Def.BFont_Purple><UID.<UID.<Ref2>.More2>.Int>
DHtmlGump 270 210 210 25 0 0 <Def.BFont_DGreen>Karma : <Def.BFont_DPurple><UID.<UID.<Ref2>.More2>.Karma>
DHtmlGump 270 240 210 25 0 0 <Def.BFont_DGreen>Fame  : <Def.BFont_Purple><UID.<UID.<Ref2>.More2>.Fame>
Endif
IF (<IsArmor <UID.<Ref2>.BaseID>>) || (<UID.<Ref2>.Type> = T_Clothing)
DHtmlGump 270 120 210 25 0 0 <Def.BFont_DGreen>Eskime Durumu : <Def.BFont_Purple>% <Eval 100 - <Eval <UID.<Ref2>.HitPoints> * 100> / <UID.<Ref2>.HitPoints>>
DHtmlGump 270 150 210 25 0 0 <Def.BFont_DGreen>Brüt Armor : <Def.BFont_DPurple><UID.<Ref2>.Armor>
DHtmlGump 270 180 210 25 0 0 <Def.BFont_DGreen>Gereken STR : <Def.BFont_Purple><UID.<Ref2>.ReqStr>
DHtmlGump 270 210 210 25 0 0 <Def.BFont_DGreen>Ağırlık : <Def.BFont_DPurple><Eval <UID.<Ref2>.Weight>/10>
DHtmlGump 270 240 210 25 0 0 <Def.BFont_DGreen>Extra Armor Oranı : <Def.BFont_Purple><Qval <UID.<Ref2>.ModAr>?<UID.<Ref2>.ModAr>:Yok>
Endif
IF (<UID.<Ref2>.Amount> > 1)
DHtmlGump 270 120 210 25 0 0 <Def.BFont_DGreen>Ürün Adedi : <Def.BFont_Purple><UID.<Ref2>.Amount> adet
DHtmlGump 270 150 210 25 0 0 <Def.BFont_DGreen>Birim Fiyatı : <Def.BFont_DPurple><Eval <UID.<Ref2>.Price> / <UID.<Ref2>.Amount>> gp
Endif

[DIALOG FirsatUrunleri Button]
On=0
Src.CTag0.BaktigimUrun
Src.CTag0.BaktigimUrun1

On=29051453 29051464

Local.Urun <Eval <dArgn> -29051453>
Src.CTag.BaktigimUrun <dLocal.Urun>
SDIALOG FirsatUrunleri,53

On=10111444 // SATIN ALMA BUTONU

Ref2=<Src.DCTag0.BaktigimUrun1>
Local.ToplamPara <Qval <Def.VSistemKesinti>?<Eval <Ref2.Price> + <Eval <Eval <Ref2.Price> * <Def.VSistemKesinti>> / 100>>:<Ref2.Price>>
IF (<Ref2.Price> <= 0)
Src.Sysmessage @38,,1 Bu eşya satılık değil.
SDialog Firsaturunleri
Return 1
Endif
IF !(<Ref2.TopObj.BaseID> = <Def.VendorKomutum>)
Src.Sysmessage @38,,1 Bu ürün sizden önce alınmış yada vendordan kaldırılmış görünüyor.
SDialog Firsaturunleri
Return 1
Endif
IF (<Ref2.TopObj.MemoryFindType.Memory_IPet.Link.UID> = <Src.UID>)
Src.Sysmessage @38,,1 Kendi vendorunuzdan alışveriş yapamazsınız.
SDialog Firsaturunleri
Return 1
Endif
IF (<Src.Gold> >= <dLocal.ToplamPara>)
Ref2.TopObj.Say <Src.Name>, vendor satış sistemi üzerinden bir ürünümü aldı.
Src.Gold -= <dLocal.ToplamPara>
Ref2.Topobj.Findlayer(29).More1 (<Ref2.Topobj.Findlayer(29).More1> + <Ref2.Price>)
Ref2.Cont <Src.Findlayer(21).UID>
Ref2.Price
Update
Src.CTag0.BaktigimUrun
Src.CTag0.BaktigimUrun1
Else
Src.Sysmessage @38,,1 Hesabınızda bu ürünü almak için <BolukAyir <dLocal.ToplamPara>> altın bulunmuyor.
SDialog Firsaturunleri
Return 1
Endif

On=18091048
Ref2=<Src.DCTag0.BaktigimUrun1>
Src.Events +VendoruAriyorum
Src.ArrowQuest <Ref2.TopObj.P>
Src.Sysmessage @07a1,,1 Takibi iptal etmek için ok'a sağ tıklayın.
Src.CTag0.BaktigimUrun


[Events VendoruAriyorum]
On=@UserQuestArrowClick
If (<Argn> ==1)
Src.Sysmessage @38,,1 Vendora gitmekten vazgeçtiniz.
Src.ArrowQuest
Src.Events -VendoruAriyorum
Src.CTag0.BaktigimUrun
Src.CTag0.BaktigimUrun1
Return 1
Endif
Return 1

On=@Logout
Src.ArrowQuest
Src.Events -VendoruAriyorum

[CHARDEF C_Vendor_Arama]
ID=C_MAN
NAME=#NAMES_HUMANMALE the Researcher
CAN=MT_NONMOVER
CATEGORY=Monsters
SUBSECTION=Miscellaneous
DESCRIPTION=Researcher

On=@Create
INVUL
COLOR=COLORS_SKIN
NPC=brain_human
FOOD 999
STR={45 55}
DEX={45 55}
INT={45 55}

  ITEMNEWBIE=i_hair_ponytail
    COLOR=0455
  ITEMNEWBIE=random_facial_hair,1,R5
  COLOR=0455
  ITEMNEWBIE=i_robe
COLOR=colors_black
ITEMNEWBIE=i_apron_half
COLOR=0455
ITEMNEWBIE=i_shoes_plain
COLOR=0455

On=@Click
Message @09A,,1 ↪ Researcher
Return 1

On=@DClick
IF ( <Distance> < 3 )
Dialog UrunArama
Else
Message @07a1,,1 Arama yapabilmeniz için yaklaşmalısınız.
Return 1
EndIF
Return 1



Yorumlar

Henüz yorum yapılmamıştır.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : 10.00   
Oylar: 1 den itibaren 18-07-2020 11:55

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
Vendor Master(Ortak Vendor Sistemi-Kaliteli!-SQ...0TestereNecmi06-09-2015
Chek vendor.( pvp serveri ideal)0Demonaz13-06-2012
Ev Vendor Sistemi0TheRaskol15-05-2010
Vendor Rental Gumps0Rowall31-08-2009
Vendor Inventory Gump0Rowall31-08-2009


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,