Kod: [PLEVEL 2]
PG
[PLEVEL 7]
PAGE
[FUNCTION pg]
IF !(<SERV.GMPAGES>)
SYSMESSAGE @,,1 Hiç page yok.
RETURN 1
ENDIF
IF (STRMATCH('<ARGS>','w') || (STRMATCH('<ARGS>','wipe')
IF (<ISPGHANDLED>)
SYSMESSAGE @,,1 Şu anda ilgilenilen pageler var.
RETURN 1
ENDIF
IF (<ACCOUNT.PLEVEL> >= 4)
PAGE wipe
SERV.ALLCLIENTS F_STAFF_MSG Bütün pageler silindi.
ELSE
SYSMESSAGE @,,1 Bunu yapabilmek için en az gamemaster olmalısınız.
ENDIF
RETURN 1
ENDIF
IF !(<TAG0.PGHANDLE>)
SDIALOG d_gmpg
RETURN 1
ENDIF
IF (<TAG0.PGHANDLE>)
REF1=<STRARG <SERV.GMPAGE.<EVAL <TAG.PGHANDLE> - 1>.REASON>>
IF (STRMATCH('<ARGS>','d') || (STRMATCH('<ARGS>','delete')
PAGE delete
TAG.PGHANDLE
ELSEIF (STRMATCH('<ARGS>','g') || (STRMATCH('<ARGS>','go')
GO <REF1.P>
ELSEIF (STRMATCH('<ARGS>','s') || (STRMATCH('<ARGS>','summon')
REF1.SUMMONTO
ELSEIF (STRMATCH('<ARGS>','j') || (STRMATCH('<ARGS>','jail')
IF (<REF1.ACCOUNT.PLEVEL> > 1)
SYSMESSAGE @,,1 :(
RETURN 1
ENDIF
SERV.NEWITEM i_jail_timer
NEW.TIMER <EVAL <DEF0.JAIL_PAGE> * 60 * 60>
NEW.TAG.SUC page
REF1.EQUIP <NEW>
SYSMESSAGE @,,1 <REF1.NAME>, <DEF0.JA_PAGE> suçundan jaillanmıştır.
PAGE delete
TAG.PGHANDLE
ELSEIF (STRMATCH('<ARGS>','m') || (STRMATCH('<ARGS>','message')
REF1.SDIALOG d_pgmsg
ELSEIF (STRMATCH('<ARGS>','o') || (STRMATCH('<ARGS>','origin')
GO <SERV.GMPAGE.<EVAL <TAG.PGHANDLE> - 1>.P>
ELSEIF (STRMATCH('<ARGS>','q') || (STRMATCH('<ARGS>','queue')
PAGE undo
TAG.PGHANDLE
ELSE
SYSMESSAGE @,,1 .pg (D)elete
SYSMESSAGE @,,1 .pg (G)o
SYSMESSAGE @,,1 .pg (J)ail
SYSMESSAGE @,,1 .pg (M)essage
SYSMESSAGE @,,1 .pg (O)rigin
SYSMESSAGE @,,1 .pg (Q)ueue
IF (<ACCOUNT.PLEVEL> >= 4)
SYSMESSAGE @,,1 .pg (W)ipe
ENDIF
ENDIF
ENDIF
[DIALOG d_gmpg]
70,70
nomove
resizepic 0 0 5054 425 <GETPGDIALOGSIZE>
gumppictiled 10 10 405 <EVAL <GETPGDIALOGSIZE> - 20> 2624
checkertrans 10 10 405 <EVAL <GETPGDIALOGSIZE> - 20>
FOR <TAG0.PG> <EVAL <TAG0.PG> + 4>
IF (STRCMP('<SERV.GMPAGE.<dLOCAL._FOR>.REASON>','0')
REF1=<STRARG <SERV.GMPAGE.<dLOCAL._FOR>.REASON>>
dtext 30 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 15> 1153 <REF1.NAME> (<SERV.GMPAGE.<dLOCAL._FOR>.ACCOUNT>): <EVAL (<SERV.GMPAGE.<dLOCAL._FOR>.TIME> / 60> dk <QVAL <SERV.GMPAGE.<dLOCAL._FOR>.HANDLED> ? <UID.<EVAL <SERV.GMPAGE.<dLOCAL._FOR>.HANDLED>>.NAME> ilgileniyor:>
dhtmlgump 30 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 35> 300 65 1 0 <STREAT <SERV.GMPAGE.<dLOCAL._FOR>.REASON>>
IF !(<SERV.GMPAGE.<dLOCAL._FOR>.HANDLED>)
button 335 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 27> 4006 4007 1 0 <EVAL <LOCAL._FOR> + 1> // go
button 370 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 27> 4015 4014 1 0 <EVAL <LOCAL._FOR> + 21> // summon
button 335 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 52> 4018 4017 1 0 <EVAL <LOCAL._FOR> + 41> // delete
button 370 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 52> 4003 4004 1 0 <EVAL <LOCAL._FOR> + 61> // jail
button 335 <EVAL ((<LOCAL._FOR> - <TAG0.PG>) * 90) + 77> 4012 4011 1 0 <EVAL <LOCAL._FOR> + 81> // msg
ENDIF
ENDIF
ENDFOR
IF (<SERV.GMPAGES> > <EVAL <TAG0.PG> + 5>)
button 380 <EVAL (<GETPGDIALOGSIZE> - 32)> 4006 4007 1 0 101
ENDIF
IF (<EVAL <TAG0.PG> - 5> >= 0)
button 30 <EVAL (<GETPGDIALOGSIZE> - 32)> 4015 4014 1 0 102
ENDIF
[DIALOG d_gmpg BUTTON]
ON=1 20
TRY GMPAGE.<EVAL <ARGN1> - 1>.HANDLE
TAG.PGHANDLE <ARGN1>
PG go
ON=21 40
TRY GMPAGE.<EVAL <ARGN1> - 21>.HANDLE
TAG.PGHANDLE <EVAL <ARGN1> - 20>
PG summon
ON=41 60
TRY GMPAGE.<EVAL <ARGN1> - 41>.HANDLE
TRY GMPAGE.<EVAL <ARGN1> - 41>.D
ON=61 80
TRY GMPAGE.<EVAL <ARGN1> - 61>.HANDLE
TAG.PGHANDLE <EVAL <ARGN1> - 60>
PG jail
ON=81 100
TRY GMPAGE.<EVAL <ARGN1> - 81>.HANDLE
TAG.PGHANDLE=<EVAL <ARGN1> - 80>
PG message
ON=101
TAG.PG=<EVAL <TAG0.PG> + 5>
PG
ON=102
TAG.PG=<EVAL <TAG0.PG> - 5>
PG
[DIALOG d_pgmsg]
230,160
nomove
page 0
resizepic 0 0 5054 350 304
gumppictiled 10 10 330 284 2624
checkertrans 10 10 330 284
dtext 23 20 1153 <UID.<STRARG <SERV.GMPAGE.<EVAL <SRC.TAG.PGHANDLE> - 1>.REASON>>.NAME> (<SERV.GMPAGE.<EVAL <SRC.TAG.PGHANDLE> - 1>.ACCOUNT>): <EVAL (<SERV.GMPAGE.<EVAL <SRC.TAG.PGHANDLE> - 1>.TIME> / 60> dk
dhtmlgump 23 40 300 65 1 0 <STREAT <SERV.GMPAGE.<EVAL <SRC.TAG.PGHANDLE> - 1>.REASON>>
dtext 23 60 1153 Cevabınız:
resizepic 24 125 3000 300 160
dtextentrylimited 28 130 290 160 1152 1 500 <VAR.BLANK>
button 245 255 4021 4022 1 0 0
button 285 255 4030 4031 1 0 1
[DIALOG d_pgmsg BUTTON]
ON=1
TAG.SENT=<STREAT <SERV.GMPAGE.<EVAL <SRC.TAG.PGHANDLE> - 1>.REASON>>
TAG.PGMSG <UID> <SERV.RTIME> <ARGTXT[1]>
IF (<ISONLINE>)
TRYSRC <UID> SDIALOG d_pgread
ELSE
EVENTS +e_pg_login
ENDIF
SRC.SYSMESSAGE @,,1 Cevabınız yollandı.
SRC.PG d
[DIALOG d_pgread]
0,30
nomove
noclose
nodispose
page 1
button 15 15 30 30 0 2 1
page 2
resizepic 50 50 5120 337 365
button 362 62 3 4 1 0 0
dtext 63 60 1153 Mesajınız Var!
dtext 63 80 1153 Gönderen: <STRARG <DEF.PLEVEL<UID.<STRARG <TAG.PGMSG>>.ACCOUNT.PLEVEL>>> <UID.<STRARG <TAG.PGMSG>>.NAME>
dtext 63 100 1153 Tarih: <STRARG <STREAT <TAG.PGMSG>>> <STRARG <STREAT <STREAT <TAG.PGMSG>>>>
dhtmlgump 65 130 300 160 1 0 <STREAT <STREAT <STREAT <TAG.PGMSG>>>>
dtext 63 310 1153 Atmış olduğunuz page:
dhtmlgump 65 330 300 65 1 0 <TAG.SENT>
[DIALOG d_pgread BUTTON]
ON=0
TAG.SENT=
TAG.PGMSG=
[FUNCTION f_staff_msg]
IF (<ACCOUNT.PLEVEL> > 1)
SYSMESSAGE @69,1,1 <args>
ENDIF
[FUNCTION ispghandled]
FOR 0 <EVAL <SERV.CLIENTS> - 1>
IF (<SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.PLEVEL> > 1)
IF (<SERV.CLIENT.<dLOCAL._FOR>.TAG0.PGHANDLE>)
RETURN 1
ENDIF
ENDIF
ENDIF
RETURN 0
[FUNCTION getpgdialogsize]
FOR <dTAG0.PG> <EVAL <TAG0.PG> + 4>
IF (STRCMP('<SERV.GMPAGE.<dLOCAL._FOR>.REASON>','0')
LOCAL.PAGETODISPLAY += 1
ENDIF
ENDFOR
RETURN <EVAL (<LOCAL.PAGETODISPLAY> * 87) + 53>
[EVENTS e_pg_login]
On=@Login
SYSMESSAGE @,,1 Page'iniz oyunda değilken cevaplandı.
SDIALOG d_pgread
EVENTS -e_pg_login
[DEFNAME plevel]
PLEVEL2 Counselor
PLEVEL3 Seer
PLEVEL4 Gamemaster
PLEVEL5 Developer
PLEVEL6 Admin
PLEVEL7 Owner
|