UO-Dev Arama


Yazar: Bilinmiyor
Tarih: 27-04-2020 11:37





Kopyalamalı Runebook

Not:Sistemi eskiden düzenlediğim için ve şimdi tekrar bir arkadaşın ricası üzerine ufak ekleme yaptım

Orjinal runebook üzerinde yapılan her değişiklik kopya kitaplarda da olacak şekildede ayarlanmıştır, fakat runebook copier tarzı bir ürün eklemedim bu basit şeyi zaten siz kendinize göre yapabilirsiniz, yapmanız gereken tek şey kopya olmasını istediğiniz runebooka ".xtag.kopya (Kopyalamak istediğiniz runebookun uidi)" şeklinde yapabilirsiniz

En azından tagları kopyalamakla uğraşmaz arkadaşlar

https://i.hizliresim.com/sPKNzP.jpg


Kod:
[Plevel 7]
RuneYasak

[Function RuneYasak]
IF (<Src.Region.Tag0.RuneYasak>)
Src.Region.Tag.RuneYasak
Src.Sysmessage @07a1,,1 Bu alan rune kullanımına açılmıştır
Else
Src.Region.Tag.RuneYasak 1
Src.Sysmessage @38,,1 Bu alan rune kullanımına kapatılmıştır
Endif

[ITEMDEF i_runebook]
NAME = Runebook
ID = 8901
TYPE = t_script
VALUE = 1550
WEIGHT = 1.5

SKILLMAKE=INSCRIPTION 100.0, MAGERY 70.0
RESOURCES=50 i_scroll_blank, 3 i_scroll_recall, 5 i_scroll_gate_travel

ON=@CREATE
Color = 0796
Attr = Attr_Newbie
Tag.Sayfa = 1
Tag.Sarj = 4

ON=@Click
Message @1153 <Name>
Return 1

On=@TargOn_Char
Return 1

ON=@TargOn_Item
IF <Src.Targ.TopObj> != <Src>
Src.Sysmessage @38,,1 Ekleyeceğiniz rune çantanızda olmalıdır.
Return 1
Endif

IF (<dTag.Sayfa> > 1)
Local.BuSayfada = <Eval ((<Tag0.Sayfa>-1)*16)+1>
Else
Local.BuSayfada = 1
Endif

IF (<Src.Targ.BaseID> = i_rune_marker)
IF (<Src.Targ.MoreP>)
Ref1 = <Src.Targ>
Local.BosAlan 0

For <Eval <dLocal.BuSayfada> + 16> <dLocal.BuSayfada>
IF (<IsEmpty <Tag.Rune.<dLocal._For>>>)
Local.BosAlan = <dLocal._For>
Endif
EndFor

IF (<Local.BosAlan>)
Try Tag.Rune.<dLocal.BosAlan> = <Ref1.Name>
Try Tag.Lokasyon.<dLocal.BosAlan> = <Ref1.MoreM> <Ref1.Morep>
Src.Sysmessage @07a1,,1 <Ref1.Name> isimli rune kitaba eklendi.
Sound 85
Ref1.Remove
Else
Src.Sysmessage @38,,1 Bu sayfada boş yer kalmamış.
Endif
Return 1
Else
Src.Sysmessage @38,,1 Bu rune boş.
Return 1
EndIF
EndIF

ON=@DClick
IF (Strmatch('<Src.Region.Name>','Jail'))
Src.Sysmessage @38,,1 Bunu jailde kullanamazsınız.
Return 1
Endif
IF (<Src.Region.Tag0.RuneYasak>)
Src.Sysmessage @38,,1 Bu alan rune kullanımına kapalıdır.
Return 1
Endif
IF (<Src.Flags>&Statf_Dead) || (<Src.Flags>&04)
Src.Sysmessage @38,,1 Şu anki durumunuzda bunu kullanamazsiniz.
Return 1
ElseIF (<UID.<Src.Region.UID>.Type> = T_Ship)
Src.Sysmessage @38,,1 Gemi içerisinde bunu kullanamazsınız.
Return 1
ElseIF (<Src.Action> = ID(Skill_Magery)) || (<Src.Action> = Skill_Magery)
Src.Sysmessage @38,,1 Büyü esnasında bunu kullanamazsınız.
Return 1
ElseIF (<Src.IsEvent.e_recall>)
Return 1
ElseIF (<Src.Tag0.Beklemelisin>)
Src.Sysmessage @38,,1 Biraz beklemelisiniz.
Return 1
Endif
sDialog d_runebook,<dTag.Sayfa>
Return 1


[Dialog d_runebook]
0,0

PAGE 0

GumpPic 200 150 2201
GumpPic 225 320 57
GumpPic 380 180 57
GumpPic 225 180 57
GumpPic 380 320 57
GumpPic 340 180 59
GumpPic 500 180 59
GumpPic 500 320 59
GumpPic 340 320 59

For 1 7
GumpPic <Eval (<Local._For>*16)+220> 180 58
EndFor
For 1 7
GumpPic <Eval (<Local._For>*16)+380> 180 58
EndFor
For 1 7
Gumppic <Eval (<Local._For>*16)+220> 320 58
EndFor
For 1 7
GumpPic <Eval (<Local._For>*16)+380> 320 58
EndFor

IF (<dTag.Sayfa> != 1)
Button 240 330 2225 2225 1 0 1001
Button 220 155 2235 2235 1 0 901
Endif
IF (<dTag.Sayfa> != 2)
Button 270 330 2226 2226 1 0 1002
Endif
IF (<dTag.Sayfa> != 3)
Button 300 330 2227 2227 1 0 1003
Endif
IF (<dTag.Sayfa> != 4)
Button 330 330 2228 2228 1 0 1004
Endif
IF (<dTag.Sayfa> != 5)
Button 400 330 2229 2229 1 0 1005
Endif
IF (<dTag.Sayfa> != 6)
Button 430 330 2230 2230 1 0 1006
Endif
IF (<dTag.Sayfa> != 7)
Button 460 330 2231 2231 1 0 1007
Endif
IF (<dTag.Sayfa> != 8)
Button 490 330 2232 2232 1 0 1008
Button 495 155 2206 2206 1 0 902
Endif

IF !(<dTag.Kopya>)
Button 265 165 2103 2104 1 0 500
DHtmlGump 275 160 50 20 0 0 <def.bfont_green> Ekle
Else
DHtmlGump 245 160 150 20 0 0 <def.bfont_dpurple> Sahibi: <def.bfont_purple><Uid.<Tag.Kopya>.TopObj.Name>
Endif

DText 425 160 0455 Sarj:
DText 465 160 0455 <dTag.Sarj>
Button 410 165 2103 2104 1 0 499
Local.Sira=0
Local.Sayfa=1

For 1 128
Local.Sira ++
IF (<dLocal.Sira> > 16)
Local.Sira 1
Local.Sayfa ++
Endif

IF (<dLocal.Sira> > 8)
Local.Hizala 391
Else
Local.Hizala 228
Endif

IF (<dLocal.YukardanAsagi> = 8)
Local.YukardanAsagi 0
Endif
Local.YukardanAsagi ++
PAGE <dLocal.Sayfa>
IF !(<dTag.Kopya>)
IF !(<IsEmpty <Tag.Rune.<dLocal._For>>>)
Local.X <StrEat <Tag.Lokasyon.<dLocal._For>>>,<StrArg <Tag.Lokasyon.<dLocal._For>>>
Button <dLocal.Hizala> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <dLocal._For>
Button <Eval <dLocal.Hizala> + 10> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <Eval <dLocal._For>+120>
DHtmlGump <Eval <dLocal.Hizala> + 24> <Eval (<dLocal.YukardanAsagi>*16)+177> 105 20 0 0 <Qval <Serv.Map(<Local.X>).Region.Guarded>?<Def.BFont_dGreen>:<Def.BFont_dRed>><Qval <Uid.<Serv.Map(<Local.X>).Region.Uid>.Type>?<Def.BFont_Black>:><Tag.Rune.<dLocal._For>>
Button <Eval <dLocal.Hizala> + 115> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <Eval <dLocal._For>+360>
Button <Eval <dLocal.Hizala> + 125> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <Eval <dLocal._For>+240>
Endif
Else
IF !(<IsEmpty <Uid.<Tag.Kopya>.Tag.Rune.<dLocal._For>>>)
Local.X <StrEat <Uid.<Tag.Kopya>.Tag.Lokasyon.<dLocal._For>>>,<StrArg <Uid.<Tag.Kopya>.Tag.Lokasyon.<dLocal._For>>>
Button <dLocal.Hizala> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <dLocal._For>
Button <Eval <dLocal.Hizala> + 10> <Eval (<dLocal.YukardanAsagi>*16)+182> 2103 2104 1 0 <Eval <dLocal._For>+120>
DHtmlGump <Eval <dLocal.Hizala> + 24> <Eval (<dLocal.YukardanAsagi>*16)+177> 105 20 0 0 <Qval <Serv.Map(<Local.X>).Region.Guarded>?<Def.BFont_dGreen>:<Def.BFont_dRed>><Qval <Uid.<Serv.Map(<Local.X>).Region.Uid>.Type>?<Def.BFont_Black>:><Uid.<Tag.Kopya>.Tag.Rune.<dLocal._For>>
Endif
Endif
Endfor
[dialog d_runebook button]

On=1 120

IF (<Tag.Kopya>)
Local.Locasyon=<Uid.<Tag.Kopya>.Tag.Lokasyon.<dArgn>>
Else
Local.Locasyon=<Tag.Lokasyon.<dArgn>>
Endif

IF (<Src.ISGM>)
Src.Tag.Recall=1
Src.Recall <Qval <dTag.Kopya>?<StrEat <Uid.<Tag.Kopya>.Tag0.Lokasyon.<dArgn>>>:<StrEat <Tag.Lokasyon.<dArgn>>>>
Return 1
Endif
IF (<UID.<Src.Region.UID>.Type> = T_Ship)
Src.Sysmessage @38,,1 Gemi içerisinde bunu kullanamazsınız.
Return 1
Endif

IF (<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Tag0.RuneYasak>)
Src.Sysmessage @38,,1 Bu bölge kapalıdır.
Return 1
Endif
IF (<Uid.<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Uid>.Type> == T_Multi) || (<Uid.<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Uid>.Type> == T_Ship)
Src.Sysmessage @38,,1 Bu bölgeye giriş yapamazsınız.
Return 1
Endif

IF (<Src.Flags>&Statf_dead) || (<Src.Flags>&04)
Return 1
Endif
IF (<Src.Mana> < 15)
Src.Sound=92
Src.Sysmessage @38,,1 Yeterli mananız yok.
Return 1
Endif
IF (<dTag0.Sarj> > 0)
Src.Mana -=15
Tag.Sarj -=1
Src.Anim 17
Src.Events +e_Recall
Src.sltnomove 30
Src.Timerf 3,Recall <StrEat <Local.Locasyon>>
Src.Tag.Recall = 1
Src.Sayua 0481,6,6,0 Kal Ort Por
ElseIF (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_mandrake_root>) && (<src.restest 1 i_reag_blood_moss>)
Src.Events +e_Recall
Src.sltnomove 30
Src.Timerf 5,Recall <StrEat <Local.Locasyon>>
src.consume 1 i_reag_black_pearl
src.consume 1 i_reag_mandrake_root
src.consume 1 i_reag_blood_moss
Src.Mana -=15
Src.Anim 17
Src.Tag.Recall = 1
Src.Sayua 0481,6,6,0 Kal Ort Por
Else
Src.Sysmessage @38,,1 Yeterli malzemeye sahip değilsiniz.
Return 1
EndIF

ON=121 240
IF (<Tag.Kopya>)
Local.Locasyon <UID.<Tag.Kopya>.Tag.Lokasyon.<Eval (<Argn>)-120>>
Else
Local.Locasyon=<Tag.Lokasyon.<Eval (<Argn>)-120>>
Endif

IF (<Src.ISGM>)
Src.Tag.Recall=1
Src.Runegate <Qval <Tag.Kopya>?<StrEat <uid.<tag.kopya>.tag.lokasyon.<eval (<argn>)-120>>>:<StrEat <tag.lokasyon.<eval (<argn>)-120>>>>
Return 1
Endif

IF (<UID.<Src.Region.UID>.Type> = T_Ship)
Src.Sysmessage @38,,1 Gemi içerisinde bunu kullanamazsınız.
Return 1
Endif

IF (<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Tag0.RuneYasak>)
Src.Sysmessage @38,,1 Bu bölge kapalıdır.
Return 1
Endif
IF (<Uid.<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Uid>.Type> == T_Multi) || (<Uid.<Serv.Map(<StrEat <Local.Locasyon>>,<StrArg <Local.Locasyon>>).Region.Uid>.Type> == T_Ship)
Src.Sysmessage @38,,1 Bu bölgeye giriş yapamazsınız.
Return 1
Endif

IF (<Src.Flags>&Statf_dead) || (<Src.Flags>&04)
Return 1
Endif
IF (<Src.Magery> < 70.0)
Src.Sysmessage @38,,1 Magery skilliniz yetersiz. (Gereken: 70.0)
return 1
endif
if (<src.mana>< 40)
src.sound=92
src.sysmessage @38,,1 Yeterli mananız yok.
return 1
endif
IF (<dtag0.sarj > 0)
src.mana -=40
tag.Sarj -=1
src.events +e_recall
src.sltnomove 50
src.timerf 5,runegate <StrEat <Local.Locasyon>>
src.anim 17
src.tag.recall = 1
src.sayua 0481,6,6,0 Vas Rel Por
ELIF (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_mandrake_root>) && (<src.restest 1 i_reag_sulfur_ash>)
src.events +e_recall
src.sltnomove 30
src.timerf 6,runegate <StrEat <Local.Locasyon>>
src.consume 1 i_reag_black_pearl
src.consume 1 i_reag_mandrake_root
src.consume 1 i_reag_sulfur_ash
src.mana -=40
src.anim 17
src.tag.recall = 1
src.sayua 0481,6,6,0 Vas Rel Por
ELSE
src.sysmessage @38,,1 Yeterli malzemeye sahip değilsiniz.
RETURN 1
ENDIF

ON = 241 360

src.sysmessage <eval (<argn>)-240>. siradaki <tag.rune.<eval (<argn>)-240>> isimli rune'u cikarttiniz.
serv.newitem i_rune_marker
new.morep <StrEat <tag.lokasyon.<eval (<argn>)-240>>>
new.name <tag.rune.<eval (<argn>)-240>>
new.cont <src.uid>
try tag.lokasyon.<eval (<argn>)-240> =
try tag.rune.<eval (<argn>)-240> =
try tag.region.<eval (<argn>)-240> =
return 1

On=361 480
src.tag.uid = <uid>
src.tag.sira = <eval (<argn>)-360>
sdialog d_rnamechange
return 1

On=499
target
Src.Sysmessage @07a1 Eklemek istediğiniz scroll'u seçin.

On=500
Target
Src.Sysmessage @07a1 Eklemek istediğiniz markı seçin.

On=901
Tag.Sayfa -=1
sDialog d_runebook,<dTag.Sayfa>

On=902
Tag.Sayfa +=1
sDialog d_runebook,<dTag.Sayfa>

On=1001 1008
Tag.Sayfa <Eval <dArgn>-1000>
sDialog d_runebook,<dTag.Sayfa>


[dialog d_rnamechange]
0,100

PAGE 0
resizepic 250 90 83 250 120
Checkertrans 257 100 237 100
resizepic 280 130 3000 200 20
dtext 280 110 1153 Mark'ın yeni ismini girin;
button 280 160 4006 4007 1 0 1
dtext 315 160 1153 Tamam
dtextentry 285 130 130 20 1153 0
dtext 415 160 1153 Sıfırla
button 380 160 4006 4007 1 0 2

[dialog d_rnamechange button]
on = 1
obJ = <src.tag.uid>
src.tag.uid =
IF (<isempty <argtxt[0]>>)
src.sysmessage @38,,1 Rune ismini bos birakamazsiniz.
return 1
ELIF (strlen(<argtxt[0]>) > 20)
src.sysmessage @38,,1 20 karakterden uzun olamaz.
return 1
ENDIF
IF (<isempty <obj.tag.region.<eval (<src.tag.sira>)>>>)
obj.tag.region.<eval (<src.tag0.sira>)> = <obj.tag.rune.<eval (<src.tag.sira>)>>
obj.tag.rune.<eval (<src.tag.sira>)> = <argtxt[0]>
src.sysmessage @07a1,,1 Rune'un ismi <argtxt[0]> olarak degistirildi.
src.tag.sira =
else
obj.tag.rune.<eval (<src.tag.sira>)> <argtxt[0]>
src.sysmessage @07a1,,1 Rune'un ismi <argtxt[0]> olarak degistirildi.
src.tag.sira =
ENDIF

on = 2
obj = <src.tag.uid>
src.tag.uid =
IF !(<isempty <obj.tag.region.<eval (<src.tag.sira>)>>>)
obj.tag.rune.<eval (<src.tag.sira>)> = <obj.tag.region.<eval (<src.tag.sira>)>>
obj.tag.region.<eval (<src.tag.sira>)> =
src.sysmessage @07a1,,1 Rune'un ismi sifirlandi.
src.tag.sira =
ENDIF

[function sltnomove]
IF (<tag0.nomovetill> < <eval <tag0.nomovetill>+<argn>>)
tag.nomovetill <eval <serv.time>+<argn>>
ENDIF

[events e_recall]
on=@logout
Src.Tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
events -e_recall
effect 3,i_fx_smoke_small,30,36,0
sysmessage The spell fizzles
sound 92

on=@Skillstart
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
skill fail
events -e_recall
effect 3,i_fx_smoke_small,30,36,0
sysmessage The spell fizzles
sound 92

ON=@Gethit
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
events -e_recall
effect 3,i_fx_smoke_small,30,36,0
sysmessage The spell fizzles
sound 92

On=@Death
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
src.events -e_recall
src.effect 3,i_fx_smoke_small,30,36,0
src.sysmessage The spell fizzles
src.sound 92

on=@UserWarMode
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
src.events -e_recall
src.tag.recall =
src.effect 3,i_fx_smoke_small,30,36,0
src.sysmessage The spell fizzles
src.sound 92


[function recall]
IF (<flags>&statf_dead)
return 1
ENDIF
IF (<UID.<Src.Region.UID>.Type> = T_Ship) || (<UID.<Src.Region.UID>.Type> = T_Multi)
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
src.tag.nomovetill =
src.tag.recall =
src.events -e_recall
src.tag.recall =
src.effect 3,i_fx_smoke_small,30,36,0
src.sysmessage The spell fizzles
src.sound 92
Return 1
Endif

IF (<tag0.recall>)
src.go <args>
src.events -e_recall
src.sound 254
src.tag.recall =
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
return 1
ENDIF

[function runegate]
IF (<flags>&statf_dead)
return 1
ENDIF
IF (<tag0.recall>)
serv.newitem i_gate_rune
new.morep <strarg <args>>,<strarg <streat <args>>>,<strarg <streat <streat <args>>>>,<strarg <streat <streat <streat <args>>>>>
new.attr attr_static|attr_decay
new.p <src.p>
serv.newitem i_gate_rune
new.morep <src.p>
new.attr attr_static|attr_decay
new.p <args>
src.tag.recall =
src.events -e_recall
src.tag.Beklemelisin 1
src.timerf 3,src.tag.Beklemelisin =
return 1
ENDIF

[ITEMDEF i_gate_rune]
ID = i_moongate_blue
NAME = Travel gate
TYPE = t_moongate

ON=@CREATE
COLOR = 0785
TIMER = 30

ON=@CLICK
message <name>
return 1

ON=@STEP
sdialog d_gatetravel2
return 1

on=@dclick
sdialog d_gatetravel2
return 1

on=@timer
remove
return 1

[dialog d_gatetravel2]
250,150

PAGE 0
Resizepic 0 0 83 250 120
Checkertrans 10 10 237 100
Resizepic 15 15 9300 220 20
Resizepic 15 35 9300 220 20
DHtmlGump 20 15 240 20 0 0 Yer : <Def.BFont_D<Qval <Serv.Map(<MoreP>,<MoreM>).Region.Guarded>?Green:Red>><Serv.Map(<MoreP>,<MoreM>).Region.Name>
DHtmlGump 20 35 240 20 0 0 Kordinat : <Def.BFont_d<Qval <Serv.Map(<MoreP>,<MoreM>).Region.Guarded>?Green:Red>><MoreP>
Button 50 70 4023 4024 1 0 1
DText 90 70 <Qval <Serv.Map(<MoreP>,<MoreM>).Region.Guarded>?1152:38> Git
Button 140 70 4020 4021 1 0 0
DText 180 70 1152 Vazgeç

[dialog d_gatetravel2 button]
ON=1
IF !(<UID>)
Src.Sysmessage @38,,1 Gate kapalı durumda.
ElseIF (<Distance> > 3) || !(<CanSeeLos>)
Src.Sysmessage @38,,1 Gateye çok uzaksınız.
Else
Src.Go <MoreP>
Src.Update
Endif


[EOF]



Yorumlar

Henüz yorum yapılmamıştır.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : Henüz Oylanmamış   
Oylar: 0

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
24 Sayfalık Runebook0Freeman13-09-2016
Staff Runebook0Freeman06-09-2016
Chivalry, Sacred Journey ekli Runebook0Andrien25-01-2015
56b Runebook0Mrs.xariyla23-02-2012
Runebook Gump0Rowall31-08-2009


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,