Merhaba, bahsettiğim bir konuda geçen oda kiralama sistemini yazmaya başladım. Bu script kimine göre çok basit gelebilir ancak benim için epey bir vakit aldı. Bu konuda bir büyük sorum ve bir kaç küçük sorum var. Vakit ayırıp yorum yapabilen olursa sevinirim.

Sistem işi bilenler için çok basit kaçacaktır; region içindeki yer alan arealar içinde bulunan roomlara kapıyı yerleştiriyorum. Anahtara dclick yapılınca target çıkıyor, seçilenin kiralık kapı olup olmadığını, daha önce kiralanıp kiralanmadığını vesairesini iflerle kontrol edip kiralanmadıysa kiralıyor ve hem kapının hem de anahtarın timerını 1 haftalık başlatıyor. Bu noktada oluşturduğum her odanın (region) ismi farklı. Kapının olduğu bölgeye göre oyuncuya bölgenin taşıdığı eventi taglamaya çalışıyorum (bu doğru olur mu bilmiyorum). Amaç bu noktada başka oyuncu bir şekilde girerse zarar vermesini engellemek bir yandan da room (region olarak) alanını kiralamış oyuncunun kutu gibi basit eşyaları sabitlemesini ve kendisinden başka birinin açamamasını sağlamak. Şu region eventini tag olarak vermeyi veya sorgulatmayı bir türlü beceremedim, odanın adını taglayabiliyorum ancak hem boşluk hem de Türkçe karakterler içerdiği için sorun çıkarabileceği kanısındayım. Tagı almaya çalıştığım yer "SRC.TAG.KIRALANAN.LINK.NAME=<argo.region.name>"

Şu ana kadar sistem sorunsuz çalışıyor gibi görünüyor ancak yine de düzenli çalışıp ilerde sorun açıp açmayacağından emin değilim, şunu şöyle değil de bu şekilde kullanırsan daha iyi olur dediğiniz var mı?

Not: O kadar uğraşmamın sonucunda scriptin bu kadar kısa tutacağını düşünmemiştim

Ek soru: scriptin ilk bir kaç satırında yer alan yorum satırlarımı sildiğimde script çalışmayı bırakıyor, bunun nedeni nedir acaba?

[ITEMDEF I_DOOR_RENTAL]

ID=06dd

NAME=Kiralik Kapi

TYPE=t_door



On=@Create

color=00

attr=attr_static

TAG.KIRACI=0



On=@DClick

if (<TAG.KIRACI> == 0)

SRC.MSJ_HA Bu odayı kiralayabilmek için hancıdan anahtar satın almanız gerekiyor.

RETURN 1

elseif !(<TAG.KIRACI> == <SRC.UID>)

SRC.MSJ_HA Bu oda başka biri tarafından kiralanmış.

RETURN 1

endif



On=@Click

if !(<TAG.KIRACI> == 0)

MESSAGE @42,,1 [<TAG.KIRACI.LINK.NAME>]

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1

else

MESSAGE @42,,1 [Kiralık]

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1

ENDIF



On=@Step

IF !(<SRC.UID>==<TAG.KIRACI>)

SRC.MSJ_HA Bu odayı siz kiralamamışsınız.

RETURN 1

ENDIF



On=@Timer

TAG.KIRACI=0



/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////



[ITEMDEF I_KEY_RENTAL]

ID=I_KEY_GOLD

name=Anahtar

VALUE=5000



ON=@CREATE

TAG.KIRALAR=0

TAG.ROOM.LOCATION=<SRC.REGION.NAME>





On=@Click

IF (<TIMER> > 86400)

	MESSAGE @42,,1 [<EVAL(<TIMER>/86400)> Gün]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

ELIF (<TIMER> < 86400) && (<TIMER> > 3600)

	MESSAGE @42,,1 [<EVAL(<TIMER>)/3600> Saat]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

RETURN 1

ELIF (<TIMER> < 3600)

	MESSAGE @42,,1 [<EVAL(<TIMER>)/60> Dakika]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

RETURN 1

ELSE

	MESSAGE @42,,1 [<TAG.ROOM.LOCATION>]

	MESSAGE @1153,1,1,1 Kiralık Oda Anahtarı

	RETURN 1

ENDIF



ON=@DCLICK

IF !(<TAG.KIRALAR>==0)

	SRC.MSJ_HA Bu anahtar hali hazırda kiralanmış bir odanın anahtarı.

	RETURN 1

ELSE

	SRC.MSJ_NO Hangi odayı kiralamak istiyorsunuz?

	TARGET

	RETURN 1

ENDIF



ON=@TargOn_Item

IF !(<ARGO.BASEID>==I_DOOR_RENTAL)

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1

ELIF (<ARGO.DISTANCE> > 1)

	SRC.MSJ_HA Çok uzaktasınız.

	Return 1

ELIF !(<ARGO.TAG.KIRACI> == <SRC.UID>) && !(<EVAL<TAG.KIRACI>> == 0)

	SRC.MSJ_HA Bu oda daha önce başkası tarafından kiralanmış!

	RETURN 1

ELIF (<ARGO.TAG.KIRACI> == <SRC.UID>)

	SRC.MSJ_HA Bu odayı zaten siz kiralamışsınız!

	RETURN 1

ELSE

	ARGO.TAG.KIRACI = <SRC.UID>

	ARGO.TAG.KIRACI.LINK.NAME = <src.name>

	ARGO.TIMER 6048

	TIMER 6048

	SRC.TAG.KIRALANAN.LINK.NAME=<argo.region.name>

	SRC.MSJ_BA Oda başarıyla 1 hafta için kiralandı.	

	RETURN 1

ENDIF



ON=@TargOn_Char

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1



ON=@TargOn_Ground

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1



[EOF]

Scriptin çalışmamasının büyük ihtimalle sebebi "type>" satırında yer alan fazladan > simgesi. Onu kaldırırsan sorun kalmayacaktır, ama ilk bir kaç satırda yorum yok.

İkinci olarak odayı eğer oyuncu üzerine kayıt edeceksen; ARGO.REGION.NAME Yerine ARGO.ROOM.NAME şeklinde kullanmalısın, ancak her şeyi bu kadar tag üzerinden yapmanı önermem, direkt kapıyı ROOM üzerine TAG olarak ata, mesela TAG.DOOR üzerine (oda içerisindeyken .ROOM.TAG.DOOR KAPIUID yada direkt scriptte room içerisine TAG.DOOR=UID şeklinde) sonrasında oyuncu kiraladığında kapı üzerine oyuncuyu LINK olarak atarsan, kapıyı her açılışta link üzerinden oyuncunun tüm bilgilerine kolaylıkla ulaşabilirsin.

Ha ama yok ben bu kadar yazdım değişmem diyorsan da dedğim gibi ilk kısımdaki gibi ARGO.REGION.NAME yerine ROOMDEF kullandığın için ARGO.ROOM.NAME kullanmalısın, yada ben sorunu tam olarak anlayamadım.

Cevabın için teşekkür ederim. 2-3 defa düzenledim bu mesajı . Kapıyı oyuncuya linkletip, kapının bulunduğu odaya tag vermeyi deneyeceğim. Tekrar atacağım yeni halini bir daha göz gezdirirsen sevinirim.

*Yorum satırında sadece slaşlar vardı 5 satır. Ekleme gereği duymadım.

Bu arada şuan aklıma geldi de yapacağın şeyi yapmanın daha kolay bir yolu daha var, eğer oda eklemek yerine bir custom multi yaratırsan eğer (4 yön için 1er tane oluşturman gerek) doğal olarak multipleri kurup tabela üzerinden sattırabilirsin, böylece insanlar normal ev almış gibi o multileri alabilir ayrıca ev multisinden farklı olmayacağı için de doğal olarak item sabitleme vs otomatik olarak aktif olacaktır. Bu kadar koda da gerek kalmayacak, eğer sunucunda vendor sistemi varsa onu uyarlayabilirsin.

Multilerle uğraşmak daha sıkıcı olur gibi geldi. Bir de var olan yapıları değerlendirmek istiyorum. Şu mantığı tam olarak kavrayabilirsem çok daha renkli sistemler ortaya çıkarabilirim gibi geliyor.


Uyarına uyarak tüm tagları kaldırdım (kalanları da bir şekilde halledeceğim) ve link ile hallettim (Scriptte hatalar olabilir, son kısmı halledene kadar dönmek istemedim ufak şeylere). Ancak yine aynı bölümde takıldım. Kiralama gerçekleştiğinde "ARGO.ROOM.TAG.KIRALANAN = <SRC.UID>" ile hedef alınan objenin bulunduğu room'a UID'i taglatmaya çalıştım. Amacım Region'da ikisini sorgulatarak kiralayan tarafından kutu koyulabilmesini sağlamak. Ancak anladığım kadarıyla hedef alınan objenin bulunduğu bölgeyi değil direkt hedef alınan objeye tagı veriyor (Region'daki if sorgusu şu şekilde; IF !(<ROOM.TAG.KIRALANAN>==<SRC.UID> ) )



Kısacası objenin bulunduğu bölgeye UID'i tag olarak verdirtemedim.

[ITEMDEF I_DOOR_RENTAL]

ID=06dd

NAME=Kiralik Kapi

TYPE=t_door



On=@Create

color=00

attr=attr_static



On=@DClick

IF !(<LINK.UID>) 

SRC.MSJ_HA Kapı kilitli. Bu odayı kiralayabilmek için hancıdan anahtar satın almanız gerekiyor.

RETURN 1

ELIF !(<LINK.UID> == <SRC.UID>)

SRC.MSJ_HA Bu oda başka biri tarafından kiralanmış.

RETURN 1

ELIF (<LINK.UID> == <SRC.UID>)

SRC.MSJ_BA Odanızın kapısını açtınız.

RETURN 0

ENDIF



On=@Click

if (<LINK.UID>)

MESSAGE @42,,1 [<LINK.NAME>]

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1

else

MESSAGE @42,,1 [Kiralık]

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1

ENDIF



On=@Step

IF !(<SRC.UID>==<<LINK.UID>>)

SRC.MSJ_HA Bu odayı siz kiralamamışsınız.

RETURN 1

ENDIF



On=@Timer

LINK.UID = 0



/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////

/////////////////////////////////////////



[ITEMDEF I_KEY_RENTAL]

ID=I_KEY_GOLD

name=Anahtar

VALUE=5000



ON=@CREATE

TAG.KIRALAR=0

TAG.ROOM.LOCATION=<SRC.REGION.NAME>



On=@Click

IF (<TIMER> > 86400)

	MESSAGE @42,,1 [<EVAL(<TIMER>/86400)> Gün]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

ELIF (<TIMER> < 86400) && (<TIMER> > 3600)

	MESSAGE @42,,1 [<EVAL(<TIMER>)/3600> Saat]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

RETURN 1

ELIF (<TIMER> < 3600) && (<TIMER> > 0)

	MESSAGE @42,,1 [<EVAL(<TIMER>)/60> Dakika]

	MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

	RETURN 1

RETURN 1

ELSE

	MESSAGE @42,,1 [<TAG.ROOM.LOCATION>]

	MESSAGE @1153,1,1,1 Kiralık Oda Anahtarı

	RETURN 1

ENDIF



ON=@DCLICK

IF !(<TAG.KIRALAR>==0)

	SRC.MSJ_HA Bu anahtar hali hazırda kiralanmış bir odanın anahtarı.

	RETURN 1

ELSE

	SRC.MSJ_NO Hangi odayı kiralamak istiyorsunuz?

	TARGET

	RETURN 1

ENDIF



ON=@TargOn_Item

IF !(<ARGO.BASEID>==I_DOOR_RENTAL)

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1

ELIF (<ARGO.DISTANCE> > 1)

	SRC.MSJ_HA Çok uzaktasınız.

	Return 1

ELIF (<ARGO.LINK.UID>) && !(<ARGO.LINK.UID> == <SRC.UID>) 

	SRC.MSJ_HA Bu oda daha önce başkası tarafından kiralanmış!

	RETURN 1

ELIF (<ARGO.LINK.UID> == <SRC.UID>)

	SRC.MSJ_HA Bu odayı zaten siz kiralamışsınız!

	RETURN 1

ELSE

	ARGO.LINK = <SRC.UID>

	ARGO.TIMER 6048

	TIMER 6048

	ARGO.ROOM.TAG.KIRALANAN = <SRC.UID>

	SRC.MSJ_BA Oda başarıyla 1 hafta için kiralandı.	

	TAG.KIRALAR = 1

	RETURN 1

ENDIF



ON=@TargOn_Char

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1



ON=@TargOn_Ground

	SRC.MSJ_HA Bunu kiralayamazsınız.

	RETURN 1



[EOF]

[ITEMDEF I_DOOR_RENTAL]

ID=06dd

NAME=Kiralik Kapi

TYPE=t_door



On=@Create

color=00

attr=attr_static

IF (<ROOM>)

  ROOM.TAG.DOOR = <UID>

ENDIF



On=@DClick

IF !(<LINK>)

  SRC.MSJ_HA Kapı kilitli. Bu odayı kiralayabilmek için hancıdan anahtar satın almanız gerekiyor.

  RETURN 1

ELIF (<LINK> != <SRC>)

  SRC.MSJ_HA Bu oda başka biri tarafından kiralanmış.

  RETURN 1

ELSE

  SRC.MSJ_BA Odanızın kapısını açtınız.

ENDIF



On=@Click

IF (<LINK>)

  MESSAGE @42,,1 [<LINK.NAME>]

ELSE

  MESSAGE @42,,1 [Kiralık]

ENDIF

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1



On=@Step

IF (<SRC> != <LINK>)

  SRC.MSJ_HA Bu odayı siz kiralamamışsınız.

  RETURN 1

ENDIF



On=@Timer

LINK = 0fffffff //Kapının linkini sıfırlayalım.

REF1=<UID>

FORINSTANCE i_key_rental //Kapı süresi bitince, kapıya bağlı tüm anahtarları silelim.

  IF (<LINK> == <REF1>)

    REMOVE

  ENDIF

ENDFOR



/////////////////////////////////////////



[ITEMDEF I_KEY_RENTAL]

ID=I_KEY_GOLD

NAME=Anahtar

VALUE=5000



On=@Click

IF (<TIMER> > 86400)

  MESSAGE @42,,1 [<EVAL(<TIMER>/86400)> Gün]

  MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

  RETURN 1

ELIF (<TIMER> < 86400) && (<TIMER> > 3600)

  MESSAGE @42,,1 [<EVAL(<TIMER>)/3600> Saat]

  MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

  RETURN 1

ELIF (<TIMER> < 3600) && (<TIMER> > 0)

  MESSAGE @42,,1 [<EVAL(<TIMER>)/60> Dakika]

  MESSAGE @1153,1,1,1 <TAG.ROOM.LOCATION>

  RETURN 1

ELSE

  MESSAGE @42,,1 [<LINK.NAME>]

  MESSAGE @1153,1,1,1 Kiralık Oda Anahtarı

  RETURN 1

ENDIF



ON=@DCLICK

IF (<LINK.TYPE> == t_door)

  SRC.MSJ_HA Bu anahtar hali hazırda kiralanmış bir odanın anahtarı.

  RETURN 1

ELSE

  SRC.MSJ_NO Hangi odayı kiralamak istiyorsunuz?

  TARGET

  RETURN 1

ENDIF



ON=@TargOn_Item

IF (<ARGO.BASEID> != I_DOOR_RENTAL)

  SRC.MSJ_HA Bunu kiralayamazsınız.

  RETURN 1

ELIF (<SRC.DISTANCE <ARGO>> > 1)

  SRC.MSJ_HA Çok uzaktasınız.

  RETURN 1

ELIF (<ARGO.LINK.isPlayer>)

  SRC.MSJ_HA Bu oda daha önce başkası tarafından kiralanmış!

  RETURN 1

ELIF (<ARGO.LINK> == <SRC>)

  SRC.MSJ_HA Bu odayı zaten siz kiralamışsınız!

  RETURN 1

ELSE

  LINK=<ARGO>

  ARGO.LINK = <SRC>

  ARGO.TIMER 6048

  SRC.MSJ_BA Oda başarıyla 1 hafta için kiralandı.

  //REMOVE //Benim tavsiyem anahtarı silmen çünkü zaten kiraladıktan sonra kapının üzerine senin verilerin kayıt olacak süre boyunca yani anahtar kullanışsız.

  RETURN 1

ENDIF



ON=@TargOn_Char

SRC.MSJ_HA Bunu kiralayamazsınız.

RETURN 1



ON=@TargOn_Ground

SRC.MSJ_HA Bunu kiralayamazsınız.

RETURN 1



[EOF]

Göz kararı şu tarz bir düzenleme yaptım, onun dışında eğer başka bir yerden sahiplik kontrol edeceksen;

Atıyorum ki bir kutuya hedef alınınca o kutunun bulunduğu yerin sahibini çekmek için;

//ARGO burda kutunun uidi (hedef)

REF1=<ARGO.ROOM.TAG.DOOR>

IF (<REF1.LINK> == <SRC>) //<SRC> burada oyuncunun uidi

Yada oyuncu adını çekeceksen;

REF1=<ARGO.ROOM.TAG.DOOR>

SYSMESSAGE <REF1.LINK.NAME>

DIPNOT: Kapının kayıt olması için önce kapıyı bir kere kaldırıp oda içerisinde tekrardan oluşturmalısın.

Teşekkürler xwerswoodx. Son hali şu şekilde ve sorunsuz şekilde iş görüyor.

[ITEMDEF I_DOOR_RENTAL]

ID=06dd

NAME=Kiralik Kapi

TYPE=t_door



On=@Create

color=00

attr=attr_static

IF (<ROOM>)

  ROOM.TAG.DOOR = <UID>

ENDIF



On=@DClick

IF !(<LINK>)

  SRC.MSJ_HA Kapı kilitli. Bu odayı kiralayabilmek için hancıdan anahtar satın almanız gerekiyor.

  RETURN 1

ELIF (<LINK> != <SRC>)

  SRC.MSJ_HA Bu oda başka biri tarafından kiralanmış.

  RETURN 1

ELSE

  SRC.MSJ_BA Odanızın kapısını açtınız.

ENDIF



On=@Click

IF (<LINK.UID>)

  MESSAGE @42,,1 [<LINK.NAME>]

ELSE

  MESSAGE @42,,1 [Kiralık]

ENDIF

MESSAGE @1153,1,1,1 Kiralık Oda

RETURN 1



On=@Step

IF (<SRC> != <LINK>)

  SRC.MSJ_HA Bu odayı siz kiralamamışsınız.

  RETURN 1

ENDIF



On=@Timer

LINK = 0fffffff //Kapının linkini sıfırlayalım.

ROOM.TAG.DOOR = <UID>



/////////////////////////////////////////



[ITEMDEF I_KEY_RENTAL]

ID=I_KEY_GOLD

NAME=Anahtar

VALUE=5000



On=@Click

  MESSAGE @42,,1 [<TAG.ROOM.LOCATION>]

  MESSAGE @1153,1,1,1 Kiralık Oda Anahtarı

 RETURN 1





ON=@DCLICK

  SRC.MSJ_NO Hangi odayı kiralamak istiyorsunuz?

  TARGET

  RETURN 1



ON=@TargOn_Item

IF (<ARGO.BASEID> != I_DOOR_RENTAL)

  SRC.MSJ_HA Bunu kiralayamazsınız.

  RETURN 1

ELIF (<SRC.DISTANCE <ARGO>> > 1)

  SRC.MSJ_HA Çok uzaktasınız.

  RETURN 1

ELIF (<ARGO.LINK.isPlayer>)

  SRC.MSJ_HA Bu oda daha önce başkası tarafından kiralanmış!

  RETURN 1

ELIF (<ARGO.LINK> == <SRC>)

  SRC.MSJ_HA Bu odayı zaten siz kiralamışsınız!

  RETURN 1

ELSE

  LINK = <ARGO>

  ARGO.LINK = <SRC>

  ARGO.TIMER 5

  ROOM.TAG.DOOR = <SRC.UID>

  SRC.MSJ_BA Oda başarıyla 1 hafta için kiralandı.

  REMOVE 

  RETURN 1

ENDIF



ON=@TargOn_Char

SRC.MSJ_HA Bunu kiralayamazsınız.

RETURN 1



ON=@TargOn_Ground

SRC.MSJ_HA Bunu kiralayamazsınız.

RETURN 1



[FUNCTION KUTUKOY]

IF (<ROOM.TAG.DOOR> == <SRC.UID>)

src.MSJ_BA Kutuyu koyabilirim.

ELSE

src.MSJ_HA Kutuyu koyamam.

ENDIF

[EOF]

Kutukoy kısmı hatalı olmuş, kutu koy kısmı şöyle olmalı;

[FUNCTION KUTUKOY]

IF (<UID.<ROOM.TAG.DOOR>.LINK> == <SRC>)

  SRC.MSJ_BA Kutuyu koyabilirim.

ELSE

  SRC.MSJ_HA Kutuyu koyamam.

ENDIF

ROOM.TAG.DOOR = <SRC.UID>

Bu kısmı da kaldırmalısın, kapıyı tekrardan odanın içinde oluştur osnra. Room üzerine kapıyı kayıt edip, oyuncuyu kapı üzerinden çekmelisin.