[Function f_give_deed] //F_GIVE_DEED dex|str|int 1,2,3,4,5(+?)
NEWITEM i_deed_<STRARG <ARGS>>
NEW.BOUNCE
NEW.MOREY <eval <STREAT <ARGS>>>
[Itemdef i_deed_dex]
ID=i_deed
Type=t_deed_stat
Name=dexterity deed
On=@Create
color=0905
morey=1
[Itemdef i_deed_str]
ID=i_deed
Type=t_deed_stat
Name=strength deed
On=@Create
color=0770
morey=1
[Itemdef i_deed_int]
ID=i_deed
Type=t_deed_stat
Name=intelligence deed
On=@Create
color=0776
morey=1
[Typedef t_deed_stat]
On=@Click
message @95 [+<dmorey> <strarg <name>>]
On=@Dclick
TARGET Select target...
return 1
On=@TargOn_Char
REF1=<SRC.TARG>
LOCAL.STAT=<strsub 7 0 <baseid>>
IF !(<DREF1.TAG0.DEED_<LOCAL.STAT>>)
REF1.TAG0.DEED_<LOCAL.STAT>=<REF1.<LOCAL.STAT>>
ENDIF
LOCAL.OSTAT=<DREF1.TAG0.DEED_<LOCAL.STAT>>
LOCAL.MAX_STAT=<eval <DLOCAL.OSTAT>+((<DLOCAL.OSTAT>*<DDEF.DEED_MAX_<LOCAL.STAT>>)/100)>
IF (<REF1.ISMYPET>) && !(<REF1.ISPLAYER>)
IF (<eval <REF1.<LOCAL.STAT>>+<MOREY>> <= <DLOCAL.MAX_STAT>)
REF1.dTAG0.DEED_<LOCAL.STAT>=<REF1.<LOCAL.STAT>>
REF1.<LOCAL.STAT> +=<MOREY>
SRC.SYSMESSAGE @,,1 <REF1.NAME> isimli bineğe <MOREY> adet <LOCAL.STAT> eklendi, yeni değeri <DREF1.<LOCAL.STAT>>.
REMOVE
ELIF (<REF1.<LOCAL.STAT>> < <DLOCAL.MAX_STAT>)
SRC.SYSMESSAGE @,,1 <REF1.NAME> isimli bineğe <eval <DLOCAL.MAX_STAT>-<REF1.<LOCAL.STAT>>> adet <LOCAL.STAT> eklendi, yeni değeri <DLOCAL.MAX_STAT>.
MOREY -=<eval <DLOCAL.MAX_STAT>-<REF1.<LOCAL.STAT>>>
REF1.<LOCAL.STAT>=<DLOCAL.MAX_STAT>
ELSE
SRC.SYSMESSAGE @,,1 <REF1.NAME> isimli bineğin <LOCAL.STAT> statı zaten en yüksek değere ulaştı.
ENDIF
ELSE
SRC.SYSMESSAGE Bunu sadece size ait olan petlerde kullanabilirsiniz.
ENDIF
Return 1
[Defname MAX_STATS]
//Tüm binekler aynı değere gelemesin diye ayarlar % üzerinden yapılmıştır.
//Buda demek oluyor ki, aşağıdaki değerler %kaç olduğunu belirler.
//50 üzerinden örnek verirsek, %50 artışa kadar izin verilir demektir.
//Yani orjinal olarak 100STR ye sahip bir binek bu deed ile en fazla (100+(100*50/100))=150'ye
//kadar yükseltilebilir anlamına gelir.
//Örneklemek gerekirse, 1000strli bir binek 1500, 5000strli bir binek 7500strye kadar
//yükseltilebilir.
//Aynı mantık dex ve int içinde geçerlidir.
//Statlara özel ayarları aşağıdan yapabilirsiniz. 0 yazarsanız veya // ile kapatısanız,
//Arttırım %0 yani hiç olmayacaktır.
DEED_MAX_STR 50
DEED_MAX_INT 50
DEED_MAX_DEX 50
