tcpip -  10-08-2009 21:18
Kod:
// tcpip tarafindan 28.01.2006 tarihinde tamamlandı 
// oyuncular pin korumasi istemeleri kosulunda
// .pin yazarak alabilirler. yazmayan oyuncular etkilenmez.
// pin sormasını istediğiniz yere
////////////////////////////////
// if (<account.tag.pin)
// if !(<tag.pingirisi>
// src.pin
// return 1
// endif
// endif
////////////////////////////////
// seklinde sormasını saglayabilirsiniz.

[plevel 1]
pin
yenipin

[function pin]
var.br <br
if !(0<tag.pingirisi>
if (0<account.tag.pin>
dialog d_pin_sistemi
else
tag.pingirisi 1
src.sysmessage @027,1,1 Yeni pin olusturabilmek icin forumlarin profil bolumunden yapiniz.
endif
else
sysmessage @0481 Zaten giris yapmissiniz.
endif


[function yenipin]
if (0<tag.pingirisi>
src.dialog d_yenipin
else
sysmessage @0481 Pin girisi yapmadan pin degistiremessiniz.
pin
endif

[dialog d_pin_sistemi]
0,0
resizepic 200 175 5054 400 260
resizepic 210 185 3000 380 140
resizepic 300 360 5054 120 20
textentry 320 360 330 35 2525 4 5

htmlgump 220 195 60 20 0 0 0
htmlgump 220 220 360 100 1 1 0

htmlgump 255 387 400 20 2 0 0
htmlgump 225 360 100 20 4 0 0
button 220 385 4005 4007 1 0 1
textentry 320 360 330 35 0 1 3

[dialog d_pin_sistemi text]
XXX UO Pin Sistemi :
Not : Yazdiginiz pin ekraninizda gozukmez. Lutfen asagidaki alana kodunuzu yazip Tamam Tusuna basin. Pin kodu account guvenliginizi artirmak icindir. Pin kodunuzu kimse ile paylasmayiniz.
Tamam Giris Yap
000000
Pin Kodunuz:
||||||||||||||||||||||||||||||||||||
[dialog d_pin_sistemi button]
On=0
tag.pingirisi
sysmessage @0481 Giris yapmadiniz bu yuzden bazi ozellikleri kullanamayacaksiniz.

On=1
if (!<isnum <argtxt[1]>>
src.sysmessage @38,1,1 Giris basarisiz!
return 1
endif
if (<account.tag.pin>==<argtxt[1]>
sysmessage @0481 Giris basarili. Artik islemlerinizi yapabilirsiniz.
tag.pingirisi 1
else
sysmessage @38,1,1 Giris basarisiz!
endif

[dialog d_yenipin]
0,0
resizepic 200 175 5054 400 260
resizepic 210 185 3000 380 240

htmlgump 220 195 60 20 0 0 0
htmlgump 220 220 360 100 1 1 0

htmlgump 255 387 400 20 2 0 0
htmlgump 225 360 100 20 5 0 0
htmlgump 425 360 100 20 6 0 0
htmlgump 225 340 300 20 7 0 0

button 220 385 4005 4007 1 0 1
textentry 300 360 330 35 1152 1 3
textentry 500 360 330 35 1152 2 4

[dialog d_yenipin text]
XXX UO Pin Sistemi :
Dikkat : Burada yapicaniz islemin donusu yoktur. Guvenliginiz icin pin kodunuzu girerken kimsenin izlemedigindem emin olun. Pin kodunuzu degistirmek istediginizde lutfen unutmayacaginiz ve kolay bulunamicak bir kombinasyon secin.
Tamam Yeni Pini Kaydet
******
******
Pin Kodunuz:
Tekrar :
Min. 4 Max. 8 hane

[dialog d_yenipin button]
on=0
tag.pingirisi
src.sysmessage @038,1,1 Pin kodunuzu degistirmediniz.

On=1
if (!<isnum <argtxt[1]>>
src.sysmessage @38,1,1 Sadece rakam girmeniz gereklidir.
return 1
endif
if (!<isnum <argtxt[2]>>
src.sysmessage @38,1,1 Sadece rakam girmeniz gereklidir.
return 1
endif
if (<eval strlen(<argtxt[1]>>>8)
src.sysmessage @38,1,1 minimum 4 maximum 8 haneli sayi olabilir.
return 1
endif
if (<eval strlen(<argtxt[1]>><4)
src.sysmessage @38,1,1 minimum 4 maximum 8 haneli sayi olabilir.
return 1
endif
if (<tag0.pingirisi>
if (<argtxt[1]>==<argtxt[2]>
src.yenipinaldim <argtxt[1]>
src.sysmessage @38,1,1 Pin Kodunuz degistirildi. Unutmayin Yeni Pin Kodunuz <argtxt[1]>
src.tag.pingirisi
else
src.sysmessage @38,1,1 Yazilan iki pin ayni degil.
endif
else
srcsysmessage @38,1,1 Pin girisi yapmadan pin degistiremessiniz.
src.pin
endif

[function yenipinaldim]
newitem i_account_pin
new.more1 <args>
new.timer 1
new.equip

[itemdef i_account_pin]
id i_gold
name account pin
type t_eq_script
layer 511

on=@timer
cont.account.tag.pin <more1>
remove

[eof]

YORUMLAR (0)

Henüz yorum yapılmamış.

BENZER SAYFALAR