s.a arkadeşlar runebook ve spellbook scplerini aldım uo devden servera yükledim yetkili çarımla çantamdan kıynatabiliyom ama yeni çar açtım onla kıynatamıyom kafayı yicem sorun ne acaba acilll.hiç kıynamıyo
Bide horsenin scpsi nerde?

İtemleri yerinden oynatamıyorsan "attr" değerlerinde bir sıkıntı vardır.

horse scripti scripts/npcs/spherechar.scp içerisinde olması gerekiyor. horse diye aratırsan 3-4 çeşit vardır. brown, tan, gray gibi.

[ITEMDEF i_runebook1]

ID=i_spellbook

TYPE=T_spellbook

WEIGHT=0.1

NAME=Runebook

RESOURCES=50 i_scroll_blank,4 i_scroll_recall

SKILLMAKE=INSCRIPTION 70.0, MAGERY 60.0



ON=@Create

COLOR=0455

MOREX=9999

ATTR=004

TAG.NAME=Isimsiz

TAG.EATRUNE=01

for 1 16

TAG.POS<dlocal._for>_X=0

endfor



ON=@Click

message @07a1,,1 Rune Book

return 1





ON=@DClick

DIALOGCLOSE d_runebook



if (<cont>) && (<topobj.uid> != <src.uid>) && (<src.account.plevel> < 6)

src.sysmessage @07a5,1,1 Sadece yerdeki veya kendi çantanızdaki runebookları açabilirsiniz.

return 1

elseif (<src.isevent.e_hapis>)

src.sysmessage @07a5,1,1 Jaildeyken bunu kullanamazsınız.

return 1

elseif (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi)

src.sysmessage @07a5,1,1 Evde iken runebook açamazsınız.

return 1

elseif ((<src.findid.i_spdelay_man>) || (<src.findid.i_spdelay_woman>))

src.sysmessage @07a5,1,1 Büyü atarken bunu kullanamazsınız.

return 1

endif



if ((<src.action> == id(skill_magery)) || (<src.action> == skill_magery))

src.f_fizzle

src.FINDID.i_rb_delay.REMOVE

src.FINDID.i_rb_delay2.REMOVE

src.EVENTS -e_x_breakspell

src.f_fizzle

src.sysmessage @07a5,1,1 Savaş hakkındaki düşüncelerin yüzünden bunu kullanamadın.

return 1

endif



if (<src.isevent.e_x_breakspell>)

src.FINDID.i_rb_delay.REMOVE

src.FINDID.i_rb_delay2.REMOVE

src.EVENTS -e_x_breakspell

src.f_fizzle

ENDIF

SRC.SOUND=85

DIALOG d_runebook

RETURN 1





ON=@TargOn_Char

RETURN 1



ON=@TargOn_Item

IF <SRC.TARG.TOPOBJ.UID> != <SRC.UID>

src.sysmessage @07a5,1,1 Ekleyeceğiniz şey çantanızda olmalı.

RETURN 1

ENDIF

IF <MORE2>=1

IF ( <SRC.TARG.ID> = 01f4c )

MOREX=<MOREX> + <SRC.TARG.AMOUNT>

SRC.TARG.REMOVE

src.sysmessage @07a5,1,1 Kitaba <src.targ.amount> adet şarj eklendi.

DIALOGCLOSE d_runebook

dialog d_runebook

ELSe

src.sysmessage @07a5,1,1 Bu bir recall scroll değil.

ENDIF

RETURN 1

ELSEIF <MORE2>=2

IF (( <SRC.TARG.TYPE> = t_rune ) || ( <SRC.TARG.TYPE> = 014 ))

IF (<SRC.TARG.MOREX>==0)

src.sysmessage @07a5,1,1 Bu rune boş, bunu kullanamazsınız.

RETURN 1

ENDIF

ELSE

src.sysmessage @07a5,1,1 Bu bir rune değil.

RETURN 1

ENDIF

TAG.HOLD_LOCAL=<SRC.TARG.NAME>

TAG.HOLD_X=<SRC.TARG.MOREX>

TAG.HOLD_Y=<SRC.TARG.MOREY>

TAG.HOLD_Z=<SRC.TARG.MOREZ>

TAG.HOLD_M=<SRC.TARG.MOREM>

ENDIF



for 1 16

IF (<TAG.POS<dlocal._for>_X>=0)

src.sysmessage @07a5,1,1 Runeyi kitaba eklediniz.

SRC.SOUND=79

try TAG.LOCAL<dlocal._for>=<TAG.HOLD_LOCAL>

try TAG.POS<dlocal._for>_X=<TAG.HOLD_X>

try TAG.POS<dlocal._for>_Y=<TAG.HOLD_Y>

try TAG.POS<dlocal._for>_Z=<TAG.HOLD_Z>

try TAG.POS<dlocal._for>_M=<TAG.HOLD_M>

SRC.TARG.REMOVE

DIALOGCLOSE d_runebook

dialog d_runebook

RETURN 1

ENDIF

endfor

src.sysmessage @07a5,1,1 Kitapda bunun icin bosyer kalmamış.

RETURN 1



[ITEMDEF i_rb_gate]

ID=i_moongate_blue

RESOURCES=i_scroll_gate_travel

TYPE=t_telepad

NAME=Gate

CATEGORY=Provisions - Alchemy & Magic

SUBSECTION=Moongates

DESCRIPTION=RB Gate



On=@Create

color 0845

more1 5

attr 010



On=@DClick

if !(<src.flags>&statf_stone)

if (<distance> > 3)

src.sysmessage @07a5,1,1 Gate'ye ulaşamıyorsunuz.

else

if (<src.findid.i_gater>)

src.findid.i_gater.remove

endif

serv.newitem i_gater

new.link <uid>

new.morep <morep>

new.equip

endif

endif

return 1



ON=@Step

if !((<src.findid.i_gater>) || (<src.flags>&statf_stone))

serv.newitem i_gater

new.link <uid>

new.morep <morep>

new.equip

endif

return 1



On=@Click

if (<color> == 0845)

message @<color>,,1 [UnGuarded Bölge]

else

message @<color>,,1 [Guarded Bölge]

endif

message @0790,,1 Runebook Gate

return 1



On=@Timer

if (<more1>)

more1 <more1> - 1

timer 1

else

sfx 528

remove

endif

return 1



[DIALOG d_runebook]

0,100

//gumppic 100 10 2200

gumppic 70 10 00002b01

gumppic 125 50 57

gumppic 145 50 58

gumppic 160 50 58

gumppic 175 50 58

gumppic 190 50 58

gumppic 205 50 58

gumppic 220 50 58

gumppic 230 50 59

gumppic 290 50 57

gumppic 310 50 58

gumppic 325 50 58

gumppic 340 50 58

gumppic 355 50 58

gumppic 370 50 58

gumppic 385 50 58

gumppic 395 50 59



page 0

//Recall Button

local.satir 65

local.satir2 65

for 1 16

if (<dlocal._for> <= 8)

button 125 <dlocal.satir> 2103 2104 1 0 <dlocal._for>

local.satir += 15

else

button 285 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>

local.satir2 += 15

endif

endfor



//Gate Button

local.satir 65

local.satir2 65

for 17 32

if (<dlocal._for> <= 24)

button 135 <dlocal.satir> 2103 2104 1 0 <dlocal._for>

local.satir += 15

else

button 295 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>

local.satir2 += 15

endif

endfor



//Rune cikar button

local.satir 65

local.satir2 65

for 33 48

if (<dlocal._for> <= 40)

button 260 <dlocal.satir> 2103 2104 1 0 <dlocal._for>

local.satir += 15

else

button 420 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>

local.satir2 += 15

endif

endfor



//Rune isim değiştir

local.satir 65

local.satir2 65

for 49 64

if (<dlocal._for> <= 56)

button 250 <dlocal.satir> 2103 2104 1 0 <dlocal._for>

local.satir += 15

else

button 410 <dlocal.satir2> 2103 2104 1 0 <dlocal._for>

local.satir2 += 15

endif

endfor



//Runebook İsim değiştir

button 140 22 2103 2104 1 0 67

dhtmlgump 155 18 100 17 0 0 <tag.name>



//Rune Ekle Şarj Et

button 303 22 2103 2104 1 0 65

button 303 37 2103 2104 1 0 66

dhtmlgump 318 18 100 20 0 0 Rune Ekle

dhtmlgump 318 33 100 20 0 0 Şarj Et

dhtmlgump 155 35 90 17 0 0 Şarj: <def.bfont_green><MOREX>



//Marklarının ismi

local.satir 61

local.satir2 61

for 1 16

if (<dlocal._for> <= 8)

dhtmlgump 148 <dlocal.satir> 100 17 0 0 <qval (<serv.map(<EVAL <TAG.POS<dlocal._for>_X>>,<EVAL <TAG.POS<dlocal._for>_Y>>,0).region.guarded> == 1)?<def.bfont_blue><TAG.LOCAL<dlocal._for>>:<def.bfont_red><TAG.LOCAL<dlocal._for>>>

local.satir += 15

else

dhtmlgump 307 <dlocal.satir2> 100 17 0 0 <qval (<serv.map(<EVAL <TAG.POS<dlocal._for>_X>>,<EVAL <TAG.POS<dlocal._for>_Y>>,0).region.guarded> == 1)?<def.bfont_blue><TAG.LOCAL<dlocal._for>>:<def.bfont_red><TAG.LOCAL<dlocal._for>>>

local.satir2 += 15

endif

endfor



//Ivırzıvır :=)

dhtmlgump 129 180 100 20 0 0 | |_

dhtmlgump 129 192 100 20 0 0 |___

dhtmlgump 239 180 100 20 0 0 __|

dhtmlgump 264 180 100 20 0 0 |

dhtmlgump 245 192 100 20 0 0 __

dhtmlgump 248 192 100 20 0 0 __|

dhtmlgump 150 184 100 20 0 0 Gate

dhtmlgump 156 196 100 20 0 0 Recall

dhtmlgump 218 184 100 20 0 0 İsim

dhtmlgump 216 196 100 20 0 0 Çıkar



[DIALOG d_runebook BUTTON]

ONBUTTON=0



on 1 16

if (<src.flags>&statf_stone) || (<src.flags>&statf_freeze)

src.sysmessage @07a5,1,1 Bu durumda iken yapamazsınız.

src.f_fizzle

return 1

endif

IF <TAG.POS<dargn>_X>=00

src.sysmessage @07a5,1,1 Bu alan boş.

RETURN 1

ENDIF

IF !<SRC.ISGM>

IF (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi)

//IF <SRC.REGION.FLAGS>&0e

src.sysmessage @07a5,1,1 Evde recall olamazsınız.

return 1

//ENDIF

ENDIF

serv.newitem i_evvarmi

new.p <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>

new.timer 2

local.itemflag <NEW.REGION.FLAGS>

if (<local.itemflag> == 01092)

src.sysmessage @07a5,1,1 Recall olmaya çalıştığınız alanda bir ev bulunmaktadır.Oraya recall olamazsınız.

return 1

endif

IF ( <SRC.MAGERY> < 250 )

src.sysmessage @07a5,1,1 Şarj ile recall olabilmek için 25.0 reg ile recall olabilmek için 40.0 mageryniz olmalıdır.

SRC.SOUND=92

RETURN 1

ENDIF

IF (<SRC.MANA><15)

SRC.SOUND=92

src.sysmessage @07a5,1,1 Yeterli mananız yok.

RETURN 1

ENDIF

IF (<MOREX> > 0)

MOREX -= 1

SRC.spell_say Kal Ort Por

src.sd 2

SRC.ANIM=17

SRC.MANA=(<SRC.MANA>+-15)

ELSEIF (<SRC.RESTEST 1 i_reag_black_pearl>) && (<SRC.RESTEST 1 i_reag_mandrake_root>) && (<SRC.RESTEST 1 i_reag_blood_moss>

IF ( <SRC.MAGERY> < 400 )

src.sysmessage @07a5,1,1 Yeterli skill puanına sahip değilsiniz. (40 Magery Gerekli)

SRC.SOUND=92

return 1

ENDIF

SRC.spell_say Kal Ort Por

src.sd 2

SRC.ANIM=17

SRC.MANA=(<SRC.MANA>+-15)

SRC.CONSUME=1 i_reag_black_pearl

SRC.CONSUME=1 i_reag_blood_moss

SRC.CONSUME=1 i_reag_mandrake_root

ELSE

src.sysmessage @07a5,1,1 Kitapda şarj kalmamış yada üzerinizde büyü yapacak malzeme yok.

SRC.SOUND 92

RETURN 1

ENDIF

ENDIF

serv.newitem i_rb_delay

new.morep <EVAL <TAG.POS<dargn>_X>> <EVAL <TAG.POS<dargn>_Y>> <EVAL <TAG.POS<dargn>_Z>> <EVAL <TAG.POS<dargn>_M>>

new.more1 4

new.equip

RETURN 1





on 17 32

if (<src.flags>&statf_stone) || (<src.flags>&statf_freeze)

src.sysmessage @07a5,1,1 Bu durumda iken yapamazsınız.

src.f_fizzle

return 1

endif

IF <TAG.POS<eval <dargn>-16>_X>=00

src.sysmessage @07a5,1,1 Bu alan boş.

RETURN 1

ENDIF

IF !<SRC.ISGM>

IF (<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi)

//IF <SRC.REGION.FLAGS>&0e

src.sysmessage @07a5,1,1 Evde gate açamazsınız.

return 1

//ENDIF

ENDIF

serv.newitem i_evvarmi

new.p <EVAL <TAG.POS<eval <dargn>-16>_X>> <EVAL <TAG.POS<eval <dargn>-16>_Y>> <EVAL <TAG.POS<eval <dargn>-16>_Z>> <EVAL <TAG.POS<eval <dargn>-16>_M>>

new.timer 2

local.itemflag <NEW.REGION.FLAGS>

if (<local.itemflag> == 01092)

src.sysmessage @07a5,1,1 Gate açmaya çalıştığınız yerde bir ev bulunmaktadır.Oraya gate açamazsınız.

return 1

endif

IF ( <SRC.MAGERY> < 750 )

src.sysmessage @07a5,1,1 Gate açabilmek için en az 75.0 magery skilliniz olmalıdır.

SRC.SOUND=92

RETURN 1

ENDIF

IF (<SRC.MANA><40)

SRC.SOUND=92

src.sysmessage @07a5,1,1 Yeterli mananız yok.

RETURN 1

ENDIF

IF ! (<SRC.RESTEST 1 i_reag_mandrake_root>) |! (<SRC.RESTEST 1 i_reag_sulfur_ash>) |! (<SRC.RESTEST 1 i_reag_black_pearl>)

src.sysmessage @07a5,1,1 Yeterli malzemeye sahip değilsiniz.

SRC.SOUND=92

RETURN 1

ENDIF

SRC.spell_say Vas Rel Por

src.sd 3

SRC.ANIM=17

SRC.MANA=(<SRC.MANA>+-40)

SRC.CONSUME=1 i_reag_black_pearl

SRC.CONSUME=1 i_reag_mandrake_root

SRC.CONSUME=1 i_reag_sulfur_ash

ENDIF

if (((<SRC.UID.<SRC.REGION.UID>.TYPE>==t_multi) || (<src.findid.i_rb_delay2>))

src.FINDID.i_rb_delay.REMOVE

src.FINDID.i_rb_delay2.REMOVE

src.EVENTS -e_x_breakspell   

src.f_fizzle

src.sysmessage @07a5,1,1 Ev içinde gate açamazsınız.

else

serv.newitem i_rb_delay2

new.morep <EVAL <TAG.POS<eval <dargn>-16>_X>> <EVAL <TAG.POS<eval <dargn>-16>_Y>> <EVAL <TAG.POS<eval <dargn>-16>_Z>> <EVAL <TAG.POS<eval <dargn>-16>_M>>

new.more1 6

new.equip

RETURN 1

endif







on 33 48

if !(<topobj.uid> == <src.uid>)

src.sysmessage @07a5,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekiyor.

return 1

endif

IF ( <TAG.POS<eval <dargn>-32>_X> == 0 )

src.sysmessage @07a5,1,1 Bu alan boş.

RETURN 1

ENDIF

serv.newitem i_rune_marker

new.morex <TAG.POS<eval <dargn>-32>_X>

new.morey <TAG.POS<eval <dargn>-32>_Y>

new.morez <TAG.POS<eval <dargn>-32>_Z>

new.morem <TAG.POS<eval <dargn>-32>_M>

new.name <TAG.LOCAL<eval <dargn>-32>>

new.bounce

try TAG.POS<eval <dargn>-32>_X 0

try TAG.LOCAL<eval <dargn>-32>

DIALOG d_runebook



on 49 64

if !(<topobj.uid> == <src.uid>)

src.sysmessage @07a5,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekiyor.

return 1

endif

IF ( <TAG.POS<eval <dargn>-48>_X> == 0 )

src.sysmessage @07a5,1,1 Bu alan boş.

RETURN 1

ELSE

try TAG.LOCALMOREP <EVAL <TAG.POS<eval <dargn>-48>_X>> <EVAL <TAG.POS<eval <dargn>-48>_Y>> <EVAL <TAG.POS<eval <dargn>-48>_Z>> <EVAL <TAG.POS<eval <dargn>-48>_M>>

f_rename <eval <dargn>-48>

src.ctag.ruid <uid>

RETURN 1

ENDIF



on 65

MORE2=2

TARGET

src.sysmessage @07a5,1,1 Eklemek istediğiniz runeyi seçiniz.

return 1



on 66

MORE2=1

TARGET

src.sysmessage @07a5,1,1 Lütfen şarj etmek istediğiniz scrollu seçin.

RETURN 1



on 67

if !(<topobj.uid> == <src.uid>)

src.sysmessage @07a5,1,1 Bu işlemi yapabilmeniz için runebookun çantanızda olması gerekmektedir.

return 1

endif

src.ctag.ruid <uid>

dialogclose d_runebook_rename

DIALOG d_runebook_rename

RETURN 1





[FUNCTION f_rename]

src.ctag.localno <ARGS>

dialogclose d_runebook_localname

dialog d_runebook_localname

RETURN 1



[DIALOG d_runebook_localname]               

100,50

obj <src.ctag.ruid>                           

resizepic 190 175 9300 335 150

resizepic 200 185 9300 315 130

resizepic 220 235 3000 270 22



dtext 215 200 1153 Rune isimi ne olsun ?                   

dtext 255 275 1153 Tamam

dtext 355 275 1153 İptal

dtext 435 275 1153 Reset           

button 220 275 4005 4007 1 0 1     

button 320 275 4005 4007 1 0 2

button 400 275 4005 4007 1 0 3   

dtextentry 225 237 253 25 990 0 <obj.tag.local<dsrc.ctag.localno>>



[DIALOG d_runebook_localname BUTTON]

on 1

obj <src.ctag.ruid> 

for 1 16

if (<dsrc.ctag.localno> == <dlocal._for>)

obj.tag.local<dlocal._for> <argtxt[0]>

endif

endfor

dialogclose d_runebook

dialog d_runebook

return 1



on 2

src.sysmessage @07a5,1,1 İşlem iptal edildi.

return 1



on 3

obj <src.ctag.ruid> 

for 1 16

if (<dsrc.ctag.localno> == <dlocal._for>)

try obj.tag.local<dlocal._for> <serv.map(<EVAL <obj.TAG.POS<dlocal._for>_X>>,<EVAL <obj.TAG.POS<dlocal._for>_Y>>,0).region.name>

endif

endfor

dialogclose d_runebook

dialog d_runebook

RETURN 1



[DIALOG d_runebook_rename]

100,50

obj <src.ctag.ruid>                           

resizepic 190 175 5120 335 150

resizepic 200 185 9300 315 130

resizepic 220 235 3000 270 22



dtext 215 200 1153 Runebook'un yeni isimi ne olsun ?                   

dtext 255 275 1153 Tamam

dtext 355 275 1153 İptal

dtext 435 275 1153 Reset           

button 220 275 4005 4007 1 0 1     

button 320 275 4005 4007 1 0 2

button 400 275 4005 4007 1 0 3   

dtextentry 225 237 253 25 990 0 <obj.tag.name>       



[DIALOG d_runebook_rename BUTTON]

on 1

obj <src.ctag.ruid>

obj.tag.name <ARGTXT[0]>

dialogclose d_runebook

DIALOG d_runebook

RETURN 1



on 2

src.sysmessage @07a5,1,1 İşlemi iptal ettiniz.

return 1



on 3

obj <src.ctag.ruid>

obj.tag.name isimsiz

dialogclose d_runebook

DIALOG d_runebook

RETURN 1

   

[ITEMDEF i_rb_delay]

NAME=runebook delay

ID=i_handr_1

TYPE=T_EQ_SCRIPT

WEIGHT=0

LAYER=layer_special



ON=@Create

ATTR=attr_invis|attr_decay



ON=@Equip

CONT.skill fail

CONT.ACTION=-1

CONT.FLAGS=(<CONT.FLAGS>&~00020)

TIMER=0

CONT.EVENTS=e_x_breakspell



ON=@UNEQUIP

CONT.EVENTS= -e_x_breakspell



ON=@Timer

IF ( <cont> )

IF ( <MORE1> ) && !( <CONT.isgm> )

MORE1=<MORE1>-1

TIMER=1

RETURN 1

ELSE

cont.go <morep>   

if !(<TOPOBJ.REGION.FLAGS>®ion_flag_ship)

topobj.fix

nudgeup

endif     

ENDIF

ENDIF

CONT.EVENTS= -e_x_breakspell

REMOVE

RETURN 1



[EVENTS e_x_breakspell]

ON=@SpellCast

src.sysmessage @07a5,1,1 Konsantrasyonunuzu kaybettiniz.

src.f_fizzle

src.findid.i_rb_delay2.remove

src.findid.i_rb_delay2.remove

src.events -e_x_breakspell



ON=@GetHit

src.sysmessage @07a5,1,1 Konsantrasyonunuzu kaybettiniz.

src.f_fizzle

src.findid.i_rb_delay2.remove

src.findid.i_rb_delay2.remove

src.events -e_x_breakspell



ON=@Hit

src.sysmessage @07a5,1,1 Konsantrasyonunuzu kaybettiniz.

src.f_fizzle

src.findid.i_rb_delay2.remove

src.findid.i_rb_delay2.remove

src.events -e_x_breakspell



ON=[url=u-death-9220.html]@death[/url]

src.findid.i_rb_delay2.remove

src.findid.i_rb_delay2.remove

src.events -e_x_breakspell



ON=@SkillStart

src.sysmessage @07a5,1,1 Konsantrasyonunuzu kaybettiniz.

src.f_fizzle

src.findid.i_rb_delay2.remove

src.findid.i_rb_delay2.remove

src.events -e_x_breakspell





[ITEMDEF i_rb_delay2]

NAME=runebook gate delay

ID=i_handr_1

TYPE=T_EQ_SCRIPT

WEIGHT=0

LAYER=layer_special



ON=@Create

ATTR=attr_invis|attr_decay



ON=@Equip

CONT.skill fail

CONT.ACTION=-1

CONT.FLAGS=(<CONT.FLAGS>&~00020)

TIMER=0

CONT.EVENTS=e_x_breakspell



ON=@UNEQUIP

CONT.EVENTS= -e_x_breakspell



ON=@Timer

IF ( <cont> )

IF ( <MORE1> ) && !( <CONT.isgm> )

IF (<MORE1> == 5)

cont.newitem i_moongate_blue_fx

cont.act.name summoning gate

cont.act.p <morep>

cont.act.morez 1

cont.act.color 0845

cont.act.attr 012

cont.act.timer 5

cont.act.sfx 526

cont.act.fix

//cont.act.morez <cont.act.p>

ENDIF

MORE1=<MORE1>-1

TIMER=1

RETURN 1

ELSE

cont.newitem i_rb_gate

cont.act.color <qval (<serv.map(<cont.p>,0).region.guarded> == 1)?084a:0845>

cont.act.p <morep>

cont.act.morep <cont.p>

cont.act.timer 45

cont.act.sfx 535 // or 526 or 524

cont.act.fix

//cont.act.morez <cont.act.p>

var.gateuid <cont.act.uid>

cont.newitem i_rb_gate

cont.act.color <qval (<serv.map(<morep>,0).region.guarded> == 1)?084a:0845>

cont.act.link <var.gateuid>

cont.act.link.link <cont.act.uid>

cont.act.p <cont.p>

cont.act.morep <morep>

cont.act.timer 45

cont.act.sfx 535 // or 526 or 524

cont.act.fix

//cont.act.morez <cont.act.p>

var.gateuid

ENDIF

ENDIF

REMOVE

RETURN 1



[itemdef i_gater]

name gater

id i_handr_1

type t_eq_script

weight 0

layer layer_special



On=@Create

attr attr_invis|attr_can_decay



On=@Equip

timer 45

src.dialog d_gatetravel

   

On=@Timer

remove

return 1





[dialog d_gatetravel]

-100,-100

nomove

resizepic 200 178 5120 260 160



resizepic 212 190 9300 240 50

resizepic 212 242 9300 240 85



htmlgump 220 197 300 20 2 0 0

htmlgump 220 215 300 20 3 0 0



htmlgump 262 252 40 20 0 0 0

htmlgump 262 275 40 20 1 0 0



htmlgump 220 300 300 20 4 0 0



button 225 250 4006 4007 1 0 1

button 225 272 4018 4019 1 0 0



[dialog d_gatetravel text]

<def.bfont_green>Evet

<def.bfont_lred>Hayır

<def.bfont_red>Gittiği yer :     <def.bfont_black><findid.i_gater.morep>

<def.bfont_red>Gittiği yer : <def.bfont_black><findid.i_gater.link.link.region.name>

<def.bfont_red>Bulunduğunuz Yer : <def.bfont_black><src.region.name>



[dialog d_gatetravel button]

On=0

findid.i_gater.remove



On=1

if !(<findid.i_gater.link.isitem>)

src.sysmessage @07a5,1,1 Gate geçmeden kapanmış.

findid.i_gater.remove

elseif (<findid.i_gater.link.distance> > 3)

src.sysmessage @07a5,1,1 Gateye çok uzaksınız.

findid.i_gater.remove

else

go <findid.i_gater.morep>

findid.i_gater.timer 2

endif



[ITEMDEF i_evvarmi]

ID=i_gold

NAME=Ev varmici

type t_eq_script

VALUE=1

weight 0



On=@Timer

remove



ON=@Create

attr attr_invis|attr_decay



[ITEMDEF i_f_s]

ID=i_spellbook

NAME=Spellbook[Full]

TYPE=t_spellbook



ON=@CREATE

ATTR=0024

MORE=04ffffffff

MORE2=04ffffffff



ON=@Click

message @07a1,,1 Spell Book(Full)

return 1

Nerde sıkıntı

ON=@CREATE
ATTR=0024
MORE=04ffffffff
MORE2=04ffffffff

ATTR 0024 nedir bilmiyorum ancak büyük ihtimalle sıkıntı bundadır. ATTR=attr_newbie yada ATTR=04 yapın. Yine çantanızdan oynatamıyorsanız başka bir scriptte sıkıntı vardır.

Olmadı anlamadım kafayı yicem elinde rune spell scp varmı?

Attr=04 yaptıktan sonra eski runbook'u sil. Yeni runebook ile dene.

Sorunu çözdüm sagolun bide safe alanına region vererek itemleri 10 saniyede sildirecek scp varmı raskoll araştırdım bulamadım

region'un altına ;

on=@enter

events +e_item_remover // veya buraya genel verdiğin bir event varsa onu yazabilirsin



[event e_item_remover]

on=@itemdropon_ground

ref1 <act>

ref1.timer 10

eklersen sorunun çözülecektir.

Çıkarken events silmeyide unutma =)

eventsin altına ekledim 10 saniyede silmiyo