UO-Dev Arama


Tüm accountları kontrol et

Yazar: Uur - Andrien
Tarih: 30-08-2015 01:46





Komutla oyuncudaki aktif olan bütün accountlar ve accountların içindeki charları kontrol etmemize yarıyan bi sistem

komutu yazdığımız da ilk çıkan kısım

https://i.hizliresim.com/2kOOGE.png



Bir account seçtiğimizde accountun içindeki charlar

https://i.hizliresim.com/ngbb1B.png


Seçtiğimiz charın bilgileri

https://i.hizliresim.com/XobbaD.png



Arama kısmı ÖRN: test
https://i.hizliresim.com/4kppEq.png



test adında içinde test geçen charları buluyoruz
https://i.hizliresim.com/rV00AP.png


Herhangi test charını seçiyoruz

https://i.hizliresim.com/zVGG84.png


Seçtiğimiz charın bilgilerini

https://i.hizliresim.com/kgMM49.png



Script:
Kod:
[function oyuncular]
sdialog d_oyuncu_panel

[dialog d_oyuncu_panel]
50,50

bozobag 10,10,300,300

dtext 90 285 0481 ARA:
button 60 285 021 022 1 0 100004
dtextentrylimited 130 285 200 20 1152 1 14

local.loop=0
local.page=1
page 1
if !<src.ctag0.oyuncu_panel>
for 1 <eval <serv.accounts>-1>
if (<local.loop> > 10)
local.loop=0
button 275 285 015e1 015e5 0 <eval <local.page>+1> 1
local.page += 1
page <dlocal.page>
button 30 285 015e3 015e7 0 <eval <local.page>-1> 1
endif
local.loop +=1

dtext 60 <eval <hval 25+<local.loop>*20>> 0481 <dlocal._for>. <serv.account.<dlocal._for>.name>
button 30 <eval <hval 25+<local.loop>*20>> 021 022 1 0 <eval <dlocal._for>+1>
endfor
else
dtext 40 13 0481 GERI
button 10 13 021 022 1 0 100003
if !<src.ctag0.oyuncu_panelUID>
for 0 <eval <serv.account.<src.dctag.oyuncu_panel>.chars>-1>
ref2=<serv.account.<src.dctag.oyuncu_panel>.char.<dlocal._for>.uid>
dtext 60 <eval <hval 45+<local.loop>*20>> <qval <ref2.isonline>?63:34> <eval <dlocal._for>+1>.<ref2.name>
button 30 <eval <hval 45+<local.loop>*20>> 021 022 1 0 <eval <dlocal._for>+1>
endfor
else
if !<src.ctag0.oyuncular_Ara>
local.sec <eval <src.ctag0.oyuncu_panelUID>-1>
ref1=<serv.account.<src.dctag.oyuncu_panel>.char.<dlocal.sec>.uid>
else
ref1=<src.ctag0.oyuncular_ara>
endif
dtext 60 40 63 <ref1.name>
dtext 60 70 0481 STR: <ref1.str>
dtext 60 90 0481 DEX: <ref1.DEX>
dtext 60 110 0481 BAKIYE: <f_bolukayir <ref1.dtag.param>>
dtext 60 130 0481 ORTALAMA: <ref1.ortalama>
dtext 60 150 0481 KILLS: <ref1.kills>
dtext 60 170 0481 FAME: <ref1.fame>
dtext 60 190 0481 KARMA: <ref1.karma>
dtext 60 210 0481 GUILD: <qval <ref1.guild>?<ref1.guild.name>:YOK>
dtext 60 230 0481 AILE: <ref1.aile>//<qval <ref1.tag.name.suffix>?<ref1.tag0.name.suffix>:YOK>
dtext 60 250 0850 YANINA GIT
button 30 250 021 022 1 0 100001
dtext 60 270 0850 YANINA GETIR
button 30 270 021 022 1 0 100002
endif
endif

local.lo=0
local.pa=1000
page 1000
for 1 <src.dctag.oyuncular>
ref1=<src.ctag0.oyuncular_uid<dlocal._for>>
if (<local.lo> > 5)
local.lo=0
button 275 285 015e1 015e5 0 <eval <local.pa>+1> 1
local.pa += 1
page <dlocal.pa>
button 30 285 015e3 015e7 0 <eval <local.pa>-1> 1
endif
local.lo +=1
dtext 60 <eval <hval 25+<local.lo>*20>> 0481 <ref1.name>
button 30 <eval <hval 25+<local.lo>*20>> 021 022 1 0 <eval <dlocal._for>+1000000>
endfor


[dialog d_oyuncu_panel button]
on 0
src.ctag0.oyuncu_panel
src.ctag0.oyuncu_panelUID
src.ctag0.oyuncular_ara
on 1 100000
local.bt <eval <dargn>-1>
if !<src.ctag0.oyuncu_panel>
src.ctag0.oyuncu_panel <dlocal.bt>
src.sysm b,<serv.account.<dlocal.bt>.name> bilgileri açılıyor.
else
src.ctag0.oyuncu_panelUID <eval <dlocal.bt>+1>
local.sec <eval <src.ctag0.oyuncu_panelUID>-1>
ref1=<serv.account.<src.dctag.oyuncu_panel>.char.<dlocal.sec>.uid>
src.sysm b,<ref1.name> bilgileri açılıyor.
endif
sdialog d_oyuncu_panel
on 100001
local.sec <eval <src.ctag0.oyuncu_panelUID>-1>
ref1=<serv.account.<src.dctag.oyuncu_panel>.char.<dlocal.sec>.uid>
src.go <ref1.p>
sdialog d_oyuncu_panel
on 100002
local.sec <eval <src.ctag0.oyuncu_panelUID>-1>
ref1=<serv.account.<src.dctag.oyuncu_panel>.char.<dlocal.sec>.uid>
ref1.go <src.p>
sdialog d_oyuncu_panel
on 100003
if <src.ctag0.oyuncular_ara>
src.ctag0.oyuncular_ara
src.ctag0.oyuncu_panelUID
src.ctag0.oyuncu_panel
elif <src.ctag0.oyuncu_panelUID>
src.ctag0.oyuncu_panelUID
elif <src.ctag0.oyuncu_panel>
src.ctag0.oyuncu_panel
endif
sdialog d_oyuncu_panel

on 100004
if <isempty <argtxt1>>
src.sysm k,Boş bırakamazsınız.
return 1
else
src.oyunculariara <argtxt1>
endif

on 1000000 1002000
local.argn <eval <dargn>-1000000>
ref1=<src.ctag0.oyuncular_uid<dlocal.argn>>
src.ctag0.oyuncular_ara <ref1>
src.ctag0.oyuncu_panel 1
src.ctag0.oyuncu_panelUID 5
sdialog d_oyuncu_panel

[function oyunculariara]
src.ctag0.oyuncular 0
for 0 <eval <serv.accounts>-1>
for a 0 <eval <serv.account.<dlocal._for>.chars>-1>
ref1 = <serv.account.<dlocal._for>.char.<dlocal.a>.uid>
if <ref1.isplayer>
if (STRMATCH(*<args>*,'<ref1.name>'))
src.ctag0.oyuncular ++
src.ctag0.oyuncular_uid<src.dctag.oyuncular> <ref1>
src.ctag0.oyuncular_ara 1
endif
endif
endfor
endfor
sdialog d_oyuncu_panel,1000



Yorumlar

Henüz yorum yapılmamıştır.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : Henüz Oylanmamış   
Oylar: 0

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
Sorter Account Sistemi v1.40TheRaskol14-02-2013
Account Master v1.0.10yazoo01-04-2012
Account Remove0aldarson27-06-2010
56b Account Sistemi0Afronola01-03-2010
Account Tag0Amesron26-08-2009


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,