Mahsuni -  13-06-2021 18:09
https://i.hizliresim.com/kpgnj0g.png


Deed çift Tıklayarak Golemi Aktif Edebilirsiniz.
Golem aktifken Birdaha deed Tıklarsaniz Nerede Olursaniz Olun Golem deed Geri döner.
Eğer golemi Keserlerse ayni Sekillde Golem tekrardan deed dönüş yapar.
-- Ben Golem Olarak tasarladim scpleri Burda siz kendinize göre Daha iyi Bir şekilde geliştirebilirsiniz

Deed Spcsi
Kod:
[itemdef i_golemc]
id i_pet_golem_iron
name Mekanic Golem

on=@create
morex=1

on=@click
if (<dmorex>==1)
message @07a1,1,1 [ <serv.name> ]
message @68,1,1 Pasif Durumda
message @38,1,1 <name>
return 1
endif

if (<dmorex>==2)
message @07a1,1,1 [ <serv.name> ]
message @70,1,1 Aktif Durumda
message @38,1,1 <name>
return 1
endif

on=@dclick
if (<dmorex>==2)
REF1=<src.tag0.elledi>
try uid.<src.tag0.elledi>.remove
src.tag0.elledi=
src.sysmessage @68,1,1 <REF1.name> Silinmiştir
morex=1
return 1
endif

if (<dmorex>==1)
morex=2
attr 010
src.newnpc c_mekanic_golem
new.p <src.p>
src.act.newitem i_memory
src.act.act.attr 04
src.act.act.more1 04
src.act.act.more2 <serv.time>
src.act.act.morep <src.act.p>
src.act.act.color memory_ipet
src.act.act.timer -1
src.act.act.link <src.uid>
src.act.act.cont <src.act.uid>
src.act.flags <src.act.flags>&statf_pet
src.act.update
src.act.anim 6
REF2=<src.act.memoryfindtype.memory_ipet.link>
REF2.TAG0.elledi=<src.act.uid>
new.tag0.bilet=<src.act.memoryfindtype.memory_ipet.link>
src.tag0.tekrar=<uid>
REF2.sysmessage @68,1,1 Başarılı bir şekillde yaratık cıkardınız.
return 1
endif


Golem Scpsi
Kod:
[CHARDEF c_mekanic_golem]
id=c_iron_golem
NAME=Mekanic Golem
ICON=i_pet_golem_iron
SOUND=snd_monster_daemon1
CAN=MT_WALK|MT_USEHANDS
DAM=31,64
ARMOR=35
MAXFOOD=45
RESOURCES=3 i_ore_iron
BLOODCOLOR=-1
SUBSECTION=Mechanical
DESCRIPTION=Iron Golem
RESLEVEL=2
ON=@Create
   COLOR=07a1
   NPC=brain_monster
   FAME={2500 2999}
   KARMA={-2500 -2999}
   STR={251 350}
   MAXHITS={151 210}
   DEX={76 100}
   MAXSTAM={76 100}
   INT={101 150}
   MAXMANA={101 150}
   MAGICRESISTANCE={150.0 190.0}
   TACTICS={60.0 100.0}
   WRESTLING={60.0 100.0}
   RESPHYSICAL={0 20}
   RESCOLD={10 30}
   RESENERGY={30 40}
   RESFIRE=100
   RESPOISON={10 25}

on=@click
IF !(<memoryfindtype.memory_ipet>)
message @38,1,1 [ Sahipsiz ]
message @07a1,1,1 <name>
return 1
endif

IF (<memoryfindtype.memory_ipet>)
message @38,1,1 [ Sahibi : <memoryfindtype.memory_ipet.name> ]
message @07a1,1,1 <name>
return 1
endif


on=@death
REF2=<findid.i_memory.link>
REF2.sysmessage @68,1,1 Npcniz Tekrardan Deed Geri dönüştür.
try uid.<ref2.tag0.tekrar>.morex=1
try uid.<ref2.tag0.tekrar>.attr=0
remove
return 1
Henüz yorum yapılmamış.


Üyelerin oylama ortalaması (10 dışında) : 7.50   
Oylar: 4 den itibaren 14-06-2021 05:52

BENZER SAYFALAR