Kod:
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%Scp Adı: explosion_yarismasi_sistemi.scp %
%Yazar: Dryas %
%İçerik: Turnuva genel içerik gate, event, cıkarıcılar..%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Notlar :
1- 671. cü satırdaki koordinatı kendi safe alanınıza yada gatenin açılmasını istediğiniz alanın koordinatına göre değiştirin.
2- 705, 706, 707, 708, 709, 710, 711, 712, 713 ve 714.cü satırlardaki koordinatlarıda yarışmayı yaptıracağınız alana göre değiştiriniz.
3- 444.ci satırdaki koordinat ise ödül taşının olacağı koordinattır. Onu da ödül alanı olarak belirlediğiniz yerin koordinatları ile değiştiriniz.
4- 208.cı satırdaki koordinat ise ödülünü alan oyuncunun gideceği safe alanın koordinatıdır. Onuda değiştiriniz.
5- 661.cı satırdaki koordinat ise turnuvayı başlattığınızda invis olup gideceğiniz alandır. O koordinatı da değiştiriniz.
Komutlar:
- Turnuvayı başlatmak için .exployap yazdığınızda çantanıza bir deed düşer. Bu deede çift tıkladığınızda karşınıza gelecek olan dialogdan öncelikle
kuralları okumalısınız. Kuralları okuyup onayladıktan sonra yarışmayı başlattığınız anda invis olarak yarışma alanına gidersiniz. Yine aynı anda ya
rışma gatesi belirlenen koordinata açılır anons geçer. Var ise yarışma alanına koyulacak itemler veya o itemleri çıkaracak olan deed çantanıza düşer.
Bunların yanında; Turnuvadan player elemek, huzuru bozan player varsa onu elemek ve kazanan playerı seçmek için 3 adet deed düşer. Ödül taşının yanı
na giden bir başkası ödül alamaz. Sadece kazanan olarak seçeceğiniz kişi ödülü alacaktır. Ne öncesinde nede sonrasında ödül alınamaz.
- Turnuvayı bitirmek için .explobitir komutunu kullanın.
Eksikler ve öneriler için lütfen [email protected] adresini messenger da ekleyiniz. Teşekkürler.
//-> Turnuvayı başlatma ve bitirme komutları.
/-> Turnuvayı başlatma fonksiyonu
[plevel 4]
exployap
[function exployap]
if (<src.tag.explo_yapti> == 1)
src.sysmessage @07a1,,1 Ayni anda birden fazla yarisma yapamazsiniz.
else
src.tag.explo_yapti 1
src.newitem i_explo_yapacagim
src.act.bounce
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion Turnuvasi yapilacaktir.
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: 2.dk icinde safe alana gate acilacaktir.
endif
return 1
/-> Turnuvayı bitirme fonksiyonu
[plevel 4]
explobitir
[function explobitir]
if (<src.tag.explo_yapti> == 0)
src.sysmessage @07a1,,1 Yapmadiginiz bir turnuvayi iptal edemezssiniz:).
else
src.tag.explo_yapti 0
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion Turnuvasina katilan tum playerlara tesekkur ederiz.
src.findid.i_explo_at.remove
src.findid.i_explo_kazanan.remove
src.findid.i_explo_alan_itemleri.remove
src.findid.i_explo_kasasi.remove
src.findid.i_explo_kasasi.remove
src.findid.i_explo_kasasi.remove
src.findid.i_explo_kasasi.remove
endif
return 1
//-> Ödül Sistemi.
/-> Ödül İhtimalleri
/-> İhtimal 4
[itemdef i_explo_odul_4] -> 240 k para
id i_deed
defname i_explo_odul_4
name Explosion Turnuvasi Odulu (Random)
on=@create
color 07a3
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
src.paraversinadama
src.paraversinadama
src.paraversinadama
src.paraversinadama
remove
return 1
/-> İhtimal 3
[itemdef i_explo_odul_3] -> 180 k para
id i_deed
defname i_explo_odul_3
name Explosion Turnuvasi Odulu (Random)
on=@create
color 07a3
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
src.paraversinadama
src.paraversinadama
src.paraversinadama
remove
return 1
/-> İhtimal 2
[itemdef i_explo_odul_2] -> 120 k para
id i_deed
defname i_explo_odul_2
name Explosion Turnuvasi Odulu (Random)
on=@create
color 07a3
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
src.paraversinadama
src.paraversinadama
remove
return 1
/-> İhtimal 1
[itemdef i_explo_odul_1] -> 60 k para
id i_deed
defname i_explo_odul_1
name Explosion Turnuvasi Odulu (Random)
on=@create
color 07a3
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
src.paraversinadama
remove
return 1
/-> Ödül deedi.
[itemdef i_explo_odul]
id i_deed
defname i_explo_odul
name Explosion Turnuvasi Odulu
on=@create
color 085a
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
src.tag.explo_kazandi 0
src.sysmessage @07a1,,1 Hediyeniz random olarak cantaniza dusmustur.
src.sysmessage @0799 Bu konu hakkinda atacaginiz pageler yanitsiz kalacaktir.
src.newitem {i_explo_odul_1 1 i_explo_odul_2 1 i_explo_odul_3 1 i_explo_odul_4 1}
src.act.bounce
remove
return 1
/-> Ödül taşı.
[itemdef i_explo_odul_tasi]
id i_grave_stone
defname i_explo_odul_tasi
name Explosion Turnuvasi Odul Tasi
on=@create
color 085f
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @867,,1 <name>
return 1
on=@dclick
if (<src.tag.explo_kazandi> == 0)
src.sysmessage @07a1,,1 Sadece turnuvayi kazanan buradan odul alabilir.
else
src.newitem i_explo_odul
src.act.bounce
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion turnuvasini <src.name> kazanmistir. Kendisini tebrik ediyoruz.
src.tag.explo_kazandi 0
src.go 5458,1230,3 // Burası Değişecek
endif
return 1
//-> Turnuvanın eventleri
/-> Binekde bankaya
[function binekle_girenler_explo]
if (<findlayer.25>)
tag.binekid <findlayer.25.more1>
tag.binekkarma <uid.<findlayer.25.more2>.karma>
tag.binekfame <uid.<findlayer.25.more2>.fame>
tag.binekfood <uid.<findlayer.25.more2>.food>
tag.binekcolor <uid.<findlayer.25.more2>.color>
tag.binekname <findlayer.25.name>
serv.newitem i_binek_zeka
new.tag.name <tag.binekname>
new.tag.fame <tag.binekfame>
new.tag.karma <tag.binekkarma>
new.tag.food <tag.binekfood>
new.tag.binekid <tag.binekid>
new.color <tag.binekcolor>
new.cont <findlayer(29).uid>
new.more2 1
findlayer.25.remove
else
return 1
endif
[itemdef i_binek_zeka]
id i_deed
type t_normal
weight 20.0
name Bineginiz
on=@click
if (<more2>
message @07a1,,1 <tag.name>
return 1
else
message @0481,1 <name>
return 1
endif
on=@dclick
if (<more2>)
try src.newnpc <tag.binekid>
link <src.act.uid>
link.name <tag.name>
link.karma <tag.karma>
link.fame <tag.fame>
link.food <tag.food>
link.color <color>
link.memorydel <src.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <src.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
link.update
link.anim 5
link.bark 3
link.message @1156 Iyi oyunlar..
remove
endif
/-> Çanta Kontrol
[function canta_kontrol_explo]
findlayer(1).cont=<findlayer.layer_pack.uid>
findlayer(2).cont=<findlayer.layer_pack.uid>
findlayer(3).cont=<findlayer.layer_pack.uid>
findlayer(4).cont=<findlayer.layer_pack.uid>
findlayer(5).cont=<findlayer.layer_pack.uid>
findlayer(6).cont=<findlayer.layer_pack.uid>
findlayer(7).cont=<findlayer.layer_pack.uid>
findlayer(8).cont=<findlayer.layer_pack.uid>
findlayer(10).cont=<findlayer.layer_pack.uid>
findlayer(12).cont=<findlayer.layer_pack.uid>
findlayer(13).cont=<findlayer.layer_pack.uid>
findlayer(14).cont=<findlayer.layer_pack.uid>
findlayer(17).cont=<findlayer.layer_pack.uid>
findlayer(18).cont=<findlayer.layer_pack.uid>
findlayer(19).cont=<findlayer.layer_pack.uid>
findlayer(20).cont=<findlayer.layer_pack.uid>
findlayer(22).cont=<findlayer.layer_pack.uid>
findlayer(23).cont=<findlayer.layer_pack.uid>
findlayer(24).cont=<findlayer.layer_pack.uid>
findlayer(layer_pack).attr 0
findlayer(layer_pack).cont <findlayer(layer_bankbox)>
findlayer(layer_pack).empty
findlayer(layer_pack).dclick
bank
update
return 1
/-> Oldugunde safeye gitsin..
[events olme]
on=@death
src.go 5458,1230,1
src.events -explo_turnuvasi
src.events -olme
//src.events +safe_alan
src.hits <str>
src.sysmessage @07a1,,1 Turnuvadan elendiniz.
src.findid.i_explo_bandana.remove
src.findid.i_explo_bot.remove
src.findid.i_explo_robe.remove
src.findid.i_explo_eldiven.remove
src.findid.i_explo_boyunluk.remove
return 1
/-> Ana eventimiz.
[events explo_turnuvasi]
on=@login
src.go 5458,1230,1
src.findid.i_explo_bandana.remove
src.findid.i_explo_bot.remove
src.findid.i_explo_robe.remove
src.findid.i_explo_eldiven.remove
src.findid.i_explo_boyunluk.remove
src.events -explo_turnuvasi
src.events -olme
//src.events +safe_alan
src.sysmessage @07a1,,1 Turnuvadan elendiniz.
return 1
on=@mount
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@atack
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@skillstart
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@skillabort
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@spellcast
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@itempickup_ground
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@unequip
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@targon_item
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@targon_char
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@pickup_pack
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
on=@click
message @07a1,,1 [Explosion Turnuvasi]
message <name>
return 1
on=@userwarmode
src.sysmessage @07a1,,1 Bu alanda bunu yapamazsiniz.
return 1
//-> Turnuvanın itemleri (Gm)
/-> Turnuvayı düzenleme deedi.
[itemdef i_explo_yapacagim]
id i_deed
defname i_explo_yapacagim
name Explosion Turnuvasi Duzenleme Deedi
on=@create
color 08a1
attr attr_newbie
return 1
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @08a1,,1 <name>
return 1
on=@dclick
src.dialog d_explo
src.sysmessage @07a1,,1 Herkese basarilar ...
remove
return 1
/-> Turnuvayı kazanan kişiyi eventten cıkar ve ödül alanına yolla.
[itemdef i_explo_kazanan]
defname i_explo_kazanan
id i_deed
name Turnuvada Kazanan Playeri Gonder
on=@create
color 080d
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @080d <name>
return 1
on=@dclick
target @07a1,,1 Turnuvayi kazanan kisiyi secin.
return 1
on=@targon_char
if (<link.tag.kazandi> == 1)
src.sysmessage @07a1,,1 Bir turnuvayi ayni anda iki kez kazanmis olamaz heralde:).
else
link <src.targ.uid>
link.go 5144,1878,1 // Burası Değişecek
link.events -explo_turnuvasi
link.events -olme
link.tag.explo_kazandi 1
link.findid.i_explo_bandana.remove
link.findid.i_explo_bot.remove
link.findid.i_explo_robe.remove
link.findid.i_explo_eldiven.remove
link.findid.i_explo_boyunluk.remove
endif
return 1
/-> Turnuvadan Player atıcı
[itemdef i_explo_at]
defname i_explo_at
id i_deed
name Turnuvadan Player At
on=@create
color 0820
attr attr_newbie
return 1
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @0820 <name>
return 1
on=@dclick
target @07a1,,1 Turnuvadan defetmek istediginiz kisiyi secin.
return 1
on=@targon_char
link <src.targ.uid>
link.go 5458,1230,3
link.events -explo_turnuvasi
link.events -olme
//link.events +safe_alan
link.findid.i_explo_bandana.remove
link.findid.i_explo_bot.remove
link.findid.i_explo_robe.remove
link.findid.i_explo_eldiven.remove
link.findid.i_explo_boyunluk.remove
link.sysmessage @07a1,,1 Turnuvadan atildiniz.
return 1
/-> Alan itemleri deedi
[itemdef i_explo_alan_itemleri]
defname i_explo_alan_itemleri
id i_deed
name Alan Itemleri
on=@create
color 0809
attr attr_newbie
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @0809 <name>
return 1
on=@dclick
src.newitem i_explo_kasasi
src.act.bounce
src.newitem i_explo_kasasi
src.act.bounce
src.newitem i_explo_kasasi
src.act.bounce
src.newitem i_explo_kasasi
src.act.bounce
src.sysmessage @07a1,,1 Birbirinden uzak yerlere koyulacak.
remove
return 1
//-> Turnuvanın itemleri (Alan)
/-> Pot kasası.
[itemdef i_explo_kasasi]
id i_chest_metal
name Potion Kasasi
defname i_explo_kasasi
type t_container
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
on=@dclick
if (<src.findid.i_pot_suresi>)
src.sysmessage @07a1,,1 Potion almak icin biraz beklemelisiniz.
else
src.newitem i_potion_explosiongreat
src.act.bounce
src.newitem i_pot_suresi
src.act.equip
endif
return 1
/-> Pot alabilme süresi
[itemdef i_pot_suresi]
id i_memory
type t_eq_script
name Potion suresi
on=@create
attr 010
timer 5
on=@timer
cont.sysmessage @07a1,,1 Artik potion kasasindan explosion potion alabilirsiniz.
remove
return 1
//-> Turnuvanın itemleri (Player)
/-> Bandana
[itemdef i_explo_bandana]
id i_bandana
name Explosion Bandana
defname i_explo_bandana
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
/-> Bot
[itemdef i_explo_bot]
id i_boots_calf
name Explosion Bot
defname i_explo_bot
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
/-> Robe
[itemdef i_explo_robe]
id i_robe
name Explosion Robe
defname i_explo_robe
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
/-> Eldiven
[itemdef i_explo_eldiven]
id i_leather_gloves
name Explosion Gloves
defname i_explo_eldiven
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
/-> Boyunluk
[itemdef i_explo_boyunluk]
id i_studded_gorget
name Explosion Gorget
defname i_explo_boyunluk
on=@create
color 0809
attr 010
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @38,,1 <name>
return 1
//-> Yapılacak anonsu, gate atma komutu ve gate
/-> Yapılacak anonsu
[function exployapilacak]
if (<account.plevel> > 2)
src.newitem i_explo_at
src.act.bounce
src.newitem i_explo_kazanan
src.act.bounce
src.newitem i_explo_alan_itemleri
src.act.bounce
src.invis
src.go 6032,2061,1 // Bunu Değiştirin.
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion turnuvasi katilimlari baslamistir.
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Safe Alan'a gate acilmistir.
endif
return 1
/-> Gate atma komutu
[function exploturnuvasi]
src.newitem i_explo_turnuvasi_gate
src.act.p 5451,1230,1 // Bunu Değiştirin. (Gatenin Açılacağı Yer)
return 1
/-> Gate
[itemdef i_explo_turnuvasi_gate]
defname i_explo_turnuvasi_gate
id i_moongate_blue
name Explosion Turnuvasi Gate
on=@create
timer 180
color 0809
on=@click
message @48,1,1,1 <serv.name> Turnuva Sistemi
message @07a1,,1 <name>
message @0799 (Gate : <timer> saniye sonra kapanacak)
return 1
on=@timer
remove
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion Turnuvasina katilimlar sona ermistir.
serv.allclients sysmessage @07a1,,1 [Turnuva Anons]: Explosion Turnuvasi baslamistir.
serv.allclients stone=0
return 1
on=@dclick
src.sysmessage @07a1,,1 Lutfen uzerinden geciniz.
return 1
on=@step
src.stone
dorand 10
src.go 6023,2017,1
src.go 6027,2065,1
src.go 6025,2054,1
src.go 6029,2057,1
src.go 6034,2060,1
src.go 6037,2069,1
src.go 6041,2056,1
src.go 6034,2056,1
src.go 6031,2060,1
src.go 6040,2060,1
enddo
src.binekle_girenler_explo
src.canta_kontrol_explo
src.events +explo_turnuvasi
src.events +olme
//src.events -safe_alan
src.newitem i_explo_bandana
src.act.equip
src.newitem i_explo_bot
src.act.equip
src.newitem i_explo_robe
src.act.equip
src.newitem i_explo_eldiven
src.act.equip
src.newitem i_explo_boyunluk
src.act.equip
//-> Turnuvanın kuralları
[dialog d_explokurallar]
130,170
nomove
resizepic 0 0 3000 540 280
resizepic 5 5 9300 530 270
button 10 250 55 56 1 0 1
text 140 10 38 0
text 138 25 2000 1
text 10 45 2937 2
text 10 65 2937 3
text 10 85 2937 4
text 10 105 2937 5
text 10 125 2937 6
text 10 145 2937 7
text 10 165 2937 8
text 10 185 2937 9
text 10 205 2937 10
text 10 225 2000 11
text 25 249 38 12
[dialog d_explokurallar text]
<serv.name> Pvp Turnuva Sistemi
Explosion Turnuvasi Kurallari
-Staff asla gereksiz sekilde playerla muhatab olamaz.
-Sistem neredeyse otomatik.
-Elemek istediginiz playeri direk olarak gondermeyin. Cikarici kullanin.
-Player gateden gectiginde yarismaya hazir vaziyette olacaktir (stoneli)
-Unutmaki burada amac playerlari eglendirmek once onlar eglenecek.
-Kesinlikle serveri ayaklar altina alacak rezillikler cikarma.
-Hata kabullenilebilir ama bilincli rezillik asla.
-Ve ben bunu direk olarak okudugunu varsaymayacagim. :) onlem onlemdir.
-Iyi ve cekismeli bir turnuva olmasi dilegiyle. Kolay gelsin herkese:)
Imza Reynald Outlias Pvp Shard Scripter&Owner...
Okudum. Kurallara sadik kalacagim.
[dialog d_explokurallar button]
onbutton=1
src.tag.kural 1
src.sysmessage @07a1,,1 Artik turnuvayi baslatabilirsiniz sayin <src.name> ! Basarilar.
src.dialog d_explo
return 1
//-> Turnuva Ana Menu
[dialog d_explo]
260,190
nomove
noclose
resizepic 0 0 3000 265 170
resizepic 5 5 9300 255 160
tilepic 205 125 3853
tilepic 205 105 3853
tilepic 205 85 3853
tilepic 185 85 3853
tilepic 165 85 3853
tilepic 145 85 3853
tilepic 125 85 3853
tilepic 105 85 3853
tilepic 85 85 3853
tilepic 65 85 3853
tilepic 45 85 3853
tilepic 25 85 3853
tilepic 25 105 3853
tilepic 25 125 3853
tilepic 45 125 3853
tilepic 65 125 3853
tilepic 85 125 3853
tilepic 105 125 3853
tilepic 125 125 3853
tilepic 145 125 3853
tilepic 165 125 3853
tilepic 185 125 3853
button 45 65 55 56 1 0 1
button 50 105 55 56 2 0 2
text 25 10 38 0
text 10 36 2000 1
text 60 64 38 2
text 65 104 1153 3
[dialog d_explo text]
<serv.name> Pvp Turnuva Sistemi
Turnuva Adi: Explosion Turnuvasi
Turnuva'nin Kurallari
Turnuva'yi Baslat!!!
[dialog d_explo button]
onbutton=1
if (<src.tag.kural> == 1)
src.sysmessage @07a1,,1 Bir kere okumaniz yeterlidir.
src.dialog d_explo
else
src.dialog d_explokurallar
src.sysmessage @07a1,,1 Kurallara uymaniz dilegiyle.
endif
return 1
onbutton=2
if (<src.tag.kural> == 0)
src.sysmessage @07a1,,1 Turnuvanin kurallarini okumadan turnuva baslatamazsiniz.
src.dialog d_explo
else
src.tag.kural 0
src.exployapilacak
src.exploturnuvasi
endif
return 1
[EOF]