UO-Dev Arama


Yazar: 4s3d3
Tarih: 26-04-2020 18:30





https://i.hizliresim.com/9XhXgD.png

Kod:
///////////////////////////////////////////////
//// Script içinde ki itemler : ///////////////
/// i_ailebelgesi               ///////////////
/// i_isimbelgesi               ///////////////
///////////////////////////////////////////////

[Plevel 1]
Aile
Aileler
AileTalebi

[Function Aile]
IF STRMatch('','<Src.Tag.BenimAilem>')
Src.Hata Herhangi bir aile mensubu değilsiniz.
Return 1
Endif

For 0 <list.onay_aile.count>
ref1 <list.onay_aile.<dlocal._for>>
if (<ref1> == <uid>)
Src.Mesaj Aile adınız şuan yetkili onayı aşamasında. Olumlu ya da olumsuz size geri dönüş yapılacaktır.
return 1
endif
endfor
Src.DialogClose Ailemenu
Src.DialogClose AileUyeleri
Src.DialogClose AileUyeDetay
Src.DialogClose AileUyeleri
Src.Dialog AileMenu

[Itemdef i_ailebelgesi]
Defname=i_ailebelgesi
ID=8792
Name=Aile Kurma Belgesi
Type=t_script
Value=500000

On=@Create
Color 086c
ATTR=Attr_Newbie

On=@Click
Message @077a,,1 <Name>
Return 1

On=@DClick
If !(Strmatch('','<src.tag.benimailem>'))
Src.Hata Sizin zaten mevcut bir aileniz var.
Return 1
Endif
Src.Dialog Soyisim
Src.Mesaj Lütfen kuralları okuduktan sonra ailenizi kurun.
Return 1

[Dialog Soyisim]
250,150
Nomove
Resizepic 0 0 83 300 170
AlphaBlack 7 10 287 150
DHtmlGump 7 20 287 30 0 0 <def.center> <def.bfont_yellow><Serv.Name> Aile Sistemi
Resizepic 0 170 83 300 100
AlphaBlack 7 180 287 80
DHtmlGump 25 190 260 60 1 1 <def.bfont_red>••• <def.bfont_black>Kuracağınız ailenin uzunluğu en fazla 12 karakter olabilir<def.br><def.bfont_red>••• <def.bfont_black>Soyisimde en fazla 2 boşluk bırakabilirsiniz.<def.br><def.bfont_red>••• <def.bfont_black>Soyisminizde Türkçe karakter kullamazsınız..<def.br><def.bfont_red>••• <def.bfont_black>Soyisminizde &%+^!&/()=? gibi saçma sapan karakterler kullanamazsınız.

Resizepic 65 60 83 170 50
Resizepic 72 70 9300 157 30
DTextentryLimited 79 75 145 20 1152 1 12 <Args>  /// Client 4 ve üzeri destekler

Button 250 130 4024 4025 1 0 1
DText 180 130 039 Ailemi Kur
Button 273 15 3 4 1 0 2

[Dialog Soyisim Button]
On=0
Src.Hata Aile kurmaktan vazgeçtiniz.
Return 1

On=1
FORINSTANCES I_Aile
If (Strmatch('<Tag0.benimailem>','<ARGTXT[1]>'))
Src.Hata <Argtxt[1]> isimli bir aile zaten mevcut.
Return 1
Endif
Endfor
if (<isempty <argtxt[1]>>)
Src.hata Soyadınızı boş bırakamazsınız.
return 1
Endif
If ((Strlen(<argtxt[1]>)) > 12)
Src.Hata Soyadiniz en fazla 12 karakterden oluşabilir.
Return 1
Endif
if ((Strlen(<argtxt[1]>)) < 3) ||
Src.hata Soyadınız en az 3 karakterden oluşabilir.
Return 1
Endif
If !(STRRegex(^[a-zA-Z ']+$,<Argtxt[1]>))
Src.hata Soyadınızda geçersiz karakter kullandınız
Return 1
Endif
If !(Strmatch('','<Src.Tag.Benimailem>'))
Src.Hata Sizin zaten bir aileniz mevcut.
Return 1
Endif
IF (<Kelimesay <Argtxt[1]>> >2)
Src.Hata Soyadınızda kullanacağınız kelime sayısı en fazla 3dür.
Return 1
Endif
If (Strmatch(*  *, <Argtxt[1]>)
Src.Hata İki kelime arasında sadece tek boşluk bırakabilirsiniz.
Return 1
Endif
If !(<Src.Restest 1 i_ailebelgesi>)
Src.Hata Aile kurmak için çantanızda bir belge yok.
Return 1
Endif
Src.Tag0.Benimailem  <Boslukbuyukharf <ArgTxt[1]>>
Src.Tag.Name.SuFFix " <Src.Tag0.Benimailem>"
Serv.Newitem i_aile,1,<Src>,1
New.Name Reis : <Src.tag0.benimailem>
New.Tag0.Benimailem <Src.tag0.benimailem>
New.Tag0.Ailereisi <Src>
New.Tag0.Aileuyesi +=1
New.Tag0.Aileuyesi_<DNew.Tag0.Aileuyesi> <SRC>
New.Tag0.AileKurulusTarihi <Serv.RTime>
Src.Tag0.Toplamkisi <NEW.UID>
Src.Consume i_ailebelgesi
Serv.Allclients Sysmessage @077a,,1 <Src.Name> tarafından "<Src.Tag0.BenimAilem>" ailesi kurulmuştur.

On=2
Src.Hata Aileyi kurmaktan vazgeçtiniz.

[Dialog AileMenu]
200,150
NoMove
Ref1=<src.tag0.Toplamkisi>
Ref2=<ref1.tag0.AileReisi>
Resizepic 0 45 83 340 180
Resizepic 7 55 9300 327 160
AlphaBlack 7 55 327 160

Resizepic 73 0 83 203 50
Resizepic 80 10 9300 190 30
DHtmlgump 85 15 180 20 0 0 <Def.Center><Def.BFont_Red><Src.Tag0.Benimailem>

Resizepic 18 72 83 163 110
Resizepic 25 82 9300 150 90
DHtmlgump 30 87 190 20 0 0 <def.bfont_black>Aile Reisi : <def.bfont_red><STRARG <STRTOUPPER(<STRSUB 0 1 <REF2.NAME>>)><STRTOLOWER(<STRSUB 1 16 <REF2.NAME>>)>>
DHtmlgump 30 117 190 20 0 0 <def.bfont_black>Üye Sayısı : <def.bfont_red><dRef1.tag0.aileuyesi> Kişi
DHtmlgump 30 147 180 20 0 0 <def.bfont_black>Kuruluş : <def.bfont_red><Ref1.Tag0.AileKurulusTarihi>

If (<Ref2.uid> == <Src.uid>)

Button 200 90 11400 11401 1 0 1
DText 220 87 039 Üye Ekle
Button 200 120 11400 11401 1 0 2
DText 220 117 039 Üye Listesi
Button 200 150 <Qval <List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>?11400:11410> <Qval <List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>?11401:11411> 1 0 3
DText 220 147 <Qval <List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>?039:38> <Qval <List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>?Talep Sayısı [<List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>]:Talep Listesi Boş>
Button 100 190 4021 4022 1 0 4
DText 140 190 38 Aileyi Dağıt
Else
Button 200 90 11400 11401 1 0 5
DText 220 87 039 Üye Listesi
Button 200 150 11410 11411 1 0 6
DText 220 147 38 Aileden ayrıl
Endif

[Dialog AileMenu button]

On=1

Src.Targetf Aileyeekle <src.uid>
Src.Mesaj2 Ailenize dahil etmek istediğiniz oyuncuyu seçin.

On=2
Src.Dialog AileUyeleri

On=3
If (0<List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count> == 0)
Src.Hata Henüz ailenize katılmak isteyin kimse bulunmamaktadır.
Return 1
Endif
Src.Dialog Talep

On=4
Ref1=<Src.Tag.Toplamkisi>
Serv.Allclients sysmessage @077a,,1 <src.name>, <src.tag0.benimailem> isimli aileyi yıkmıştır.
For 1 <Ref1.TAG0.Aileuyesi>
Ref2=<Ref1.Tag0.Aileuyesi_<dlocal._for>>
Ref2.Cleartags Benimailem
Ref2.Cleartags ToplamKisi
Ref2.Dialogbildiri Sayın <Ref2.Name> aileniz yıkılmış, adınız eski haline getirilmiştir.
Ref2.Tag.Name.SUFFIX=
Endfor
Ref1.Remove

On=5
Src.Dialog AileUyeleri

On=6

Ref1=<Src.Tag.Toplamkisi>
Src.Ailedencik <Ref1>

[Dialog AileUyeleri]
200,150
NoMove
Resizepic 73 0 83 203 50
Resizepic 80 10 9300 190 30
DHtmlgump 85 15 180 20 0 0 <Def.Center><Def.BFont_Red><Src.Tag0.Benimailem>
Resizepic 0 45 83 340 180
Resizepic 7 55 9300 327 160
AlphaBlack 7 55 327 160

Ref1=<Src.Tag0.Toplamkisi>
Local.Kisisayisi=0
Local.Sayfasayisi=1

Page 1

For 1 <Ref1.Tag0.Aileuyesi>
Ref2=<Ref1.Tag0.Aileuyesi_<dlocal._for>>
Ref3=<Ref1.Tag0.AileReisi>

IF (<Local.Kisisayisi> > 5)
Local.Kisisayisi=0
Button 200 190 015e1 015e5 0 <Eval <Local.Sayfasayisi>+1>
Local.SayfaSayisi += 1
Page <Eval <Local.Sayfasayisi>>
Button 100 190 015e3 015e7 0 <Eval <Local.Sayfasayisi>-1>
Endif
Local.Kisisayisi += 1

If (<Ref2>)
Resizepic 40 <Eval (<Local.Kisisayisi>*20)+45> 9300 180 20
DText 55 <Eval (<Local.Kisisayisi>*20)+45> <Qval (<Ref2.IsOnline>)?73<Ref2.name>:38<Ref2.name>>
Button 20 <EVAL (<Local.Kisisayisi>*21)+45> 10741 10742 1 0 <Eval <Local._For>+99999>
Endif
IF !(<Ref2> == <Src.UID>)
IF !(<Src.CTag0.AILETAKIP> == <REF2>)
Button 305 <EVAL (<Local.Kisisayisi>*21)+45> <Qval (<Ref2.IsOnline>)?11400:11410> <Qval (<Ref2.IsOnline>)?11401:11411> 1 0 <Eval <dlocal._for>+999>
DText 230 <Eval (<Local.Kisisayisi>*20)+45> 039 Takip Et
Else
Button 305 <EVAL (<Local.Kisisayisi>*20)+45> 11410 11411 1 0 9999
DText 230 <Eval (<Local.Kisisayisi>*20)+45> 039 Takip Iptal
Endif
Endif
EndFor

[Dialog AileUyeleri button]
ON=1 998
Ref1=<Src.tag0.Toplamkisi>
Ref2=<Ref1.tag0.aileuyesi_<dargn>>
IF (<Src> == <Ref2>)
Src.Hata Patron çıldırdı :)
Return 1
Endif
Ref2.Ailedencik <REF1>
Src.Mesaj <Ref2.Name> isimli oyuncuyu kovdunuz.

ON=99999 999998
Ref1=<src.tag0.Toplamkisi>
Ref2=<ref1.tag0.aileuyesi_<eval <argn>-99999>>
Try uid.<ref2>.Dialog AileUyeDetay

ON=999 9998
Ref1=<src.tag0.Toplamkisi>
Ref2=<ref1.tag0.aileuyesi_<eval <argn>-999>>

IF (<Src> == <REF2>)
Src.Hata Kendinizi takip edemezsiniz
Return 1
Endif
if !(<ref2.isonline>)
Src.Hata Takip edeceğiniz kişinin oyunda olması gerekmektedir.
return 1
endif
IF (<Src.Tag0.AileTakip>)
Src.Hata Şuanda zaten bir kişiyi takip ediyorsun
return 1
endif
if (<Ref2.Account.Tag0.AYAR_2>)
Src.Hata <Ref2.Name> takipleri kapatmış.
Return 1
Endif
Src.CTag0.AileTakip <Ref2>
Src.Events takipevent
Src.Ctag0.Takipedilenkisi <Ref2>
Src.Mesaj <Ref2.name> isimli oyuncuyu takip etmeye başladınız.
Ref2.Mesaj <Name> sizi takip etmeye başladı.
Src.Timerf 1,TakipDialog
Serv.Newitem I_oyuncutakip,1,<Src>
Ref2.events takipevent
Ref2.Ctag0.Takipcilerim <Src.Uid>

ON=9999
Src.Takipiptal

[Dialog AileUyeDetay]
200,150
NoMove
Resizepic 73 0 83 203 50
Resizepic 80 10 9300 190 30
DHtmlgump 85 15 180 20 0 0 <Def.Center><def.h3><Def.bfont_black><Name>
Resizepic 0 45 83 340 180
Resizepic 7 55 9300 327 160
AlphaBlack 7 55 327 160

Ref1=<Src.Tag0.Toplamkisi>
Ref2=<Ref1.Tag0.AileReisi>

Resizepic 25 65 9300 290 120
DHtmlGump 30 70 280 30 0 0 <def.bfont_green>Son Giriş Tarihi : <def.bfont_black><ACCOUNT.LASTCONNECTDATE>
DHtmlGump 30 100 280 30 0 0 <def.bfont_green>Bağlı olduğu guild : <Qval (<Guild>)?<def.bfont_black><Argo.memoryfindtype.memory_guild.link.name>:<def.bfont_red>Guildi Yok>
DHtmlGump 30 130 280 30 0 0 <def.bfont_green>Bunduğu Yer : <Qval (<IsOnline>)?<def.bfont_black><Region.name>:<def.bfont_red>Oyunda Değil>
DHtmlGump 30 160 280 30 0 0 <def.center><def.bfont_green>Ölüm Sayısı : <def.bfont_black><Deaths> <def.bfont_green>Kill Sayısı : <def.bfont_black><kills>

If (<Src> == <Ref2>)
//DText 160 190 0480 Aileden At
//Button 120 190 4020 4021 1 0 1
Button 130 190 2463 2464 1 0 1
Endif

[Dialog AileUyeDetay Button]
On=0
Src.Dialog AileUyeleri

On=1
If (<Uid> == <Src.Uid>)
Src.Hata İmkanı yok :)
Return 1
Endif
Ailedencik <Tag0.Toplamkisi>
Tag.AileUyesi=
Src.Mesaj <Name> isimli oyuncuyu ailenizden çıkardınız.

[Function Ailedencik]
Ref1=<Argv[0]>
Ref2=<Ref1.Tag0.AileReisi>

Name <STRARG <STRTOUPPER(<STRSUB 0 1 <NAME>>)><STRTOLOWER(<STRSUB 1 16 <NAME>>)>>
Tag.Name.Suffix=
Dialogbildiri Sayın <Name>, <ref1.tag0.benimailem> isimli aileden ayrıldınız.
Ref2.Dialogbildiri <Name> isimli oyuncu ailenizden ayrıldı.
Ref1.Tag0.Aileuyesi -=1
//Ref1.Tag0.Aileuyesi_<dref1.tag0.aileuyesi>-=

Tag0.Benimailem=
Tag0.Toplamkisi=

[Function Aileyeekle]
Ref1=<args>
Ref2=<argo>

If !(<Ref2.isplayer>)
Ref1.Hata Sadece oyuncuları aileye davet edebilirsiniz.
ElseIf (<Ref1.uid> == <ref2.uid>)
Ref1.Dialog Accounticinaile
ElseIf !(<Ref2.isonline>)
Ref1.Hata <Ref2.name> isimli kişi oyuna bağlı değil.
ElseIf (<ref2.findid.i_rune_incognito>)
Ref1.Hata <ref2.name> isimli kişi Incognite büyüsü etkisinde.
ElseIf (<ref2.isdialogopen Aileteklif>)
Ref1.Hata <Ref2.name> isimli oyuncu şuan bir aileye davet edilmiş durumda.
ElseIf !strmatch('','<Ref2.Tag.Benimailem>')
Ref1.Hata <Ref2.name> isimli kişi zaten bir aileye üye.
Else
Ref1.Mesaj <ref2.name> isimli kişiye teklif gönderdiniz.
Ref2.CTag0.Aileyedavet <Ref1.uid>
Ref1.CTag0.Aileyedavet <Ref2.uid>
Ref1.Dialog Aileteklifiptal
TRYSRC <ref2> dialogclose Aileteklif
TRYSRC <ref2> dialog Aileteklif,0,<ref1>,<ref1.tag.benimailem>
Endif

[Function EkleAileye]  ////Oyunda Olmayan Charlar İçin
Ref1=<Argv[0]>
Ref2=<Ref1.Tag0.AileReisi>

TAG0.NAME.SUFFIX " <ref1.tag0.benimailem>"
Tag0.BenimAilem <ref1.tag0.benimailem>
Tag0.Toplamkisi <ref1.uid>
IF (<ISONLINE>)
Ctag.Aileyedavet=
Endif

Ref1.tag0.aileuyesi +=1
Ref1.tag0.aileuyesi_<dref1.tag0.aileuyesi> <uid>


[Dialog Accounticinaile]
250,150
NoMove
Resizepic 0 0 83 200 190
Resizepic 7 10 9300 187 170
AlphaBlack 7 10 187 170
Resizepic 45 0 83 110 50
DText 57 15 039 Karakterleriniz
For 0 <Eval <DSrc.Account.Chars>-1>
Ref1 <Src.Account.Char.<dLocal._For>.UID>
If !(<Ref1.ISOnline>)
Resizepic 20 <Eval (<Local._For>*30)+25> 9300 160 25
Button 25 <Eval (<Local._For>*30)+30> 11400 11401 1 0 <Eval (<Local._For> + 1)>
DText 50 <Eval (<Local._For>*30)+28> 039 <Ref1.name>
Endif
Endfor

[Dialog Accounticinaile Button]

ON=1 10

Ref1 <Src.Tag.Toplamkisi>
Ref2 <Src.Account.Char.<Eval <Argn>-1>.UID>
If (<Ref2.Tag0.Toplamkisi> == <Src.Tag0.Toplamkisi>)
Src.Hata <Ref2.name> zaten ailenizin bir üyesi
Return 1
Endif
If (<Ref2> == <Src>)
Src.Hata Kendinizi seçemezsiniz.
Return 1
Endif
If (<Ref2.Tag0.Benimailem>)
Src.Hata <Ref2.name> başka bir aileye üye.
Return 1
Endif

Src.Mesaj <Ref1.Name> artık ailenizin bir üyesi.
Ref2.EkleAileye <Ref1>

[Function Kelimesay]
Args=<Explode " ",<Args>>
Return <Eval <DArgv> - 1>

[Function Boslukbuyukharf]
Args=<Explode " ",<Args>>
For 0 <Eval <Dargv> - 1>
Local.Return .=" <Ilkharfbuyuk <Argv[<DLocal._For>]>>"
EndFor
Return <STRSub 2 0 <Local.Return>>

[Function ilkharfbuyuk]
Return <STRTOUPPER <STRSUB 0 1 <ARGS>>><STRTOLOWER <STRSUB 1 0 <ARGS>>>

[Function Dialogbildiri]
If (<IsPlayer>)
TAG.Dialogbildiri=<ARGS>
EVENTS +Dialogbildiri
IF (<ISOnline>)
TimerF 1,SDIALOG Dialogekrani
Endif
Endif

[Events Dialogbildiri]

[Dialog Dialogekrani]
200,150

Resizepic 0 0 83 340 200
Resizepic 7 10 9300 327 180
AlphaBlack 7 10 327 180

DHtmlgump 7 20 327 20 0 0 <DeF.center><Def.bfont_Yellow><Serv.name> Bildiri
Button 316 13 3 4 1 0 0

Resizepic 30 45 9300 280 100
DHtmlgump 35 45 280 100 0 1 <Def.bfont_red><TAG0.Dialogbildiri>

[DIALOG Dialogekrani Button]
On=0
Src.Sysmessage @039,1,1 Bildiri ekranını kapattınız.
Tag.Dialogbildiri=
Events -Dialogbildiri

[Dialog AileteklifIptal]
0,595
NoMove
Ref1=<src.ctag0.Aileyedavet>
Resizepic 0 0 83 340 120
Resizepic 7 10 9300 327 100
AlphaBlack 7 10 327 100
Resizepic 30 20 9300 280 50
Button 130 80 4018 4019 1 0 1
DHtmlgump 35 25 270 50 0 0 <def.center><def.bfont_red><Ref1.Name><def.bfont_black> isimli oyuncuya;<def.br> yapmış olduğum teklifi iptal et
Dtext 170 80 039 Iptal Et


[Dialog AileteklifIptal Button]

On=1
Ref1=<src.ctag0.Aileyedavet>
TrySrc <Ref1> Dialogclose Aileteklif
Src.Mesaj Yapmış olduğunuz teklifi iptal ettiniz.


[Dialog Aileteklif]
250,150
Resizepic 0 0 83 300 170
Resizepic 7 10 9300 287 150
AlphaBlack 7 10 287 150
Resizepic 45 40 9300 210 50
DHtmlGump 50 40 210 60 0 0 <def.bfont_red><Name> <def.bfont_black>sizi <def.bfont_red><tag0.benimailem> <def.bfont_black>isimli ailesine davet ediyor.

Button 170 110 4018 4019 1 0 0
Dtext 210 110 039 Reddet

Button 50 110 4024 4025 1 0 1
Dtext 90 110 039 Kabul Et


[Dialog Aileteklif button]

On=0

REF1=<src.ctag0.Aileyedavet>
Ref1.Hata Sayın <Name>, <Src.Name> isimli oyuncuya yapmış olduğunuz aile teklifiniz red edilmiştir.
Src.Hata Yapılan aile teklifini reddettiniz.
TRYSRC <ref1> dialogclose AileteklifIptal

On=1

REF1=<src.ctag0.Aileyedavet>
REF2=<ref1.tag0.Toplamkisi>

If (<ref1.uid> == <src.uid>)
Ref1.hata <src.name> isimli oyuncunun zaten bir ailesi var.
Return 1
Endif

If (<src.findid.i_rune_incognito>)
Ref1.hata <src.name> isimli oyuncu Incognito büyüsünün etkisi altında teklif gönderilemez.
Return 1
Endif

SRC.EkleAileye <Ref2>
TRYSRC <Ref1> Dialogclose AileteklifIptal
TRYSRC <Ref1> Mesaj2 <Src.Name> isimli oyuncu ailenize katılmıştır.
Endif

[itemdef i_aile]
Name Aile
id i_memory
weight 0
type t_eq_script
layer layer_special

ON=@Create
ATTR=attr_invis|attr_decay

ON=@Equip
timer -1

ON=@timer
timer -1
return 1

////////////////////////AİLE TAKİP//////////////

[Function Takipiptal]
if !(<isevent.takipevent>)
Src.hata Takipte değilsiniz.
return 1
endif

try uid.<Ctag0.takipedilenkisi>.Hata <Src.name> sizi takibi bıraktı.
try uid.<Ctag0.takipedilenkisi>.consume 9999 i_oyuncutakip
try uid.<Ctag0.takipedilenkisi>.arrowquest
try uid.<Ctag0.takipedilenkisi>.Ctag.kordinat=
try uid.<Ctag0.takipedilenkisi>.events -takipevent
try uid.<Ctag0.takipedilenkisi>.Ctag0.Takipcilerim=
try uid.<Ctag0.Takipcilerim>.Hata <name> takibi iptal etti.
try uid.<Ctag0.Takipcilerim>.consume 9999 i_oyuncutakip
try uid.<Ctag0.Takipcilerim>.arrowquest
try uid.<Ctag0.Takipcilerim>.Ctag.kordinat=
try uid.<Ctag0.Takipcilerim>.events -takipevent

CTag0.AileTakip =
Events -takipevent
Hata Takibi iptal ettiniz.
consume 9999 i_oyuncutakip
arrowquest
CTag.Kordinat =

[Events Takipevent]

On=@Death
src.takipiptal

On=@Logout
src.takipiptal


[itemdef i_oyuncutakip]
name Oyuncu Takip
id 0186a
type t_eq_script
weight 0
layer layer_special

On=@Create
Attr attr_invis|attr_newbie
timer 1

On=@Equip
Timer 1

On=@Timer
If (<cont>)
Cont.Ctag.kordinat <uid.<cont.Ctag0.takipedilenkisi>.p>
Cont.arrowquest <uid.<cont.Ctag0.takipedilenkisi>.p>
Timer 1
Return 1
Endif

[Function TakipDialog]
if (<Src.isevent.TakipEvent>)
Dialogclose Takip
Dialog Takip
Timerf 1,Takipdialog
Return 1
Endif
Dialogclose Takip

[Dialog Takip]
0,0
NoClose
resizepic 0 0 83 295 115
resizepic 10 10 9300 275 95
Checkertrans 10 10 275 95
resizepic 50 15 9300 200 20
resizepic 20 40 9300 250 20
resizepic 20 65 9300 250 20
dhtmlgump 30 15 240 20 0 0 <def.center><def.bfont_black><uid.<Ctag0.takipedilenkisi>.name>
dhtmlgump 30 40 240 20 0 0 <def.bfont_green>Bulunduğu yer : <def.h6><def.bfont_red><uid.<Ctag0.takipedilenkisi>.region.name>
dhtmlgump 30 65 250 20 0 0 <def.h7><def.bfont_green>Bulunduğu Kordinat : <def.h7><def.bfont_red><uid.<Ctag0.takipedilenkisi>.p>
Button 230 15 9008 9009 1 0 1

[Dialog Takip Button]
On=1
Takipiptal
CTag.takipedilenkisi=

[Function Aileler]
Src.Tumaileler

if (0<List.Aileler.Count> == 0)
Src.Hata Serverde henüz kurulu bir aile bulunmamaktadır.
Return 1
Else
Src.Mesaj Serverde şuan <Eval <Var.Aileler>> aile bulunmaktadır.
Src.DialogClose OyundakiAileler
Src.Dialog OyundakiAileler
Endif

[Function Tumaileler]
List.Aileler.Clear
ForInstances i_aile
List.Aileler.Add <uid>
Local.AileSayi ++
EndFor
Var.Aileler <Eval <Local.AileSayi>>

[DIALOG OyundakiAileler]
200,150
//NoMove
Resizepic 0 45 83 340 280
Resizepic 7 55 5120 327 260
//AlphaBlack 7 55 327 160

Resizepic 73 0 83 203 50
Resizepic 80 10 9300 190 30
DHtmlgump 85 15 180 20 0 0 <Def.Center><Def.BFont_Red><Serv.name> Aile Listesi
Resizepic 70 55 9300 80 20
Resizepic 195 55 9300 80 20
RESIZEPICS 30,70,280,230
DHTMLGUMP 75 55 70 25 0 0 <DEF.CENTER><DEF.BFONT_GREEN>AİLE
DHTMLGUMP 200 55 70 25 0 0 <DEF.CENTER><DEF.BFONT_GREEN>KURUCU

Local.Ailesayisi=0
Local.AileSayfa=1

PAGE 1
FOR 0 <EVAL <DLIST.AILELER.COUNT>-1>
REF1=<LIST.AILELER.<DLOCAL._FOR>>
REF2=<REF1.TAG0.Ailereisi>

IF (<Local.Ailesayisi> > 9)
Local.Ailesayisi=0
Button 250 295 9702 9703 0 <Eval <Local.Ailesayfa>+1>
Local.Ailesayfa += 1
PAGE <EVAL <Local.Ailesayfa>>
Button 100 295 9706 9707 0 <Eval <Local.AileSayfa>-1>
ENDIF

IF (<REF1>)
Resizepic 50 <Eval (<Local.Ailesayisi>*20)+90> 9300 115 20
Resizepic 170 <Eval (<Local.Ailesayisi>*20)+90> 9300 120 20
DHtmlGump 60 <EVAL (<Local.Ailesayisi>*20)+90> 105 25 0 0 <def.bfont_red><ref1.tag0.benimailem>
DHtmlGump 180 <EVAL (<Local.Ailesayisi>*20)+90> 105 25 0 0 <def.bfont_black><STRARG <STRTOUPPER(<STRSUB 0 1 <REF2.NAME>>)><STRTOLOWER(<STRSUB 1 16 <REF2.NAME>>)>>
Button 15 <EVAL (<Local.Ailesayisi>*20)+90> 10740 10741 1 0 <Eval <dlocal._for>+1>
Local.Ailesayisi += 1
ENDIF
ENDFOR

[Dialog OyundakiAileler Button]
On=0
Src.Hata Menüyü kapattınız.

On=1 1000
Ref1=<DList.Aileler.<Eval <Argn>-1>>
Try UID.<Ref1>.Dialog Tumailelerdetay

[Function Resizepics]
Resizepic <argv[0]> <argv[1]> 83 <argv[2]> <argv[3]>
Resizepic <EVAL <argv[0]>+7> <EVAL <argv[1]>+10> 9300 <EVAL <argv[2]>-13> <EVAL <argv[3]>-20>

[Dialog Talep]
200,150
NoMove
Resizepic 0 45 83 340 220
Resizepic 7 55 5120 327 200
AlphaBlack 7 55 327 200
Resizepic 0 255 83 340 50
Resizepic 7 265 5120 327 30
AlphaBlack 7 265 327 30
Button 115 269 4021 4022 1 0 29051453
Resizepic 155 270 9300 80 20
DHtmlGump 160 270 260 60 0 0 <def.bfont_red>Tümünü sil
Resizepic 50 65 9300 50 20
DHtmlGump 65 65 260 80 0 0 <def.bfont_black>İsim
Resizepic 160 65 9300 50 20
DHtmlGump 170 65 260 80 0 0 <def.bfont_black>Guild
Local.Talepedenler 0
Local.Sayfam 1
Page 1
For 0 <eval <List.aile_<Src.Tag0.Toplamkisi>_talep.count>-1>
If <Local.Talepedenler> >7
Local.Talepedenler=0
Button 290 270 015e1 015e5 0 <Eval <Local.Sayfam>+1> 1
Local.Sayfam +=1
Page <Eval <Local.Sayfam>>     
Button 30 270 015e3 015e7 0 <Eval <Local.Sayfam>-1> 1
Endif
Ref1=<List.aile_<Src.Tag0.Toplamkisi>_talep.<dlocal._for>>
If (<Ref1.IsMurderer>)
Local.Taleprenk <def.bfont_red>
Else
Local.Taleprenk <def.bfont_blue>
Endif
If !(<Ref1> == 0)
Local.Talepedenler += 1
Resizepic 20 <Eval (<Local.Talepedenler>*20)+70> 9300 110 20
DHtmlGump 30 <Eval (<Local.Talepedenler>*20)+70> 260 80 0 0 <Local.Taleprenk><ref1.name>
Resizepic 130 <Eval (<Local.Talepedenler>*20)+70> 9300 120 20
DHtmlGump 135 <Eval (<Local.Talepedenler>*20)+70> 260 80 0 0 <def.bfont_black><Qval <ref1.guild>?<def.bfont_green><ref1.memoryfindtype.memory_guild.link.name>:<def.bfont_black>     Yok>
Button 250 <Eval (<Local.Talepedenler>*20)+70> 4024 4025 1 0 <Eval <DLocal._For>+1>  //Onay
Button 290 <Eval (<Local.Talepedenler>*20)+70> 4018 4019 1 0 <Eval <dlocal._for>+1000> ///,İptal
Endif
EndFor

[Dialog talep Button]
On=0
Src.Aile

ON=1 999
Ref1=<List.Aile_<Src.Tag0.Toplamkisi>_Talep.<eval <argn>-1>>
if (<ref1.findid.i_rune_incognito>)
Src.Hata <Ref1.name> isimli oyuncunun ismi gizli olduğundan aileye kabul edilemedi.
Ref1.Mesaj2 [Aile : <Src.Tag0.Benimailem>]
Ref1.Hata Sayın <Ref1.name>, isminizin gizli olmasından dolayı talebinizi değerlendiremedik.
Return 1
Endif
if (<ref1.isdialogopen aileteklif>)
Src.Hata <Ref1.name> isimli oyuncu şuan bir aile teklifi almış durumda.
Return 1
Endif
If !(Strmatch('','<Ref1.Tag.Benimailem>'))
Src.Hata <Ref1.name> isimli oyuncunun zaten bir ailesi mevcut.
Local.Elem <List.aile_<Src.Tag0.Toplamkisi>_Talep.Findelem <Ref1.uid>>
List.Aile_<Src.Tag0.Toplamkisi>_Talep.<DLocal.Elem>.Remove
Return 1
Endif
Ref1.EkleAileye <Src.Tag.Toplamkisi>
Src.Mesaj <Ref1.name> isimli oyuncu artık ailenizin bir üyesi.
Ref1.Mesaj1 Sayın <Ref1.name> artık sizde <Src.Tag0.Benimailem> isimli ailenin bir üyesisiniz.
Local.Elem <List.aile_<Src.Tag0.Toplamkisi>_Talep.Findelem <Ref1.uid>>
List.Aile_<Src.Tag0.Toplamkisi>_Talep.<DLocal.Elem>.Remove


On=1000 2000000
Ref1=<Serv.List.Aile_<Src.Tag0.Toplamkisi>_Talep.<eval <argn>-1000>>
Local.Elem <List.aile_<Src.Tag0.Toplamkisi>_Talep.Findelem <Ref1.uid>>
List.Aile_<Src.Tag0.Toplamkisi>_Talep.<DLocal.Elem>.Remove
Ref1.Mesaj2 Aile teklifiniz kabul edilmemiştir, ilginizden dolayı teşekkür ederiz.
Src.Hata <Ref1.name> isimli oyuncunun talebi silinmiştir.

On=29051453
If (0<List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count> > 0)
Src.Hata Tüm talepler silinmiştir.
Src.Mesaj1 Toplam silinen talep sayısı <Eval <List.Aile_<Src.Tag0.Toplamkisi>_Talep.Count>> adet.
List.Aile_<Src.Tag0.Toplamkisi>_Talep.Clear
Return 1
Endif
Src.Hata Şuan listede bekleyen talep bulunmamaktadır.

[Function AileTalebi]
If !(Strmatch('','<Src.Tag.Benimailem>'))
Src.Hata Sizin zaten mevcut bir aileniz var.
Return 1
Endif
Src.Targetf Talebim <Src>
Src.Mesaj2 Ailesine katılmak istediğiniz playeri seçin.

[Function Talebim]
Ref1=<Argo>
Ref2=<Ref1.Tag0.Toplamkisi>
Ref3=<Ref2.Tag0.AileReisi>
Local.Elem <List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.findelem <Src>>
If (<Src.uid> == <Ref1.Uid>)
Src.Hata Kendinizi seçemezsiniz.
ElseIf !(<Ref1.isplayer>)
Src.Hata Sadece oyuncuları seçebilirsiniz.
ElseIf !(Strmatch('','<Src.Tag.Benimailem>'))
Src.Hata Sizin zaten mevcut bir aileniz var.
ElseIf (Strmatch('','<Ref1.Tag.Benimailem>'))
Src.Hata Seçtiğiniz oyuncunun ailesi olması gerekmektedir.
ElseIf (<Ref1.findid.i_rune_incognito>)
Src.Hata <Ref1.name> isimli kişi sahte kimlik kullanıyor.
ElseIf (0<List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.<local.elem>> == <Src>)
Src.Hata <Ref1.Tag0.Benimailem> isimli ailede bir talebiniz mevcut.
Else
List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.Add <Src>
Src.Mesaj2 <Ref1.Tag0.Benimailem> isimli aileye üye talebiniz iletilmiştir.
Ref3.Mesaj1 Sayın <Ref3.name>, <Src.name> isimli oyuncu ailenize katılmak için başvuruda bulunmuştur.
Return 1
Endif

[Dialog TumAilelerDetay]
200,150
NoMove
Resizepic 73 0 83 203 50
Resizepic 80 10 9300 190 30
DHtmlgump 85 15 180 20 0 0 <Def.Center><def.h3><Tag0.Benimailem>
Resizepic 0 45 83 340 180
Resizepic 7 55 9300 327 160
AlphaBlack 7 55 327 160

Local.Elem <List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.findelem <Src>>
Ref1=<UID.<Tag.AileReisi>>

Resizepic 25 65 9300 290 120
DHtmlGump 30 70 280 30 0 0 <def.center><def.bfont_red>Aile Reisi :<def.bfont_black> <Ref1.Name>
DHtmlGump 30 100 280 30 0 0 <def.bfont_red>Toplam Üye Sayısı : <def.bfont_black><DTag0.Aileuyesi>
DHtmlGump 30 130 280 30 0 0 <def.bfont_red>Aile Kuruluş Tarihi : <def.bfont_green><Tag0.Ailekurulustarihi>

If (Strmatch('','<Src.Tag.Benimailem>'))
DText 110 190 <Qval (0<List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.<local.elem>> == <Src>)?38:039> <Qval (0<List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.<local.elem>> == <Src>)?Talep Onay Bekliyor..:Aileye Üyelik Talebinde Bulun>
Button 75 188 4030 4031 1 0 1
Endif

[Dialog TumAilelerDetay Button]
On=0
Src.Dialog OyundakiAileler

On=1
Ref1=<UID.<Tag0.AileReisi>>
Local.Elem <List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.findelem <Src>>
If !(Strmatch('','<Src.Tag.Benimailem>'))
Src.Hata Sizin zaten mevcut bir aileniz var.
Return 1
Endif
If (0<List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.<local.elem>> == <Src>)
Src.Hata <Ref1.Tag0.Benimailem> isimli ailede bir talebiniz mevcut.
Return 1
Endif
If (<Src.findid.i_rune_incognito>)
Src.Hata Üzerinizde sahte kimlik varken talepte bulunamazsınız.
Return 1
Endif
List.Aile_<Ref1.Tag0.Toplamkisi>_Talep.Add <Src>
Src.Mesaj2 <Ref1.Tag0.Benimailem> isimli aileye üye talebiniz iletilmiştir.
Ref1.Mesaj1 Sayın <Ref1.name>, <Src.name> isimli oyuncu ailenize katılmak için başvuruda bulunmuştur.

[Function AC]
If STRMatch('','<Src.Tag.Benimailem>')
Src.Hata Bir aileye üye değilsiniz.
ElseIf (STRMatch("<Args>",""))
Src.Hata Boş mesaj gönderemezsiniz.
ElseIf (STRMatch("<Args>","<CTag0.Sonkayit>"))
Src.Hata Yazı tekrarı yapamazsın.
Return 1
Else
CTag0.Sonkayit <Args>
Serv.Allclients AileChat <Args>
endif

[Function AileChat]
If (Strmatch('<Src.Tag0.Toplamkisi>','<Tag0.Toplamkisi>'))
Src.Chataile <Src.Name> : <Args>
Endif

[Function Chataile]
sysmessage @57,,1 <args>

[Function Hata]
sysmessage @38,0,1 <args>

[Function mesaj]
sysmessage @73,,1 <args>

[Function Mesaj1]
Sysmessage @1153,,1 <args>

[Function Mesaj2]
sysmessage @077a,,1 <args>

////////////////////////////İSİM DEĞİŞTİRME//////////

[Itemdef i_isimbelgesi]
Defname=i_isimbelgesi
ID=8792
Name=İsim Belgesi
Type=t_script
Value=500000

On=@Create
Color 0455
ATTR=Attr_Newbie

On=@Click
Message @1142,,1 [Kaybolmaz]
Message @077a,,1 <Name>
Return 1

On=@DClick
Src.DialogClose Isimdegistirme
Src.Dialog Isimdegistirme
Return 1

[Dialog Isimdegistirme]
250,150
Nomove
Resizepic 0 0 83 300 150
AlphaBlack 7 10 287 130
DHtmlGump 7 20 287 30 0 0 <def.center> <def.bfont_yellow><Serv.Name> Rename Sistem

Resizepic 65 50 83 170 50
Resizepic 72 60 9300 157 30
DTextentryLimited 79 65 145 20 1152 1 12
Button 190 110 4024 4025 1 0 1
Button 273 15 3 4 1 0 2
DText 100 110 039 Adımı değiştir
[Dialog Isimdegistirme Button]
On 2
Src.Hata İsim değiştirmekten vazgeçtiniz.
On 1
Local.Isim <Boslukyok <Argtxt[1]>>
If !(<Src.Restest 1 i_IsimBelgesi>)
Src.Hata Çantanızda isim belgesi bulunmamaktadır.
Return 1
ElseIf (<ISEmpty <Argtxt[1]>>)
Src.Hata İsminizi boş bırakamazsınız.
Return 1
ElseIf !(STRRegex(^[a-zA-Z]+$,<Argtxt[1]>))
Src.hata İsminizde geçersiz karakter kullandınız
Return 1
ElseIf (Strmatch('<Src.Name>','<Local.Isim>'))
Src.Hata Şuanki isminizden farklı bir isim seçmelisiniz.
Return 1
ElseIf ((Strlen(<Argtxt[1]>)) < 3) ||
Src.Hata İsminiz en az 3 karakterden oluşabilir.
Return 1
ElseIf ((Strlen(<Argtxt[1]>)) > 14)
Src.Hata İsminiz en fazla 14 karakterden oluşabilir.
Return 1
ElseIf (<Isimara <Local.Isim>> >0)
Src.Hata <Ilkharfbuyuk <Local.Isim>> isimli biri sunucuda mevcut.
Return 1
ElseIf (<Src.Flags>&StatF_Dead)
Src.Hata Ölü durumda bu işlemi gerçekleştiremezsiniz.
Return 1
ElseIf (<Src.Findid.I_Rune_Incognito>)
Src.Hata Incognito büyüsü kullanıyorken isim değiştiremezsiniz.
Return 1
ElseIf !(<Src.Restest 1 i_IsimBelgesi>)
Src.Hata Çantanızda isim belgesi bulunmamaktadır.
Return 1
Endif
Src.Consume i_isimbelgesi
Src.Name <Ilkharfbuyuk <Local.Isim>>
Src.Mesaj İsminiz <Ilkharfbuyuk <Local.Isim>> olarak değiştirilmiştir.

[Function Isimara]
For 0 <Eval <Serv.Accounts>-1>
For a 0 <Eval <Serv.Account.<dLocal._For>.Chars>-1>
Ref1 = <Serv.Account.<dLocal._For>.Char.<dLocal.a>.UID>
If (Strmatch('<Ref1.Name>','<Args>'))
Local.Bulunanisim ++
Endif
Endfor
Endfor
Return <dLocal.Bulunanisim>

[Function Boslukyok]
Args=<Explode " ",<Args>>
For 0 <Eval <dArgv> - 1>
Local.Boslukyok .="<Argv[<DLocal._For>]>"
Endfor
Return <STRSub 1 0 <Local.Boslukyok>>



Yorumlar

Henüz yorum yapılmamıştır.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : Henüz Oylanmamış   
Oylar: 0

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
Asalet Sistemi0MirroR29-11-2017
Aile Sistemi0MirroR27-09-2017
Barbut Sistemi (Zar)0MirroR26-08-2017
Binek Geliştirme Sistemi0MirroR23-08-2016
Aile Sistemi0Flamer20-06-2016


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,