Bilinmiyor -  29-07-2009 18:03
Kod:
//****************************************************************************
// Dancing Sword
// this sword leaves the hand of the wielder when dclicked
// and fights on its own for 15 seconds. after that, it
// will return to the wielders hands.
//****************************************************************************

[ITEMDEF i_dancing_sword]
ID=i_sword_long
NAME=dancing sword
TYPE=T_WEAPON_SWORD
FLIP=0
DAM=4,26
SKILL=Swordsmanship
REQSTR=25
TWOHANDS=N
WEIGHT=8
RESOURCES=8 i_ingot_iron
SKILLMAKE=BLACKSMITHING 60.0
ON=@Create
HITPOINTS={31 110}
ON=@DClick
SRC.MESSAGE The weapon leaves your hands.
SRC.NEWNPC c_dancing_sword
VAR.DancingSwordUID=<SRC.ACT.UID>
// set attributes to that of SRC
SRC.ACT.STR=<SRC.STR>
SRC.ACT.DEX=<SRC.DEX>
SRC.ACT.INT=<SRC.INT>
SRC.ACT.WRESTLING=<SRC.SWORDSMANSHIP>
SRC.ACT.TACTICS=<SRC.TACTICS>
// tell it it works for SRC
SRC.NEWITEM=i_memory
SRC.ACT.COLOR=memory_ipet
SRC.ACT.LINK=<SRC.UID>
SRC.ACT.LAYER=layer_special
SRC.ACT.CONT=<VAR.DancingSwordUID>
// add a remove timer (15 seconds)
SRC.NEWITEM=i_ds_remove_timer
SRC.ACT.TIMER=15
SRC.ACT.LINK=<SRC.UID>
SRC.ACT.MORE1=<BASEID>
SRC.ACT.CONT=<VAR.DancingSwordUID>
REMOVE
RETURN 1

[ITEMDEF i_ds_remove_timer]
NAME=Link Remove Timer
ID=i_worldgem_bit
TYPE=T_EQ_SCRIPT
WEIGHT=0
LAYER=layer_special
ON=@Create
ATTR=080
ON=@Timer
LINK.MESSAGE The weapon returns into your hands.
LINK.NEWITEM=<EVAL (<MORE1>&0FFFFFF)>
LINK.ACT.CONT=<LINK.UID>
CONT.REMOVE
REMOVE
RETURN 1

[CHARDEF c_dancing_sword]
ID=c_sword
NAME=Dancing Sword
CAN=MT_WALK|MT_RUN|MT_FLY|MT_FIRE_IMMUNE
DAM=4,14
ARMOR=10
ON=@Create
NPC=brain_animal
FAME=0
KARMA=0
STR=100
DEX=100
INT=100
TACTICS={30.0 40.0}
WRESTLING={30.0 40.0}
MAGICRESISTANCE=100.0
ON=@GetHit
RETURN 1
ON=@Spelleffect
RETURN 1

//****************************************************************************

[EOF]

YORUMLAR (0)

Henüz yorum yapılmamış.

BENZER SAYFALAR