UO-Dev Arama

 



İçerde : 1 misafir, 0 üye : --- Sayfalar: 1
Yazar

Pinke


UO-Dev Üyesi
Skill Title: Novice
Online durumu
Toplam Mesaj: 43
Oyun Tarzı: Rp
Emulatör: 0.56b
Tecrübe: Player
Yaş: 30
Mesaj #95551   30-04-2018 02:07 GMT    
        
elimde cok güzel bir zarbahis scpti var (4s3d3 Arkadaşımız paylaşmış) kullanmak isteyen arkadaşlarda alıp baka bilirlr tamamını atıcam scptin kesmicen işine yarıyan olur belki diye. şöyle bir sıkıntı var zar teklifi atıyorum hersey güzel bug falanda yok yanlız teklifde bekleyince kendinden iptal etmesini bekliyorum ediyor ama ikinci teklifi atınca kişi şuanda bir teklif alıyor diyor nerde hata ola bilir

Kod:
[ITEMDEF 0fa7]
DEFNAME=i_bahis_zar
NAME Zar
WEIGHT=1
SUBSECTION=Barkeep
DESCRIPTION=Dice and Cup

ON=@Create
Attr Attr_Move_Never|Attr_Decay
Color 0

On=@Click
If (<TagCount> < 1)
Message @07e5,1,1 [<Serv.Name>]
Message @07a1,1,1 Bahis Zar
Return 1
Endif
Message @68,,1 [Bahis : <BolukAyir <dTag0.BahisMiktari>>]
Message @68,,1 [<Uid.<Tag0.KullananKisi>.Name> vs <Uid.<Tag0.RakipKisi>.Name>]
Return 1

ON=@DClick
If (<Distance> > 3)
Src.Sysmessage @38,,1 Hata; Cok uzaktadasiniz
Return 1
Endif
IF (<Tag0.KullananKisi>) && (<Tag0.RakipKisi>) && (<Src.Uid> == <Uid.<Tag0.KullananKisi>>) || (<Src.Uid> == <Uid.<Tag0.RakipKisi>>)
IF (<Tag0.ZarAtti_<Src.Uid>>)
Src.Sysmessage @38,,1 Hata; Zar attiniz siranizi beklemelisiniz !
Return 1
Endif
Local.IlkZar <Eval (Rand(6) +1)>
Local.IkinciZar <Eval (Rand(6) +1)>
Src.Say @68,,1 [<dLocal.IlkZar>,<dLocal.IkinciZar>]
Src.Say @68,,1 Toplam : <Eval <dLocal.IlkZar>+<dLocal.IkinciZar>>
Tag.ZarAtti_<Src.Uid> <Eval <dLocal.IlkZar>+<dLocal.IkinciZar>>
ZarKontrol
TimerF Clear
If (<TagCount> > 0)
GeriSay <Eval <Def.ZarAtmakIcinSure>>
Return 1
Endif
Return 1
Endif
If (<Tag0.Kullanimda>)
Src.Sysmessage @38,,1 Hata; Bu zar Su anda <Uid.<Tag0.Kullanankisi>.Name> tarafindan kullaniliyor.
Return 1
Endif
Color 6028
Tag0.Kullanimda 1
Tag0.KullananKisi <Src.Uid>
Dialog ZarBahis
Timer 20
Tag.TeklifSuresi 1
Return 1
Endif

On=@TargON_Item
Src.Sysmessage @38,,1 Hata; Sadece oyunculari secebilirsiniz.
ZariSifirla
Return 1

On=@TargON_Ground
Src.Sysmessage @38,,1 Hata; Sadece oyunculari secebilirsiniz.
ZariSifirla
Return 1

On=@TargON_Char
If !(<Tag0.KullananKisi> == <Src.Uid>)
Src.Sysmessage @38,,1 Hata; Kisi seciminiz zaman asimina Ugradi !
Return 1
Endif
If (<Argo.Distance> > 3)
Src.Sysmessage @38,,1 Hata; Teklif gondereceginiz kisiye yakin olmalisiniz.
ZariSifirla
Return 1
Endif
If (<Argo.Distance <UID>> > 5i
Src.Sysmessage @38,,1 Hata; Teklif gondereceniniz kisi zara yakin olmalidir.
ZariSifirla
Return 1
Endif
If !(<Argo.Isplayer>)
Src.Sysmessage @38,,1 Hata; Sadece oyunculari secebilirsiniz.
ZariSifirla
Return 1
Endif
If (<Argo.Uid> == <Src.Uid>)
Src.Sysmessage @38,,1 Hata; Kendinizi secemezsiniz.
ZariSifirla
Return 1
Endif
If (<Argo.IsDialogOpen ZarTeklif>)
Src.Sysmessage @38,,1 Hata; Sectiginiz kisi zaten bir zar teklifi aliyor.
ZariSifirla
Return 1
Endif
If (<Argo.Tag0.ZarAtiyor>) || (<Argo.IsDialogOpen ZarBahis>)
Src.Sysmessage @38,,1 Hata; Sectiginiz kisi zaten bir oyunda.
ZariSifirla
Return 1
Endif
If (<Argo.Gold> < <Tag0.BahisMiktari>)
Src.Sysmessage @38,,1 Hata; Sectiginiz kiside yeteri miktarda para bulunmuyor.
ZariSifirla
Return 1
Endif

Src.Tag.ZarAtiyor 1
Src.Gold= <Eval <Src.Gold>-<dTag0.BahisMiktari>>
TrySrc <Argo> Dialog ZarTeklif
Tag.TeklifSuresi
Tag.TeklifIletildi <Argo.Uid>
Timer 15 // Teklif Cevap Bekleme Suresi
Src.Sysmessage @68,6,1 Teklifiniz iletilmistir.
Return 1

On=@TargON_Cancel
Src.Sysmessage @38,,1 Hata; Secim yapmadiginiz icin iptal edildi.
ZariSifirla
Return 1

On=@Timer
If (<Tag0.TeklifSuresi>) || (<Tag0.TeklifIletildi>)
TrySrc <Uid.<Tag0.KullananKisi>> DialogClose ZarBahis
If (<Tag0.TeklifIletildi>)
TrySrc <Uid.<Tag0.TeklifIletildi>> DialogClose ZarTeklif
TrySrc <Uid.<Tag0.KullananKisi>> Src.Tag.ZarAtiyor
Uid.<Tag0.TeklifIletildi>.Sysmessage @38,,1 Hata; Teklife cevap vermediginiz icin iptal olmustur.
Endif
Uid.<Tag0.KullananKisi>.Sysmessage @38,,1 Hata; Bahis isleminiz zaman asimina ugramistir.
ZariSifirla
Return 1
Endif
If (<Tag0.ZarBasladi>)
If !(<Tag0.ZarAtti_<Uid.<Tag.KullananKisi>>>) && !(<Tag0.ZarAtti_<Uid.<Tag.RakipKisi>>>)
Uid.<Tag0.KullananKisi>.Sysmessage @38,,1 Hata; iki tarafta zar atmadigi icin iptal edildi.
Uid.<Tag0.RakipKisi>.Sysmessage  @38,,1 Hata; iki tarafta zar atmadigi icin iptal edildi.
If (<Def.BahisKesintiVar>)
Uid.<Tag.KullananKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>>>
Uid.<Tag.RakipKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>>>
Else
Uid.<Tag.KullananKisi>.Gold += <Eval <dTag0.BahisMiktari>>
Uid.<Tag.RakipKisi>.Gold += <Eval <dTag0.BahisMiktari>>
Endif
Message @38,,1 Zar iptal
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
ZariSifirla
Return 1
Endif
If (<Tag0.ZarAtti_<Uid.<Tag.KullananKisi>>>) && !(<Tag0.ZarAtti_<Uid.<Tag.RakipKisi>>>)
Message @68,6,1 Kazanan : <Uid.<Tag.KullananKisi>.Name>
Uid.<Tag0.RakipKisi>.Sysmessage @38,,1 Hata; Verilen surede zar atmadiginiz icin maglup sayildiniz !
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
Uid.<Tag0.KullananKisi>.Sysmessage @68,6,1 Tebrikler! Rakibiniz zar atmadigi icin galip sayildiniz.
Uid.<Tag0.KullananKisi>.Sysmessage @68,6,1 Kazanilan tutar <Eval <dTag0.BahisMiktari>*2>
If (<Def.BahisKesintiVar>)
Uid.<Tag.KullananKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>*2>>
Else
Uid.<Tag.KullananKisi>.Gold += <Eval <dTag0.BahisMiktari>*2>
Endif
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
ZariSifirla
Return 1
Endif
If !(<Tag0.ZarAtti_<Uid.<Tag.KullananKisi>>>) && (<Tag0.ZarAtti_<Uid.<Tag.RakipKisi>>>)
Message @68,6,1 Kazanan : <Uid.<Tag.RakipKisi>.Name>
Uid.<Tag0.KullananKisi>.Sysmessage @38,,1 Verilen surede zar atmadiginiz icin maglup sayildiniz.
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
Uid.<Tag0.RakipKisi>.Sysmessage @68,6,1 Tebrikler! Rakibiniz zar atmadigi icin galip sayildiniz.
Uid.<Tag0.RakipKisi>.Sysmessage @68,6,1 Kazanilan tutar <Eval <dTag0.BahisMiktari>*2>
If (<Def.BahisKesintiVar>)
Uid.<Tag.RakipKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>*2>>
Else
Uid.<Tag.RakipKisi>.Gold += <Eval <dTag0.BahisMiktari>*2>
Endif
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
ZariSifirla
Return 1
Endif
Return 1

[Function TeklifIptal]
Src.DialogClose ZarTeklif

[Function ZarKontrol]
IF (<Tag0.ZarAtti_<Uid.<Tag.KullananKisi>>>) && (<Tag0.ZarAtti_<Uid.<Tag.RakipKisi>>>)
IF (<dTag.ZarAtti_<Uid.<Tag.KullananKisi>>> == <dTag.ZarAtti_<Uid.<Tag.RakipKisi>>>)
Message @68,6,1 (<dTag.ZarAtti_<Uid.<Tag.KullananKisi>>>,<dTag.ZarAtti_<Uid.<Tag.RakipKisi>>>) Berabere!
Tag.Zaratti_<Uid.<Tag.KullananKisi>>
Tag.Zaratti_<Uid.<Tag.RakipKisi>>
Return 1
Endif
IF (<dTag.Zaratti_<Uid.<Tag.KullananKisi>>> < <dTag.Zaratti_<Uid.<Tag.RakipKisi>>>)
Message @68,6,1 Kazanan : <Uid.<Tag.RakipKisi>.Name>
If (<Def.BahisKesintiVar>)
Uid.<Tag.RakipKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>*2>>
Else
Uid.<Tag.RakipKisi>.Gold += <Eval <dTag0.BahisMiktari>*2>
Endif
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
ZariSifirla
Else
Message @68,6,1 Kazanan : <Uid.<Tag.KullananKisi>.Name>
If (<Def.BahisKesintiVar>)
Uid.<Tag.KullananKisi>.Gold += <KesintiYap <Eval <dTag0.BahisMiktari>*2>>
Else
Uid.<Tag.KullananKisi>.Gold += <Eval <dTag0.BahisMiktari>*2>
Endif
Uid.<Tag.KullananKisi>.Tag.ZarAtiyor
Uid.<Tag.RakipKisi>.Tag.ZarAtiyor
ZariSifirla
Return 1
Endif
Endif

[Function KesintiYap]
Local.AnaPara <Args>
Local.Kesinti1 <Eval <dLocal.AnaPara>*<Def.BahisKesintiYuzdesi>>
Local.Kesinti2 <Eval <dLocal.Kesinti1>/100>
Local.Kesinti3 <Eval <dLocal.AnaPara> - <dLocal.Kesinti2>>
Return <dLocal.Kesinti3>

[Function Gerisay]
TimerF Clear
Local.GeriSay <Args>
Timer <dLocal.GeriSay>
For 0 <Eval <dLocal.GeriSay> -1>
TimerF <dLocal._For>, Message @38,,1 <Eval <dLocal.GeriSay> - <dLocal._For>>
EndFor

[Function ZariSifirla]
Color 0
ClearTags
Timer -1

[Dialog ZarBahis]
300,150
Resizepic 3 0 83 233 <QVal <Def.BahisKesintiVar>?160:140>
Resizepic 10 10 3600 220 <QVal <Def.BahisKesintiVar>?140:120>
Checkertrans 10 10 220 <QVal <Def.BahisKesintiVar>?140:120>
If (<Def.BahisKesintiVar>)
DText 35 120 38 Bahisten yapilan kesinti % <Eval <Def.BahisKesintiYuzdesi>>
Endif
DText 100 20 1152 Bahis Sistemi
DText 20 50 38 Bahis Tutari :
Resizepic 120 50 9300 100 20
//DTextentry 125 50 80 20 1152 1 <Args>   /// 2x Clientler için
DTextentrylimited 125 50 135 25 1152 1 7 <Args>  /// 4x ve üzeri clientler için
DText 120 90 1152 Onaylyyorum
Button 80 90 4024 4025 1 0 1

[Dialog Zarbahis Button]
On=0
Src.Sysmessage @38,,1 Hata; Bahis ekranini Kapatiniz !
ZariSifirla

On=1
If !(<IsNum <ArgTxt[1]>>)
Src.Sysmessage @38,,1 Hata; Bir rakam girisi yapmalisiniz.
ZariSifirla
Return 1
Endif
If (StrMatch('<StrSub 0 1 <ArgTxt[1]>>','0'))
Src.Sysmessage @38,,1 Hata; ilk rakam "0" olamaz.
ZariSifirla
Return 1
Endif
If (<ArgTxt[1]> > <Eval <Def.EnFazlaZarBahsi>>) || (<ArgTxt[1]> < <Eval <Def.EnAzZarBahsi>>)
Src.Sysmessage @38,,1 Hata; Girmis oldugunuz rakam 5m'den buyuk 10k'dan kucuk olamaz.
ZariSifirla
Return 1
Endif
IF (<Src.Gold> < <ArgTxt[1]>)
Src.Sysmessage @38,,1 Hata; Hesabiniz'da <BolukAyir <ArgTxt[1]>> altin bulunmuyor.
ZariSifirla
Return 1
Endif
Tag.BahisMiktari <ArgTxt[1]>
Target @68,,1 Hata; Lutfen meydan okuyacaginiz kisiyi secin.

[Dialog ZarTeklif]
250,150
Resizepic 0 0 83 300 160
Resizepic 7 10 9300 287 140
Checkertrans 7 10 287 140
Resizepic 45 20 3000 215 80
DHtmlGump 50 20 210 70 0 0 <def.bfont_green><UID.<Tag0.KullananKisi>.Name> <def.bfont_black>size <def.bfont_green><BolukAyir <DTag0.Bahismiktari>> <def.bfont_black>altin tutarinda zar atmayi teklif ediyor, kabul ediyor musunuz ?
Button 175 110 4018 4019 1 0 0
Dtext 220 110 1152 Reddet
Button 45 110 4024 4025 1 0 1
Dtext 90 110 1152 Kabul Et

[Dialog ZarTeklif Button]

On=0
UID.<DTag0.KullananKisi>.Gold +=<DTag0.Bahismiktari>
UID.<DTag0.KullananKisi>.Sysmessage @38,,1 Hata; <Src.Name> isimli kisi teklifinizi reddetti.
UID.<DTag0.KullananKisi>.Tag.ZarAtiyor
Src.Sysmessage @38,,1 Yapilan teklifi reddettiniz.
ZariSifirla

On=1
If (<Src.Gold> < <dTag0.BahisMiktari>)
Src.Sysmessage @38,,1 Hata; Hesabinizda <BolukAyir <dTag0.BahisMiktari>> altin bulunmuyor.
ZariSifirla
Return 1
Endif
Src.Tag.ZarAtiyor 1
Src.Gold= <Eval <Src.Gold>-<dTag0.BahisMiktari>>
Tag.TeklifIletildi
Tag.ZarBasladi 1
Ref1=<UID.<Dtag0.KullananKisi>>
Tag.Rakipkisi <Src.Uid>
Src.Sysmessage @07a1,,1 Teklifi kabul ettiniz.
Ref1.Sysmessage @68,6,1 <Src.Name> teklifinizi kabul etti, zar atmak icin sureniz baslamistir.
Message @68,6,1 Sure Basladi!
GeriSay 20

////////////////////////////////////////////// ALINTI ////////////////////////////////////////////////

[FUNCTION BolukAyir]
IF (<EVAL STRLEN(<ARGS>)> > 3)
   LOCAL.STRLEN=<EVAL STRLEN(<ARGS>)>
   LOCAL.CURRENTDIGIT=<EVAL STRLEN(<ARGS>)>
   WHILE (<LOCAL.CURRENTDIGIT> > 3)
      ARGS=<STRSUB 0 <EVAL (<LOCAL.CURRENTDIGIT> - 3)> <ARGS>>.<STRSUB <EVAL (<LOCAL.CURRENTDIGIT> - 3)> 50 <ARGS>>
      LOCAL.CURRENTDIGIT -= 3
   ENDWHILE
ENDIF
RETURN <ARGS>


Son güncelleme: Pinke tarafından 30-04-2018 02:32 GMT, 148 Gün önce düzenlendi.



Yazar

azmanomer


UO-Dev Üyesi
Skill Title: Apprentice
Online durumu
Toplam Mesaj: 56
Oyun Tarzı: Rp
Emulatör: 0.56b
Tecrübe: Scripter
Yaş: 28
Mesaj #95552   30-04-2018 05:06 GMT    
        
Kod:
On=@Timer
ref1 = <Tag0.TeklifIletildi>
If (<Tag0.TeklifSuresi>) || (<Tag0.TeklifIletildi>)
TrySrc <Uid.<Tag0.KullananKisi>> DialogClose ZarBahis
If (<Tag0.TeklifIletildi>)
ref1.DialogClose ZarTeklif //veya ref1.closealldialogs
TrySrc <Uid.<Tag0.KullananKisi>> Src.Tag.ZarAtiyor
ref1.Sysmessage @38,,1 Hata; Teklife cevap vermediginiz icin iptal olmustur.
Endif

muhtemelen dialogclose çalışmıyo



Sayfalar: 1



Benzer Konular

KonularMesajlarSon gönderenTarih
Staff title yardım3nefrelius15-06-2018
Npc Bow yardım6mahsuni21-06-2018
Stable sistemi yardım9MirroR27-04-2018
Script yardım yarışma3TheRaskol06-02-2018
Script Yardım9Volkyn19-01-2018


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,