UO-Dev Arama

 



İçerde : 1 misafir, 0 üye : --- Sayfalar: 1
Yazar

muratyavas


UO-Dev Üyesi
Skill Title: Novice
Online durumu
Toplam Mesaj: 46
Oyun Tarzı: Pvp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 42
Mesaj #39231   17-02-2011 22:45 GMT    
        
selam arkadaşlar ben ev komutlarında sorun yaşıyorum..

bu house scp

Kod:
[defname fhouse]
removeday 15 //silinme gün sayısı
maxcoowner 5 //max. ortak sayısı (max 8)
maxfriend 20 //max. dost sayısı (max 20)
maxitem 150 //max. sabitlenebilir item sayısı
maxstrongbox 3 //max. strongbox sayısı +1 ev sahibi hariç
maxsecurebox 10 //max. güvenli kasalar
abletopassword 1 //strongboxları şifrele
housebank 1 //evde banka açılsın

[itemdef 0bd1]
//brass sign
Defname=i_sign_brass
Type=t_sign_gump
Tdata2=064
Flip=1
Resources=2 I_BOARD, 1 i_ingot_iron
Dupelist=0bd2

On=@Create
timer=60*60*24*<eval <def.removeday> -1>

On=@Click
if (<timer> > 60*60*24*<eval <def.removeday> -5>) && !(<morex>)
message [yepyeni]
elseif (<timer> < 60*60*24*<eval <def.removeday> -5>) && !(<morex>)
message [eski]
elseif (<timer> < 60*60*24) && !(<morex>)
message [cok eski]
elseif (<morex> = 1)
message [yikilacak]
endif
message @55 <name>
return 1

On=@DClick
if (<link.baseid>) && (<link.type> = t_multi)
link.region.events +r_fhouse
link.more2 <uid>
src.ctag.flist 0
fhouse 1
endif
return 1

On=@Timer
if (<morex> = 1)
link.remove
else
timer=60*60*24
color=0481
morex=1
endif

On=@Targon_Char
ftargonchar
return 1

On=@Targon_Item
ftargonitem
return 1

[function fhouse]
call frights <src.uid>
if (<local.rights> > 0)
src.ctag.page <argn2>
sdialog d_fhouse,<argn1>
endif

[function frights]
for 1 <eval <def.maxcoowner> + <def.maxfriend>>
if (0<strarg <streat <link.tag0.allow_<dlocal._for>>>> = <args>)
if (0<strarg <link.tag0.allow_<dlocal._for>>> = 1)
local.rights 1
elseif (0<strarg <link.tag0.allow_<dlocal._for>>> = 2)
local.rights 2
endif
elseif (<link.more1> == <args>)
local.rights 3
else
for 0 <eval <src.account.chars>-1>
if (<uid.<link.more1>.account.char.<dlocal._for>.uid> = <args>)
local.rights 3
endif
endfor
endif
endfor

[plevel 1]
eveventimiver
eveventimial

[function eveventimiver]
src.events +e_fhouse

[function eveventimial]
src.events -e_fhouse

[regiontype r_fhouse]
On=@Enter
if (<src.ischar>)
src.events +e_fhouse
endif

On=@Exit
src.events -e_fhouse



[events e_fhouse]
On=@Login
call uid.<uid.<region.uid>.more2>.frights <src.uid>
if !(<local.rights>)
src.p <uid.<uid.<region.uid>.more2>.p>
endif

On=@ItemClick
if (<act.region.uid> == <region.uid>) && !(<act.cont>) && (<act.attr>&attr_move_never) && !(<act.type> = t_fsecure) && !((<act.baseid> == i_strong_box) || (<act.type> == t_door) || (<act.type> == t_door_locked) || (<act.type> == t_sign_gump) || (<act.type> == t_stone_guild))
act.message [sabit]
endif

[function fstrongbox]
newitem i_strong_box
act.p <src.p>
act.link <args>
act.more2 <src.uid>

[function fstrongboxcount]
for 1 <def.maxstrongbox>
if (0<streat <streat <tag0.allow_<dlocal._for>>>>)
local.strongbox +=1
endif
endfor

[typedef t_fsecure]
On=@Click
message [sabit,kilitli]
if (<rescount> > 0)
message <typedef.name> [<rescount>,<eval ((<weight> / 10) - <typedef.weight>)>]
else
message <typedef.name>
endif
return 1

On=@DClick
call frights <src.uid>
if (<local.rights> > 2)
type t_container
use
type t_fsecure
endif

On=@PickUp_Ground
return 1

[itemdef i_strong_box]
defname i_strong_box
type t_container
id i_box_brass
name strongbox
tdata2 04b

On=@Create
timer -1
attr attr_move_never

On=@Click
if (<src.region.uid> == <link.uid>)
message <src.uid.<more2>.name>
endif
if (<rescount> > 0)
message a <name> [<rescount>,<eval ((<weight> / 10) - <typedef.weight>)>]
else
message a strongbox [esya yok]
endif
return 1

On=@DClick
call frights <src.uid>
if (<local.rights> > 1)
if (<link.more1> == <src.uid>) || (<more2> == <src.uid>) || (<src.account.plevel> > 5)
if (<def.abletopassword> = 1)
src.ctag.password
src.ctag.strongbox
src.ctag.newpassword
src.ctag.strongboxuid <uid>
try uid.<link.more2>.fhouse 10
return 1
endif
else
return 1
endif
endif

On=@PickUp_Ground
return 1
endif

[function faddmember]
src.targ.ctag.argn1 <argn1>
src.targ.ctag.argn2 <argn2>
src.targ.ctag.argn3 <argn3>
src.targ.timerf 1,sdialog d_fquestion

[dialog d_fquestion]
5,5
nomove
resizepic 0 0 9300 275 120
checkertrans 0 0 275 155
resizepic 5 5 9300 265 110

dhtmlgump 15 20 223 60 0 0 <uid.<src.ctag.argn1>.name>, sizi bu eve <qval (strmatch(<src.dctag.argn3>,1))?dost:ortak> olarak eklemek istiyor, kabul ediyormusunuz?
dhtmlgump 40 60 140 20 0 0 Evet
dhtmlgump 40 80 150 20 0 0 Hayir
button 20 60 56 55 1 0 1
button 20 80 56 55 1 0 2

[dialog d_fquestion button]
on=1
if (strmatch(<src.dctag.argn3>,1))
local.faddmember <ddef.maxfriend>
elseif (strmatch(<src.dctag.argn3>,2))
local.faddmember <ddef.maxcoowner>
endif

if (<uid.<src.ctag.argn2>.tag0.<qval (strmatch(<src.dctag.argn3>,1))?friend:coowner>> < <local.faddmember>)
try uid.<src.ctag.argn2>.tag0.<qval (strmatch(<src.dctag.argn3>,1))?friend:coowner> <eval <uid.<src.ctag.argn2>.tag0.<qval (strmatch(<src.dctag.argn3>,1))?friend:coowner>> + 1>
for 1 <local.faddmember>
if !(<uid.<src.ctag.argn2>.tag0.allow_<dlocal._for>>)
try uid.<src.ctag.argn2>.tag.allow_<dlocal._for> <src.dctag.argn3> <src.uid>
try uid.<src.ctag.argn1>.sysmessage @55 <src.name>, eve <qval (strmatch(<src.dctag.argn3>,1))?dost:ortak> olarak eklendi.
src.sysmessage @55 Bu eve <qval (strmatch(<src.dctag.argn3>,1))?dost:ortak> olarak eklendiniz.
return 1
endif
endfor
else
src.sysmessage @55 Bu evin <qval (strmatch(<src.dctag.argn3>,1))?dost:ortak> ekleme limiti dolmus.
endif

on=2
try uid.<src.ctag.argn1>.sysmessage @55 Teklifiniz kabul edilmedi.


[dialog d_fhouse]
5,5
resizepic 0 0 9300 385 240
checkertrans 0 0 385 240
resizepic 5 5 9300 375 230

button 10 20 100 100 0 1 99
dhtmlgump 40 40 100 20 0 0 Ev Sahibi:
dhtmlgump 30 60 130 40 0 0 <uid.<link.more1>.name>
dhtmlgump 40 160 100 20 0 0 Komutlar
dhtmlgump 40 180 100 20 0 0 Re-Deed
dhtmlgump 40 200 100 20 0 0 Devret
dhtmlgump 160 160 100 30 0 0 Dost Ekle
dhtmlgump 160 180 100 20 0 0 Dost Listesi
dhtmlgump 160 200 100 20 0 0 Dost Temizle
dhtmlgump 280 160 100 20 0 0 Ortak Ekle
dhtmlgump 280 180 100 20 0 0 Ortak Listesi
dhtmlgump 280 200 100 20 0 0 Ortak Temizle
button 20 160 56 55 0 3 99 //99 no action
button 20 180 56 55 0 4 99
button 20 200 56 55 0 5 99
button 140 160 56 55 1 0 1 //add friend
button 140 180 56 55 0 6 99
button 140 200 56 55 0 7 99
button 260 160 56 55 1 0 2 //add coowner
button 260 180 56 55 0 8 99
button 260 200 56 55 0 9 99

page 1 //default
call uid.<link>.fstrongboxcount
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Evin Ismi : <name>
dhtmlgump 180 40 160 20 0 0 <def.bfont_red>Yikilmasina : <qval (<morex> = 1) ? <eval (<timer> / 86400)>:<eval (<timer> / 86400) +1>>g <eval ((<timer> / 3600) - (<timer> / 86400) * 24)>s <eval ((<timer> / 60) - (<timer> / 3600) * 60)>d
dhtmlgump 160 60 160 20 0 0 Esya <link.dtag0.item>/<ddef.maxitem>
dhtmlgump 160 80 160 20 0 0 Dost <link.dtag0.friend>/<ddef.maxfriend>
dhtmlgump 160 100 160 20 0 0 Ortak <link.dtag0.coowner>/<ddef.maxcoowner>
dhtmlgump 260 60 160 20 0 0 Strongbox <dlocal.strongbox>/<ddef.maxstrongbox>
dhtmlgump 260 80 160 20 0 0 Kilitli <link.dtag0.securebox>/<ddef.maxsecurebox>

button 160 20 56 55 0 2 99
button 160 40 56 55 1 0 3

page 2 //change name
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Yeni Ev Ismi
resizepic 180 40 3000 180 20
dtextentry 190 40 160 20 0 1
button 180 80 56 55 1 0 4
button 260 80 56 55 0 1 99
dhtmlgump 200 80 150 20 0 0 Degistir
dhtmlgump 280 80 150 20 0 0 Iptal

page 3 //commands 1
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Komutlar
button 340 20 015e3 015e7 0 1 99 //last
dhtmlgump 180 40 190 100 1 1 <def.bfont_red><qval (<def.housebank> = 1)?house bank - bank<def.br>:?>house menu - menu <def.br>house help - help<def.br>i ban thee<def.br>i wish to place a strongbox<def.br>i wish remove this<def.br>i wish lock this down<def.br>i wish release this<def.br>i wish to secure this<def.br>item up<def.br>item down

page 4 //re-deed
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Re-Deed (topla)
button 340 20 015e3 015e7 0 1 99 //last
dhtmlgump 180 40 200 40 0 0 Evi re-deed edecekmisiniz? Eve ait tum esyalar silinecek.
button 180 80 56 55 1 0 6
button 260 80 56 55 0 1 99
dhtmlgump 200 80 150 20 0 0 Evet
dhtmlgump 280 80 150 20 0 0 Hayir

page 5 //change owner
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Devret
button 340 20 015e3 015e7 0 1 99 //last
dhtmlgump 180 40 200 40 0 0 Evi baska bir oyuncuya devretmek istediginize eminmisiniz?
button 180 80 56 55 1 0 7
button 260 80 56 55 0 1 99
dhtmlgump 200 80 150 20 0 0 Evet
dhtmlgump 280 80 150 20 0 0 Hayir

page 6 //friends list
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Dost Listesi
button 340 20 015e3 015e7 1 0 8 //last
if (<eval <link.tag0.friend> -4> > <src.ctag0.flist>)
button 360 20 015e1 015e5 1 0 9 //next
endif
dorigin 0 20
for 1 4
if (<strarg <link.tag0.allow_<eval <local._for> + <src.ctag.flist>>>> = 1)
button 160 *20 56 55 1 0 <eval (<local._for> + <src.ctag.flist>) +99>
dhtmlgump 180 - 150 20 0 0 <uid.<strarg <streat <link.tag0.allow_<eval <local._for> + <src.ctag.flist>>>>>.name> <eval (<local._for> + <src.ctag.flist>) +99>
endif
endfor

page 7 //friends clear
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Dost Temizle
button 340 20 015e3 015e7 0 1 99 //last
dhtmlgump 180 40 200 40 0 0 Evinize dost olan tum oyunculari silmek istediginizden eminmisiniz?
button 180 80 56 55 1 0 10
button 260 80 56 55 0 1 99
dhtmlgump 200 80 150 20 0 0 Evet
dhtmlgump 280 80 150 20 0 0 Hayir

page 8 //coowner list
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Ortak Listesi
button 340 20 015e3 015e7 1 0 11 //last
if (<eval <link.dtag0.coowner> -4> > <src.ctag0.flist>)
button 360 20 015e1 015e5 1 0 12 //next
endif
dorigin 0 20
for 1 4
if (<strarg <link.dtag0.allow_<eval <local._for> + <src.ctag.flist>>>> = 2)
button 160 *20 56 55 1 0 <eval (<local._for> + <src.ctag.flist>) +199>
dhtmlgump 180 - 150 20 0 0 <uid.<strarg <streat <link.tag0.allow_<eval <local._for> + <src.ctag.flist>>>>>.name> <eval (<local._for> + <src.ctag.flist>) +199>
endif
endfor

page 9 //coowners clear
dhtmlgump 180 20 150 20 0 0 <def.bfont_blue>Ortak Temizle
button 340 20 015e3 015e7 0 1 99 //last
dhtmlgump 180 40 200 40 0 0 Evinize ortak olan tum oyunculari silmek istediginizden eminmisiniz?
button 180 80 56 55 1 0 13
button 260 80 56 55 0 1 99
dhtmlgump 200 80 150 20 0 0 Evet
dhtmlgump 280 80 150 20 0 0 Hayir

page 10 //strongbox password
dhtmlgump 180 20 200 20 0 0 <def.bfont_blue>Strongbox Sifresi
resizepic 180 40 3000 60 20
if (strlen(<src.ctag0.password>) = 2)
dhtmlgump 190 40 200 20 0 0 <strsub 1 1 <src.ctag.password>>
elseif (<src.ctag0.password>) && (strlen(<src.ctag0.password>) > 2)
for <eval (strlen(<src.ctag.password>)) -1>
dhtmlgump <eval (<local._for> *10) +180> 40 200 20 0 0 *
endfor
endif

ref1=<src.ctag.strongboxuid>
if (<ref1.tag0.password>) && (strlen(<src.ctag0.password>) < 5)
dhtmlgump 180 60 200 20 0 0 <def.bfont_red>4 haneli sifrenizi girin
if (strlen(<src.ctag0.password>) > 1)
button 240 40 56 55 1 0 33
dhtmlgump 260 40 150 20 0 0 Sifirla
endif
elseif !(<ref1.tag0.password>)
dhtmlgump 180 60 200 20 0 0 <def.bfont_red>Daha once sifre belirlemediniz
elseif (<ref1.tag0.password>) && (<ref1.tag0.password> = <src.ctag0.password>)
dhtmlgump 180 60 200 20 0 0 <def.bfont_blue>Girdiginiz sifre dogru
endif

//**********************\\ special thank%s 2 "jeem" 4 this code%s x) //**********************\\

button 180 80 <qval (<src.ctag0.password>) ? <qval (strlen(<src.ctag0.password>) < 5) ? 56 : 55> : 55> 55 <qval (<src.ctag0.password>) ? <qval (strlen(<src.ctag0.password>) < 5) ? 1 : 0> : 0> 0 20
dhtmlgump 185 100 150 20 0 0 0

dorigin 180 80
for 9
button *15 - <qval (strlen(<src.ctag0.password>) < 5) ? 56 : 55> 55 <qval (strlen(<src.ctag0.password>) < 5) ? 1 : 0> 0 <eval <local._for> +20>
dhtmlgump +5 +20 150 20 0 0 <dlocal._for>
endfor

button 240 <qval (<src.ctag0.strongbox> = 1) ? 40 : -4000> 56 55 1 0 30
button 300 <qval (<src.ctag0.strongbox> = 1) ? 40 : -4000> 56 55 0 1 31
dhtmlgump 260 <qval (<src.ctag0.strongbox> = 1) ? 40 : -4000> 150 20 0 0 Ac
dhtmlgump 320 <qval (<src.ctag0.strongbox> = 1) ? 40 : -4000> 150 20 0 0 Sifre

button 240 <qval (<src.ctag0.newpassword> = 1) ? 40 : -4000> 56 55 1 0 32
button 300 <qval (<src.ctag0.newpassword> = 1) ? 40 : -4000> 56 55 1 0 33
dhtmlgump 260 <qval (<src.ctag0.newpassword> = 1) ? 40 : -4000> 150 20 0 0 Tamam
dhtmlgump 320 <qval (<src.ctag0.newpassword> = 1) ? 40 : -4000> 150 20 0 0 Iptal

[dialog d_fhouse button]
on=1 //friend add
call frights <src.uid>
if (<local.rights> > 1)
morex 1
target @55 Eve dost olarak eklenecek kisiyi secin.
else
src.sysmessage @55 Bunu sadece ev sahibi veya ortagi yapabilir.
fhouse 1
endif

on=2 //coowner add
call frights <src.uid>
if (<local.rights> > 2)
morex 2
target @55 Eve ortak olarak eklenecek kisiyi secin.
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
fhouse 1
endif

on=3 //refresh
call frights <src.uid>
if (<local.rights> > 2)
src.sysmessage @55 Eviniz yenilendi.
timer=60*60*24*<eval <def.removeday> -1>
morex=00
color=00
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
endif
fhouse 1

on=4 //change name
call frights <src.uid>
if (<local.rights> > 2)
name <argtxt[1]>
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
endif
fhouse 1

on=6 //re-deed
call frights <src.uid>
if (<local.rights> > 2)
src.newitem=i_deed
src.act.more=<link.baseid>
src.act.name=<link.name>
src.act.bounce
src.act.attr 04
link.remove
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
fhouse 1
endif

on=7 //change owner
call frights <src.uid>
if (<local.rights> > 2)
morex 3
target @55 Evi devredeceginiz kisiyi secin.
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
fhouse 1
endif

on=8 //last page friends list
if (<src.ctag0.flist> < 4)
fhouse 1
else
src.ctag.flist -=4
fhouse 6
endif

on=9 //next page friends list
src.ctag.flist +=4
fhouse 6

on=10 //friends clear
call frights <src.uid>
if (<local.rights> > 1)
for 1 <def.maxfriend>
if (<strarg <link.tag0.allow_<dlocal._for>>> = 1)
link.tag.allow_<dlocal._for>
endif
endfor
link.tag.friend 0
src.sysmessage @55 Eve dost olan tum oyuncular silindi.
else
src.sysmessage @55 Bunu sadece ev sahibi veya ortagi yapabilir.
endif

on=11 //last page friends list
if (<src.ctag0.flist> < 4)
fhouse 1
else
src.ctag.flist -=4
fhouse 8
endif

on=12 //next page friends list
src.ctag.flist +=4
fhouse 8

on=13 //coowners clear
call frights <src.uid>
if (<local.rights> > 2)
for 1 <def.maxcoowner>
if (0<strarg <link.dtag0.allow_<dlocal._for>>> = 2)
try uid.0<streat <streat <link.tag0.allow_<dlocal._for>>>>.remove
link.tag.allow_<dlocal._for>
endif
endfor
link.tag.coowner 0
src.sysmessage @55 Eve ortak olan tum oyuncular silindi.
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
endif

on=100,120
call frights <src.uid>
if (<local.rights> > 1)
src.sysmessage @55 <uid.<strarg <streat <link.tag.allow_<eval <argn> -99>>>>.name>, dost listenizden silindi.
link.tag0.friend -=1
link.tag0.allow_<eval <argn> -99>

for 1 <def.maxfriend>
if !(<link.tag0.allow_<eval <local._for>>>)
link.tag0.allow_<eval <local._for>> <link.tag0.allow_<eval <local._for> +1>>
link.tag0.allow_<eval <local._for> +1>
endif
endfor
fhouse 6
else
src.sysmessage @55 Bunu sadece ev sahibi veya ortagi yapabilir.
endif

on=200,208
call frights <src.uid>
if (<local.rights> > 2)
src.sysmessage @55 <uid.<strarg <streat <link.tag.allow_<eval <argn> -199>>>>.name>, ortak listenizden silindi.
link.tag0.coowner -=1
if (0<streat <streat <link.tag0.allow_<eval <argn> -199>>>>)
try uid.<streat <streat <link.tag0.allow_<eval <argn> -199>>>>.remove
endif
link.tag0.allow_<eval <argn> -199>

for 1 <def.maxcoowner>
if !(<link.tag0.allow_<eval <local._for>>>)
link.tag0.allow_<eval <local._for>> <link.tag0.allow_<eval <local._for> +1>>
link.tag0.allow_<eval <local._for> +1>
endif
endfor
fhouse 8
else
src.sysmessage @55 Bunu sadece ev sahibi yapabilir.
endif

on=20 29
ref1=<src.ctag.strongboxuid>
src.ctag.password .= <eval <argn> - 20>
if (strlen(<src.ctag0.password>) > 4)
if (<ref1.tag0.password>) && (<ref1.tag0.password> = <src.ctag.password>)
src.ctag.strongbox 1
elseif !(<ref1.tag0.password>)
src.ctag.newpassword 1
else
src.dialogclose d_fhouse
src.ctag.password
src.sysmessage @55 Sifre yanlis
endif
endif
fhouse 10

on=30
ref1=<src.ctag.strongboxuid>
ref1.open

on=32
ref1=<src.ctag.strongboxuid>
ref1.tag0.password <src.ctag0.password>
ref1.open
src.sysmessage @55 Strongbox sifreniz [<strsub 1 4 <src.ctag.password>>] olarak belirlendi.

on=33
src.ctag.password
src.ctag.newpassword
fhouse 10

[function ftargonchar]
call frights <src.targ.uid>
if (<dmorex> > 9)
return 0
elseif (<local.rights> > 0)
src.sysmessage @55 <src.targ.name>, bu eve zaten uye.
elseif !(<src.targ.region.uid> == <region.uid>)
src.sysmessage @55 <src.targ.name>, evinizde degil.
else
if (<dmorex> = 1) && (<src.targ.npc> < 1) //add friend
if (<link.tag0.friend> < <def.maxfriend>)
src.sysmessage @55 Dost ekleme teklifi soruluyor.
faddmember <src.uid> <link.uid> 1
else
src.sysmessage @55 Bu eve daha fazla dost ekleyemezsiniz.
endif
elseif (<dmorex> = 2) && (<src.targ.npc> < 1) //add coowner
if (<link.tag0.coowner> < <def.maxcoowner>)
src.sysmessage @55 Ortak ekleme teklifi soruluyor.
faddmember <src.uid> <link.uid> 2
else
src.sysmessage @55 Bu eve daha fazla ortak ekleyemezsiniz.
endif
elseif (<dmorex> = 3) && (<src.targ.npc> < 1) //change owner
if (<src.targ.memoryfindtype.memory_guard>)
if !(<src.targ.memoryfindtype.memory_guard.link.type> == t_ship)
src.sysmessage @55 <src.targ.name>, zaten bir eve sahip.
return 1
endif
endif
if (<src.memoryfindtype.memory_guard>)
if (<src.memoryfindtype.memory_guard.link> == <link.uid>)
src.memoryfindtype.memory_guard.remove
endif
endif
link.more1 <src.targ.uid>
src.sysmessage @55 <src.targ.name>, evin yeni sahibi.
src.targ.sysmessage @55 Evin yeni sahibi sizsiniz.
src.newitem i_key_copper
src.act.cont <src.targ.findlayer.21.uid>
src.act.link <link.uid>
src.act.more <link.uid>
src.act.attr 04
elseif (<dmorex> = 4) //ban the bastard x)
src.sysmessage @55 <src.targ.name>, evden kovuldu.
src.targ.sysmessage @55 <src.name>, sizi evden kovdu.
src.targ.go <p>
endif
endif

[function ftargonitem]
if (<src.targ.cont>) || (<src.targ.type> == t_stone_guild) || (<src.targ.type> == t_spell) || (<src.targ.baseid> == i_corpse) || (<src.targ.type> == t_blood) || (<src.targ.type> == t_door) || (<src.targ.type> == t_door_locked) || (<src.targ.baseid> == i_pouch) || (<src.targ.baseid> == i_sign_brass)
src.sysmessage @55 Bunun uzerinde islem yapamazsiniz.
elseif !(<src.targ.region.uid> == <link.region.uid>)
src.sysmessage @55 Esya evinizde degil.
else
if (<dmorex> = 10) && (<src.targ.attr>&attr_move_never) && (<src.targ.baseid> = i_strong_box) && (<src.targ.more2> == <src.uid>) || (<link.more1> == <src.uid>)
for 1 <def.maxcoowner>
if (0<strarg <streat <link.tag0.allow_<dlocal._for>>>> = <src.targ.more2>)
link.tag.allow_<dlocal._for> 2 <src.targ.more2> 0
src.targ.remove
else
if (<link.more1> = <src.uid>)
link.tag.allow_0
endif
src.targ.remove
endif
return 1
endfor
elseif (<dmorex> = 11) && !(<src.targ.attr>&attr_move_never) && !(<src.targ.link.baseid>)
if (<src.targ.isneartype t_sign_gump 2>) || (<src.targ.isneartype t_door 2>) || (<src.targ.isneartype t_door_locked 2>)
src.sysmessage @55 Evin tabela veya kapi yakinlarina esya sabitleyemezsiniz.
else
if (<link.tag0.item> < <ddef.maxitem>)
link.tag0.item +=1
src.targ.link <link.uid>
src.targ.attr <src.targ.attr>&~attr_decay
src.targ.attr <src.targ.attr>|attr_move_never
src.targ.timer -1
src.targ.message [sabit]
src.targ.message <src.targ.name>
else
src.sysmessage @55 Bu eve daha esya sabitleyemezsiniz.
endif
endif
elseif (<dmorex> = 12) && (<src.targ.attr>&attr_move_never) && !(<src.targ.baseid> == i_strong_box)
link.tag0.item -=1
if (<src.targ.type> = t_fsecure)
link.tag0.securebox -=1
endif
src.targ.link 04fffffff
src.targ.attr <src.targ.attr>&~attr_move_never
src.targ.attr <src.targ.attr>|attr_decay
src.targ.tag.updown
src.targ.message [sabit degil]
src.targ.message <src.targ.name>
elseif (<dmorex> = 13) && (<src.targ.attr>&attr_move_never) && (<src.targ.link> == 04fffffff)
src.targ.nudgeup 1
src.targ.tag0.updown +=1
elseif (<dmorex> = 14) && (<src.targ.attr>&attr_move_never) && (<src.targ.link> == 04fffffff)
if (<src.targ.tag0.updown> > 0)
src.targ.nudgedown 1
src.targ.tag0.updown -=1
endif
elseif (<dmorex> = 15)
if (<link.tag0.securebox> < <ddef.maxsecurebox>)
if (<src.targ.type> = t_fsecure) || (<src.targ.baseid> = i_strong_box)
src.sysmessage @55 Bu kutu veya canta zaten kilitli.
elseif !(<src.targ.type> = t_container)
src.sysmessage @55 Sadece kutu ve cantalari kilitlebilirsiniz.
elseif !(<src.targ.attr>&attr_move_never)
src.sysmessage @55 Kilitlemek istediginiz kutuyu, once sabitlemelisiniz.
else
link.tag0.securebox +=1
src.targ.type t_fsecure
src.targ.link <link.uid>
src.targ.message [kilitli]
src.targ.message <src.targ.name>
endif
else
src.sysmessage @55 Bu eve daha kutu kilitleyemezsiniz.
endif
endif
endif

[speech spk_house_cmds]
on=menu
on=house menu
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.fhouse 1
endif

on=help
on=house help
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.fhouse 3
endif

on=i ban thee
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.morex 4
try uid.<more2>.target @55 Evden kovacaginiz kisiyi secin.
endif

on=i wish to place a strongbox
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
if (<more1> = <src.uid>) && (<tag0.allow_0>)
src.sysmessage @55 Size ait bir strongbox var.
return 1
elseif (<more1> = <src.uid>) && !(<tag0.allow_0>)
src.fstrongbox <uid>
tag.allow_0 1
return 1
endif
call fstrongboxcount
if (<local.strongbox> >= <def.maxstrongbox>)
src.sysmessage @55 Bu eve daha fazla strongbox koyamazsiniz.
return 1
endif
for 1 <def.maxcoowner>
if (0<strarg <streat <tag0.allow_<dlocal._for>>>> = <src.uid>)
if (0<streat <streat <tag0.allow_<dlocal._for>>>>)
src.sysmessage @55 Size ait bir strongbox var.
else
src.fstrongbox <uid>
tag.allow_<dlocal._for> 2 <src.uid> <new>
endif
return 1
endif
endfor
endif

on=i wish to remove this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 10
try uid.<more2>.target
endif

on=i wish to lock this down
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
if (<tag0.item> < <ddef.maxitem>)
try uid.<more2>.morex 11
try uid.<more2>.target
else
src.sysmessage @55 Bu eve daha esya sabitleyemezsiniz.
endif
endif

on=i wish to release this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 12
try uid.<more2>.target
endif

on=item up
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 13
try uid.<more2>.target
endif

on=item down
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 14
try uid.<more2>.target
endif

on=bank
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
if (<def.housebank> = 1)
src.bankself
endif
endif

on=i wish to secure this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 2)
if (<tag0.securebox> < <ddef.maxsecurebox>)
try uid.<more2>.morex 15
try uid.<more2>.target
else
src.sysmessage @55 Bu eve daha fazla kutu kilitleyemezsiniz.
endif
endif

[eof]


buda sphere speech

Kod:
[SPEECH spk_player]
on=menu
on=house menu
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.fhouse 1
endif

on=help
on=house help
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.fhouse 3
endif

on=i ban thee
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
try uid.<more2>.morex 4
try uid.<more2>.target @55 Evden kovacaginiz kisiyi secin.
endif

on=i wish to place a strongbox
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
if (<more1> = <src.uid>) && (<tag0.allow_0>)
src.sysmessage @55 Size ait bir strongbox var.
return 1
elseif (<more1> = <src.uid>) && !(<tag0.allow_0>)
src.fstrongbox <uid>
tag.allow_0 1
return 1
endif
call fstrongboxcount
if (<local.strongbox> >= <def.maxstrongbox>)
src.sysmessage @55 Bu eve daha fazla strongbox koyamazsiniz.
return 1
endif
for 1 <def.maxcoowner>
if (0<strarg <streat <tag0.allow_<dlocal._for>>>> = <src.uid>)
if (0<streat <streat <tag0.allow_<dlocal._for>>>>)
src.sysmessage @55 Size ait bir strongbox var.
else
src.fstrongbox <uid>
tag.allow_<dlocal._for> 2 <src.uid> <new>
endif
return 1
endif
endfor
endif

on=i wish to remove this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 10
try uid.<more2>.target
endif

on=i wish to lock this down
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
if (<tag0.item> < <ddef.maxitem>)
try uid.<more2>.morex 11
try uid.<more2>.target
else
src.sysmessage @55 Bu eve daha esya sabitleyemezsiniz.
endif
endif

on=i wish to release this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 12
try uid.<more2>.target
endif

on=item up
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 13
try uid.<more2>.target
endif

on=item down
call uid.<more2>.frights <src.uid>
if (<local.rights> > 1)
try uid.<more2>.morex 14
try uid.<more2>.target
endif

on=bank
call uid.<more2>.frights <src.uid>
if (<local.rights> > 0)
if (<def.housebank> = 1)
src.bankself
endif
endif

on=i wish to secure this
call uid.<more2>.frights <src.uid>
if (<local.rights> > 2)
if (<tag0.securebox> < <ddef.maxsecurebox>)
try uid.<more2>.morex 15
try uid.<more2>.target
else
src.sysmessage @55 Bu eve daha fazla kutu kilitleyemezsiniz.
endif
endif


evde hangi komutu kullansam bu konsolda bu hatayı alıyorum.. ve hiç bir komut çalışmıyor.

Kod:
00:20:ERROR:(sphere_speech.scp,50)Can't resolve <more2>
00:20:ERROR:(sphere_speech.scp,50)Undefined symbol 'frights'


//TheRaskol
Bu tür hatalarınızı lütfen Konsol Hataları bölümüne açınız.
Taşınmıştır.


Son güncelleme: TheRaskol tarafından 17-02-2011 22:55 GMT, önce düzenlendi.



Yazar

Mac-Fusion


UO-Dev Üyesi
Skill Title: Adept
Online durumu
Toplam Mesaj: 692
Oyun Tarzı: Pp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 33
Mesaj #39234   18-02-2011 00:26 GMT    
        
Bu kodu yazanın allah belasını verecek az kaldı


 B3LyRsy2
Yazar

Nemara


UO-Dev Üyesi
Skill Title: Novice
Online durumu
Toplam Mesaj: 30
Oyun Tarzı: Pvp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 30
Mesaj #54665   23-12-2011 11:41 GMT    
        
calişir kardeşim tabeleya cift tikla ayrica ordaki yazandaki help sistemi deki scripterlar ait değil sen
bilidğin komutlari yaz örnek veriyorum evi kurduktan sonra tabelaya cift tikla yoksa komutlar aktif olmaz/Genco


www.neropvp.com

Genco

Karanlıkların Efendisi

Yazar

Walkova


UO-Dev Üyesi
Skill Title: Novice
Online durumu
Toplam Mesaj: 14
Oyun Tarzı: Pp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 31
Mesaj #54671   23-12-2011 20:32 GMT    
        
Bu ev sistemini kullanmamanı öneririm.Eğer ev sistemi bulmada sıkıntı çekiyorsan özel mesaj ile gönderebilirim.



Yazar

Nemara


UO-Dev Üyesi
Skill Title: Novice
Online durumu
Toplam Mesaj: 30
Oyun Tarzı: Pvp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 30
Mesaj #54689   24-12-2011 10:13 GMT    
        
O scripteri denemedim güzelde Sadece İtem up ve item down calişmiyor başkada sorun yok ama elinde güzel bi house scripteri olan herşeyi calişan birisi varsa verebilir bu başlik altinda sphere.speech icindede verirseniz adam zorluk cekmez


www.neropvp.com

Genco

Karanlıkların Efendisi

Yazar

goztepe1925


UO-Dev Üyesi
Skill Title: Neophyte
Online durumu
Toplam Mesaj: 8
Oyun Tarzı: Pvp
Emulatör: RunUO
Tecrübe: Scripter
Yaş: 32
Mesaj #61057   14-07-2012 03:58 GMT    
        
Ev komutlarım çalışmıyor banada ev script ve speech scripti verirseniz minnetter kalırım



Yazar

MirroR


UO-Dev Üyesi
Skill Title: Adept
Online durumu
Toplam Mesaj: 598
Oyun Tarzı: Rp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 27
Mesaj #61124   16-07-2012 04:51 GMT    
        
Ev komutlarınız eğer çalışmıyor ise, dikkat edeceğiniz hususlardan biride bu. Ev komutlarını öncelikle evlere okutmalısınız.
Bakın " i ban thee " çalışıyor " item up " çalışmıyor demeyin bana sadece bilginiz olsun diyorum.

Kod:
[MULTIDEF 064]
DEFNAME=i_multi_house_stone_plaster_small
Name=Small Stone and Plaster House
TYPE=T_MULTI
VALUE=43800
CATEGORY=Multis
SUBSECTION=Houses
DESCRIPTION=Small Stone and Plaster House
TSPEECH=spk_player_house // Şu satırın sizin scriptslerinizde olup olmadığına bi bakın.
MULTIREGION=-3,-3,3,4
COMPONENT=i_door_wood,0,3,7
COMPONENT=i_sign_brass_2,2,4,5


Hayat dediğin bir çift bacak gidebildiğin yol kadardır.

Yazar

Barbarossa


UO-Dev Üyesi
Skill Title: Adept
Online durumu
Toplam Mesaj: 572
Oyun Tarzı: Pvp
Emulatör: 0.56b
Tecrübe: World Builder
Yaş: 28
Mesaj #61125   16-07-2012 05:05 GMT    
        
Kod:
//****************************************************************************
//SPHERE by : Menasoft ©1997-2007
//www.sphereserver.net
// All SPHERE script files and formats are copyright Menasoft & Partners.
// This file may be freely edited for personal use, but may not be distributed
// in whole or in part, in any format without express written permission from
// Menasoft & Partners.  All donations and contributions
// become the property of Menasoft & Partners.
//****************************************************************************
// FILE LAST UPDATED: 15-Nov-2003

VERSION=0.56b


// In the process of moving this stuff to scripts.

[SPEECH spk_player]
// All players speech filtered through here.
ON=home home home // Ghosts can go home.
if (<flags>&STATF_DEAD)
go <home>
endif

ON=I must consider my sins

ON=I resign from my guild

ON=I resign from my town

ON=Guard help *
ON=Guards*
ON=Help Guards*
// trying to call guards for help.

[SPEECH spk_pet]
// Pets that cannot talk
ON=ATTACK
ON=COME
ON=DEFEND ME
ON=DISMISS
ON=DROP // "GIVE" ?
ON=DROP ALL
ON=FETCH
ON=FOLLOW
ON=FOLLOW ME
ON=FRIEND
ON=GO
ON=GUARD
ON=GUARD ME
ON=KILL
ON=RELEASE
ON=SPEAK
ON=STAY
ON=STAY HERE
ON=STOP
ON=TRANSFER

[SPEECH spk_hireling]
// Pets that can talk.
ON=ATTACK
ON=BOUGHT
ON=CASH
ON=COME
ON=DEFEND ME
ON=DISMISS
ON=DROP // "GIVE" ?
ON=DROP ALL
ON=EQUIP
ON=EQUIP ALL
ON=FETCH
ON=FOLLOW
ON=FOLLOW ME
ON=FRIEND
ON=GET DRESSED
ON=GO
ON=GUARD
ON=GUARD ME
ON=INVENTORY
ON=KILL
ON=PRICE // may have args ?
ON=RECIEVED
ON=RELEASE
ON=SAMPLES
ON=SPEAK
ON=STATUS
ON=STAY
ON=STAY HERE
ON=STOCK
ON=STOP
ON=SUIT UP
ON=TRANSFER

[EOF]


exenpvp.com

Sayfalar: 1



Benzer Konular

KonularMesajlarSon gönderenTarih
etheral horse sorun1emre1108-04-2018
safe kordinat sorun3eren199428-02-2018
En Zengin Player Sorun3Anduo10-02-2018
deed sorun4Freeman01-01-2018
Ultima Sorun (AOS & ML)2Gokku22-03-2017


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,