UO-Dev Arama


Rakip oyuncuların bir birlerine karşı bahis üzerine zar atması.

Yazar: MirroR
Tarih: 26-08-2017 16:04





i_Stone_zar taşını oluşturun daha sonra karşılıklı iki oyuncunun taşa katılmasını bekleyin. Sistemi ben yazdım diye söylemiyorum basit ve güzeldir.
Aynı zamanda los önlemine karşı oto zar atma seçeneği vardır.
Rakip oyuncu 15 saniye içerisinde zar atı kullanmaz zar otomatik atılır.
Yüksek atan kazanır.
Daha önceden kullanılmış bir sistem değildir hataları olabilir. İYİCE TEST EDİNİZ.

Menü görselleri için. // Ayrıştırıp kendi gumplarınıza entegre edebilirsiniz.
http://s9.dosya.tc/server3/7uocu5/gumpxx.rar.html

https://i.hizliresim.com/gW3ypb.jpg

https://i.hizliresim.com/r2lRpz.jpg


Kod:
[defname barbut_sys_zar_gump]
_zar 1450,1451,1452,1453,1454,1455 // kırmızı zarlar
_zar_1 11280,11281,11282,11283,11284,11285 // beyaz zarlar

[itemdef i_stone_zar]
id = i_grave_stone
name Barbut
type = t_normal

on=@click
message @0481,,1 Barbut
return 1

on=@create
color = 0481
tag._zar_sirasi = 1

on=@dclick
if (<distance <src>> > 2)
src.sysmessage @34,,1 Uzaksınız.
elif !(<dtag._bahis>)
sdialog d_barbut_bahis
elif (<tag0._1>) && (<tag0._2>)
src.sysmessage @34,,1 Masa dolu.
else
sdialog d_sys_barbut
endif
return 1

on=@timer
ref1 = <tag._1>
ref2 = <tag._2>
local._zar_1 = <R1,6>
local._zar_2 = <R1,6>
if (<dtag._zar_sirasi> == 1)
tag._1_zar_1 = <dlocal._zar_1>
tag._1_zar_2 = <dlocal._zar_2>
tag._1_zar_1_pos_1 = <R65,90>,<R135,180>
tag._1_zar_2_pos_2 = <R110,175>,<R135,180>
tag._zar_sirasi = 2
timer = 15
ref2.sysmessage @,,1 15 saniye içerisinde zar atmalısınız.
elif (<dtag._zar_sirasi> == 2)
tag._2_zar_1 = <dlocal._zar_1>
tag._2_zar_2 = <dlocal._zar_2>
tag._2_zar_1_pos_1 = <R230,250>,<R135,180>
tag._2_zar_2_pos_2 = <R300,365>,<R135,180>
tag._zar_sirasi = 3
local._player_1 = <eval <dtag._1_zar_1>+<dtag._1_zar_2>>
local._player_2 = <eval <dtag._2_zar_1>+<dtag._2_zar_2>>
if (<dlocal._player_1>) && (<dlocal._player_2>)
if (<dlocal._player_1> == <dlocal._player_2>)
tag._kazanan = 1
ref1.newgold = <tag0._bahis>
ref2.newgold = <tag0._bahis>
elif (<dlocal._player_1> > <dlocal._player_2>)
ref1.newgold = <eval <tag0._bahis>*2>
ref2.gold -= <tag0._bahis>
tag._kazanan = <ref1>
elif (<dlocal._player_2> > <dlocal._player_1>)
ref2.newgold = <eval <tag0._bahis>*2>
ref1.gold -= <tag0._bahis>
tag._kazanan = <ref2>
endif
tag._bahis =
endif
endif
ref1.f_senk_dialog <uid>
ref2.f_senk_dialog <uid>
if (<dtag._zar_sirasi> == 3)
cleartags
tag._zar_sirasi = 1
endif
return 1

[dialog d_barbut_bahis]
0,0
resizepic 50 50 1460 260 100
button 61 95 4005 4007 1 0 1
dtext 135 62 0481 Barbut Bahis
gumppic 95 95 2446
textentry 123 97 200 20 1152 0 5000
dtext 273 97 0481 gp's

[dialog d_barbut_bahis button]
on=1
if (<distance <src>> > 2)
return 1
elif !(<isnumeric <argtxt[0]>>)
src.sysmessage @34,,1 Sadece rakam kabul edilebilir.
else
src.sysmessage @044,,1 Yeni bahis: <f_bolukayir <dargtxt[0]>>
tag._bahis = <dargtxt[0]>
src.f_senk_dialog <uid>
endif

[dialog d_sys_barbut]
0,0
noclose
resizepic 50 50 1460 350 200
gumppictiled 61 66 328 50 1467
ebutton 61 61 1 0 0
dhtmlgump 108 66 300 100 0 0 <def.bfont_white>Bahis: <f_bolukayir <dtag0._bahis>>gp's / Kazanana: <f_bolukayir <eval <dtag0._bahis>*2>>gp's<def.br>Tek atış, en yüksek atan kazanır!
ref1 = <tag._1>
ref2 = <tag._2>
if !((<ref1>) || (<ref2>))
button 61 83 4011 4012 1 0 9
else
button 61 83 4008 4009 1 0 10
endif
if !(<tag0._kazanan>)
if !(<ref1>)
dbutton 61 217 1 0 1,Masaya otur.
elif (<ref1> == <src>)
ebutton 61 217 1 0 1,Kalk: <ref1.name>
elif (<ref1> != <src>)
nobutton 61 217,<ref1.name>
endif
if !(<ref2>)
dbutton 228 217 1 0 2,Masaya otur.
elif (<ref2> == <src>)
ebutton 228 217 1 0 2,Kalk: <ref2.name>
elif (<ref2> != <src>)
nobutton 228 217,<ref2.name>
endif
else
endif
gumppictiled 61 172 328 50 1467
gumppictiled 218 112 10 127 1463
if !((<tag0._1_zar_1>) && (<tag0._2_zar_2>)
if (<ref1>) && (<ref2>)
if (<ref1> == <src>)
if (<tag0._zar_sirasi> == 1)
dbutton 100 150 1 0 3,ZAR AT
else
dhtmlgump 240 145 150 100 0 0 <def.bfont_yellow>Rakibinizin zar atması<def.br>bekleniyor..
endif
endif
if (<ref2> == <src>)
if (<tag0._zar_sirasi> == 2)
dbutton 263 150 1 0 3,ZAR AT
else
dhtmlgump 240 145 150 100 0 0 <def.bfont_yellow>Rakibinizin zar atması<def.br>bekleniyor..
endif
endif
endif
endif
if (<tag0._1_zar_1>)
gumppic <getargvx 1,<tag._1_zar_1_pos_1>> <getargvx 2,<tag._1_zar_1_pos_1>> <getargvx <dtag._1_zar_1>,<def._zar_1>>
gumppic <getargvx 1,<tag._1_zar_2_pos_2>> <getargvx 2,<tag._1_zar_2_pos_2>> <getargvx <dtag._1_zar_2>,<def._zar_1>>
dtext 65 190 0481 toplam sayı: <eval <dtag._1_zar_1>+<dtag._1_zar_2>>
endif
if (<tag0._2_zar_1>)
gumppic <getargvx 1,<tag._2_zar_1_pos_1>> <getargvx 2,<tag._2_zar_1_pos_1>> <getargvx <dtag._2_zar_1>,<def._zar_1>>
gumppic <getargvx 1,<tag._2_zar_2_pos_2>> <getargvx 2,<tag._2_zar_2_pos_2>> <getargvx <dtag._2_zar_2>,<def._zar_1>>
dtext 232 190 0481 toplam sayı: <eval <dtag._2_zar_1>+<dtag._2_zar_2>>
endif
if (<tag0._kazanan>)
dtext 61 217 044 Kazanan: <qval (<tag0._kazanan> == 1)?Berabere!:<uid.<tag0._kazanan>.name>>
dtext 228 217 044 Kazanan: <qval (<tag0._kazanan> == 1)?Berabere!:<uid.<tag0._kazanan>.name>>
endif

[dialog d_sys_barbut button]
on=0
ref1 = <tag._1>
ref2 = <tag._2>
if (<ref1>) && (<ref2>)
if ((<ref1>) && (<ref2>)) && ((<ref1> == <src>) || (<ref2> == <src>))
src.sysmessage @34,,1 Şuandan itibaren yarışma bitene kadar masadan kalkamazsınız.
sdialog d_sys_barbut
return 1
endif
endif
if (<ref1> == <src>) || (<ref2> == <src>)
<qval (<ref1> == <src>)?tag._1 = : tag._2 = >
src.sysmessage @34,,1 Masadan ayrıldınız.
endif

on=1
ref1 = <tag._1>
ref2 = <tag._2>
if !(<dtag._bahis>)
src.sysmessage @34,,1 Bahis belirlenmemiş.
sdialog d_sys_barbut
return 1
endif
if (<ref2> == <src>)
src.sysmessage @34,,1 Zaten masaya oturmuş bulunmaktasınız!
elif !(<ref1>)
if !(<src.gold> >= <dtag._bahis>)
src.sysmessage @34,,1 Bahis ücretini karşılayak kacar altınınız yok.
return 1
endif
tag._1 = <src>
src.sysmessage @044,,1 Masaya oturdunuz.
if (<tag0._1> && (<tag0._2>)
src.sysmessage @,,1 15 saniye içerisinde zar atmalısınız.
timer = 15
endif
elif (<ref1> == <src>)
if ((<ref1>) && (<ref2>)) && ((<ref1> == <src>) || (<ref2> == <src>))
src.sysmessage @34,,1 Şuandan itibaren yarışma bitene kadar masadan kalkamazsınız.
else
tag._1 =
src.sysmessage @34,,1 Masadan kalktınız.
endif
elif (<ref1> != <src>)
src.sysmessage @34,,1 <ref1.name>, sizden hızlı davranıp masaya oturmuş!
endif
sdialog d_sys_barbut
if (<ref2>)
ref2.f_senk_dialog <uid>
endif

on=2
ref1 = <tag._1>
ref2 = <tag._2>
if !(<dtag._bahis>)
src.sysmessage @34,,1 Bahis belirlenmemiş.
sdialog d_sys_barbut
return 1
endif
if (<ref1> == <src>)
src.sysmessage @34,,1 Zaten masaya oturmuş bulunmaktasınız!
elif !(<ref2>)
if !(<src.gold> >= <dtag._bahis>)
src.sysmessage @34,,1 Bahis ücretini karşılayak kacar altınınız yok.
return 1
endif
tag._2 = <src>
src.sysmessage @044,,1 Masaya oturdunuz.
if (<tag0._1> && (<tag0._2>)
ref1.sysmessage @,,1 15 saniye içerisinde zar atmalısınız.
timer = 15
endif
elif (<ref2> == <src>)
if ((<ref1>) && (<ref2>)) && ((<ref1> == <src>) || (<ref2> == <src>))
src.sysmessage @34,,1 Şuandan itibaren yarışma bitene kadar masadan kalkamazsınız.
else
tag._2 =
src.sysmessage @34,,1 Masadan kalktınız.
endif
elif (<ref2> != <src>)
src.sysmessage @34,,1 <ref2.name> sizden hızlı davranıp masaya oturmuş!
endif
sdialog d_sys_barbut
if (<ref1>)
ref1.f_senk_dialog <uid>
endif

on=3
ref1 = <tag._1>
ref2 = <tag._2>
local._zar_1 = <R1,6>
local._zar_2 = <R1,6>
if (<ref1> == <src>)
tag._1_zar_1 = <dlocal._zar_1>
tag._1_zar_2 = <dlocal._zar_2>
tag._1_zar_1_pos_1 = <R65,90>,<R135,180>
tag._1_zar_2_pos_2 = <R110,175>,<R135,180>
tag._zar_sirasi = 2
ref2.f_senk_dialog <uid>
timer = 15
ref2.sysmessage @,,1 15 saniye içerisinde zar atmalısınız.
elif (<ref2> == <src>)
timer -1
tag._2_zar_1 = <dlocal._zar_1>
tag._2_zar_2 = <dlocal._zar_2>
tag._2_zar_1_pos_1 = <R230,250>,<R135,180>
tag._2_zar_2_pos_2 = <R300,365>,<R135,180>
local._player_1 = <eval <dtag._1_zar_1>+<dtag._1_zar_2>>
local._player_2 = <eval <dtag._2_zar_1>+<dtag._2_zar_2>>
if (<dlocal._player_1>) && (<dlocal._player_2>)
if (<dlocal._player_1> == <dlocal._player_2>)
tag._kazanan = 1
elif (<dlocal._player_1> > <dlocal._player_2>)
tag._kazanan = <ref1>
ref1.newgold = <eval <tag0._bahis>*2>
ref2.gold -= <tag0._bahis>
elif (<dlocal._player_2> > <dlocal._player_1>)
tag._kazanan = <ref2>
ref2.newgold = <eval <tag0._bahis>*2>
ref1.gold -= <tag0._bahis>
endif
tag._bahis =
endif
ref1.f_senk_dialog <uid>
endif
sdialog d_sys_barbut
if (<ref2> == <src>)
cleartags
tag._zar_sirasi = 1
endif

on=9
if !(<tag0._1>) || (<tag0._2>)
sdialog d_barbut_bahis
endif

on=10
sdialog d_sys_barbut


[function f_senk_dialog]
trysrc <uid> src.dialogclose d_sys_barbut
trysrc <uid> uid.<args>.dialog d_sys_barbut

[function dbutton]
button <strarg <argv[0]>> <strarg <streat <argv[0]>>> 4005 4007 <streat <streat <argv[0]>>>
dtext <eval <strarg <argv[0]>>+34> <eval <strarg <streat <argv[0]>>>+3> 0480 <argv[1]>

[FUNCTION ebutton]
button <strarg <argv[0]>> <strarg <streat <argv[0]>>> 4017 4018 <streat <streat <argv[0]>>>
dtext <eval <strarg <argv[0]>>+32> <eval <strarg <streat <argv[0]>>>+2> 0481 <argv[1]>

[FUNCTION nobutton]
gumppic <strarg <argv[0]>> <strarg <streat <argv[0]>>> 4020 38
dtext <eval <strarg <argv[0]>>+33> <eval <strarg <streat <argv[0]>>>+3> 0481 <argv[1]>

[eof]



Yorumlar

1.   Gönderen paris16   02-10-2017 14:28    

Bunun arka penceresini nasil degisdire biliriz beceremesim ben

2.   Gönderen MirroR   09-10-2017 10:37    

Yapman gereken Resizepic ve Gumppic kodları ile oynaman fakat pencere boyutlarının aynı boyutlarda olmasına özen göstermelisin aksi taktirde zarlar dışarı taşabilir, posizyonları belirli çerçeveye göre ayarlandı.

Oylamalar

Oylama :
Üyelerin oylama ortalaması (10 dışında) : 10.00   
Oylar: 1 den itibaren 02-10-2017 14:28

Benzer Sayfalar

SayfalarYorumlarGönderenTarih
Asalet Sistemi0MirroR29-11-2017
Aile Sistemi0MirroR27-09-2017
Binek Geliştirme Sistemi0MirroR23-08-2016
Aile Sistemi0Flamer21-06-2016
Vendor Master(Ortak Vendor Sistemi-Kaliteli!-SQ...0TestereNecmi06-09-2015


Keywords:

ultima online, RunUO, ultima online download, sphere scripting, role play, uo grafik, second age ultima, uo loop, macroman, pvp server, server kurulumu, sphere, multool, ml mulls, 56b 55r 55i, htmlgumps, client 4x, client edit, sphere release, osi, rp server, sunucular, ghost mouse, inside uo, kingdom reborn, stygian abyss, uo nasıl oynanır, mondain's legacy, age of shadows, world build, grandmaster, ultima online pvp, player dosyaları, ultima online indir, frp game, RunUO 1.0.0, razor, uo rice, hue editör, skill tools, ultima online patch, axis, world build, verdata, verdata patcher, map editör, gump editör, mul patcher, aos mulls, scriptler, anim edit, anim publish, hues mul, hosting vps, event dialog, account sistemi, skill gain, static yapımı,