UO-Dev Arama


Sunucular için gerekli olan blacksmith craft menüsü

Yazar: Bilinmiyor
Tarih: 19-09-2009 19:05





Kod:
[DIALOG D_BS_ITEM_PROPS]
40, 20
src.closealldialogs
PAGE 0
resizepic 0 0 5054 550 465
checkertrans 10 10 530 445
gumppictiled 10 205 170 45 2624
checkertrans 10 205 170 45
gumppictiled 10 390 365 30 2624
checkertrans 10 390 365 30
gumppictiled 10 285 170 70 2624
checkertrans 10 285 170 70
gumppictiled 10 10 530 30 2624
checkertrans 10 10 530 30
gumppictiled 10 45 160 155 2624
checkertrans 10 45 160 155
gumppictiled 175 45 365 100 2624
checkertrans 175 45 365 100
gumppictiled 175 150 365 100 2624
checkertrans 175 150 365 100
gumppictiled 175 255 365 100 2624
checkertrans 175 255 365 100
gumppictiled 175 360 365 60 2624
checkertrans 175 360 365 60

tilepic 40 60 <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.ID>

xmfhtmlgumpcolor 190 15 200 35 1044002 0 0 32767 //blacksmithing menu

xmfhtmlgumpcolor 180 55 100 30 1011152 0 0 32767 //item
dhtmlgump 330 55 250 30 0 0 <DEF.BFONT_WHITE><SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.NAME><DEF.BFONTE>

IF (0<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>)
LOCAL.CRAFTCHANCE=<eval <floatval ((<src.blacksmithing>/(<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10))*0.75)-0.05>/10000>
LOCAL.EXCEPTIONALCHANCE=<eval <floatval ((<src.armslore>/(<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10))*0.75)-0.30>/10000>
ELSE
LOCAL.CRAFTCHANCE=100
LOCAL.EXCEPTIONALCHANCE=100
ENDIF
IF (<LOCAL.CRAFTCHANCE> > 100)
LOCAL.CRAFTCHANCE=100
ENDIF
IF (<LOCAL.EXCEPTIONALCHANCE> > 100)
LOCAL.EXCEPTIONALCHANCE=100
ENDIF

xmfhtmlgumpcolor 180 100 120 30 1044057 0 0 32767 //success chance
dtext 420 100 1153 <FVAL <LOCAL.CRAFTCHANCE>*10>%
xmfhtmlgumpcolor 180 120 120 30 1044058 0 0 32767 //exceptional chance
dtext 420 120 1153 <FVAL <LOCAL.EXCEPTIONALCHANCE>*10>%

dhtmlgump 180 160 250 30 0 0 <DEF.BFONT_WHITE>Blacksmithing<DEF.BFONTE>
dtext 420 160 1153 <FVAL <serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>>

xmfhtmlgumpcolor 30 260 100 30 1044055 0 0 32767
dhtmlgump 200 260 300 200 0 0 <DEF.BFONT_WHITE><serv.itemdef.<SRC.CTAG.BS.ITEM>.RESMAKE><DEF.BFONTE>

xmfhtmlgumpcolor 30 360 100 30 1044056 0 0 32767
xmfhtmlgumpcolor 200 360 300 30 1044059 0 0 32767
xmfhtmlgumpcolor 200 380 300 30 1044152 0 0 32767

resizepic 10 430 5120 530 23
checkertrans 10 430 530 23

button 20 431 0fae 0fb0 1 0 1
xmfhtmlgumpcolor 55 433 100 30 1044150 0 0 32767 //back

button 320 431 4005 4006 1 0 2
xmfhtmlgumpcolor 355 433 100 30 1044151 0 0 32767 //make now

[DIALOG D_BS_ITEM_PROPS BUTTON]
ON=1
DIALOG d_newcraft_dialog_bs

ON=2
SRC.F_CRAFTITEM_BS

[DIALOG d_newcraft_dialog_bs]
40, 20
src.closealldialogs
PAGE 0
resizepic 0 0 5054 550 465
gumppictiled 10 10 530 30 2624
checkertrans 10 10 530 30
gumppictiled 10 45 160 280 2624
checkertrans 10 45 160 280
gumppictiled 175 45 365 280 2624
checkertrans 175 45 365 280
//////
gumppictiled 10 330 160 40 2624
checkertrans 10 330 160 40
gumppictiled 175 330 365 40 2624
checkertrans 175 330 365 40
gumppictiled 10 375 530 85 2624
checkertrans 10 375 530 85
xmfhtmlgumpcolor 190 15 200 35 1044002 0 0 32767 //blacksmithing menu
xmfhtmlgumpcolor 10 45 150 35 1044010 0 0 32767 //categories
FOR 0 8
xmfhtmlgumpcolor 40 <EVAL 65+(22*<LOCAL._FOR>)> 100 35 <EVAL 1011076+<LOCAL._FOR>> 0 0 32767
button 10 <EVAL 65+(22*<LOCAL._FOR>)> 4005 4006 0 <EVAL <LOCAL._FOR>+2> 1
ENDFOR
xmfhtmlgumpcolor 280 45 150 35 1044011 0 0 32767 //selections
xmfhtmlgumpcolor 20 340 100 35 1044012 0 0 32767 //notices
dhtmlgump 200 330 320 35 0 0 <DEF.BFONT_WHITE><SRC.CTAG.BS.MESSAGE><DEF.BFONTE>

button 290 425 4005 4006 1 0 88
xmfhtmlgumpcolor 325 427 100 35 1044013 0 0 32767 //make last
button 290 400 4005 4006 1 0 10000
IF (!(<SRC.TAG0.MARKITEM>))
xmfhtmlgumpcolor 325 402 100 35 1044017 0 0 32767 //mark item
ELSE
xmfhtmlgumpcolor 325 402 100 35 1044018 0 0 32767 //do not mark
ENDIF
button 290 375 4005 4006 1 0 10001
xmfhtmlgumpcolor 325 377 100 35 1044015 0 0 32767 //repair

button 20 400 4005 4006 0 13 10002 //ingots
IF (<ISEMPTY <SRC.CTAG.BSMATERIAL>>)
SRC.CTAG.BSMATERIAL=iron
ENDIF
IF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,iron)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>IRON(<SRC.RESCOUNT i_ingot_iron>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,dull_copper)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>DULL COPPER(<SRC.RESCOUNT i_ingot_dull_copper>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,silver)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>SILVER(<SRC.RESCOUNT i_ingot_silver>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,copper)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>COPPER(<SRC.RESCOUNT i_ingot_copper>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,bronze)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>BRONZE(<SRC.RESCOUNT i_ingot_bronze>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,gold)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>GOLD(<SRC.RESCOUNT i_ingot_gold>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,agapite)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>AGAPITE(<SRC.RESCOUNT i_ingot_agapite>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,verite)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>VERITE(<SRC.RESCOUNT i_ingot_verite>)<DEF.BFONTE>
ELIF (!(STRCMPI(<SRC.CTAG.BSMATERIAL>,valorite)))
dhtmlgump 55 402 200 35 0 0 <DEF.BFONT_WHITE>VALORITE(<SRC.RESCOUNT i_ingot_valorite>)<DEF.BFONTE>
ENDIF

button 20 375 4005 4006 1 0 10003
xmfhtmlgumpcolor 55 377 100 35 1044016 0 0 32767 //smelt

button 20 425 0fb1 0fb3 1 0 0
xmfhtmlgumpcolor 55 427 100 35 1011441 0 0 32767 //exit

PAGE 2 //ringmail
xmfhtmlgumpcolor 215 65 150 35 1025100 0 0 32767 //ringmail tunic
button 180 65 4005 4006 1 0 2
button 500 65 0FAB 0FAD 1 0 1002
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1025102 0 0 32767 //ringmail sleeves
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 3
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1003
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1025104 0 0 32767 //ringmail leggings
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 4
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1004
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1025106 0 0 32767 //ringmail gloves
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 5
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1005

PAGE 3 //chainmail
xmfhtmlgumpcolor 215 65 150 35 1025060 0 0 32767 //chainmail tunic
button 180 65 4005 4006 1 0 6
button 500 65 0FAB 0FAD 1 0 1006
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1025057 0 0 32767 //chainmail leggings
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 7
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1007
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1025056 0 0 32767 //chainmail coif
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 8
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1008
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1053012 0 0 32767 //dragon barding deed
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 87
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1087

PAGE 4 //platemail
xmfhtmlgumpcolor 215 65 150 35 1025141 0 0 32767 //platemail tunic
button 180 65 4005 4006 1 0 9
button 500 65 0FAB 0FAD 1 0 1009
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1025146 0 0 32767 //legs
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 10
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1010
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1025143 0 0 32767 //arms
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 11
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1011
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1025144 0 0 32767 //gloves
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 12
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1012
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1025139 0 0 32767 //gorget
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 13
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1013
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1030105 0 0 32767 //mempo
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 14
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1014
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1030109 0 0 32767 //do
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 15
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1015
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1030112 0 0 32767 //hiro-sode
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 16
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1016
xmfhtmlgumpcolor 215 <EVAL 65+(22*8)> 150 35 1030120 0 0 32767 //suneate
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 17
button 500 <EVAL 65+(22*8)> 0FAB 0FAD 1 0 1017
xmfhtmlgumpcolor 215 <EVAL 65+(22*9)> 150 35 1030125 0 0 32767 //haidate
button 180 <EVAL 65+(22*9)> 4005 4006 1 0 18
button 500 <EVAL 65+(22*9)> 0FAB 0FAD 1 0 1018

PAGE 5 //helmets
xmfhtmlgumpcolor 215 65 150 35 1025133 0 0 32767 //bascinet
button 180 65 4005 4006 1 0 19
button 500 65 0FAB 0FAD 1 0 1019
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1025129 0 0 32767 //close helm
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 20
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1020
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1025130 0 0 32767 //helmet
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 21
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1021
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1025135 0 0 32767 //norse helm
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 22
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1022
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1025138 0 0 32767 //plate helm
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 23
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1023
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1030100 0 0 32767 //chainmail hatsuburi
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 24
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1024
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1030101 0 0 32767 //platemail hatsuburi
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 25
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1025
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1030121 0 0 32767 //kabuto
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 26
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1026
xmfhtmlgumpcolor 215 <EVAL 65+(22*8)> 150 35 1031118 0 0 32767 //circlet
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 27
button 500 <EVAL 65+(22*8)> 0FAB 0FAD 1 0 1027

PAGE 6 //shields
xmfhtmlgumpcolor 215 65 150 35 1015044 0 0 32767 //buckler
button 180 65 4005 4006 1 0 28
button 500 65 0FAB 0FAD 1 0 1028
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1015045 0 0 32767 //bronze
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 29
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1029
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1015049 0 0 32767 //heater
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 30
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1030
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1015046 0 0 32767 //metal
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 31
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1031
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1015048 0 0 32767 //kite
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 32
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1032
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1027107 0 0 32767 //chaos
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 33
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1033
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1027108 0 0 32767 //order
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 34
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1034

PAGE 7 //bladed
xmfhtmlgumpcolor 215 65 150 35 1029915 0 0 32767 //bone harvester
button 180 65 4005 4006 1 0 35
button 500 65 0FAB 0FAD 1 0 1035
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1023935 0 0 32767 //broadsword
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 36
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1036
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1029921 0 0 32767 //crescent blade
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 37
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1037
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1025185 0 0 32767 //cutlass
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 38
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1038
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1023922 0 0 32767 //dagger
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 39
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1039
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1025118 0 0 32767 //katana
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 40
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1040
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1025120 0 0 32767 //kryss
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 41
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1041
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1029597 0 0 32767 //longsword
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 42
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1042
xmfhtmlgumpcolor 215 <EVAL 65+(22*8)> 150 35 1025046 0 0 32767 //scimitar
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 43
button 500 <EVAL 65+(22*8)> 0FAB 0FAD 1 0 1043
xmfhtmlgumpcolor 215 <EVAL 65+(22*9)> 150 35 1025049 0 0 32767 //viking sword
button 180 <EVAL 65+(22*9)> 4005 4006 1 0 44
button 500 <EVAL 65+(22*9)> 0FAB 0FAD 1 0 1044
xmfhtmlgumpcolor 215 <EVAL 65+(22*10)> 150 35 1030221 0 0 32767 //no dachi
button 180 <EVAL 65+(22*10)> 4005 4006 1 0 45
button 500 <EVAL 65+(22*10)> 0FAB 0FAD 1 0 1045
xmfhtmlgumpcolor 400 <EVAL 83+(22*10)> 150 35 1044045 0 0 32767 //next page
button 360 <EVAL 82+(22*10)> 4005 4006 0 11 1

PAGE 11 //continuation of bladed
xmfhtmlgumpcolor 215 65 150 35 1030223 0 0 32767 //wakizashi
button 180 65 4005 4006 1 0 46
button 500 65 0FAB 0FAD 1 0 1046
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1030226 0 0 32767 //lajatang
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 47
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1047
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1030228 0 0 32767 //daisho
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 48
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1048
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1030230 0 0 32767 //tekagi
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 49
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1049
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1030232 0 0 32767 //kama
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 50
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1050
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1030234 0 0 32767 //sai
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 51
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1051
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1031559 0 0 32767 //radiant scimitar
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 52
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1052
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1031555 0 0 32767 //war cleaver
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 53
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1053
xmfhtmlgumpcolor 215 <EVAL 65+(22*8)> 150 35 1031552 0 0 32767 //elven spellblade
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 54
button 500 <EVAL 65+(22*8)> 0FAB 0FAD 1 0 1054
xmfhtmlgumpcolor 215 <EVAL 65+(22*9)> 150 35 1031553 0 0 32767 //assassin spike
button 180 <EVAL 65+(22*9)> 4005 4006 1 0 55
button 500 <EVAL 65+(22*9)> 0FAB 0FAD 1 0 1055
xmfhtmlgumpcolor 215 <EVAL 65+(22*10)> 150 35 1031554 0 0 32767 //leafblade
button 180 <EVAL 65+(22*10)> 4005 4006 1 0 56
button 500 <EVAL 65+(22*10)> 0FAB 0FAD 1 0 1056
xmfhtmlgumpcolor 380 <EVAL 83+(22*10)> 150 35 1044045 0 0 32767 //next page
button 340 <EVAL 82+(22*10)> 4005 4006 0 12 1
xmfhtmlgumpcolor 230 <EVAL 83+(22*10)> 150 35 1044044 0 0 32767 //prev page
button 310 <EVAL 82+(22*10)> 0fae 0fb0 0 7 1

PAGE 12 //continuation of bladed
xmfhtmlgumpcolor 215 65 150 35 1031570 0 0 32767 //rune blade
button 180 65 4005 4006 1 0 57
button 500 65 0FAB 0FAD 1 0 1057
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1031573 0 0 32767 //elven machete
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 58
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1058
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1072916 0 0 32767 //cold forged blade
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 59
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1059
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1072920 0 0 32767 //overseer sundered blade
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 60
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1060
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1072922 0 0 32767 //luminous rune blade
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 61
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1061
xmfhtmlgumpcolor 230 <EVAL 83+(22*10)> 150 35 1044044 0 0 32767 //prev page
button 310 <EVAL 82+(22*10)> 0fae 0fb0 0 11 1

PAGE 8 //axes
xmfhtmlgumpcolor 215 65 150 35 1023913 0 0 32767 //axe
button 180 65 4005 4006 1 0 62
button 500 65 0FAB 0FAD 1 0 1062
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1023912 0 0 32767 //battle axe
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 63
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1063
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1023915 0 0 32767 //double axe
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 64
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1064
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1023909 0 0 32767 //executioner's axe
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 65
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1065
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1025114 0 0 32767 //large battle axe
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 66
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1066
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1015061 0 0 32767 //two handed axe
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 67
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1067
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1015064 0 0 32767 //war axe
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 68
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1068
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1031560 0 0 32767 //ornate axe
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 69
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1069

PAGE 9 //polearms
xmfhtmlgumpcolor 215 65 150 35 1023918 0 0 32767 //bardiche
button 180 65 4005 4006 1 0 70
button 500 65 0FAB 0FAD 1 0 1070
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1029917 0 0 32767 //bladed staff
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 71
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1071
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1029919 0 0 32767 //double bladed staff
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 72
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1072
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1025183 0 0 32767 //halberd
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 73
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1073
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1028758 0 0 32767 //lance
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 74
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1074
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1029928 0 0 32767 //pike
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 75
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1075
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1025123 0 0 32767 //short spear
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 76
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1076
xmfhtmlgumpcolor 215 <EVAL 65+(22*7)> 150 35 1029914 0 0 32767 //scythe
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 77
button 500 <EVAL 65+(22*7)> 0FAB 0FAD 1 0 1077
xmfhtmlgumpcolor 215 <EVAL 65+(22*8)> 150 35 1029595 0 0 32767 //spear
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 78
button 500 <EVAL 65+(22*8)> 0FAB 0FAD 1 0 1078
xmfhtmlgumpcolor 215 <EVAL 65+(22*9)> 150 35 1025125 0 0 32767 //war fork
button 180 <EVAL 65+(22*9)> 4005 4006 1 0 79
button 500 <EVAL 65+(22*9)> 0FAB 0FAD 1 0 1079

PAGE 10 //bashing
xmfhtmlgumpcolor 215 65 150 35 1025180 0 0 32767 //hammer pick
button 180 65 4005 4006 1 0 80
button 500 65 0FAB 0FAD 1 0 1080
xmfhtmlgumpcolor 215 <EVAL 65+(22*1)> 150 35 1023933 0 0 32767 //mace
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 81
button 500 <EVAL 65+(22*1)> 0FAB 0FAD 1 0 1081
xmfhtmlgumpcolor 215 <EVAL 65+(22*2)> 150 35 1025178 0 0 32767 //maul
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 82
button 500 <EVAL 65+(22*2)> 0FAB 0FAD 1 0 1082
xmfhtmlgumpcolor 215 <EVAL 65+(22*3)> 150 35 1029916 0 0 32767 //scepter
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 83
button 500 <EVAL 65+(22*3)> 0FAB 0FAD 1 0 1083
xmfhtmlgumpcolor 215 <EVAL 65+(22*4)> 150 35 1029599 0 0 32767 //war mace
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 84
button 500 <EVAL 65+(22*4)> 0FAB 0FAD 1 0 1084
xmfhtmlgumpcolor 215 <EVAL 65+(22*5)> 150 35 1025177 0 0 32767 //war hammer
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 85
button 500 <EVAL 65+(22*5)> 0FAB 0FAD 1 0 1085
xmfhtmlgumpcolor 215 <EVAL 65+(22*6)> 150 35 1031556 0 0 32767 //diamond mace
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 86
button 500 <EVAL 65+(22*6)> 0FAB 0FAD 1 0 1086

PAGE 13
dhtmlgump 215 65 150 35 0 0 <DEF.BFONT_WHITE>IRON(<SRC.RESCOUNT i_ingot_iron>)<DEF.BFONTE>
button 180 65 4005 4006 1 0 2001
dhtmlgump 215 <EVAL 65+(22*1)> 150 35 0 0 <DEF.BFONT_WHITE>DULL COPPER(<SRC.RESCOUNT i_ingot_dull_copper>)
button 180 <EVAL 65+(22*1)> 4005 4006 1 0 2002
dhtmlgump 215 <EVAL 65+(22*2)> 150 35 0 0 <DEF.BFONT_WHITE>SILVER(<SRC.RESCOUNT i_ingot_silver>)
button 180 <EVAL 65+(22*2)> 4005 4006 1 0 2003
dhtmlgump 215 <EVAL 65+(22*3)> 150 35 0 0 <DEF.BFONT_WHITE>COPPER(<SRC.RESCOUNT i_ingot_copper>)
button 180 <EVAL 65+(22*3)> 4005 4006 1 0 2004
dhtmlgump 215 <EVAL 65+(22*4)> 150 35 0 0 <DEF.BFONT_WHITE>BRONZE(<SRC.RESCOUNT i_ingot_bronze>)
button 180 <EVAL 65+(22*4)> 4005 4006 1 0 2005
dhtmlgump 215 <EVAL 65+(22*5)> 150 35 0 0 <DEF.BFONT_WHITE>GOLD(<SRC.RESCOUNT i_ingot_gold>)
button 180 <EVAL 65+(22*5)> 4005 4006 1 0 2006
dhtmlgump 215 <EVAL 65+(22*6)> 150 35 0 0 <DEF.BFONT_WHITE>AGAPITE(<SRC.RESCOUNT i_ingot_agapite>)
button 180 <EVAL 65+(22*6)> 4005 4006 1 0 2007
dhtmlgump 215 <EVAL 65+(22*7)> 150 35 0 0 <DEF.BFONT_WHITE>VERITE(<SRC.RESCOUNT i_ingot_verite>)
button 180 <EVAL 65+(22*7)> 4005 4006 1 0 2008
dhtmlgump 215 <EVAL 65+(22*8)> 150 35 0 0 <DEF.BFONT_WHITE>VALORITE(<SRC.RESCOUNT i_ingot_valorite>)
button 180 <EVAL 65+(22*8)> 4005 4006 1 0 2009

[DIALOG d_newcraft_dialog_bs BUTTON]
ON=0
SRC.CTAG.BS.MESSAGE=

ON=2 88
IF (<ARGN1> != 88)
F_SELECT_BSITEM <EVAL <ARGN1>-2>
ENDIF
SRC.F_CRAFTITEM_BS

ON=1002 1087
F_SELECT_BSITEM <EVAL <ARGN1>-1002>
DIALOG D_BS_ITEM_PROPS

ON=2001 2009
IF (<ARGN1> == 2001)
SRC.CTAG.BSMATERIAL=iron
ELIF (<ARGN1> == 2002)
SRC.CTAG.BSMATERIAL=dull_copper
ELIF (<ARGN1> == 2003)
SRC.CTAG.BSMATERIAL=silver
ELIF (<ARGN1> == 2004)
SRC.CTAG.BSMATERIAL=copper
ELIF (<ARGN1> == 2005)
SRC.CTAG.BSMATERIAL=bronze
ELIF (<ARGN1> == 2006)
SRC.CTAG.BSMATERIAL=gold
ELIF (<ARGN1> == 2007)
SRC.CTAG.BSMATERIAL=agapite
ELIF (<ARGN1> == 2008)
SRC.CTAG.BSMATERIAL=verite
ELIF (<ARGN1> == 2009)
SRC.CTAG.BSMATERIAL=valorite
ENDIF
DIALOG d_newcraft_dialog_bs

ON=10000
IF (<SRC.TAG0.MARKITEM>)
SRC.TAG.MARKITEM=
ELSE
SRC.TAG.MARKITEM=1
ENDIF
DIALOG d_newcraft_dialog_bs

ON=10001
SRC.TARGETF F_REPAIR_ITEM_BS

ON=10003
IF (<SRC.ISNEARTYPE t_forge 3>)
SRC.TARGETF f_bs_ruo_smelt
SRC.CTAG.BS.MESSAGE=Choose the item.
ENDIF
DIALOG d_newcraft_dialog_bs

[FUNCTION F_CRAFTITEM_BS]
LOCAL.ARMSLOREPROPCHANCE=<FEVAL <FLOATVAL ((<SRC.ARMSLORE>/3.25)+(<SRC.BLACKSMITHING>/3.25)+(<SRC.LUCK>/45))+5>>
IF (<LOCAL.ARMSLOREPROPCHANCE> > 98)
LOCAL.ARMSLOREPROPCHANCE=98
ENDIF
LOCAL.ITEMIDPROPCHANCE=<FEVAL <FLOATVAL ((<SRC.ITEMID>/3.25)+(<SRC.BLACKSMITHING>/3.25)+(<SRC.LUCK>/45))+5>>
IF (<LOCAL.ITEMIDPROPCHANCE> > 98)
LOCAL.ITEMIDPROPCHANCE=98
ENDIF
IF (0<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>)
LOCAL.CRAFTCHANCE=<eval <floatval ((<src.blacksmithing>/(<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10))*0.75)-0.05>/10000>
LOCAL.EXCEPTIONALCHANCE=<eval <floatval ((<src.armslore>/(<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10))*0.75)-0.30>/10000>
ELSE
LOCAL.CRAFTCHANCE=100
LOCAL.EXCEPTIONALCHANCE=100
ENDIF
REF1=<SRC.FINDLAYER.1.UID>
IF (!(<SRC.CTAG0.BS.ITEM>))
SRC.CTAG.BS.MESSAGE=You must select an item to make.
ELIF (!(<SRC.ISNEARTYPE T_FORGE 2>)) && (!(<SRC.ISNEARTYPE T_ANVIL 2>))
SRC.CTAG.BS.MESSAGE=You must be near an anvil and a forge to smith items.
ELIF (<SRC.FINDLAYER.1.TYPE> != T_WEAPON_MACE_SMITH)
SRC.CTAG.BS.MESSAGE=The tool must be on your person to use.
ELIF (!(<SRC.CANMAKESKILL <SRC.CTAG.BS.ITEM>>))
SRC.CTAG.BS.MESSAGE=You don't have the required skills to attempt this item.
ELIF (!(<SRC.F_BS_CHECK_FOR_MATERIALS <SRC.CTAG.BS.ITEM>>))
SRC.CTAG.BS.MESSAGE=You don't have the components needed to make that.
ELIF (<SRC.CTAG0.IJUSTCRAFTED>)
SRC.CTAG.BS.MESSAGE=You must wait a few moments before crafting another item.
ELIF (<LOCAL.CRAFTCHANCE> >= <R1,100>)
IF (<LOCAL.CRAFTCHANCE> < 100)
SRC.SKILLGAIN Blacksmithing <EVAL (<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10)>
SRC.SKILLGAIN Armslore <EVAL (<serv.itemdef.<SRC.CTAG.BS.ITEM>.skillmake.1.val>/10)>
ENDIF
SRC.CTAG.IJUSTCRAFTED=1
SRC.TAG.NoMoveTill=<EVAL <SERV.TIME>+50>
SRC.TIMERF 2,TAG.NoMoveTill
SRC.TIMERF 2,CTAG.IJUSTCRAFTED=
SRC.CTAG.BS.MESSAGE=You craft the item.
SERV.NEWITEM=<SRC.CTAG.BS.ITEM>
SERV.LOG <NAME> (<UID>) crafts <NEW.NAME> (<NEW.BASEID>)
IF (!(<NEW.TAG0.ISARTIFACT>))
NEW.GIVEITEMEVENT T_PROPRIEDADES
NEW.F_GIVE_BONUS_FROM_METAL <SRC.CTAG.BSMATERIAL>
IF (<LOCAL.EXCEPTIONALCHANCE> >= <R1,100>)
IF (<NEW.VALUE>)
NEW.QUALITY=200
ENDIF
SRC.CTAG.BS.MESSAGE=You create an exceptional quality item.
IF (<SRC.TAG0.MARKITEM>)
NEW.TAG.CRAFTEDBY=<SRC.NAME>
ENDIF
IF (<NEW.ISWEAPON>)
LOCAL.BONUSFORDAMAGEINCREASE=<EVAL (35+(<SRC.ARMSLORE>/200))>
NEW.TAG0.DAMINCREASE += <LOCAL.BONUSFORDAMAGEINCREASE>
SRC.SYSMESSAGE @04ec,3,1 Your item receives a <dLOCAL.BONUSFORDAMAGEINCREASE>% damage increase bonus for being exceptional.
ENDIF
ENDIF
IF (<NEW.ISWEAPON>)
NEW.F_GIVE_PROPS <LOCAL.ARMSLOREPROPCHANCE>
ELIF (<NEW.ISARMOR>) && (<NEW.TYPE> != t_clothing) && (<NEW.TYPE> != T_SHIELD)
FOR <R3,4>
LOCAL.GAVEPROP=0
IF (<LOCAL.ARMSLOREPROPCHANCE> >= <R1,100>)
WHILE (!(<LOCAL.GAVEPROP>))
DORAND 7
BEGIN
IF (!(<LOCAL.GAVELOWERMANACOST>))
NEW.TAG0.LOWERMANACOST += <R3,8>
LOCAL.GAVELOWERMANACOST=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEREGENERATION>))
NEW.GIVEITEMEVENT T_STATUS_BONUS
DORAND 3
NEW.TAG0.MANAREGENERATION += <R1,2>
NEW.TAG0.HITSREGENERATION += <R1,2>
NEW.TAG0.STAMREGENERATION += <R1,2>
ENDDO
LOCAL.GAVEREGENERATION=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEINCREASE>))
NEW.GIVEITEMEVENT T_STATUS_BONUS
DORAND 3
NEW.TAG0.MANAINCREASE += <R3,6>
NEW.TAG0.STAMINCREASE += <R3,6>
NEW.TAG0.HITSINCREASE += <R3,6>
ENDDO
LOCAL.GAVEINCREASE=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVESELFREPAIR>))
NEW.TAG.SELFREPAIR=<R1,4>
LOCAL.GAVESELFREPAIR=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEDAMAGERETURN>))
NEW.GIVEITEMEVENT T_DAMAGERETURN
NEW.TAG.DAMAGERETURN=<R4,10>
LOCAL.GAVEDAMAGERETURN=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVELUCK>))
NEW.GIVEITEMEVENT T_LUCK_ITEM
NEW.TAG0.LUCK += <R40,100>
LOCAL.GAVELUCK=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVELOWERREAGENTCOST>))
NEW.TAG0.LOWERREAGENTCOST += <R10,20>
LOCAL.GAVELOWERREAGENTCOST=1
LOCAL.GAVEPROP=1
ENDIF
END
ENDDO
ENDWHILE
ENDIF
ENDFOR
ELIF (<NEW.TYPE> == T_SHIELD)
FOR 5
LOCAL.GAVEPROP=0
IF (<LOCAL.ARMSLOREPROPCHANCE> >= <R1,100>)
WHILE (!(<LOCAL.GAVEPROP>))
DORAND 7
BEGIN
IF (!(<LOCAL.GAVELOWERMANACOST>))
NEW.TAG0.LOWERMANACOST += <R3,8>
LOCAL.GAVELOWERMANACOST=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVESELFREPAIR>))
NEW.TAG.SELFREPAIR=<R1,4>
LOCAL.GAVESELFREPAIR=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEHITCHANCEDECREASE>))
NEW.TAG.HITCHANCEDECREASE=<R6,15>
LOCAL.GAVEHITCHANCEDECREASE=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEDAMAGERETURN>))
NEW.GIVEITEMEVENT T_DAMAGERETURN
NEW.TAG.DAMAGERETURN=<R5,10>
LOCAL.GAVEDAMAGERETURN=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVESPELLCHANNELING>))
NEW.TAG.SPELLCHANNELING=1
NEW.TAG.FASTERCASTING=-1
LOCAL.GAVESPELLCHANNELING=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVEFASTERCASTING>))
NEW.TAG0.FASTERCASTING ++
IF (!(<NEW.TAG0.FASTERCASTING>))
NEW.TAG.FASTERCASTING=
ENDIF
LOCAL.GAVEFASTERCASTING=1
LOCAL.GAVEPROP=1
ENDIF
END
BEGIN
IF (!(<LOCAL.GAVELUCK>))
NEW.GIVEITEMEVENT T_LUCK_ITEM
NEW.TAG0.LUCK += <R20,40>
LOCAL.GAVELUCK=1
LOCAL.GAVEPROP=1
ENDIF
END
ENDDO
ENDWHILE
ENDIF
ENDFOR
ENDIF
ENDIF
NEW.BOUNCE
FOR <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.COUNT>
IF (<SERV.ITEMDEF.<SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>.TYPE> != T_INGOT)
SRC.CONSUME <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL> <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>
ELSE
SRC.CONSUME <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL> i_ingot_<SRC.CTAG.BSMATERIAL>
ENDIF
ENDFOR
SRC.ANIM 5
SRC.SOUND 42
SRC.TIMERF 2,ANIM 5
SRC.TIMERF 2,SOUND 42
IF (<REF1.TAG0.CHARGES> == 1)
SRC.MESSAGE @,,2 1044262
REF1.TIMERF 1,REMOVE
ELSE
REF1.TAG0.CHARGES --
REF1.RESENDTOOLTIP 1
ENDIF
ELSE
SRC.CTAG.BS.MESSAGE=You failed to create the item, and some of your materials are lost.
FOR <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.COUNT>
IF (<SERV.ITEMDEF.<SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>.TYPE> != T_INGOT)
SRC.CONSUME <EVAL (30*<SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL>)/100> <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>
ELSE
SRC.CONSUME <EVAL (30*<SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL>)/100> i_ingot_<SRC.CTAG.BSMATERIAL>
ENDIF
ENDFOR
IF (<REF1.TAG0.CHARGES> == 1)
SRC.MESSAGE @,,2 1044262
REF1.TIMERF 1,REMOVE
ELSE
REF1.TAG0.CHARGES --
REF1.RESENDTOOLTIP 1
ENDIF
ENDIF
DIALOG d_newcraft_dialog_bs

[FUNCTION F_REPAIR_ITEM_BS]
IF (<ARGO.BASEID> == i_scroll_blank) && (<ARGO.TOPOBJ.UID> == <SRC.UID>)
ARGO.f_create_repair_contract 7
ELSE
LOCAL.SKILL=<DEF.<SERV.ITEMDEF.<ARGO.ID>.SKILLMAKE.1.KEY>>
LOCAL.SKILL &= ~0c0000000
IF (!(<ARGO.MAXHITS>)) || (<ARGO.HITS> == <ARGO.MAXHITS>) || (<ARGO.TOPOBJ.UID> != <SRC.UID>)
SRC.SYSMESSAGELOC -1,1047014
ELIF (<LOCAL.SKILL> != 7)
SRC.SYSMESSAGELOC -1,1061136
ELSE
IF (<R<EVAL <SRC.BLACKSMITHING>/10>> < <R<EVAL (<ARGO.MAXHITS>*10)/(<ARGO.HITS>+1))>>)
ARGO.MAXHITS --
IF (<ARGO.MAXHITS> <= 0)
ARGO.REMOVE
SRC.SYSMESSAGELOC -1,500424
ELSE
ARGO.HITS=<ARGO.MAXHITS>
SRC.SYSMESSAGELOC -1,1062782
ENDIF
ELSE
ARGO.HITS=<ARGO.MAXHITS>
SRC.SYSMESSAGELOC -1,500425
ENDIF
ARGO.RESENDTOOLTIP 1
ENDIF
ENDIF
DIALOG d_newcraft_dialog_bs

[FUNCTION F_BS_CHECK_FOR_MATERIALS]
FOR <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.COUNT>
IF (<SERV.ITEMDEF.<SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.KEY>.TYPE> != T_INGOT)
IF (<SRC.RESTEST <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>>>)
LOCAL.OK ++
ENDIF
ELSE
IF (<SRC.RESTEST <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.<dLOCAL._FOR>.VAL> i_ingot_<SRC.CTAG.BSMATERIAL>>)
LOCAL.OK ++
ENDIF
ENDIF
ENDFOR
IF (<LOCAL.OK> < <SERV.ITEMDEF.<SRC.CTAG.BS.ITEM>.RESOURCES.COUNT>)
RETURN 0
ELSE
RETURN 1
ENDIF

[FUNCTION f_bs_ruo_smelt]
IF (<ARGO.ISITEM>)
IF (<ISNEARTYPE t_forge 3>)
IF (((<argo.isweapon>) || (<argo.isarmor>) || (<argo.type> == t_shield)) && (<argo.type>!=t_weapon_bow) && (<argo.type>!=t_weapon_xbow) && (<ARGO.TYPE> != t_armor_leather))
IF !(<ISEMPTY <ARGO.TAG.CRAFTED.MATERIAL>>)
IF (<ARGO.TOPOBJ.UID> == <UID>)
IF !(<ARGO.ISINBANK <UID>>)
SERV.NEWITEM <ARGO.TAG.CRAFTED.MATERIAL>,<EVAL <STRARG <ARGO.RESOURCES>>/2>,<UID>
ARGO.REMOVE
ENDIF
ENDIF
ENDIF
ENDIF
ENDIF
ENDIF

[FUNCTION F_SELECT_BSITEM]
DOSWITCH <ARGN1>
SRC.CTAG.BS.ITEM=i_ringmail_tunic
SRC.CTAG.BS.ITEM=i_ringmail_sleeves
SRC.CTAG.BS.ITEM=i_ringmail_leggings
SRC.CTAG.BS.ITEM=i_ringmail_gloves
SRC.CTAG.BS.ITEM=i_chainmail_tunic
SRC.CTAG.BS.ITEM=i_chainmail_leggings
SRC.CTAG.BS.ITEM=i_chainmail_coif
SRC.CTAG.BS.ITEM=i_platemail_chest
SRC.CTAG.BS.ITEM=i_platemail_leggings
SRC.CTAG.BS.ITEM=i_platemail_arms
SRC.CTAG.BS.ITEM=i_platemail_gloves
SRC.CTAG.BS.ITEM=i_platemail_gorget
SRC.CTAG.BS.ITEM=i_platemail_mempo
SRC.CTAG.BS.ITEM=i_platemail_do
SRC.CTAG.BS.ITEM=i_platemail_hiro_sode
SRC.CTAG.BS.ITEM=i_platemail_suneate
SRC.CTAG.BS.ITEM=i_platemail_haidate
SRC.CTAG.BS.ITEM=i_bascinet
SRC.CTAG.BS.ITEM=i_helm_closed
SRC.CTAG.BS.ITEM=i_helm_open
SRC.CTAG.BS.ITEM=i_helm_nose
SRC.CTAG.BS.ITEM=i_platemail_helm
SRC.CTAG.BS.ITEM=i_chainmail_hatsuburi
SRC.CTAG.BS.ITEM=i_platemail_hatsuburi
SRC.CTAG.BS.ITEM=i_platemail_kabuto
SRC.CTAG.BS.ITEM=i_circlet
SRC.CTAG.BS.ITEM=i_shield_buckler
SRC.CTAG.BS.ITEM=i_shield_round_bronze
SRC.CTAG.BS.ITEM=i_shield_heater
SRC.CTAG.BS.ITEM=i_shield_round_metal
SRC.CTAG.BS.ITEM=i_shield_kite_metal
SRC.CTAG.BS.ITEM=i_shield_chaos
SRC.CTAG.BS.ITEM=i_shield_order
SRC.CTAG.BS.ITEM=i_bone_harvester
SRC.CTAG.BS.ITEM=i_sword_broad
SRC.CTAG.BS.ITEM=i_double_blade
SRC.CTAG.BS.ITEM=i_cutlass
SRC.CTAG.BS.ITEM=i_dagger
SRC.CTAG.BS.ITEM=i_katana
SRC.CTAG.BS.ITEM=i_kryss
SRC.CTAG.BS.ITEM=i_sword_long
SRC.CTAG.BS.ITEM=i_scimitar
SRC.CTAG.BS.ITEM=i_sword_viking
SRC.CTAG.BS.ITEM=i_nodachi
SRC.CTAG.BS.ITEM=i_wakizashi
SRC.CTAG.BS.ITEM=i_lajatang
SRC.CTAG.BS.ITEM=i_daicho
SRC.CTAG.BS.ITEM=i_tekagi
SRC.CTAG.BS.ITEM=i_kama
SRC.CTAG.BS.ITEM=i_sai
SRC.CTAG.BS.ITEM=i_radiant_scimitar
SRC.CTAG.BS.ITEM=i_sword_warcleaver
SRC.CTAG.BS.ITEM=i_elven_spellblade
SRC.CTAG.BS.ITEM=i_sword_assassin_spike
SRC.CTAG.BS.ITEM=i_sword_leafblade
SRC.CTAG.BS.ITEM=i_rune_blade
SRC.CTAG.BS.ITEM=i_elven_machete
SRC.CTAG.BS.ITEM=i_cold_forged_blade
SRC.CTAG.BS.ITEM=i_overseer_sundered_blade
SRC.CTAG.BS.ITEM=i_luminous_rune_blade
SRC.CTAG.BS.ITEM=i_axe
SRC.CTAG.BS.ITEM=i_axe_battle
SRC.CTAG.BS.ITEM=i_axe_double
SRC.CTAG.BS.ITEM=i_axe_exec
SRC.CTAG.BS.ITEM=i_axe_battle_large
SRC.CTAG.BS.ITEM=i_axe_two_hand
SRC.CTAG.BS.ITEM=i_axe_war
SRC.CTAG.BS.ITEM=i_ornate_axe
SRC.CTAG.BS.ITEM=i_bardiche
SRC.CTAG.BS.ITEM=i_bladed_staff
SRC.CTAG.BS.ITEM=i_double_bladed_staff
SRC.CTAG.BS.ITEM=i_halberd
SRC.CTAG.BS.ITEM=i_lance
SRC.CTAG.BS.ITEM=i_pike
SRC.CTAG.BS.ITEM=i_spear_short
SRC.CTAG.BS.ITEM=i_scyth
SRC.CTAG.BS.ITEM=i_spear
SRC.CTAG.BS.ITEM=i_war_fork
SRC.CTAG.BS.ITEM=i_hammer_pick
SRC.CTAG.BS.ITEM=i_mace
SRC.CTAG.BS.ITEM=i_maul
SRC.CTAG.BS.ITEM=i_scepter
SRC.CTAG.BS.ITEM=i_mace_war
SRC.CTAG.BS.ITEM=i_hammer_war
SRC.CTAG.BS.ITEM=i_mace_diamondmace
SRC.CTAG.BS.ITEM=i_barding_deed
ENDDO

[FUNCTION F_GIVE_BONUS_FROM_METAL]
GIVEITEMEVENT T_PROPRIEDADES
IF (STRCMPI(iron,<ARGS>))
COLOR=color_o_<args>
IF (STRCMPI(dull_copper,<ARGS>))
NAME=<ARGS> <NAME>
ELSE
NAME=Dull Copper <NAME>
ENDIF
TAG.CRAFTED.MATERIAL=i_ingot_<ARGS>
ELSE
TAG.CRAFTED.MATERIAL=i_ingot_iron
ENDIF
IF (<ISWEAPON>)
IF (!(STRCMPI(iron,<ARGS>)))
RETURN 1
ELSE
MAXHITS += <EVAL 15+<SERV.ITEMDEF.i_ingot_<ARGS>.TAG.HITSBONUS>+<R0,5>>
HITS=<MAXHITS>
ENDIF
ELIF (<ISARMOR>) && (<TYPE> != T_SHIELD)
IF (!(STRCMPI(silver,<ARGS>)))
TAG0.HITCHANCEINCREASE += 3
ELIF (!(STRCMPI(gold,<ARGS>)))
EVENTS +T_LUCK_ITEM
TAG0.LUCK += 40
ELIF (!(STRCMPI(agapite,<ARGS>)))
TAG0.HITCHANCEDECREASE += 3
ELIF (!(STRCMPI(verite,<ARGS>)))
TAG0.SWINGINCREASE += 3
ELIF (!(STRCMPI(valorite,<ARGS>)))
TAG0.DAMINCREASE += 3
ENDIF
IF (STRCMPI(iron,<ARGS>))
MODAR += <SERV.ITEMDEF.i_ingot_<ARGS>.TAG.ARMORBONUS>
ENDIF
ENDIF

[EOF]



Yorumlar

1.   Gönderen Belvoure   24-11-2017 10:14    

Şu scp'yi sırf dialog boxla uğraşmamak için aldım yani varya bugunu düzeltip servera uyarlayana kadar yazmış kadar oldum ITEM EVENTLERI NERDEEEE??????

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : Henüz Oylanmamış   
Oylar: 0

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
House Crafting0aldarson26-06-2010
Tinkering Crafting0TheRaskol19-09-2009
Tailor Crafting0TheRaskol19-09-2009
Inscription Crafting0TheRaskol19-09-2009
Carpentry Crafting0TheRaskol19-09-2009


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,