Neden Çalışmıyor ? MySql - UO-Developer.COM

Neden Çalışmıyor ? MySql

Serkan_Acar

Novice UO-Dev Üyesi

Skill Title: Novice

Toplam Mesaj: 64

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Excelsior

Beğeni: 2 / 0

MySql kullanmıyorum çalışmamasının sebebi MySqlleden mi ? bunu kullanamam mı

[CHARDEF c_h_genel_vendor]			

Defname c_h_genel_vendor

Name #NAMES_HUMANMALE the Genel Tuccar

Id c_man

DESIRES=i_gold

CAN=mt_nonmover|mt_usehands|mt_equip



ON=@Create

invul=1

EVENTS +E_GENEL_VENDOR

THISVENDORS 2

STR=100

DEX=100

INT=100

ALLSKILLS=100.0

STEALTH=0

HIDING=0





[CHARDEF c_h_genel_vendor_f]

Defname c_h_genel_vendor_f

Name #NAMES_HUMANFEMALE the Genel Tuccar

Id c_WOMAN

DESIRES=i_gold

CAN=mt_nonmover|mt_usehands|mt_equip



ON=@Create

invul=1

EVENTS +E_GENEL_VENDOR

THISVENDORS 2

STR=100

DEX=100

INT=100

ALLSKILLS=100.0

STEALTH=0

HIDING=0





[EVENTS E_GENEL_VENDOR]

on=@dclick

IF (<SRC.ISUZAK <UID>>)

SRC.SYS_KIRMIZI Tüccara yetişemiyorsun.

RETURN 1S

ENDIF

SRC.CTAG0.VEND_GENERAL=<UID>

SRC.CTAG0.VEND_INDEX=0

SRC.CTAG0.VEND_ORDER="`date` DESC"

SRC.CTAG0.VEND_WHERE=

SRC.F_DIALOG D_VEND_MAIN_GENERAL

FACE <SRC>

RETURN 1



on=@click

msg_kirmizi (Genel Tüccar)







[dialog d_vend_main_general]

<DEF.DIALOGSTARTPOSITION>



MAIN 0,0,770,550,Genel Tüccar



DHTMLGUMP 50 50 220 25 1 0 <DEF.CENTER>EŞYA

DHTMLGUMP 280 50 150 25 1 0 <DEF.CENTER>FİYATI

DHTMLGUMP 440 50 150 25 1 0 <DEF.CENTER>EKLEME TARİHİ



//orta kısım

DORIGIN 20 80

OPAC 50,80,540,280



DILERI 80,400,100003

DGERI 50,400,100004





DB.CONNECT

IF (<DB.CONNECTED>)



IF (strmatch(*where*,'<src.ctag0.vend_where>'))

db.query "SELECT id,`uid`, `name`,`value`,`date` FROM vend_market <src.ctag0.vend_where> ORDER BY <src.ctag0.vend_order> LIMIT <src.dctag0.vend_index>,13";

ELSE

db.query "SELECT id,`uid`, `name`,`value`,`date` FROM vend_market ORDER BY <src.ctag0.vend_order> LIMIT <src.dctag0.vend_index>,13";

ENDIF



while <db.row.<dlocal._while>.id>



REF1=<db.row.<dlocal._while>.uid>

LOCAL.NAME <croptext 30 <db.row.<dlocal._while>.name>>



BUTTON +0 *20 4006 4007 1 0 <eval <db.row.<dlocal._while>.id>>



IF (<REF1.TYPE> == t_container)



IF (<REF1.findtype.t_armor>) && !(<REF1.findtype.t_shield>)

DTEXT +30 *0 <qval (<ref1.findcont.0.color>)?<ref1.findcont.0.color>:<DEF.BEYAZ_YAZI>> <basharfbuyuk <ref1.findcont.0.f_value>> Plate (Kalkansız) 

ELSE

DTEXT +30 *0 <qval (<ref1.color>)?<ref1.color>:<DEF.BEYAZ_YAZI>> <LOCAL.NAME> (<DREF1.rescount>) 

ENDIF



ELSEIF (<REF1.TYPE> == T_PLATE_DEED) || (<REF1.TYPE> == T_ARMOR) || (<REF1.TYPE> == T_SHIELD) || (<REF1.TYPE> == T_ARMOR_LEATHER)

DTEXT +30 *0 <qval (<ref1.color>)?<ref1.color>:<DEF.BEYAZ_YAZI>> <LOCAL.NAME>



ELSE

DTEXT +30 *0 <DEF.BEYAZ_YAZI> <LOCAL.NAME>

ENDIF



IF (<db.row.<dlocal._while>.value> < 1)

DTEXT +295 *0 <DEF.KIRMIZI_YAZI> Satılık değil

ELSE

DTEXT +295 *0 <DEF.BEYAZ_YAZI> <bolukayir <eval <db.row.<dlocal._while>.value>>> GP

ENDIF



DTEXT +430 *0 <DEF.BEYAZ_YAZI> <croptext 13 <db.row.<dlocal._while>.date>>

ENDWHILE

ENDIF



IF !<Ddb.row.numrows>

YAZI_K 50,370,Hiç eşya bulunamadı

ELSE

YAZI_K 50,370,Toplam <Ddb.row.numrows> eşya bulundu

ENDIF



DB.CLOSE



//panel

DHTMLGUMP 600 50 100 25 1 0 <DEF.CENTER>SIRALAMA



TBUTTON_B 600,80,99990,Alfabetik

TBUTTON_B 600,110,99991,Fiyat

TBUTTON_B 600,140,99992,Ekleme Tarihi



DHTMLGUMP 600 180 100 25 1 0 <DEF.CENTER>FİLTRELE



TBUTTON_B 600,210,99993,Satılıklar

TBUTTON_B 600,240,99994,Silahlar

TBUTTON_B 600,270,99995,Zırhlar

TBUTTON_B 600,300,999999,Kalkanlar

TBUTTON_B 600,330,99996,Kıyafetler

TBUTTON_B 600,360,99997,Binekler

TBUTTON_B 600,390,99998,Diğer

TBUTTON_B 600,420,99999,Hepsi

TBUTTON_B 600,450,999998,Evler

TBUTTON_B 600,480,999999,Tüm Tüccarlar





//arama

TBUTTON_B 120,405,100001,İsim

DENTRY 185,400,110,1



TBUTTON_B 320,405,100002,Fiyat

DENTRY 395,400,180,2



YAZI_K 460,405,ile

DENTRY 505,405,180,3



[dialog d_vend_main_general button]

on=0

src.clearctags=vend



on=1 99989



db.connect

db.query "SELECT `uid` FROM vend_market WHERE id=<dargn>";

ref7=<db.row.0.uid>



if (<ref7.type> == t_multi)

REF2=<ref7> 	// EV

REF3=<REF7.MORE1> 			// SAHIBI

REF4=<REF7.LINK> 			// TABELA

REF10=<SRC.CTAG0.VEND_GENERAL>



IF (<src.isuzak <ref10>>)

src.sys_kirmizi Genel tüccara yetişemiyorsunuz.

RETURN 1



ELSEIF (<SRC.ISYARALI>)

SRC.SYS_KIRMIZI Yaralıyken bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISPOISONED>)

SRC.SYS_KIRMIZI Zehirliyken bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISSTUCK2>)

SRC.SYS_KIRMIZI Stuck halinde bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISJAIL>)

SRC.SYS_KIRMIZI Hapisteyken bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISETKINLIKTE>)

SRC.SYS_KIRMIZI Etkinliğe katılmışken bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISDUEL>)

SRC.SYS_KIRMIZI Düello esnasında bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISNOMOVERFLAGS>)

SRC.SYS_KIRMIZI Bu durumda bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISINDUNGEON>)

SRC.SYS_KIRMIZI Dungeon'da bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.ISRAIDDER>)

SRC.SYS_KIRMIZI Raid Dungeon'da bunu kullanamazsınız.

RETURN 1



ELSEIF (<SRC.IsBAHIS>)

SRC.SYS_KIRMIZI Bahisli kumar esnasında bunu kullanamazsınız.

RETURN 1



ENDIF



src.CTAG0.EMLAK_EV=1



src.sys_beyaz Satılık eve gidiyorsun...

src.sayu Kal Ort Por

src.spd 3

serv.newitem i_runebookdelay,1,<src>,1

new.more1=1

new.more2=3

new.morep=<ref4.p>

src.equip <new>

SRC.MANA -=<SERV.SPELL.32.MANAUSE>

src.anim 17

return 1

endif



ref5=<uid.<db.row.0.uid>.topobj> // vendor

ref6=<db.row.0.uid>



if !(<ref6.type> == t_multi)



if !(<db.row.0.uid>)

SRC.SYS_KIRMIZI Satılık eşyalar arasında böyle bir eşya bulunmuyor.

else



if !(<ref6>)

SRC.SYS_KIRMIZI Böyle bir eşya bulunmuyor.

else

src.dialogcloseall

ref6.sdialog d_vend_detail

endif



endif

endif



db.close







on=99990

src.ctag0.vend_order="`name` <src.orderset>"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99991

src.ctag0.vend_order="`value` <src.orderset>"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99992

src.ctag0.vend_order="`date` <src.orderset>"

src.ctag0.vend_index=0

sdialog d_vend_main_general





on=99993

src.ctag0.vend_where="WHERE `value` > 0"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99994

src.ctag0.vend_where="WHERE `type` LIKE '%weapon%'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99995

src.ctag0.vend_where="WHERE `type` LIKE '%armor%'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99996

src.ctag0.vend_where="WHERE `type` LIKE '%cloth%'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99997

src.ctag0.vend_where="WHERE `baseid` LIKE 'i_deed_animal'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99998

src.ctag0.vend_where="WHERE `type` NOT LIKE '%weapon%' AND `type` NOT LIKE '%armor%' AND `type` NOT LIKE '%cloth%' AND `baseid` != 'i_deed_animal' AND `type` != 't_figurine' AND `type` != 't_multi'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=99999

src.ctag0.vend_where=

src.ctag0.vend_index=0

sdialog d_vend_main_general



on=100001

if <isempty <argtxt[1]>>

	SRC.SYS_KIRMIZI Anahtar kelimeyi girmelisiniz.

elif !<isalfa <argtxt[1]>>

	SRC.SYS_KIRMIZI Sadece alfabetik karakterler kullanabilirsiniz.

else

	src.ctag0.vend_index=0

	src.ctag0.vend_where="WHERE `name` LIKE '%<argtxt[1]>%'"

endif

sdialog d_vend_main_general



on=100002

if (<isempty <argtxt[2]>>) || (<isempty <argtxt[3]>>)

	SRC.SYS_KIRMIZI Fiyat aralığı belirtmelisiniz.



elif !(<isnumeric <argtxt[2]>>) || !(<isnumeric <argtxt[3]>>)

	SRC.SYS_KIRMIZI Sadece rakam girebilirsiniz.

elif <dargtxt[2]> >= <dargtxt[3]>

	SRC.SYS_KIRMIZI İlk girilen fiyat ikinciden büyük olmalı.

else

	src.ctag0.vend_index=0

	src.ctag0.vend_where="WHERE `value` BETWEEN <dargtxt[2]> AND <dargtxt[3]>"

endif

sdialog d_vend_main_general



on=100003

src.ctag0.vend_index +=13

sdialog d_vend_main_general



on=100004

if (<src.dctag0.vend_index> > 0)

	src.ctag0.vend_index -=13

endif

sdialog d_vend_main_general



on=999998

src.ctag0.vend_where="WHERE `type` LIKE 't_multi'"

src.ctag0.vend_index=0

sdialog d_vend_main_general



ON=999999

LIST.VENDORS.CLEAR



FORCHARS 999999

IF (<ID> == C_VENDOR_PLAYER)

IF (<FINDID.I_VEND_MEM>)

LIST.VENDORS.ADD <UID>

ENDIF

ENDIF

ENDFOR



SDIALOG D_VEND_ALL



[DIALOG D_VEND_ALL]

<DEF.DIALOGSTARTPOSITION>

MAIN 0,0,770,450,Ev Tüccarları Listesi (<DLIST.VENDORS.COUNT> Tüccar)



OPAC 50,50,80,30

YAZI_K 70,55,Tüccar



OPAC 140,50,110,30

YAZI_K 175,55,Sahibi



OPAC 260,50,100,30

YAZI_K 275,55,Toplam Eşya



OPAC 370,50,120,30

YAZI_K 410,55,Bölge



OPAC 500,50,120,30

YAZI_K 530,55,Koordinat



OPAC 630,50,110,30

YAZI_K 645,55,Bölgesel Filtre



LOCAL.AUMENTAR=0

LOCAL.PAGE=1



PAGE 1



IF (<SRC.CTAG0.VEND_SEARCH_FILTER>)

FOR 1 <DSRC.CTAG0.VEND_NPC>

REF3=<SRC.CTAG0.VEND_NPC_<DLOCAL._FOR>>

REF4=<REF3.TAG0.OWNER>



IF (<LOCAL.AUMENTAR> > 9)

LOCAL.AUMENTAR=0

PILERI 40,320,<EVAL <LOCAL.PAGE>+1>

LOCAL.PAGE += 1

PAGE <EVAL <LOCAL.PAGE>>

PGERI 20,320,<EVAL <LOCAL.PAGE>-1>

ENDIF

LOCAL.AUMENTAR += 1

IF (<REF3>)

YAZI_B 50,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<dLOCAL.AUMENTAR>.<CROPTEXT 13 <REF3.NAME>>

YAZI_B 180,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<CROPTEXT 13 <REF4.NAME>>

YAZI_B 300,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<REF3.FINDLAYER.21.RESCOUNT>

YAZI_B 375,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<CROPTEXT 23 <REF3.REGION.NAME>>

DTEXT 530 <EVAL (<LOCAL.AUMENTAR>*20)+60> <DEF.BEYAZ_YAZI> <REF3.P>

ELSE

YAZI_K 20,100,Bu bölgede ev tüccarı bulunamadı!

ENDIF



ENDFOR



ELSE



FOR 0 <EVAL <LIST.VENDORS.COUNT>-1>

REF1=<LIST.VENDORS.<dLOCAL._FOR>>

REF2=<REF1.TAG0.OWNER>

IF (<LOCAL.AUMENTAR> > 9)

LOCAL.AUMENTAR=0

PILERI 40,320,<EVAL <LOCAL.PAGE>+1>

LOCAL.PAGE += 1

PAGE <EVAL <LOCAL.PAGE>>

PGERI 20,320,<EVAL <LOCAL.PAGE>-1>

ENDIF

LOCAL.AUMENTAR += 1

YAZI_B 50,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<dLOCAL.AUMENTAR>.<CROPTEXT 13 <REF1.NAME>>

YAZI_B 180,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<CROPTEXT 13 <REF2.NAME>>

YAZI_B 300,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<REF1.FINDLAYER.21.RESCOUNT>

YAZI_B 375,<EVAL (<LOCAL.AUMENTAR>*20)+60>,<REF1.REGION.NAME>

DTEXT 530 <EVAL (<LOCAL.AUMENTAR>*20)+60> <DEF.BEYAZ_YAZI> <REF1.P>

ENDFOR



ENDIF



for x 1 16

TBUTTON_B 630,<eval (<dlocal.x>*20)+70>,<dlocal.x>,<f_Array <def.SOSARIA>,<dlocal.x>>

endfor



TBUTTON_B 630,410,999,Heryer



[DIALOG D_VEND_ALL BUTTON]

ON=1 16

SRC.CLEARCTAGS VEND_NPC

SRC.CTAG0.VEND_SEARCH_FILTER=1



FORCHARS 999999

IF (<ID> == C_VENDOR_PLAYER)

IF (<FINDID.I_VEND_MEM>)

IF (STRMATCH(*<f_Array <def.SOSARIA>,<dARGN>>*,'<REGION.NAME>'))

SRC.CTAG0.VEND_NPC +=1

SRC.CTAG0.VEND_NPC_<DSRC.CTAG0.VEND_NPC> <UID>

ENDIF

ENDIF

ENDIF

ENDFOR

SDIALOG D_VEND_ALL



ON=999

SRC.CLEARCTAGS VEND_NPC

SRC.CTAG0.VEND_SEARCH_FILTER=

SDIALOG D_VEND_ALL





[eof]

Devamını göster

xwerswoodx

Elder Sphere Destek

Üye bilgileri

Mesaj 1861

Oyun tarzı Rp

Emulatör Sphere

Tecrübe Scripter

Favori Server Second Age

Beğeni 341 / 177

Skill Title: Elder

Toplam Mesaj: 1861

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Second Age

Beğeni: 341 / 177

Üye bilgilerini göster

MYSQL kullanmadan DB kullanamazsın, doğal olarak çalışmaz, ya LDB yani SQLite kullanarak düzenleyerek kodlayacaksın ya da başka sistem bakman gerekiyor.
Devamını göster

Geçmişi olmayanın, geleceği olmaz.
Scripting Destek Discord: https://discord.gg/yXQ3m5S

#100268 08-01-2021 23:39 GMT

BENZER BAŞLIKLAR

Konu	Kategori	Son cevap	Son yazan	Mesaj	Görüntüleme
.add & .gm komutu çalışmıyor Son cevap: 13-04 21:14 · Son yazan: The And · Mesaj: 12 · Görüntü: 5277	FUNCTION & EVENTS Script Yardımı	13-04 21:14	The And	12	5277
Binekler neden siliniyor? Son cevap: 26-03 21:06 · Son yazan: senedor250 · Mesaj: 9 · Görüntü: 4081	Script Yardımı	26-03 21:06	senedor250	9	4081
s_Refresh çalışmıyor Son cevap: 21-02 12:16 · Son yazan: xrambo · Mesaj: 5 · Görüntü: 2739	Konsol Hataları	21-02 12:16	xrambo	5	2739
Neden scriptler paylaşılmıyor ! Son cevap: 19-02 14:09 · Son yazan: Slothere · Mesaj: 6 · Görüntü: 3194	Script Yardımı	19-02 14:09	Slothere	6	3194
MySql Hata Alıyorum Son cevap: 21-10 22:19 · Son yazan: Pidra · Mesaj: 8 · Görüntü: 5039	Konsol Hataları	21-10 22:19	Pidra	8	5039

Sosyal Ağ ile Giriş Yap

Google ile Bağlan Facebook ile Bağlan Twitch ile Bağlan Discord ile Bağlan

BENZER BAŞLIKLAR

Sosyal Ağ ile Giriş Yap

Çerez Tercihleri