///////////////////////////////////////////////////////////////////////
// *Scripter Name : -
// *Shard Name : The Rosario Game
// *Shard Address : www.rosario.gen.tr
// *Personal Address : www.raskolserna.com
// *Messenger and E-Mail : [email protected]
// *Sphere Version : Specially 0.56b and maybe other releases
//
// *Bu kodlar TheRaskol tarafından yazılmış veya editlenmiştir.
// *The codes are written or were edited by TheRaskol (Raskol Serna).
///////////////////////////////////////////////////////////////////////
[itemdef i_potion_Shrink]
ID=0f0e
NAME=Potion of Shrink
VALUE=1000
TYPE=T_NORMAL
TDATA1=i_bottle_empty
RESOURCES=250 i_gold,i_reag_batwing 20, i_bottle_EMPTY
SKILLMAKE=ALCHEMY 60.0
CATEGORY=Provisioners - Alchemy
SUBSECTION=Potions
DESCRIPTION=Potion of Shrink
ON=@Create
COLOR=0ba7
ON=@DROPON_CHAR
SAY Binegi kücültmek icin tıklayın
ON=@DCLICK
IF <CONT.UID>!=<SRC.FINDLAYER(21).UID>
SRC.MESSAGE Potion elinizde değil
RETURN 1
ENDIF
IF <AMOUNT>>1
SRC.MESSAGE Bir yaratık secin
RETURN 1
ENDIF
TARGET Neyi küçültmek istiyorsunuz
return 1
ON=@TARGON_ITEM
SRC.SYSMESSAGE Esyalar kücültülmez!
RETURN 1
ON=@TARGON_CHAR
IF (<SRC.TARG.BODY>==c_man) || (<SRC.TARG.BODY>==c_woman) ||
(<SRC.TARG.NPC>==0)
SRC.SYSMESSAGE İnsanları kücültemezsiniz.!
RETURN 1
ELSEIF <src.targ.flags>&statf_conjured
src.sysmessage Yaratıkları kücültemezsiniz
return 1
ELSEIF <src.targ.flags>&statf_war
src.sysmessage Binek çok ac.
return 1
ELSEIF <SRC.TARG.ISMYPET>
if <src.targ.hits>!=<src.targ.str>
src.sysmessage Binek kan kaybetmis
return 1
endif
SRC.NEWITEM=<SRC.TARG.ICON>
SRC.ACT.NAME=<SRC.TARG.NAME>
SRC.ACT.COLOR=<SRC.TARG.COLOR>
SRC.ACT.MORE1=<SRC.TARG.BASEID>
src.act.tag.id=<src.targ.baseid>
src.act.tag.special_pet=01
if <src.targ.str>>700
src.act.tag.str=700
else
src.act.tag.str=<src.targ.str>
endif
src.act.tag.int=<src.targ.int>
src.act.tag.dex=<src.targ.dex>
if <src.targ.hits>><src.targ.str>
src.act.tag.hits=<src.targ.str>
else
src.act.tag.hits=<src.targ.hits>
endif
src.act.tag.mana=<src.targ.mana>
src.act.tag.stam=<src.targ.stam>
src.act.tag.karma=<src.targ.karma>
src.act.tag.fame=<src.targ.fame>
src.act.tag.kills=<src.targ.kills>
src.act.tag.flags=<src.targ.flags>
src.act.tag.food=<src.targ.food>
if <src.targ.parrying>>750
src.act.tag.Parrying=750
else
src.act.tag.Parrying=<src.targ.Parrying>
endif
src.act.tag.Magery=<src.targ.Magery>
src.act.tag.MagicResistance=<src.targ.MagicResistance>
if <src.targ.tactics>>1000
src.act.tag.Tactics=1000
else
src.act.tag.Tactics=<src.targ.Tactics>
endif
src.act.tag.Wrestling=<src.targ.Wrestling>
src.act.tag.Taming=<src.targ.Taming>
SRC.ACT.BOUNCE
SRC.ACT.TYPE=t_pet_shrunk
SRC.TARG.REMOVE
SRC.SYSMESSAGE <SRC.TARG.NAME> is Shrunk and in your Bag!
SRC.CONSUME 1 i_potion_shrink
ELSE
src.sysmessage Bu sizin bineginiz degil!
return 1
ENDIF
[typedef t_pet_shrunk]
on=@dclick
if (!<tag.special_pet>) || (<tag.special_pet>==01) //shrunk pet
src.newnpc=<tag.id>
src.act.name=<name>
src.act.p=<SRC.P>
SRC.act.MOVE 0,-2
src.act.color=<color>
src.act.str=<eval <tag.str>>
src.act.int=<eval <tag.int>>
src.act.dex=<eval <tag.dex>>
src.act.hits=<eval <tag.hits>>
src.act.mana=<eval <tag.mana>>
src.act.stam=<eval <tag.stam>>
src.act.karma=<eval <tag.karma>>
src.act.fame=<eval <tag.fame>>
src.act.kills=<eval <tag.kills>>
src.act.flags=<tag.flags>
src.act.food=<eval <tag.food>>
src.act.Parrying=<eval <tag.Parrying>>
src.act.Magery=<eval <tag.Magery>>
src.act.MagicResistance=<eval <tag.MagicResistance>>
src.act.Tactics=<eval <tag.Tactics>>
src.act.Wrestling=<eval <tag.Wrestling>>
src.act.Taming=<eval <tag.Taming>>
elseif <tag.special_pet>==02 //off vendor
src.newnpc=<tdata3>
src.act.p=<SRC.P>
SRC.act.MOVE 0,-2
endif
src.act.newitem=i_memory//add ownership
src.act.act.color=042
src.act.act.link=<src.uid>
src.act.act.cont <src.act.uid>
src.act.flags=<src.act.flags>|statf_pet
src.act.findlayer(21).remove //remove pack
src.sysmessage <name> has been un-shrunk.
remove
return 1
