[comment credits]
This script will add feature to your Forensics skill. When a player uses forensics on a corpse, the player will be able to collect a DNA Sample of the killer. Afterwards the player can convict the killer and send the killer to jail for 25 minutes.
Installation:
-Add the event e_forensics_dna to all your players.
[events e_forensics_dna]
on=@skillselect
if (<serv.skill.<argn1>.key>==forensics)
if !(<rescount i_bottle_empty>)
sysmessage You are missing a <serv.itemdef.i_bottle_empty.name>.
return 1
endif
endif
on=@skillsuccess
if (<serv.skill.<action>.key>==forensics)
if (<rescount i_bottle_empty>)
if (<act.link.ischar>)
serv.newitem=i_bottle_dna
new.link=<act.link.uid>
trysrc <uid> new.bounce
consume 1 i_bottle_empty
message You collect a DNA sample.
else
message You could not find any DNA on the corpse.
endif
else
sysmessage You are missing a <serv.itemdef.i_bottle_empty.name>.
action=-1
return 1
endif
endif
[itemdef i_bottle_dna]
defname=i_bottle_dna
name=DNA Sample
id=i_bottle_red
type=t_bottle_dna
[typedef t_bottle_dna]
on=@dclick
if (<link.ischar>)
src.targetf f_target_dna <link.uid>
else
src.sysmessage The DNA is invalid.
endif
return 1
[function f_target_dna]
if (<argo.ischar>)
if (<argo.uid>==<argn1>)
trysrc <argo.uid> argo.message <name> has matched your DNA!
argo.sysmessage You have been convicted of murder and sentenced to jail for 25 minutes.
trysrc <uid> message You match the DNA!
sysmessage You have convicted <argo.name> of murder and sentenced him to 25 minutes in jail.
serv.newitem=i_memory_dna_convicted
new.tag.p=<argo.p>
argo.equip=<new.uid>
new.timer=<eval 60*25>
else
trysrc <uid> message The DNA was not a match.
endif
else
sysmessage Try matching the DNA to a character.
endif
[itemdef i_memory_dna_convicted]
defname=i_memory_dna_convicted
name=DNA Matched Memory
id=i_memory
type=t_eq_script
on=@create
attr=attr_move_never|attr_invis
on=@equip
src.go jail
on=@unequip
if !(<isempty <tag.p>>)
src.go=<tag0.p>
else
if (<src.notogetflag <src.uid>> > 1)
src.go Serpent's Hold
else
src.go Britain
endif
endif
on=@timer
remove
return 1
[eof]
