UO-Dev Arama

 

İçerde : 1 misafir, 0 üye : --- Sayfalar: 1
Yazar
Skill Title: Novice
Toplam Mesaj: 14
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Diğer
Yaş: 20
Beğeni: 0
Mesaj #102157   11-07-2021 22:21 GMT    
     
Merhaba, fix scriptinde gemide runebook açmayı engelledim eyvallah. Ama dışardan gate açıp gemi içine girilebiliyor. Aynı şekilde recall ve gate büyülerini de engelledim ama dışardan açıp girince işlemiyor. Ne yapmak gerek?



Yazar
Skill Title: Expert
Toplam Mesaj: 305
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Scripter
Yaş: 30
Beğeni: 68
Mesaj #102158   12-07-2021 02:16 GMT    
     
Kendi gate eventinle değiştirirsin bu şekilde gate açmaya çalışırken gemiye giriş yapamaz.

Script Kodu:
[typedef T_SHIP_PLANK]
on=@dclick
if (<src.isevent.f_recall>)
   src.sysmessage @38,1,1 Gate açarken gemiye giriş yapamazsınız.
  return 1
endif


ben bu şekil çözüm yolu üterttim başka türlü engellenirmi bilmiyorm.
her gemiye girişte bir kapi vardır yukardaki typedef gemi kapıların type. gate açmak için kitaptan bir bolgeyi seçtiğimiz zaman herhangi bir saldiri esnasinda fizzle olayi olsun diye event verilir. o event playerin üstündeyken bu şekilde geminin kapısına tıklarsa return 1 ile bitirdiğimiz için sorguyu dclick yaptığı zamn sadece sysmesssage devreye girer eğer event yoksa zaten adamda if sorgusunu göörmez normal bir şekilde gemiye giriş yapar.


Son güncelleme: mahsuni tarafından 12-07-2021 10:16 GMT, 18 Gün önce düzenlendi.


 Ege ERKEK
Discord= Zedikus#4967
Script && Mull && Word

Yazar
Skill Title: Novice
Toplam Mesaj: 14
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Diğer
Yaş: 20
Beğeni: 0
Mesaj #102159   12-07-2021 16:39 GMT    
     
Teşekkürler cevap için.


Script Kodu:
[Typedef t_ship_plank]
On=@Dclick
if (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)
src.skill fail
endif
if (<ARGN>==32) || (<ARGN>==52)
src.skill fail
endif
if (<src.isevent.f_recall>)
   src.sysmessage @38,1,1 Gate açarken gemiye giriş yapamazsınız.
  return 1
endif

[events f_recall]
IF (<eval <SRC.REGION.FLAGS>> & 04000)
if (<ARGN>==32) || (<ARGN>==52)
src.skill fail
endif
endif


f_recall eventsi oluşturdum evet oldu gate açarken gemiye girilmiyor. Ama gate açıldıktan sonrada giremiyor. Yani recall olurken eventsi alıp, recall bittikten sonra eventsi kaldırtabilir miyiz böyle bir imkan var mı?



Yazar
Skill Title: Expert
Toplam Mesaj: 305
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Scripter
Yaş: 30
Beğeni: 68
Mesaj #102160   12-07-2021 18:00 GMT    
     
boyle bir event olsuturmana gerek yok sen runebook scpnin button bölüümüünü buraya atarsan daha iyi yardimci olurum.


Discord= Zedikus#4967
Script && Mull && Word

Yazar
Skill Title: Novice
Toplam Mesaj: 14
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Diğer
Yaş: 20
Beğeni: 0
Mesaj #102161   12-07-2021 18:21 GMT    
     

Script Kodu:
[function markyasakhemso]
foritems 13
if (strmatch('<baseid>','i_mark_yasak'))
local.yasak +=1
endif
endfor
return <dlocal.yasak>

[plevel 1]
kitapkopyala

[function kitapkopyala]
targetf f_kitapkopya
src.sysmessage @0481,1,1 Hangi kitabı kopyalamak istiyorsunuz ?

[function f_kitapkopya]
ref1 <argo>
if (<src.inscription> < 1000)
src.sysmessage @0481,1,1 Kitap kopyalamak icin 100.0 inscription skilli gerekmekte
elseif !(<ref1.topobj.uid> == <src.uid>)
src.sysmessage @0481,1,1 Sadece çantanızda ki kitapları kopyalayabilirsiniz.
elseif !(<ref1.baseid> == i_runebook)
src.sysmessage @0481,1,1 Bu bir runebook degil
elseif !(<src.restest 10 i_rune_marker>) || !(<src.restest 4 i_scroll_recall>) || !(<src.restest 1 i_scroll_gate_travel>) || !(<src.restest 16 i_scroll_blank>)
src.sysmessage @0481,1,1 Yaninizda yeterli rune marker (10), recall scroll (4), gate travel scroll (1) veya bos scroll (16) bulunmamaktadir.
else
ref1.dupe
src.sysmessage @0481,1,1 Kitabiniz kopyalandi. Hareket ettiriniz...
src.consume 10 i_rune_marker
src.consume 4 i_scroll_recall
src.consume 1 i_scroll_gate_travel
src.consume 16 i_scroll_blank
return 1
endif

[ITEMDEF i_runebook]
ID=i_spellbook
TYPE=t_script
WEIGHT=0.1
NAME=Runebook
RESOURCES=16 i_scroll_blank, 4 i_scroll_recall, 1 i_rune_marker, 1 i_scroll_gate_travel
SKILLMAKE=INSCRIPTION 80.0, MAGERY 70.0
value=10

ON=@Create
COLOR=05aa
MOREX=4
attr=attr_newbie|attr_decay
TAG.NAME=isimsiz
TAG.EATRUNE=01
for 1 16
TAG.POS<dlocal._for>_X=0
endfor

ON=@Click
ref1 <tag.kitapsil>

if (<tag0.kitapsil>) && !(<isempty <tag.name>>)
messageua 0481,6,6,0 <name> (<tag0.name>)
messageua 038,6,6,0 Loca : <ref1.name>
elseif !(<isempty <tag.name>>)
messageua 0481,6,6,0 <name> (<tag0.name>)
else
messageua 0481,6,6,0 <name>
endif
return 1


ON=@DClick
if (<tag0.kitapsil>) && !(<tag0.kitapsil> == <src.memoryfindtype.memory_guild.link.uid>)
src.sysmessage @0481,1,1 Siz bu loncaya mensup değilsiniz.
remove
return 1
endif


DIALOGCLOSE d_runebook
//DIALOGCLOSE d_runebook_double

if (<cont>) && (<topobj.uid> != <src.uid>) && (<src.account.plevel> < 6)
src.sysmessage @0481,1,1 Sadece yerdeki veya kendi çantanızdaki runebookları açabilirsiniz.
return 1
elseif ((<src.findid.i_jailcik>))
src.sysmessage @0481,1,1 Jaildeyken bunu kullanamazsınız.
return 1
elseif (<src.region.safe> == 1)
src.sysmessage @0481,1,1 Bu bölgede runebook kullanamazsınız
return 1
elseif (<src.isevent.e_safe>)
src.sysmessage @0481,1,1 Bu bölgede runebook kullanamazsınız
return 1
elseif (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi_custom) || (<src.region.flags> == 010d2)
src.sysmessage @0481,1,1 Evde veya gemide iken runebook açamazsınız.
return 1
elseif ((<src.findid.i_spdelay_man>) || (<src.findid.i_spdelay_woman>))
src.sysmessage @0481,1,1 Büyü atarken bunu kullanamazsınız.
return 1
endif

if ((<src.action> == id(skill_magery)) || (<src.action> == skill_magery))
src.f_fizzle
src.FINDID.i_rb_delay.REMOVE
src.FINDID.i_rb_delay2.REMOVE
src.EVENTS -e_x_breakspell
src.f_fizzle
src.sysmessage @0481,1,1 Savaş hakkındaki düşüncelerin yüzünden bunu kullanamadın.
return 1
endif

if (<src.isevent.e_x_breakspell>)
src.FINDID.i_rb_delay.REMOVE
src.FINDID.i_rb_delay2.REMOVE
src.EVENTS -e_x_breakspell
src.f_fizzle
ENDIF
SRC.SOUND=85
DIALOG d_runebook
RETURN 1


ON=@TargOn_Char
RETURN 1

ON=@TargOn_Item
IF <SRC.TARG.TOPOBJ.UID> != <SRC.UID>
src.sysmessage @0481,1,1 Ekleyeceğiniz şey çantanızda olmalı.
RETURN 1
ENDIF
IF <MORE2>=1
IF ( <SRC.TARG.ID> = 01f4c )
MOREX=<MOREX> + <SRC.TARG.AMOUNT>
SRC.TARG.REMOVE
src.sysmessage @0481,1,1 Kitaba <src.targ.amount> adet şarj eklendi.
DIALOGCLOSE d_runebook
dialog d_runebook
ELSe
src.sysmessage @0481,1,1 Bu bir recall scroll değil.
ENDIF
RETURN 1
ELSEIF <MORE2>=2
IF (( <SRC.TARG.TYPE> = t_rune ) || ( <SRC.TARG.TYPE> = 014 ))
IF (<SRC.TARG.MOREX>==0)
src.sysmessage @0481,1,1 Bu rune boş, bunu kullanamazsınız.
RETURN 1
ENDIF
ELSE
src.sysmessage @0481,1,1 Bu bir rune değil.
RETURN 1
ENDIF
TAG.HOLD_LOCAL=<SRC.TARG.NAME>
TAG.HOLD_X=<SRC.TARG.MOREX>
TAG.HOLD_Y=<SRC.TARG.MOREY>
TAG.HOLD_Z=<SRC.TARG.MOREZ>
TAG.HOLD_M=<SRC.TARG.MOREM>
ENDIF

for 1 16
IF (<TAG.POS<dlocal._for>_X>=0)
src.sysmessage @0481,1,1 Runeyi kitaba eklediniz.
SRC.SOUND=79
try TAG.LOCAL<dlocal._for>=<TAG.HOLD_LOCAL>
try TAG.POS<dlocal._for>_X=<TAG.HOLD_X>
try TAG.POS<dlocal._for>_Y=<TAG.HOLD_Y>
try TAG.POS<dlocal._for>_Z=<TAG.HOLD_Z>
try TAG.POS<dlocal._for>_M=<TAG.HOLD_M>
SRC.TARG.REMOVE
DIALOGCLOSE d_runebook
dialog d_runebook
RETURN 1
ENDIF
endfor
src.sysmessage @0481,1,1 Kitapda bunun icin bosyer kalmamış.
RETURN 1

[ITEMDEF i_rb_gate]
ID=i_moongate_blue
RESOURCES=i_scroll_gate_travel
TYPE=t_telepad
NAME=Gate
CATEGORY=Provisions - Alchemy & Magic
SUBSECTION=Moongates
DESCRIPTION=RB Gate

On=@Create
color 0845
more1 5
attr 010

On=@DClick
if !(<src.flags>&statf_stone)
if (<distance> > 3)
src.sysmessage @0481,1,1 Gate'e ulaşamıyorsunuz.
else
if (<src.findid.i_gater>)
src.findid.i_gater.remove
endif
serv.newitem i_gater
new.link <uid>
new.morep <morep>
new.equip
endif
endif
return 1


ON=@Step
src.sysmessage @0481,,1 Çift tıklayın.
return 1

//ON=@Step
//if !((<src.findid.i_gater>) || (<src.flags>&statf_stone))
//if (<src.flags>&statf_dead)
//serv.newitem i_gater
//new.link <uid>
//new.morep <morep>
//new.equip
//else
//src.sysmessage @0481,1,1 Gatelerden çift tıklayarak geçebilirsiniz
//endif
//endif
//return 1

On=@Click
if (<link.region.flags>®ion_flag_guarded)
message @100,,1 [Guarded bölge]
message <def.sys> <link.region.name>
//new.color 07a2
else
message @38,,1 [Unguarded bölge]
//new.color 07a3
message <def.sys> <link.region.name>
endif
return 1

On=@Timer
if (<more1>)
more1 <more1> - 1
timer 1
else
sfx 528
remove
endif
return 1

[DIALOG d_runebook]
0,100
gumppic 100 10 089b
gumppic 125 50 57
gumppic 145 50 58
gumppic 160 50 58
gumppic 175 50 58
gumppic 190 50 58
gumppic 205 50 58
gumppic 220 50 58
gumppic 230 50 59
gumppic 290 50 57
gumppic 310 50 58
gumppic 325 50 58
gumppic 340 50 58
gumppic 355 50 58
gumppic 370 50 58
gumppic 385 50 58
gumppic 395 50 59

page 0
//Recall Button
local.satir 65
local.satir2 65
for 1 16
if (<dlocal._for> <= 8)
button 125 <dlocal.satir> 2103 2104 1 0 <dlocal._for>
local.satir += 15
else
button 285 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>
local.satir2 += 15
endif
endfor

//Gate Button
local.satir 65
local.satir2 65
for 17 32
if (<dlocal._for> <= 24)
button 135 <dlocal.satir> 2103 2104 1 0 <dlocal._for>
local.satir += 15
else
button 295 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>
local.satir2 += 15
endif
endfor

//Rune cikar button
local.satir 65
local.satir2 65
for 33 48
if (<dlocal._for> <= 40)
button 260 <dlocal.satir> 2103 2104 1 0 <dlocal._for>
local.satir += 15
else
button 420 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>
local.satir2 += 15
endif
endfor

//Rune isim değiştir
local.satir 65
local.satir2 65
for 49 64
if (<dlocal._for> <= 56)
button 250 <dlocal.satir> 2103 2104 1 0 <dlocal._for>
local.satir += 15
else
button 410 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>
local.satir2 += 15
endif
endfor

//Runebook İsim değiştir
button 140 22 2103 2104 1 0 67
dhtmlgump 155 18 100 17 0 0 <tag.name>

//Rune Ekle Şarj Et
button 303 22 2103 2104 1 0 65

dhtmlgump 318 18 100 20 0 0 Rune Ekle



//Marklarının ismi
local.satir 61
local.satir2 61
for 1 16
if (<dlocal._for> <= 8)
dhtmlgump 148 <dlocal.satir> 100 17 0 0 <qval (<serv.map(<EVAL <TAG.POS<dlocal._for>_X>>,<EVAL <TAG.POS<dlocal._for>_Y>>,0).region.guarded> == 1)?<def.bfont_blue><TAG.LOCAL<dlocal._for>>:<def.bfont_red><TAG.LOCAL<dlocal._for>>>
local.satir += 15
else
dhtmlgump 307 <dlocal.satir2> 100 17 0 0 <qval (<serv.map(<EVAL <TAG.POS<dlocal._for>_X>>,<EVAL <TAG.POS<dlocal._for>_Y>>,0).region.guarded> == 1)?<def.bfont_blue><TAG.LOCAL<dlocal._for>>:<def.bfont_red><TAG.LOCAL<dlocal._for>>>
local.satir2 += 15
endif
endfor

//Ivırzıvır :=)
dhtmlgump 129 180 100 20 0 0 | |_
dhtmlgump 129 192 100 20 0 0 |___
dhtmlgump 239 180 100 20 0 0 __|
dhtmlgump 264 180 100 20 0 0 |
dhtmlgump 245 192 100 20 0 0 __
dhtmlgump 248 192 100 20 0 0 __|
dhtmlgump 150 184 100 20 0 0 gate
dhtmlgump 156 196 100 20 0 0 recall
dhtmlgump 218 184 100 20 0 0 isim
dhtmlgump 216 196 100 20 0 0 cikar

[DIALOG d_runebook BUTTON]
ONBUTTON=0
src.sysmessage @0481,1,1 Runebook kapandı.
RETURN 1

on 1 16

if (<src.flags>&statf_stone) || (<src.flags>&statf_freeze)
src.sysmessage @0481,1,1 Bu durumda iken yapamazsınız.
src.f_fizzle
return 1
elseif ((<src.findid.i_spdelay_man>) || (<src.findid.i_spdelay_woman>))
src.sysmessage @0481,1,1 Büyü atarken isinlanamazsiniz.
src.f_fizzle
return 1
endif
if (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi_custom) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_ship)
src.sysmessage @0481,1,1 Evde veya gemide iken runebook kullanamazsınız
src.f_fizzle
return 1
endif


IF <TAG.POS<dargn>_X>=00
src.sysmessage @0481,1,1 Bu alan boş.
RETURN 1
ENDIF

IF !<SRC.ISGM>
IF (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi_custom)
//IF <SRC.REGION.FLAGS>&0e
src.sysmessage @0481,1,1 Evde recall olamazsınız.
return 1
ENDIF
ENDIF

IF !<SRC.ISGM>
IF (<SRC.region.flags>==0200)
src.sysmessage @0481,1,1 Burada recall olamazsınız.
return 1
ENDIF
endif

serv.newitem i_evvarmi
new.p <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>
new.timer 2
local.itemflag <NEW.REGION.FLAGS>

if (<local.itemflag> == 0892)
src.sysmessage @0481,1,1 Recall olmaya çalıştığınız alanda bir ev bulunmaktadır.
return 1
endif

if (<local.itemflag> == 0a089)
src.sysmessage @0481,1,1 Bu bölgeye recall olamazsınız.
return 1
endif

if !<SRC.ISGM>
if (<local.itemflag> == 0200)
src.sysmessage @0481,1,1 Recall olmaya çalıştığınız alana buyu ile giremezsiniz.
return 1
endif
if (<local.itemflag> == 0900)
src.sysmessage @0481,1,1 Recall olmaya çalıştığınız alana buyu ile giremezsiniz.
return 1
endif
endif



IF (<SRC.MANA><15)
SRC.SOUND=92
src.sysmessage @0481,1,1 Yeterli mananız yok.
RETURN 1
ENDIF

IF ( <SRC.MAGERY> < 400 )
if (<MOREX> > 0)
MOREX = 0
src.sayua 0bb2,6,0,enu Kal Ort Por
src.sd 2
SRC.ANIM=17
SRC.MANA=(<SRC.MANA>+-15)
serv.newitem i_rb_delay
new.morep <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>
new.more1 4
new.equip
else
src.sysmessage @0481,1,1 Kitabınızda yeterli şarj kalmamış
RETURN 1
endif
endif

if ( <SRC.MAGERY> >= 400 )
//if (<SRC.RESTEST 1 i_reag_black_pearl>) && (<SRC.RESTEST 1 i_reag_mandrake_root>) && (<SRC.RESTEST 1 i_reag_blood_moss>)
src.sayua 0bb2,6,0,enu Kal Ort Por
src.sd 2
SRC.ANIM=17
SRC.MANA=(<SRC.MANA>+-15)
//SRC.CONSUME=1 i_reag_black_pearl
//SRC.CONSUME=1 i_reag_blood_moss
//SRC.CONSUME=1 i_reag_mandrake_root
serv.newitem i_rb_delay
new.morep <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>
new.more1 4
new.equip
elseif (<MOREX> > 0)
MOREX = 0
src.sayua 0bb2,6,0,enu Kal Ort Por
src.sd 2
SRC.ANIM=17
SRC.MANA=(<SRC.MANA>+-15)
serv.newitem i_rb_delay
new.morep <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>
new.more1 4
new.equip
else
src.sysmessage @0481,1,1 Üzerinizde büyü yapacak malzeme yok yada kitabınızda yeterli şarj kalmamış
SRC.SOUND 92
return 1
//ENDIF
endif


on 17 32
if (<src.flags>&statf_stone) || (<src.flags>&statf_freeze)
src.sysmessage @0481,1,1 Bu durumda iken yapamazsınız.
src.f_fizzle
return 1
endif

IF <TAG.POS<eval <dargn>-16>_X>=00
src.sysmessage @0481,1,1 Bu alan boş.
RETURN 1
ENDIF

IF !<SRC.ISGM>
IF (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi_custom) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_ship)
//IF <SRC.REGION.FLAGS>&0e
src.sysmessage @0481,1,1 Evde gate açamazsınız.
return 1
//ENDIF
ENDIF
IF !<SRC.ISGM>
IF (<SRC.region.flags>==0200)
src.sysmessage @0481,1,1 Burada gate açamazsınız.
return 1
elseif (<SRC.region.flags> == 0900)
src.sysmessage @0481,1,1 Burada gate açamazsınız.
return 1
ENDIF
endif

serv.newitem i_evvarmi
new.p <EVAL <TAG.POS<eval <dargn>-16>_X>> <EVAL <TAG.POS<eval <dargn>-16>_Y>> <EVAL <TAG.POS<eval <dargn>-16>_Z>> <EVAL <TAG.POS<eval <dargn>-16>_M>>
new.timer 2
local.itemflag <NEW.REGION.FLAGS>
//local.itemflagg <new.region.name>

//IF !<SRC.ISGM>
if (<local.itemflag> == 0200)
src.sysmessage @0481,1,1 Gate açmaya çalıştığınız yere buyu ile giremezsiniz.
return 1
endif
if (<local.itemflag> == 0900)
src.sysmessage @0481,1,1 Gate açmaya çalıştığınız alana buyu ile giremezsiniz.
return 1
endif
if (<local.itemflag> == 0892)
src.sysmessage @0481,1,1 Gate açmaya çalıştığınız alana buyu ile giremezsiniz.
return 1
endif
if (<local.itemflag> == 0a089)
src.sysmessage @0481,1,1 Gate açmaya çalıştığınız alana buyu ile giremezsiniz.
return 1
endif
//endif
IF ( <SRC.MAGERY> < 750 )
src.sysmessage @0481,1,1 Gate açabilmek için en az 75.0 magery skilliniz olmalıdır.
SRC.SOUND=92
RETURN 1
ENDIF
IF (<SRC.MANA><40)
SRC.SOUND=92
src.sysmessage @0481,1,1 Yeterli mananız yok.
RETURN 1
ENDIF
//IF ! (<SRC.RESTEST 1 i_reag_mandrake_root>) || ! (<SRC.RESTEST 1 i_reag_sulfur_ash>) || ! (<SRC.RESTEST 1 i_reag_black_pearl>)
//src.sysmessage @0481,1,1 Yeterli malzemeye sahip değilsiniz.
//SRC.SOUND=92
//RETURN 1
//ENDIF
src.sayua 0bb2,6,0,enu Vas Rel Por
src.sd 3
SRC.ANIM=17
SRC.MANA=(<SRC.MANA>+-40)
SRC.CONSUME=1 i_reag_black_pearl
SRC.CONSUME=1 i_reag_mandrake_root
SRC.CONSUME=1 i_reag_sulfur_ash
ENDIF

if (((<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi_custom))  || (<src.findid.i_rb_delay2>))
src.FINDID.i_rb_delay.REMOVE
src.FINDID.i_rb_delay2.REMOVE
src.EVENTS -e_x_breakspell
src.f_fizzle
src.sysmessage @0481,1,1 Evde iken Gate Acamazsiniz....
else
serv.newitem i_rb_delay2
new.morep <EVAL <TAG.POS<eval <dargn>-16>_X>> <EVAL <TAG.POS<eval <dargn>-16>_Y>> <EVAL <TAG.POS<eval <dargn>-16>_Z>> <EVAL <TAG.POS<eval <dargn>-16>_M>>
new.more1 6
new.equip
RETURN 1
endif



on 33 48
if !(<topobj.uid> == <src.uid>)
src.sysmessage @0481,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekiyor.
return 1
endif
IF ( <TAG.POS<eval <dargn>-32>_X> == 0 )
src.sysmessage @0481,1,1 Bu alan boş.
RETURN 1
ENDIF
serv.newitem i_rune_marker
new.morex <TAG.POS<eval <dargn>-32>_X>
new.morey <TAG.POS<eval <dargn>-32>_Y>
new.morez <TAG.POS<eval <dargn>-32>_Z>
new.morem <TAG.POS<eval <dargn>-32>_M>
new.name <TAG.LOCAL<eval <dargn>-32>>
new.bounce
try TAG.POS<eval <dargn>-32>_X 0
try TAG.LOCAL<eval <dargn>-32>
DIALOG d_runebook

on 49 64
if !(<topobj.uid> == <src.uid>)
src.sysmessage @0481,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekiyor.
return 1
endif
IF ( <TAG.POS<eval <dargn>-48>_X> == 0 )
src.sysmessage @0481,1,1 Bu alan boş.
RETURN 1
ELSE
try TAG.LOCALMOREP <EVAL <TAG.POS<eval <dargn>-48>_X>> <EVAL <TAG.POS<eval <dargn>-48>_Y>> <EVAL <TAG.POS<eval <dargn>-48>_Z>> <EVAL <TAG.POS<eval <dargn>-48>_M>>
f_rename <eval <dargn>-48>
src.ctag.ruid <uid>
RETURN 1
ENDIF

on 65
MORE2=2
TARGET
src.sysmessage @0481,1,1 Eklemek istediğiniz runeyi seçiniz.
return 1

on 66
MORE2=1
TARGET
src.sysmessage @0481,1,1 Lütfen şarj etmek istediğiniz scrollu seçin.
RETURN 1

on 67
if !(<topobj.uid> == <src.uid>)
src.sysmessage @0481,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekmektedir.
return 1
endif
src.ctag.ruid <uid>
dialogclose d_runebook_rename
DIALOG d_runebook_rename
RETURN 1


[FUNCTION f_rename]
src.ctag.localno <ARGS>
dialogclose d_runebook_localname
dialog d_runebook_localname
RETURN 1

[DIALOG d_runebook_localname]               
100,50
obj <src.ctag.ruid>                           
resizepic 190 175 5054 335 150

resizepic 220 235 3000 270 22
dhtmlgump 215 200 200 30 0 0 <def.bfont_red>Yeni isim ne olsun ?                   
dhtmlgump 255 275 50 30 0 0 Tamam
dhtmlgump 355 275 50 30 0 0 <def.bfont_red>İptal
dhtmlgump 435 275 50 30 0 0 <def.bfont_green>Reset           
button 220 275 4005 4007 1 0 1     
button 320 275 4005 4007 1 0 2
button 400 275 4005 4007 1 0 3   
dtextentry 225 237 253 25 990 0 <obj.tag.local<dsrc.ctag.localno>>

[DIALOG d_runebook_localname BUTTON]
on 1
obj <src.ctag.ruid> 
for 1 16
if (<dsrc.ctag.localno> == <dlocal._for>)
obj.tag.local<dlocal._for> <argtxt[0]>
endif
endfor
dialogclose d_runebook
dialog d_runebook
return 1

on 2
src.sysmessage @0481,1,1 İşlem iptal edildi.
return 1

on 3
obj <src.ctag.ruid> 
for 1 16
if (<dsrc.ctag.localno> == <dlocal._for>)
try obj.tag.local<dlocal._for> <serv.map(<EVAL <obj.TAG.POS<dlocal._for>_X>>,<EVAL <obj.TAG.POS<dlocal._for>_Y>>,0).region.name>
endif
endfor
dialogclose d_runebook
dialog d_runebook
RETURN 1

[DIALOG d_runebook_rename]
100,50
obj <src.ctag.ruid>                           
resizepic 190 175 5054 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22
dhtmlgump 215 200 200 30 0 0 <def.bfont_red>Runebook'un yeni isimi ne olsun ?                   
dhtmlgump 255 275 50 30 0 0 Tamam
dhtmlgump 355 275 50 30 0 0<def.bfont_red> İptal
dhtmlgump 435 275 50 30 0 0<def.bfont_green> Reset           
button 220 275 4005 4007 1 0 1     
button 320 275 4005 4007 1 0 2
button 400 275 4005 4007 1 0 3   
dtextentry 225 237 253 25 990 0 <obj.tag.name>       

[DIALOG d_runebook_rename BUTTON]
on 1
obj <src.ctag.ruid>
obj.tag.name <ARGTXT[0]>
dialogclose d_runebook
DIALOG d_runebook
RETURN 1

on 2
src.sysmessage @0481,1,1 İşlemi iptal ettiniz.
return 1

on 3
obj <src.ctag.ruid>
obj.tag.name isimsiz
dialogclose d_runebook
DIALOG d_runebook
RETURN 1

[ITEMDEF i_rb_delay]
NAME=runebook delay
ID=i_handr_1
TYPE=T_EQ_SCRIPT
WEIGHT=0
LAYER=layer_special

ON=@Create
ATTR=attr_invis|attr_decay

ON=@Equip
CONT.skill fail
CONT.ACTION=-1
CONT.FLAGS=(<CONT.FLAGS>&~00020)
TIMER=0
CONT.EVENTS=e_x_breakspell

ON=@UNEQUIP
CONT.EVENTS= -e_x_breakspell

ON=@Timer
IF ( <cont> )
IF ( <MORE1> ) && !( <CONT.isgm> )
MORE1=<MORE1>-1
TIMER=1
RETURN 1
ELSE
cont.go <morep>   
if !(<TOPOBJ.REGION.FLAGS>®ion_flag_ship)
topobj.fix       
endif     
ENDIF
ENDIF
CONT.EVENTS= -e_x_breakspell
REMOVE
RETURN 1

[EVENTS e_x_breakspell]
ON=@SpellCast
sysmessage @0481,1,1 Konsantrasyonunuzu kaybettiniz.
FINDID.i_rb_delay.REMOVE
FINDID.i_rb_delay2.REMOVE
EVENTS= -e_x_breakspell
f_fizzle


ON=@GetHit
sysmessage @0481,1,1 Konsantrasyonunuzu kaybettiniz.
FINDID.i_rb_delay.REMOVE
FINDID.i_rb_delay2.REMOVE
EVENTS= -e_x_breakspell
f_fizzle

ON=@Hit
sysmessage @0481,1,1 Konsantrasyonunuzu kaybettiniz.
FINDID.i_rb_delay.REMOVE
FINDID.i_rb_delay2.REMOVE
EVENTS= -e_x_breakspell
f_fizzle

ON=@Death
FINDID.i_rb_delay.REMOVE
FINDID.i_rb_delay2.REMOVE
EVENTS= -e_x_breakspell

ON=@SkillStart
src.sysmessage @0481,1,1 Konsantrasyonunuzu kaybettiniz.
FINDID.i_rb_delay.REMOVE
FINDID.i_rb_delay2.REMOVE
EVENTS= -e_x_breakspell
f_fizzle

[ITEMDEF i_rb_delay2]
NAME=runebook gate delay
ID=i_handr_1
TYPE=T_EQ_SCRIPT
WEIGHT=0
LAYER=layer_special

ON=@Create
ATTR=attr_invis|attr_decay

ON=@Equip
CONT.skill fail
CONT.ACTION=-1
CONT.FLAGS=(<CONT.FLAGS>&~00020)
TIMER=0
CONT.EVENTS=e_x_breakspell

ON=@UNEQUIP
CONT.EVENTS= -e_x_breakspell

ON=@Timer
IF ( <cont> )
IF ( <MORE1> ) && !( <CONT.isgm> )
IF (<MORE1> == 5)
cont.newitem i_moongate_blue_fx
cont.act.name summoning gate
cont.act.p <morep>
cont.act.morez 1
cont.act.color 0845
cont.act.attr 012
cont.act.timer 5
cont.act.sfx 526
//cont.act.fix
//cont.act.morez <cont.act.p>
ENDIF
MORE1=<MORE1>-1
TIMER=1
RETURN 1
ELSE
cont.newitem i_rb_gate
cont.act.color <qval (<serv.map(<cont.p>,0).region.guarded> == 1)?084a:0845>
cont.act.p <morep>
cont.act.morep <cont.p>
cont.act.timer 30
cont.act.sfx 535 // or 526 or 524
//cont.act.fix

//cont.act.morez <cont.act.p>
var.gateuid <cont.act.uid>
cont.newitem i_rb_gate
cont.act.color <qval (<serv.map(<morep>,0).region.guarded> == 1)?084a:0845>
cont.act.link <var.gateuid>
cont.act.link.link <cont.act.uid>
cont.act.p <cont.p>
cont.act.morep <morep>
cont.act.timer 30
cont.act.sfx 535 // or 526 or 524
//cont.act.fix
//cont.act.morez <cont.act.p>
var.gateuid
ENDIF
ENDIF
REMOVE
RETURN 1


[ITEMDEF i_evvarmi]
ID=i_gold
NAME=research coin
type t_eq_script
VALUE=1
weight 0

On=@Timer
remove

ON=@Create
attr attr_invis|attr_decay


[itemdef i_gater]
name gater
id i_handr_1
type t_eq_script
weight 0
layer layer_special

On=@Create
attr attr_invis|attr_can_decay

On=@Equip
timer 30
src.sdialog d_gatetravel

On=@Timer
remove
return 1

[itemdef i_moongater]
name moongater
id i_handr_1
type t_eq_script
weight 0
layer layer_special

On=@Create
attr attr_invis|attr_can_decay

On=@Equip
timer 10
//src.dialog d_facet_moongate

on=@unequip
//src.dialogclose d_facet_moongate

On=@Timer
remove
return 1

[typedef t_facet_moongate]
On=@Step
if !((<src.findid.i_moongater>) || (<src.flags>&statf_stone))
src.newitem i_moongater
src.act.link <uid>
src.act.equip
endif
var.font1 <basefont color=#ffffff
return 1

On=@Dclick
if !(<src.flags>&statf_stone)
if (<distance> > 3)
src.sysmessage @50,,1 Hata: Gate'e ulasamiyorsunuz.
else
if (<src.findid.i_moongater>)
src.findid.i_moongater.remove
endif
src.newitem i_moongater
src.act.link <uid>
src.act.equip
endif
endif
var.font1 <basefont color=#ffffff
return 1

On=@Click
if (<src.region.type> == <region.type>)
sayua 0905,0,0,0 a Moongate
else
message @0713,3,0 a Moongate
endif
return 1

[dialog d_gatetravel]
100,-100
//nomove

resizepic 190 165 5054 250 150
resizepic 200 175 3000 230 130
dtext 265 185 0455 Alaves Gate
dtext 255 230 100 Evet
dtext 255 260 38 Hayir

button 220 230 4006 4007 1 0 1
button 220 260 4006 4007 1 0 2
tilepic 340 160 <serv.itemdef.i_frunebook_gate.id>


[dialog d_gatetravel button]
On=0
findid.i_gater.remove

On=1
if !(<findid.i_gater.link.isitem>)
sysmessage @38,,1 Hata: Gate gecemeden kapanmis.
findid.i_gater.remove
elseif (<findid.i_gater.link.distance> > 3)
sysmessage @39,,1 Hata: Gate'e ulasamiyorsunuz.
findid.i_gater.remove
elseif (<isevent.e_ticaret>)
sysmessage @0481,1,1 Ticaret yaparken bu sistemi kullanamazsınız
findid.i_gater.remove
elseif (<isevent.e_rarespell>)
events -e_rarespell
findid.i_raretimer.remove
sysmessage @38,,1 Cicegi toplayamadiniz !!!
go <findid.i_gater.morep>
findid.i_gater.timer 2
else
go <findid.i_gater.morep>
findid.i_gater.timer 2
endif




[dialog d_gatetravel22]
100,-100
//nomove

resizepic 190 165 5054 250 150
resizepic 200 175 3000 230 130
dtext 222 185 38 Covede Pk'ların Yanında
dtext 222 205 38 Savasmak istiyorum...
dtext 222 225 38 Pk Olacagim...(10 Kill)
dtext 250 250 100 Evet
dtext 320 250 100 Hayir
dtext 220 280 0713 Kordinat : Cove Disi

button 220 250 5601 5605 1 0 1
button 370 250 5603 5607 1 0 2


[dialog d_gatetravel22 button]
On=0
findid.i_gater.remove

On=1
if (<distance> > 3)
sysmessage @39,,1 Hata: Gate'e ulasamiyorsunuz.
elseif (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @38,,1 Hata: Gizlenmis durumdayken gateten gecemezsiniz
elseif (<isevent.e_rarespell>)
events -e_rarespell
findid.i_raretimer.remove
sysmessage @38,,1 Cicegi toplayamadiniz !!!
go 2303,1210
if (<kills> < 10)
kills 10
endif
findid.i_gater.timer 2
else
go 2303,1210
if (<kills> < 10)
kills 10
endif
endif


[ITEMDEF i_rb_gate22]
ID=i_moongate_blue
RESOURCES=i_scroll_gate_travel
TYPE=t_telepad
NAME=Gate
CATEGORY=Provisions - Alchemy & Magic
SUBSECTION=Moongates
DESCRIPTION=RB Gate

On=@Create
color 0845
more1 5
attr 010

On=@DClick
src.sdialog d_gatetravel22
return 1


ON=@Step
src.sdialog d_gatetravel22


On=@Click
message @38,,1 [Unguarded bölge]
message @38 Covede Pk Olacagim...
return 1

On=@Timer
return 1

[itemdef i_frunebook_gate]
id=i_moongate_blue
type=t_script

on=@create
attr attr_move_never
color 022
timer 30

on=@timer
sfx 528
remove
return 1

on=@click
message <serv.map.region.name>
message <morep>
return 1

on=@step
src.ctag.moongate <uid>
src.sdialog d_frunebookgate
return 1

[ITEMDEF i_gate_bucs1]
defname=i_gate_bucs1
id=i_moongate_blue
type t_normal
name Bucs Gate Giris

On=@Step
if (<src.flags>&statf_stone)
return 1
endif

dorand 3
src.go 2611,976
src.go 2600,986
src.go 2609,993
enddo

ON=@DCLICK
if (<src.flags>&statf_stone)
return 1
endif
IF ( <DISTANCE> > 3 )
SRC.sysmessage @0481,1,1 Gate'e ulasamiyorsunuz.
RETURN 1
ENDIF

dorand 3
SRC.GO = 2611,976
SRC.GO = 2600,986
SRC.GO = 2609,993
enddo
RETURN 1


ON=@CLICK
SAYUa 025,6,6,0 <name>
RETURN 1

[ITEMDEF i_gate_bucs2]
defname=i_gate_bucs2
id=i_moongate_blue
type t_normal
name Bucs Gate Cikis

On=@Step
if (<src.flags>&statf_stone)
return 1
endif
dorand 3
SRC.GO = 2729,2142
SRC.GO = 2726,2127
SRC.GO = 2736,2134
enddo

ON=@DCLICK
if (<src.flags>&statf_stone)
return 1
endif
IF ( <DISTANCE> > 3 )
SRC.sysmessage @0481,1,1 Gate'e ulasamiyorsunuz.
RETURN 1
ENDIF

dorand 3
SRC.GO = 2729,2142
SRC.GO = 2726,2127
SRC.GO = 2736,2134
enddo
RETURN 1

ON=@CLICK
SAYUa 025,6,6,0 <name>
RETURN 1



[EOF]


tamamını attım scriptin



Yazar
Skill Title: Expert
Toplam Mesaj: 305
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Scripter
Yaş: 30
Beğeni: 68
Mesaj #102162   12-07-2021 18:29 GMT    
     
Senin runebook eventin var zaten yukarda olusturduğun eventi sil ve t_ship_plank typedef'ini bunla deyiştir.

Script Kodu:
[Typedef t_ship_plank]
On=@Dclick
if (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)
src.skill fail
endif
if (<ARGN>==32) || (<ARGN>==52)
src.skill fail
endif
if (<src.isevent.e_x_breakspell>)
   src.sysmessage @38,1,1 Gate açarken gemiye giriş yapamazsınız.
  return 1
endif


 Slothere, Ege ERKEK, manolya
Discord= Zedikus#4967
Script && Mull && Word

Yazar
Skill Title: Novice
Toplam Mesaj: 14
Oyun Tarzı: Pp
Emulatör: Sphere
Tecrübe: Diğer
Yaş: 20
Beğeni: 0
Mesaj #102163   12-07-2021 18:51 GMT    
     
Teşekkür ederim oldu



Sayfalar: 1


Benzer Konular :

KonularMesajlarSon gönderenTarih
Gemi Batırma1mahsuni07-07-2021
Web siteden, oyuna kayıt olma sistemi7Jackape11-05-2020
Dialog içinde chat sistemi6xwerswoodx10-03-2018
Recall Olunca Duvar Üstüne Çıkma3MirroR19-10-2017
Evin 2 hafta içinde silinmesi24s3d320-09-2017


Kullanıcı Adı:Parola: Beni Hatırla?


Mythic broadsword sphereserver modernuo runuo ServUO JustUO

Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,

UO-Dev Footer UO-Dev Footer