// SON GUNCELLEME : Pazar, Mart 29, 2010
// TIP : Sıfırdan Hazırlama
VERSION=0.56b
//###################################################//
//####### Zindan sistemi değişken tanımları #########//
//###################################################//
[DEFNAME PARTY_SYSTEM]
DUNGEONPLACE = 5364,1767,-116
SAFEALAN = 5546,1648,0
RESTOCKERP = 5319,1587
//###################################################//
//####### Zindan sistemi alan tanımlaması ###########//
//###################################################//
[AREADEF A_INISTANCE_ROOM]
NAME=Zindan
RECT=5377,1780,5125,1523
P=5364,1767,-116
EVENTS=R_INISTANCE_EVENT
FLAGS=REGION_ANTIMAGIC_RECALL_IN|REGION_ANTIMAGIC_RECALL_OUT|REGION_ANTIMAGIC_GATE|REGION_ANTIMAGIC_TELEPORT|REGION_FLAG_NOBUILDING
//###################################################//
//######### Zindan sistemi genel işlemler ###########//
//###################################################//
[FUNCTION F_DUNGEON_RESTOCK]
REF1 = <VAR.RESTOCKERID>
IF (<REF1> == 0)
SERV.NEWITEM I_DUNGEON_RESTOCKER
NEW.P <DEF.RESTOCKERP>
REF1 = <NEW.UID>
ENDIF
REF1.ATTR ATTR_STATIC|ATTR_INVIS
REF1.REGION.RESTOCK
[FUNCTION F_PARTY_CONTROL]
IF (<SRC.ISINPARTY> == 1)
IF ((<SRC.PARTY.MEMBERS> == 5)
IF (<SRC.PARTY.MEMBER.0.UID> == <VAR.INISTANCELEADER>)
RETURN 1
ELSE
RETURN 0
ENDIF
ELSE
RETURN 0
ENDIF
ELSE
RETURN 0
ENDIF
[FUNCTION F_PARTY_CHECKER]
IF (<SRC.F_PARTY_CONTROL> == 0)
SRC.DUNGEONEXIT <VAR.INISTANCELEADER>
ELSE
SRC.TIMERF 5,F_PARTY_CHECKER
ENDIF
[ITEMDEF I_DUNGEON_RESTOCKER]
ID=01E9
NAME=Zindan Yenileyici
TYPE=T_NORMAL
ON=@CLICK
MESSAGE @39,0,1 [ Zindan Sistemi ]
MESSAGE @50,0,1 [ Zindan Yenileyicisi ]
SRC.SYSMESSAGE @39,0,1 Zindan Sistemi yenilenmesi için gerekli bir objedir lütfen bu obje ile oynamayınız aski halinde sorgusuz bloke edilirsiniz..
RETURN 1
ON=@CREATE
ATTR=ATTR_INVIS|ATTR_MOVE_NEVER|ATTR_STATIC|ATTR_DECAY
VAR.RESTOCKERID = <UID>
TIMER = 1
ON=@PICKUP_GROUND
RETURN 1
ON=@DCLICK
RETURN 1
ON=@DESTROY
RETURN 1
ON=@TIMER
IF !(<DVAR.INISTANCETIMER> == -1)
VAR.INISTANCETIMER -= 1
ENDIF
IF (<DVAR.INISTANCETIMER> == 3300)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 55 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 3000)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 50 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 2700)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 45 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 1800)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 30 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 900)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 15 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 450)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 7.5 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 225)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 3.5 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 60)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 1 dakika içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ELSEIF (<DVAR.INISTANCETIMER> == 10)
SERV.ALLCLIENTS SYSMESSAGE @39,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 <UID.<VAR.INISTANCELEADER>.NAME> ve partisi 10 saniye içerisinde zindanı bitiremezlerse zindandan atılacaktırlar..
ENDIF
IF (<DVAR.INISTANCETIMER> == 0)
DUNGEONEXIT <VAR.INISTANCELEADER>
VAR.INISTANCETIMER = -1
ENDIF
TIMER 1
RETURN 1
[REGIONTYPE R_INISTANCE_EVENT]
ON=@ENTER
IF (<SRC.ISPLAYER>) && !(<SRC.ISGM>)
IF (<SRC.ISEVENT.E_DUNGEONACTIVE> == 0)
SRC.TIMERF 5,SRC.GO <DEF.SAFEALAN>
ENDIF
ENDIF
ON=@EXIT
IF (<SRC.ISPLAYER>) && !(<SRC.ISGM>)
IF (<SRC.ISINPARTY> == 1)
SRC.DUNGEONEXIT <SRC.UID>
ENDIF
ENDIF
[ITEMDEF I_DUNGEON_STONE]
ID = 10901
NAME = Dungeon Stone
TYPE = T_DUNGEONSTONE
VALUE = 1
ON=@CREATE
COLOR = 07C4
ATTR = ATTR_STATIC
[TYPEDEF T_DUNGEONSTONE]
ON=@CLICK
MESSAGE @39,0,1 [ <SERV.NAME> ]
MESSAGE @07A1,0,1 Zindan Girişi
IF (<DVAR.ISPARTYACTIVE> == 1)
MESSAGE @39,0,1 Şu anda dolu
ELSEIF (<DVAR.ISPARTYACTIVE> == 0)
MESSAGE @50,0,1 Boş
ENDIF
RETURN 1
ON=@DCLICK
IF (<DISTANCE <SRC.UID>> > 5)
SRC.SYSMESSAGE @39,0,1 Bu sistemi kullanabilmek için taşa 5 kare yakın olmanız gerekmektedir..
ELSEIF (<SRC.ISINPARTY> == 0)
SRC.SYSMESSAGE @39,0,1 Bu sistemi sadece parti sahibi kullanabilir..
ELSEIF (<SRC.DCTAG.DUNGEONNOFLOOD> == 1)
SRC.SYSMESSAGE @39,0,1 Bu sistemi sadece 10 saniyede bir kullanabilirsiniz..
ELSEIF (<VAR.ISPARTYACTIVE> == 1)
SRC.SYSMESSAGE @39,0,1 Şu anda bir parti zindanı kullanmaktadır..
ELSEIF !(<SRC.PARTY.MEMBER.0.UID> == <SRC.UID>)
SRC.SYSMESSAGE @39,0,1 Bu sistemi sadece parti sahibi kullanabilir..
ELSEIF !(<SRC.PARTY.MEMBERS> == 5) && (<SRC.ACCOUNT.PLEVEL> == 1)
SRC.SYSMESSAGE @39,0,1 Bu sistemi kullanabilmek için partinizde 5 kişi olması gerekmektedir..
ELSEIF (<SRC.PARTYMEMBERCHECK <UID>,<SRC.UID>>)
SRC.SYSMESSAGE @39,0,1 Lütfen zindana girecek olan parti oyuncularınızı toplayıp tekrar deneyiniz..
ELSE
SRC.PARTY_TELEPORT <SRC.UID>
ENDIF
SRC.F_PARTYWAIT
RETURN 1
[FUNCTION DUNGEONEXIT]
REF1 = <ARGV[0]>
IF (<REF1> == 0)
RETURN 1
ENDIF
FOR PARTY_PLAYERS 0 4
REF2 = <VAR.INISTANCEMEMBER<DLOCAL.PARTY_PLAYERS>>
REF2.EVENTS -E_DUNGEONACTIVE
REF2.STONE 1
REF2.TIMERF 10,STONE 0
REF2.HITS = <REF2.STR>
REF2.TIMERF 10,GO <DEF.SAFEALAN>
REF2.FINDID.I_DUNGEON_QUITTER.REMOVE
REF2.SYSMESSAGE @39,0,1 <REF1.NAME> isimli oyuncu zindandan ayrıldığı için zindandan atıldınız..
REF2.SYSMESSAGE @39,0,1 10 saniye içerisinde safe alana ışınlanıcaksınız..
ENDFOR
VAR.ISPARTYACTIVE = 0
REF1.PARTY.DISBAND
SERV.ALLCLIENTS SYSMESSAGE @07A1,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 Zindan şu anda kullanılabilir durumdadır..
VAR.INISTANCETIMER = -1
VAR.INISTANCELEADER = 0
RETURN 1
[FUNCTION F_PARTYWAIT]
SRC.CTAG.DUNGEONNOFLOOD = 1
SRC.TIMERF 10,SRC.CTAG.DUNGEONNOFLOOD = 0
[FUNCTION PARTYMEMBERCHECK]
REF1 = <ARGV[0]>
REF2 = <ARGV[1]>
LOCAL.PARTYNOTALLOWED = 0
FOR PARTY_PLAYERS 0 <EVAL <REF2.PARTY.MEMBERS> - 1>
REF3 = <REF2.PARTY.MEMBER.<DLOCAL.PARTY_PLAYERS>.UID>
IF (<REF1.DISTANCE <REF3.UID>> > 5)
LOCAL.PARTYNOTALLOWED = 1
REF2.PARTY.MEMBER.0.SYSMESSAGE @39,0,1 <REF3.NAME> isimli oyuncu taştan 5 kare uzakta olduğu için işleminiz iptal edildi..
ENDIF
IF !(<REF3.FINDLAYER.25.UID> == 0)
LOCAL.PARTYNOTALLOWED = 1
REF2.PARTY.MEMBER.0.SYSMESSAGE @39,0,1 <REF3.NAME> isimli oyuncunun altında bineği olduğu için işleminiz iptal edildi..
ENDIF
ENDFOR
RETURN <DLOCAL.PARTYNOTALLOWED>
[FUNCTION PARTY_TELEPORT]
F_DUNGEON_RESTOCK
REF1 = <ARGV[0]>
FOR PARTY_PLAYERS 0 <EVAL <REF1.PARTY.MEMBERS> - 1>
REF2 = <REF1.PARTY.MEMBER.<DLOCAL.PARTY_PLAYERS>.UID>
REF2.EVENTS +E_DUNGEONACTIVE
REF2.GO <DEF.DUNGEONPLACE>
REF2.HITS = <REF2.STR>
REF2.MANA = <REF2.INT>
REF2.STAM = <REF2.DEX>
VAR.INISTANCEMEMBER<DLOCAL.PARTY_PLAYERS> = <REF2.UID>
ENDFOR
SERV.NEWITEM I_DUNGEON_QUITTER
NEW.CONT <REF1.UID>
REF1.TIMERF 5,F_PARTY_CHECKER
VAR.INISTANCELEADER = <REF1.PARTY.MEMBER.0.UID>
VAR.INISTANCETIMER = 3600
VAR.INISTANCELOOTSTART = 0
VAR.ISPARTYACTIVE = 1
SERV.ALLCLIENTS SYSMESSAGE @07A1,0,1 Zindan Sistemi :
SERV.ALLCLIENTS SYSMESSAGE @50,0,1 Zindana şu anda <REF1.NAME> ve partisi girmiş bulunmaktadır..
[EVENTS E_DUNGEONACTIVE]
ON=@CLICK
MESSAGE @39,0,1 [ Zindan Takımı ]
MESSAGE @50,0,1 <NAME>
RETURN 1
ON=@LOGOUT
SRC.DUNGEONEXIT <SRC.UID>
ON=@DEATH
BEYAZ 30 Saniye Donar
STONE 1
HITS = <STR>
TIMERF 30,STONE 0
RETURN 1
ON=@SPELLSELECT
IF (<ARGN1> == 45) || (<ARGN1> == 32) || (<ARGN1> == 52) || (<ARGN1> == 22)
SRC.SYSMESSAGE @39,0,1 Büyünüz zindanın kudretli güçleri tarafından bloke edilmiştir..
RETURN 1
ENDIF
ON=@HITTRY
IF !(<UID> == <SRC.UID>)
IF (<INSAMEPARTY <SRC.UID>>)
ACTION - 1
RETURN 1
ENDIF
ENDIF
ON=@ATTACK
TRIGGER=@HITTRY
ON=@SPELLEFFECT
IF !(<UID> == <SRC.UID>) && !(<ARGN> == 59) && !(<ARGN> == 4) && !(<ARGN> == 29)
IF (<INSAMEPARTY <UID>>)
SRC.ACTION - 1
RETURN 1
ENDIF
ENDIF
ON=@HIT
TRIGGER=@HITTRY
ON=@ITEMDCLICK
IF (<ACT.BASEID> == I_RUNEBOOK)
SRC.SYSMESSAGE @39,0,1 Zindanın kudretli güçleri eşyanın kullanılmasını engelliyor..
RETURN 1
ENDIF
IF (<ACT.LINK> != <SRC.UID>)
IF (<ACT.ID> == 02006) && !(<ACT.LINK> == 04FFFFFFF)
RETURN 1
ENDIF
ENDIF
ON=@MOUNT
SRC.SYSMESSAGE @39,0,1 Bu alanda bineğe binemezsiniz..
RETURN 1
ON=@ITEMTARGON_ITEM
IF (<ARGO.LINK> != <UID>)
IF (<ARGO.ID> == 02006) && !(<ARGO.LINK> == 04FFFFFFF)
RETURN 1
ENDIF
ENDIF
[FUNCTION INSAMEPARTY]
IF ((<UID.<ARGV[0]>.ISINPARTY>) && (<ISINPARTY>))
IF <UID.<ARGV[0]>.PARTY.MEMBER.0.UID>==<PARTY.MEMBER.0.UID>
RETURN 1
ELSE
RETURN 0
ENDIF
ELSE
RETURN 0
ENDIF
[ITEMDEF I_DUNGEON_QUITTER]
ID=01F19
NAME=Zindan Bitirici
TYPE=T_NORMAL
VALUE=1
ON=@CREATE
COLOR 07B5
ATTR ATTR_NEWBIE
ON=@CLICK
MESSAGE @50,0,1 [ Zindan ]
MESSAGE @07A1,0,1 [ Zindan bitirici ]
RETURN 1
ON=@DCLICK
IF (<SRC.ISEVENT.E_DUNGEONACTIVE> == 1)
SRC.BEYAZ Zindan bitirici kullanır
SRC.DUNGEONEXIT <SRC.UID>
ENDIF
REMOVE
RETURN 1
//###################################################//
//########### Inistance Boss Eşyaları ###############//
//###################################################//
[ITEMDEF I_INISTANCE_POINT]
ID=9909
NAME=Zindan Puanı
TYPE=T_NORMAL
VALUE=1
ON=@CREATE
COLOR 07C5
ON=@DCLICK
SRC.SYSMESSAGE @39,0,1 Bu eşya zindan sistemindeki yaratıklardan çıkmaktadır.. Bu eşya ile zindan sisteminin özel olarak size sunduğu eşyaları satın alabilirsiniz..
RETURN 1
ON=@CLICK
MESSAGE @50,0,1 [ <AMOUNT> Adet ]
MESSAGE @07A1,0,1 <NAME>
RETURN 1
[ITEMDEF I_INISTANCE_RESURRECT]
ID=I_MOONGATE_BLACK
NAME=Diriltme Gatesi
TYPE=T_NORMAL
ON=@CREATE
COLOR 07C4
ATTR ATTR_STATIC
ON=@CLICK
MESSAGE @39,0,1 [ Zindan ]
MESSAGE @07A1,0,1 Diriltme Taşı
RETURN 1
ON=@STEP
IF (<SRC.HITS> == 0)
SRC.RESURRECT
SRC.BEYAZ Zindan gücü diriltir
RETURN 1
ENDIF
ON=@DCLICK
TRIGGER=@STEP
//###################################################//
//########### Inistance Boss Eventleri ##############//
//###################################################//
[EVENTS E_INISTANCE_EVENT]
ON=@CLICK
MESSAGE @07a1,0,1 [ Zindan ]
MESSAGE @39,0,1 <NAME>
RETURN 1
ON=@DCLICK
IF (!(<SRC.ACCOUNT.PLEVEL> == 1) && !(<SRC.DTAG.HIGHTERSTAFF> == 1))
RETURN 1
ENDIF
ON=@SPELLEFFECT
IF (<MANA> >= 40)
IF (<ARGN> == 20) || (<ARGN> == 38) || (<ARGN> == 43)
BEYAZ Resist
ATTACK
MANA -= 40
RETURN 1
ENDIF
ENDIF
ON=@DEATHCORPSE
ARGO.TAG.INISTANCELOOT = 1
ARGO.TAG.INISTANCELOOTER = <VAR.INISTANCEMEMBER<DVAR.INISTANCELOOTSTART>>
IF (<DVAR.INISTANCELOOTSTART> == 4)
VAR.INISTANCELOOTSTART = 0
ELSE
VAR.INISTANCELOOTSTART += 1
ENDIF
ON=@GETHIT
IF (<SRC.ISEVENT.E_DUNGEONACTIVE> == 0)
SRC.HITS -= 200
RETURN 1
ENDIF
IF (<MANA> >= 500)
IF (<HITS> <= <EVAL <STR>/4>)
HITS += <EVAL <STR> / 8>
MANA -= 500
BEYAZ Heal
EFFECT 3,0376A,1,30,1
SOUND SND_SPELL_HEAL
ENDIF
ENDIF
IF (<MANA> >= 25)
IF (<FINDID.I_RUNE_POISON>) || (<FINDID.I_RUNE_POISON_FIELD>)
IF (RAND(3) == 1)
FACE
ANIM 17
EFFECT 3,0376A,1,30,1
SOUND SND_SPELL_CURE
FINDID.I_RUNE_POISON.REMOVE
FINDID.I_RUNE_POISON_FIELD.REMOVE
MANA -= 25
BEYAZ Resist
ENDIF
ELSEIF (<SRC.FINDID.I_RUNE_SUMMON_CREATURE>) && (<MANA> > 20)
FACE
ANIM 17
SOUND SND_SPELL_DISPEL
SRC.HITS 0
MANA -= 25
MANA (<MANA> - 20)
BEYAZ Dispel
ENDIF
ENDIF
[EVENTS E_BOSS_EVENT]
ON=@CLICK
MESSAGE @50,0,1 [ Şampıyon ]
MESSAGE @39,0,1 <NAME>
RETURN 1
ON=@DCLICK
IF (!(<SRC.ACCOUNT.PLEVEL> == 1) && !(<SRC.DTAG.HIGHTERSTAFF> == 1))
RETURN 1
ENDIF
ON=@SPELLEFFECT
IF (<MANA> >= 40)
IF (<ARGN> == 20) || (<ARGN> == 38) || (<ARGN> == 43)
BEYAZ Resist
ATTACK
MANA -= 40
RETURN 1
ENDIF
ENDIF
IF (<ARGN> == 31) || (<ARGN> == 53)|| (<ARGN> == 20)
BEYAZ Resist
RETURN 1
ELSEIF (<ARGN> == 47) || (<ARGN> == 39)
FORITEMS 10
IF (<ATTR>&ATTR_MAGIC)
IF (<TYPE> == T_SPELL)
REMOVE
ENDIF
ENDIF
ENDFOR
BEYAZ Resist
RETURN 1
ENDIF
ON=@GETHIT
IF (<SRC.ISEVENT.E_DUNGEONACTIVE> == 0)
SRC.HITS -= 200
RETURN 1
ENDIF
IF (<MANA> >= 400)
IF (<HITS> <= <EVAL <STR>/4>)
HITS += <EVAL <STR> / 8>
MANA -= 400
BEYAZ Heal
EFFECT 3,0376A,1,30,1
SOUND SND_SPELL_HEAL
ENDIF
ENDIF
IF (<MANA> >= 25)
IF (<FINDID.I_RUNE_POISON>) || (<FINDID.I_RUNE_POISON_FIELD>)
IF (RAND(3) == 1)
FACE
ANIM 17
EFFECT 3,0376A,1,30,1
SOUND SND_SPELL_CURE
FINDID.I_RUNE_POISON.REMOVE
FINDID.I_RUNE_POISON_FIELD.REMOVE
MANA -= 25
BEYAZ Resist
ENDIF
ELSEIF (<SRC.FINDID.I_RUNE_SUMMON_CREATURE>) && (<MANA> > 20)
FACE
ANIM 17
SOUND SND_SPELL_DISPEL
SRC.HITS 0
MANA -= 25
MANA (<MANA> - 20)
BEYAZ Dispel
ENDIF
ENDIF
//###################################################//
//########## Inistance LowLevel Npcleri #############//
//###################################################//
[CHARDEF C_INISTANCE_LORD]
ID=C_ORC
NAME=Zindan Lordu
DAM=20,50
ARMOR={10 100}
TEVENTS=E_INISTANCE_EVENT
ON=@CREATE
COLOR=0455
NPC=BRAIN_MONSTER
STR={10 200}
DEX={100 500}
INT={100 300}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={1000 5999}
KARMA={-9998 -9999}
ON=@DEATH
F_INISTANCE_LOOT
[CHARDEF C_INISTANCE_WARRIOR]
ID=C_ORC_W_CLUB
NAME=Zindan Sovalyesi
DAM=20,50
ARMOR={50 150}
TEVENTS=E_INISTANCE_EVENT
ON=@CREATE
COLOR=50
NPC=BRAIN_MONSTER
STR={10 200}
DEX={100 500}
INT={100 300}
SWORDSMANSHIP={1000 2500}
TACTICS={1000 5000}
WRESTLING={1000 2500}
ANATOMY={1000 5000}
ARMSLORE={1000 5000}
PARRYING={1000 5000}
FAME={1000 5999}
KARMA={-9998 -9999}
ITEMNEWBIE=I_KATANA_VANQ
ITEMNEWBIE=I_BLACKROCK_HEATER_SHIELD
ON=@DEATH
F_INISTANCE_LOOT
[CHARDEF C_INISTANCE_MAGE]
ID=C_ORC
NAME=Zindan Buyucusu
DAM=20,50
ARMOR={10 50}
TEVENTS=E_INISTANCE_EVENT
ON=@CREATE
COLOR=025
NPC=BRAIN_MONSTER
STR={10 200}
DEX={100 300}
INT={100 500}
MAGERY={1000 2500}
MEDITATION={1000 5000}
EVALUATINGINTEL={1000 5000}
POISONING={1000 5000}
FAME={1000 5999}
KARMA={-9998 -9999}
ITEMNEWBIE=i_spellbook
ADDSPELL=s_fireball
ADDSPELL=s_energy_bolt
ADDSPELL=s_poison
ADDSPELL=s_flamestrike
ADDSPELL=s_explosion
ADDSPELL=s_curse
ADDSPELL=s_clumsy
ADDSPELL=s_paralyze
ADDSPELL=s_lightning
ON=@DEATH
F_INISTANCE_LOOT
//###################################################//
//############ Inistance Boss Npcleri ###############//
//###################################################//
[CHARDEF C_BOSS_COLOR]
DEFNAME=C_BOSS_COLOR
NAME=Gülyabani
CAN=MT_RUN|MT_WALK
ID=73
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
[CHARDEF C_BOSS_ORUMCEK2]
DEFNAME=C_BOSS_ORUMCEK2
NAME=Örümcek
CAN=MT_RUN|MT_WALK
ID=C_SPIDER_GIANT_2
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
[CHARDEF C_BOSS_ORUMCEK]
DEFNAME=C_BOSS_ORUMCEK
NAME=Karadul
CAN=MT_RUN|MT_WALK
ID=c_spider_lord
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
[CHARDEF C_BOSS_GORIL]
DEFNAME=C_BOSS_GORIL
NAME=Godzilla
CAN=MT_RUN|MT_WALK
ID=C_GORIL
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
[CHARDEF C_BOSS_CRYSTAL]
DEFNAME=C_BOSS_CRYSTAL
NAME=Kristalistik
CAN=MT_RUN|MT_WALK
ID=C_CRYSTAL_GOLEM
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
WRESTLING={1000 2500}
TACTICS={1000 5000}
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
[CHARDEF C_BOSS_DRAGON]
DEFNAME=C_BOSS_DRAGON
NAME=Dragolan
CAN=MT_RUN|MT_WALK
ID=C_DRAGON_SERPENTINE
DAM=200,400
ARMOR=150
TEVENTS=E_BOSS_EVENT
ON=@CREATE
COLOR=07A1
NPC=BRAIN_MONSTER
STR={8000 10000}
DEX={30000 32000}
INT={3000 3200}
MAGERY={1000 2500}
MEDITATION={1000 5000}
EVALUATINGINTEL={1000 5000}
POISONING={1000 5000}
FAME={1000 5999}
KARMA={-9998 -9999}
ITEMNEWBIE=i_spellbook
ADDSPELL=s_fireball
ADDSPELL=s_energy_bolt
ADDSPELL=s_poison
ADDSPELL=s_flamestrike
ADDSPELL=s_explosion
ADDSPELL=s_curse
ADDSPELL=s_clumsy
ADDSPELL=s_paralyze
ADDSPELL=s_lightning
FAME={7000 9999}
KARMA={-9998 -9999}
ON=@DEATH
F_BOSS_LOOT
//###################################################//
//########## Inistance Loot Fonksyonları ############//
[TEMPLATE T_LOOT_INISTANCE_GOLD]
CONTAINER=i_bag
ITEM=I_GOLD,{1000 15000}
[TEMPLATE T_LOOT_INISTANCE_POINT]
CONTAINER=i_bag
ITEM=I_INISTANCE_POINT,{1 5}
//###################################################//
[FUNCTION F_INISTANCE_LOOT]
SERV.NEWITEM T_LOOT_INISTANCE_GOLD
NEW.BOUNCE
SERV.NEWITEM T_LOOT_INISTANCE_GOLD
NEW.BOUNCE
SERV.NEWITEM T_LOOT_INISTANCE_POINT
NEW.BOUNCE
SERV.NEWITEM T_LOOT_INISTANCE_POINT
NEW.BOUNCE
SERV.NEWITEM BACKPACK_MEAGER
NEW.BOUNCE
SERV.NEWITEM LOOT_ORCISH_LORD
NEW.BOUNCE
[FUNCTION F_BOSS_LOOT]
SERV.NEWITEM { I_ELVEN_MACHETE 2 I_DAISHO 2 I_STAFF_BLADED 2 I_PIKE 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_RICH_MAGIC_LOOT 1 I_ELVEN_COMPOSITE_LONGBOW 2 I_MAGICAL_SHORTBOW 2 I_LANCE 2 I_BONE_HARVESTER 2 I_RADIANT_SCIMITAR 2 I_ORNATE_AXE 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_CRESCENT_BLADE 2 I_NUNCHAKU 2 I_MACE_DIAMOND 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 I_RUNE_BLADE 2 I_MACE_WILDSTAFF 2 I_SCEPTER 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 I_TESSEN 2 I_SAI 2 I_TEKAGI 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 I_SWORD_WARCLEAVER 2 I_STAFF_BLADED_DOUBLE 2 I_SCYTHE 2 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
FOR X 1 7
SERV.NEWITEM I_GOLD
NEW.AMOUNT {4000 65000}
NEW.BOUNCE
ENDFOR
SERV.NEWITEM I_BERSERK_CRYSTAL
NEW.BOUNCE
SERV.NEWITEM { I_PURE_MAGE_ROBE 1 I_PURE_WARRIOR_ROBE 1 I_WARLOCK_ROBE 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_PURE_MAGE_ROBE 1 I_PURE_WARRIOR_ROBE 1 I_WARLOCK_ROBE 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_MANA_BOOTS 1 I_STAM_BOOTS 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_MANA_BOOTS 1 I_STAM_BOOTS 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_EGG_OSTARD 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { I_EGG_OSTARD 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_WEAPON_VANQ 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_WEAPON_POWER 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_WEAPON_VANQ 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_WEAPON_POWER 1 RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM { RANDOM_FILTHY_RICH_MAGIC_LOOT 1 RANDOM_RICH_MAGIC_LOOT 1 }
NEW.BOUNCE
SERV.NEWITEM I_INISTANCE_POINT
NEW.AMOUNT {400 1000}
NEW.BOUNCE
//###################################################//
//############# NPC Drop Fonksyonları ###############//
//###################################################//
[FUNCTION F_INISTANCE_MAGE]
SERV.NEWITEM 01EA7
NEW.BOUNCE
NEW.DROP
NEW.TYPE 34
NEW.ATTR 00B0
NEW.AMOUNT 1
NEW.MORE1 C_INISTANCE_MAGE
NEW.MOREP 9999 9999 5
NEW.TIMER 1
[FUNCTION F_INISTANCE_WARRIOR]
SERV.NEWITEM 01EA7
NEW.BOUNCE
NEW.DROP
NEW.TYPE 34
NEW.ATTR 00B0
NEW.AMOUNT 1
NEW.MORE1 C_INISTANCE_WARRIOR
NEW.MOREP 9999 9999 5
NEW.TIMER 1
[FUNCTION F_INISTANCE_LORD]
SERV.NEWITEM 01EA7
NEW.BOUNCE
NEW.DROP
NEW.TYPE 34
NEW.ATTR 00B0
NEW.AMOUNT 1
NEW.MORE1 C_INISTANCE_LORD
NEW.MOREP 9999 9999 5
NEW.TIMER 1
[EOF]
