Gillet - 20-04-2010 17:07 GMT -
arkadaşlar ben bunu
i_gold değilde i_bilet yapmak istiyorum ama bir türlü yapamadim yardimci olucak varmi michaelin scripti
Kod:
[DIALOG d_banka_hesap_al]
0,0
PAGE 0
resizepic 0 0 5120 381 180
resizepic 12 12 3000 360 157
dtext 20 20 1153 Sayın <src.name>,
dtext 20 40 1153 Sizin bir banka hesabınız bulunmamaktadır.
dtext 20 70 07d4 15.000 gp altın karşılığında,
dtext 20 90 07d4 bir banka hesabı edinebilirsiniz.
dtext 55 130 0455 Banka hesabı satın al.
button 20 130 4005 4006 1 0 1
[DIALOG d_banka_hesap_al button]
on 1
if (<gold> >= 15000)
src.gold -= 15000
src.tag.bhesabi 1
src.tag.bhparam 0
src.sys_trk Tebrikler, banka hesabınız aktif hale gelmiştir.
else
src.sysh_trk Banka hesabı satın alabilmek için, 15.000 gp altınınız bulunmamaktadır.
endif
[DIALOG d_banka_hesap]
0,0
PAGE 0
resizepic 0 0 5120 381 300
resizepic 12 12 3000 360 277
dtext 20 20 1153 Sayın <src.name>,
dtext 20 40 1153 Banka işlemlerinizi buradan yapabilirsiniz.
dtext 20 70 07d4 Banka hesabınızdaki altın miktarı: <dsrc.tag0.bhparam>
dtext 20 90 07d4 Banka hesap numaranız: <src.uid>
dtext 55 130 0455 Banka hesabıma altın yatır.
dtext 55 160 0455 Banka hesabımdan altın çek.
dtext 55 190 0455 Çek yaz.
dtext 55 220 0455 Çek bozdur.
dtext 55 250 0455 Havale yap.
button 20 130 4005 4006 1 0 1
button 20 160 4005 4006 1 0 2
button 20 190 4005 4006 1 0 3
button 20 220 4005 4006 1 0 4
button 20 250 4005 4006 1 0 5
[DIALOG d_banka_hesap button]
on 1
src.sdialog d_banka_hesap_altinyatir
return 1
on 2
src.sdialog d_banka_hesap_altincek
return 1
on 3
src.sdialog d_banka_hesap_cekyaz
return 1
on 4
targetf f_cek_bozdur
src.sys_trk Lütfen bozdurmak istediğiniz çeki seçiniz.
return 1
on 5
src.sdialog d_banka_hesap_havale
return 1
[DIALOG d_banka_hesap_altinyatir]
0,0
resizepic 0 0 5120 371 160
resizepic 12 12 3000 350 137
dtext 20 20 1153 Lütfen bir miktar giriniz;
resizepic 140 54 3000 140 25
dtextentry 142 58 135 35 07d4 1
dtext 20 60 0455 Banka hesabıma, gp altın,
dtext 20 80 0455 yatırmak istiyorum.
dtext 55 111 0455 İşlemi tamamla.
dtext 235 111 0455 İşlemi iptal et.
button 20 110 4029 4030 1 0 1
button 200 109 4017 4018 1 0 2
[DIALOG d_banka_hesap_altinyatir button]
on 1
if (strmatch('<argtxt[1]>',''))
src.sysh_trk Bir miktar girmelisiniz.
return 1
elseif ((strlen(<argtxt[1]>)) > 7)
src.sysh_trk Bir seferde en fazla 7 haneli miktar girebilirsiniz.
return 1
elseif (<IsNum <ARGTXT[1]>>==0)
src.sysh_trk Sadece rakam girebilirsiniz.
return 1
elseif (<gold> < <ARGTXT[1]>)
src.sysh_trk <ARGTXT[1]> gp kadar altınınız bulunmamaktadır.
return 1
endif
src.tag.bhparam += <ARGTXT[1]>
src.gold -= <ARGTXT[1]>
src.sys_trk Banka hesabınıza <ARGTXT[1]> gp altın yatırılmıştır.
return 1
on 2
src.sys_trk İşlemi iptal ettiniz.
return 1
[DIALOG d_banka_hesap_altincek]
0,0
resizepic 0 0 5120 371 160
resizepic 12 12 3000 350 137
dtext 20 20 1153 Lütfen bir miktar giriniz;
resizepic 150 54 3000 140 25
dtextentry 152 58 135 35 07d4 1 <dsrc.tag0.bhparam>
dtext 20 60 0455 Banka hesabımdan gp altın,
dtext 20 80 0455 çekmek istiyorum.
dtext 55 111 0455 İşlemi tamamla.
dtext 235 111 0455 İşlemi iptal et.
button 20 110 4029 4030 1 0 1
button 200 109 4017 4018 1 0 2
[DIALOG d_banka_hesap_altincek button]
on 1
if (strmatch('<argtxt[1]>',''))
src.sysh_trk Bir miktar girmelisiniz.
return 1
elseif ((strlen(<argtxt[1]>)) > 7)
src.sysh_trk Bir seferde en fazla 7 haneli miktar girebilirsiniz.
return 1
elseif (<IsNum <ARGTXT[1]>>==0)
src.sysh_trk Sadece rakam girebilirsiniz.
return 1
elseif (<src.tag.bhparam> < <ARGTXT[1]>)
src.sysh_trk Banka hesabınızda <ARGTXT[1]> gp kadar altınınız bulunmamaktadır.
return 1
endif
src.tag.bhparam -= <ARGTXT[1]>
src.paraver <ARGTXT[1]>
src.sys_trk <ARGTXT[1]> gp kadar altın bankanıza konulmuştur.
return 1
on 2
src.sys_trk İşlemi iptal ettiniz.
return 1
[DIALOG d_banka_hesap_cekyaz]
0,0
resizepic 0 0 5120 371 160
resizepic 12 12 3000 350 137
dtext 20 20 1153 Lütfen bir miktar giriniz;
resizepic 20 54 3000 140 25
dtextentry 22 58 135 35 07d4 1
dtext 170 60 0455 gp miktarın da,
dtext 170 80 0455 çek yazmak istiyorum.
dtext 55 111 0455 İşlemi tamamla.
dtext 235 111 0455 İşlemi iptal et.
button 20 110 4029 4030 1 0 1
button 200 109 4017 4018 1 0 2
[DIALOG d_banka_hesap_cekyaz button]
on 1
if (strmatch('<argtxt[1]>',''))
src.sysh_trk Bir miktar girmelisiniz.
return 1
elseif ((strlen(<argtxt[1]>)) > 7)
src.sysh_trk Bir seferde en fazla 7 haneli miktar girebilirsiniz.
return 1
elseif (<IsNum <ARGTXT[1]>>==0)
src.sysh_trk Sadece rakam girebilirsiniz.
return 1
elseif (<src.tag.bhparam> < <ARGTXT[1]>)
src.sysh_trk Banka hesabınızda <ARGTXT[1]> gp kadar altınınız bulunmamaktadır.
return 1
endif
src.tag.bhparam -= <ARGTXT[1]>
serv.newitem i_cek_makbuzu
new.more <ARGTXT[1]>
new.more2 <src.uid>
new.bounce
src.sys_trk <ARGTXT[1]> gp miktarında çek çantanızdadır.
return 1
on 2
src.sys_trk İşlemi iptal ettiniz.
return 1
[DIALOG d_banka_hesap_havale]
0,0
PAGE 0
resizepic 0 0 5120 501 220
resizepic 12 12 3000 480 197
dtext 20 20 1153 Sayın <src.name>,
dtext 20 40 1153 Lütfen boşlukları doldurunuz.
dtext 20 65 07d4 Banka hesabınızdaki altın miktarı: <dsrc.tag0.bhparam>
resizepic 20 94 3000 140 25
dtextentry 22 98 135 35 07d4 1
resizepic 20 134 3000 140 25
dtextentry 22 138 135 35 07d4 2
dtext 170 99 0455 banka hesap numaralı kişiye,
dtext 170 139 0455 gp altın havale etmek istiyorum.
dtext 55 180 0455 İşlemi tamamla.
dtext 235 180 0455 İşlemi iptal et.
button 20 179 4029 4030 1 0 1
button 200 179 4017 4018 1 0 2
[dialog d_banka_hesap_havale button]
on 1
if (strmatch('<argtxt[1]>',''))
src.sysh_trk Parayı yollayacağınız kişinin banka hesap numarasını girmelisiniz.
return 1
elseif (strmatch('<argtxt[2]>',''))
src.sysh_trk Havale etmek istediğiniz gp değerini girmelisiniz.
return 1
elseif ((strlen(<argtxt[1]>)) > 12) || ((strlen(<argtxt[1]>)) < 4)
src.sysh_trk Kişinin banka hesap numarası en az 4, en fazla 12 haneli olabilir.
return 1
elseif ((strlen(<argtxt[2]>)) > 7) || ((strlen(<argtxt[2]>)) < 5)
src.sysh_trk Havale etmek istediğiniz gp değeri, en az 5, en fazla 7 haneli olabilir.
return 1
elseif (<IsNum <ARGTXT[2]>>==0)
src.sysh_trk Havale etmek istediğiniz gp değerine, sadece rakam girmelisiniz.
return 1
elseif (<uid.<ARGTXT[1]>> == 00) || !(<uid.<ARGTXT[1]>.isplayer>)
src.sysh_trk Böyle bir banka hesabı bulunamadı.
return 1
elseif (<ARGTXT[1]> == <src.uid>)
src.sysh_trk Kendi kendinize altın havale edemezsiniz.
return 1
elseif !(<uid.<ARGTXT[1]>.tag0.bhesabi>)
src.sysh_trk Böyle bir banka hesabı bulunamadı.
return 1
endif
src.ctag.bhesapno <argtxt[1]>
src.ctag.bhaltin <dargtxt[2]>
src.dialogclose d_bhhavale_sor
src.dialog d_bhhavale_sor
return 1
on 2
src.sys_trk İşlemi iptal ettiniz.
return 1
[dialog d_bhhavale_sor]
200,180
resizepic 0 0 5120 271 210
resizepic 12 12 3000 250 187
obj <src.ctag.bhesapno>
dtext 20 20 1153 Sayın <src.name>,
dtext 20 50 1153 <obj.name> isimli kişiye,
dtext 20 70 1153 <dsrc.ctag.bhaltin> gp altın göndermek,
dtext 20 90 1153 istiyormusunuz ?
dtext 20 170 025 Havale ücreti: 5.000 gp
dtext 55 130 0455 Evet
dtext 155 130 0455 Hayır
button 20 129 4029 4030 1 0 1
button 120 129 4017 4018 1 0 0
[dialog d_bhhavale_sor button]
on 1
obj <src.ctag.bhesapno>
if (<dsrc.tag0.bhparam> < <eval <dsrc.ctag.bhaltin>+5000>)
src.sysh_trk Banka hesabınızda <eval <dsrc.ctag.bhaltin>+5000> gp altin bulunmamaktadır.(5 k havale parasıdır)
return 1
endif
src.tag.bhparam -= <eval <dsrc.ctag.bhaltin>+5000>
src.sys_trk <obj.name> isimli kişiye, <dsrc.ctag.bhaltin> gp altın havale edilmiştir.
obj.tag.bhparam += <dsrc.ctag.bhaltin>
if (<obj.isonline>)
obj.sys_trk <src.name> isimli kişi, banka hesabınıza <dsrc.ctag.bhaltin> gp altın havale etmiştir.
else
obj.notice <src.name> isimli kişi, banka hesabınıza <dsrc.ctag.bhaltin> gp altın havale etmiştir.
endif
on 2
src.sysh_trk İşlemi iptal ettiniz.
return 1
[FUNCTION f_cek_bozdur]
obj <argo>
if !(<obj.baseid> == i_cek_makbuzu)
src.sysh_trk Bu bir çek değil.
return 1
elseif !(<obj.topobj.uid> == <src.uid>)
src.sysh_trk Bozdurmak istediğiniz çek, çantanızda veya bankanızda olmalıdır.
return 1
elseif !(<obj.more>)
src.sysh_trk Bu çekin bir miktarı yok.
obj.remove
return 1
endif
src.tag.bhparam += <obj.more>
src.sys_trk <uid.<obj.more2>.name> isimli kişinin, çekini bozdurdunuz. <obj.more> gp banka hesabınıza yatırılmıştır.
obj.remove
return 1
[itemdef i_cek_makbuzu]
id i_deed
type t_script
weight 0.1
name Check
On=@Create
color 0515
attr 04
On=@Click
message @033,,1 Çek karşılığı: <more>
message @1173,,1 [<uid.<more2>.name>]
return 1
On=@DClick
src.sysh_trk Çekleri bozdurabilmek için banka hesap sistemini kullanmalısınız.
return 1
[FUNCTION paraver]
IF (<ARGS> > 0)
serv.newitem i_gold
IF (<ARGS> > 65000)
new.amount=65000
new.cont <src.findlayer.29.uid>
paraver <eval <ARGS>-<NEW.AMOUNT>>
ELSE
new.amount=<ARGS>
new.cont <src.findlayer.29.uid>
ENDIF
ENDIF
[EOF]
arkadaşlar ben bunu
i_gold değilde i_bilet yapmak istiyorum ama bir türlü yapamadim yardimci olucak varmi michaelin scripti
aldarson - 20-04-2010 17:39 GMT -
Emin misin uğraştığına ?
Emin misin uğraştığına ?
uzana - 22-04-2010 14:45 GMT -
Gold yerlerine bilet yap olur herhalde
Gold yerlerine bilet yap olur herhalde