[PLEVEL 2]
s
[FUNCTION s]
if (<ISEMPTY <ARGS>>)
sysmessage @084d Staff :: Membros Online
serv.allclients sl_resposta
else
serv.allclients staffconversa Staff :: <name> :: <args>
endif
[FUNCTION staffconversa]
IF (<ACCOUNT.PLEVEL> > 1)
SYSMESSAGE @084d <ARGS>
ENDIF
///////////////////////
[EVENTS e_staff]
ON=@LOGIN
serv.allclients staffonline
stafflog <NAME> (<UID>) logged in at <REGION.NAME>
ON=@LOGOUT
serv.allclients staffoffline
stafflog <NAME> (<UID>) logged out at <REGION.NAME>
ON=@Hunger
return 1
ON=@ClientToolTip
IF (<FLAGS>&statf_invul)
SRC.ADDCLILOC 3000509
ENDIF
IF (<FLAGS>&statf_insubstantial)
SRC.ADDCLILOC 3005124
ENDIF
ON=@ItemCreate
stafflog <NAME> (<UID>) created <ARGO.NAME> (<ARGO.UID>)
ON=@ItemPickUp_Pack
stafflog <name> (<uid>) grabs <act.amount> <act.name> (<ACT>) from <act.cont.name> (<act.cont>) [POS:<p>]
ON=@ITEMDROPON_GROUND
stafflog <name> (<uid>) throws <act.amount> <act.name> (<ACT>) on the FLOOR [POS:<p>]
ON=@ITEMDROPON_ITEM
stafflog <name> (<uid>) stores <act.amount> <act.name> (<ACT>) in <argo.name> (<argo.uid>) [POS:<p>]
///////////////////////
[FUNCTION staffonline]
IF (<ACCOUNT.PLEVEL> > 1)
SYSMESSAGE @084d Staff :: <src.name> logged in at <src.region.name> (<src.mapname>)
ENDIF
[FUNCTION staffoffline]
IF (<ACCOUNT.PLEVEL> > 1)
SYSMESSAGE @084d Staff :: <src.name> logged out at <src.region.name> (<src.mapname>)
ENDIF
///////////////////////
[function sl_resposta]
if (<isgm>)
src.sysmessage @084d <name> logged in <region.name> (<mapname>)
endif
[function stafflog]
WRITEFILE Stafflogs\<TAG0.GMNAME>_<serv.rtime.format %d><serv.rtime.format %m><serv.rtime.format %Y>.txt <RTIME.HOUR>:<RTIME.MINUTE>:<RTIME.SECOND> : <ARGS><DEF.BR>
[EOF]
